DNB      TITLE '   IHEDNB    ARITHMETIC TO BIT STRING DIRECTOR         *00700013
               O/S 360 PL/1 LIBRARY'                                    01400013
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  02100013
*                                                                       02800013
*   STATUS     CHANGE LEVEL - 0                                         03500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DNB000-TSS 03700001
*        ----------------------------------------------------DNB000-TSS 03900001
*                                                                       04200013
*   SIZE       216 BYTES                                                04900013
*                                                                       05600013
*   FUNCTION   TO CONVERT ANY ARITHMETIC DATA TYPE TO A FIXED OR        06300013
*              VARYING LENGTH BIT STRING.                               07000013
*                                                                       07700013
*   ENTRY POINTS                                                        08400013
*              IHEDNBA                                                  09100013
*                 RA = A(SOURCE)                                        09800013
*                 RB = A(SOURCE DED)                                    10500013
*                 RC = A(TARGET DOPE VECTOR)                            11200013
*                 RD = A(TARGET DED)                                    11900013
*                                                                       12600013
*   INPUT      N/A                                                      13300013
*                                                                       14000013
*   OUTPUT     N/A                                                      14700013
*                                                                       15400013
*   EXTERNAL MODULES                                                    16100013
*              IHEDMA - ARITHMETIC CONVERSION DIRECTOR                  16800013
*              IHEVSA - BIT STRING ASSIGNMENT MODULE                    17500013
*                                                                       18200013
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              18900013
*                                                                       19600013
*   TABLES/WORKAREA                                                     20300013
*              WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)         21000013
*   ATTRIBUTES,READ ONLY AND REENTRANT                                  21700013
*                                                                       22400013
*   PRIVATE MACROS                                                      23100013
*              IHELIB,IHEPRV,IHESDR                                     23800013
*                                                                       24500013
*   ASSEMBLY REQUIREMENTS                                               25200013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   25900013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        26600013
*                                                                       27300013
*   NOTES      SEE O/S360 PL/1 LIBRARY PLM FOR LIBRARY MODULE           28000013
*              CONVENTIONS AND STANDARDS                                28700013
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON        29400013
*              A PARTICULAR INTERNAL REPRESENTATION OF THE              30100013
*              EXTERNAL CHARACTER SET.                                  30800013
         EJECT                                                          31500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DNB001-TSS 31800001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   32200013
         PUNCH     ' LIBRARY *(IHEDMAA)                                /32900013
                                    DNB0000A'                           33600013
*        ----------------------------------------------------DNB001-TSS 33900001
         SPACE                                                          34300013
IHEDNB   CSECT                                                          35000013
         IHELIB                                                         35700013
IHEZLW2  DSECT                                                          36400013
         DS    15D                                                      37100013
WORK     EQU   IHEZLW2                                                  37800013
IHEDNB   CSECT                                                          38500013
         ENTRY IHEDNBA                                                  39200013
         USING *,RJ                                                     39900013
         USING IHEZLCA,WR                                               40600013
         USING IHEZLW2,DR                                               41300013
IHEDNBA  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          42000013
         IHESDR LW2,WR                  UPDATE SAVE AREA POINTER        42700013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  43400013
         LR    RJ,BR                    TRANSFER BASE REGISTER          44100013
         STM   RC,RD,PSAVE              SAVE TARGET PARAMETERS          44800013
GETPR    SR    RF,RF                    GET SOURCE                      45500013
         IC    RF,1(RB)                 PRECISION                       46200013
         TM    0(RB),FIXD               SOURCE SCALE FIXED              46900013
         BZ    CALCP                    YES BRANCH                      47600013
TESTB    TM    0(RB),BINY               SOURCE BASE BINARY              48300013
         BZ    SETPN                    NO,BRANCH                       49000013
COMPR    CH    RF,K031                  RESULTING PRECISION GREATER 31  49700013
         BNH   CONVT                    NO,BRANCH                       50400013
         LA    RF,31                    SET PRECISION EQUAL TO 31       51100013
CONVT    EQU   *                                                  18372 51300017
         TM    0(RB),X'C0'         IS SOURCE CHAR FORM OF ARITH?  18372 51500017
         BNO   NOTCHAR             NO BRANCH ROUND                18372 51700017
         IHEPRV ERR,BR,OP=LA       ELSE SET ERROR CODE IN CASE    18372 51900017
         OI    1(BR),X'04'                       OF ERROR         18372 52100017
NOTCHAR  EQU   *                                                  18372 52300017
         BNE   MVIFB                    NO.                             52500013
         CLI   2(RB),XNIL               SOURCE FIXED BINARY INTEGER..   53200013
         BNE   MVIFB                    NO.                             53900013
         TM    0(RB),HWRD         TEST DED FOR HALF WORD                54100001
         BO    LOADH                                                    54300001
         L     RG,0(RA)           LOAD FULL_WORD SOURCE                 54500001
         B     NODMA                                                    54700001
LOADH    LH    RG,0(RA)           LOAD HALF WORD SOURCE                 54900001
         B     NODMA                    SKIP OVER CONVERSION.           55300013
MVIFB    MVI   PSAVE+8,FXBD             STORE DED FLAG BYTE.            56000013
         STC   RF,PSAVE+9               STORE PRECISION                 56700013
         MVI   PSAVE+10,XNIL            STORE SCALE FACTOR              57400013
         LA    RD,PSAVE+8               LOAD ADDRESS OF DED             58100013
         LA    RC,PSAVE+12              LOAD ADDRESS OF FIELD           58800013
CALLD    L     BR,DMAA                  LOAD BRANCH ADDRESS             59500013
         BALR  LR,BR                    CALL ARITH CONVERSION DIRECTOR  60200013
         L     RG,PSAVE+12              LOAD FIXED BINARY RESULT        60900013
NODMA    C     RG,MXNG                  COMPARE WITH MAXIMUM NEGATIVE.  61600013
         BE    NOSET                                                    62300013
         LPR   RG,RG                    SET POSITIVE                    63000013
NOSET    LCR   RH,RF                    COMPLEMENT PRECISION.           63700013
         SLL   RG,32(RH)                LEFT ADJUST P BITS              64400013
         ST    RG,PSAVE+12              STORE BIT STRING                65100013
         LA    RG,PSAVE+12              GET ADDRESS OF CREATED BIT STR. 65800013
         ST    RG,PSAVE+16              STORE ADDRESS IN DOPE VECTOR    66500013
SETPS    STH   RF,PSAVE+22              STORE CURRENT LENGTH IN DOPE V  67200013
         LA    RA,PSAVE+16              LOAD ADDRESS OF DOPE VECTOR     67900013
STDED    LA    RB,BITD                  LOAD ADDRESS OF BIT STRING DED  68600013
         LM    RC,RD,PSAVE              RESTORE TARGET PARAMETERS       69300013
         L     BR,VSAA                  LOAD BRANCH ADDRESS             70000013
         BALR  LR,BR                    CALL BIT STRING ASSIGNMENT RTN  70700013
RESET    L     DR,OFDR(DR)              RESET SAVE AREA POINTER         71400013
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       72100013
         BR    LR                       RETURN                          72800013
CALCP    SR    RG,RG                    CLEAR REGISTER                  73500013
         ST    RG,PSAVE+20              SET CURRENT LENGTH ZERO         74200013
         IC    RG,2(RB)                 GET SCALE FACTOR Q              74900013
         SH    RG,K128                  REMOVE EXCESS                   75600013
         SR    RF,RG                    CALCULATE (P-Q)                 76300013
         BP    TESTB                    BRANCH POSITIVE                 77000013
         LA    RG,PSAVE+12              GET ADDRESS OF STRING           77700013
         ST    RG,PSAVE+16              STORE ADDRESS IN DOPE VECTOR    78400013
         LA    RA,4(RG)                 LOAD ADDRESS OF DOPE VECTOR     79100013
         B     STDED                                                    79800013
SETPN    MH    RF,K332                  MULTIPLY BY 3.32                80500013
         SRL   RF,8                     TAKE CEIL                       81200013
         LA    RF,1(RF)                 OF RESULT                       81900013
         B     COMPR                                                    82600013
DMAA     DC    V(IHEDMAA)                                               83300013
VSAA     DC    V(IHEVSAA)                                               84000013
MXNG     DC    X'80000000'              MUST BE ON WORD BOUNDARY.       84700013
K332     DC    X'0352'                                                  85400013
K001     DC    H'1'                                                     86100013
K031     DC    H'31'                                                    86800013
K128     DC    H'128'                                                   87500013
BITD     DC    X'18'                                                    88200013
FDED     DC    X'7F'                                                    88900013
FXBD     EQU   X'8C'                                                    89600013
XNIL     EQU   X'80'                                                    90300013
PSAVE    EQU   WORK+72                                                  91000013
BINY     EQU   X'04'                                                    91700013
FIXD     EQU   X'02'                                                    92400013
HWRD     EQU   X'10'                                                    92700001
       END                                                              93100013
