DNC      TITLE '   IHEDNC    ARITHMETIC TO CHARACTER                   *00300013
               O/S 360 PL/1 LIBRARY'                                    00600013
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  00900013
*                                                                       01200013
*   STATUS     CHANGE LEVEL - 0                                         01500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DNC000-TSS 01600001
*        ----------------------------------------------------DNC000-TSS 01700001
*                                                                       01800013
*   SIZE       632 BYTES                                                02100013
*                                                                       02400013
*   FUNCTION   TO CONVERT ANY ARITHMETIC DATA TYPE TO A FIXED OR        02700013
*              VARYING LENGTH CHARACTER STRING,OR TO A PICTURED         03000013
*              CHARACTER STRING                                         03300013
*                                                                       03600013
*   ENTRY POINTS                                                        03900013
*              IHEDNCA                                                  04200013
*                   RA = A(SOURCE)                                      04500013
*                   RB = A(SOURCE DED)                                  04800013
*                   RC = A(TARGET DOPE VECTOR)                          05100013
*                   RD = A(TARGET DED)                                  05400013
*                                                                       05700013
*   INPUT      N/A                                                      06000013
*                                                                       06300013
*   OUTPUT     N/A                                                      06600013
*                                                                       06900013
*   EXTERNAL MODULES                                                    07200013
*              IHEDMA - ARITHMETIC CONVERSION DIRECTOR                  07500013
*              IHEUPA - TO OBTAIN ADDRESS OF IMAGINARY PART OF A        07800013
*                       CODED COMPLEX VARIABLE                          08100013
*              IHEVSC - CHARACTER STRING ASSIGNMENT ROUTINE             08400013
*              IHEVSE - CHARACTER STRING TO PICTURED CHARACTER STRING.  08700013
*              IHEVSB - BIT STRING TO CHARACTER STRING CONVERSION       09000013
*              IHEVSF - BIT STRING TO PICTURED CHARACTER STRING.        09300013
*                                                                       09600013
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              09900013
*                                                                       10200013
*   TABLES/WORKAREA                                                     10500013
*              WORKAREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)          10800013
*                                                                       11100013
*   ATTRIBUTES READ ONLY AND REENTRANT.                                 11400013
*                                                                       11700013
*   PRIVATE MACROS                                                      12000013
*              IHELIB,IHEPRV,IHESDR                                     12300013
*                                                                       12600013
*   ASSEMBLY REQUIREMENTS                                               12900013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   13200013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        13500013
*                                                                       13800013
*   NOTE       SEE O/S360 PL/1 LIBRARY PLM FOR DESCRIPTION OF MODULE    14100013
*              CONVENTIONS AND STANDARDS                                14400013
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    14700013
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    15000013
*              THE SAME AS THAT USED AT ASSEMBLY TIME. THE CODING HAS   15300013
*              BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''      15600013
*              CONSTANTS,BY REASSEMBLY,WILL RESULT IN A CORRECT MODULE  15900013
         EJECT                                                          16200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DNC001-TSS 16300001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   16500013
         PUNCH     ' LIBRARY *(IHEDMAA,IHEUPAB,IHEVSCA,IHEVSBA,IHEVSFA,/16800013
               IHEVSEB,IHEVQCA)     DNC0000A'                           17100013
*        ----------------------------------------------------DNC001-TSS 17200001
         SPACE                                                          17400013
IHEDNC   CSECT                                                          17700013
         IHELIB                                                         18000013
IHEZLW2  DSECT                                                          18300013
         DS    15D                                                      18600013
WORK     EQU   IHEZLW2                                                  18900013
IHEDNC   CSECT                                                          19200013
         ENTRY IHEDNCA                                                  19500013
         USING *,RJ                                                     19800013
         USING IHEZLCA,WR                                               20100013
         USING IHEZLW2,DR                                               20400013
IHEDNCA  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          20700013
         IHESDR LW2,WR                  GET WORKSPACE ADDRESS           21000013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  21300013
         LR    RJ,BR                    TRANSFER BASE REGISTER          21600013
         MVI   PSWT,ZERO                RESET SWITCHES                  21900013
         MVI   WSWB,0                   SET FOR CHARACTER TARGET.       22000015
         TM    0(RB),CODE               TEST SOURCE TYPE                22200013
         BZ    TCOMP                    BRANCH IF NUMERIC               22500013
         L     BR,VQCA                  DOES VQC EXIST?                 22800013
         LTR   BR,BR                                                    23100013
         BZ    QGONE                                                    23400013
         LH    BR,0(BR)                 GET TOP TWO BYTES OF VCON.      23420001
         CH    BR,XFER               +  IS IT A TRANSFER VECTOR.        23440001
         L     BR,VQCA                  GET VCON ONCE AGAIN.            23460001
         BNE   SHRLIB                *  NO. MUST BE A(CONV MODULE).     23480001
         LR    R0,RA                    SAVE REGISTER ONE.              23500001
         LH    LR,2(BR)                 STEP DOWN TRANSFER              23520001
         LH    RA,6(BR)                  VECTOR UNTILL THE              23540001
         L     BR,0(LR,PR)               REAL VCON IS                   23560001
         L     BR,0(RA,BR)               LOADED INTO BR.                23580001
         LR    RA,R0                    RESTORE REGISTER ONE.           23600001
         LTR   BR,BR                 +  IS THE MODULE PRESENT.          23620001
         BZ    QGONE                 *  NO. USE IHEDMA.                 23640001
SHRLIB   EQU   *                                                        23660001
         CLI   0(RB),X'88'              TEST FOR FIXED DECIMAL.         23700013
         BE    QCALL                                                    24000013
         CLI   0(RB),X'8C'              TEST FOR FIXED BINARY.          24300013
         BNE   QGONE                                                    24600013
         CLI   2(RB),X'80'                                              24900013
         BE    QCALL                                                    25200013
QGONE    EQU   *                                                        25270017
         STM   RC,RD,SAV1          SAVE TARGET PARAMETERS               25340017
         TM    0(RB),X'C0'         IS SOURCE CHAR FORM OF ARITH?  18372 25410017
         BNO   NOTCHAR             NO BRANCH ROUND                18372 25480017
         IHEPRV ERR,BR,OP=LA       ELSE SET ERROR CODE IN CASE    18372 25550017
         OI    1(BR),X'04'                       OF ERROR         18372 25620017
NOTCHAR  EQU   *                                                  18372 25690017
         LA    RC,WCFD                  GET ADDRESS OF CREATED FED      25800013
         ST    RC,WFDT                  STORE IN TARGET FED POINTER     26100013
         LA    RC,PWRK                  SET TEMPORARY STORE ADDRESS.    26400013
         SR    RF,RF                    CLEAR                           26700013
         LR    RE,RF                    REGISTERS                       27000013
         IC    RF,1(RB)                 GET SOURCE PRECISION            27300013
         IC    RE,2(RB)                 GET SOURCE SCALE FACTOR         27600013
         SH    RE,K128                  REMOVE EXCESS                   27900013
         TM    0(RB),BINY               TEST BASE OF SOURCE             28200013
         BZ    TSCAL                    BRANCH IF DECIMAL               28500013
         LR    RG,RF                    SET MULTIPLICAND                28800013
         M     RF,K332                  PRECISION *1/3.32               29100013
         LTR   RG,RG                    TAKE                            29400013
         BZ    TSCLE                    CEIL                            29700013
         LA    RF,1(RF)                 OF RESULT                       30000013
TSCLE    TM    0(RB),FLOT               TEST SCALE OF SOURCE            30300013
         BO    CALLE                    BRANCH IF FLOAT                 30600013
         LA    RF,1(RF)                 BUMP PRECISION BY ONE           30900013
         LPR   RI,RE                    SET MULTIPLICAND TO ABS SF.     31200013
         M     RH,K332                  CALCULATE CEIL(Q*1/3.32)        31500013
         LTR   RI,RI                    EQUIVALENT                      31800013
         BZ    TESTQ                    OF SOURCE                       32100013
         LA    RH,1(RH)                 SCALE FACTOR                    32400013
TESTQ    LTR   RE,RE                    TEST SIGN OF SOURCE SCALE FACTR 32700013
         LR    RE,RH                    REPLACE WITH DECM EQUIV OF SF.  33000013
         BNL   TSCFC                    BRANCH IF POSITIVE              33300013
         LCR   RE,RE                    SET DECIMAL EQUIVALENT NEGATIVE 33600013
TSCFC    LTR   RE,RE                    TEST SCALE FACTOR               33900013
         BM    FTYPE                    BRANCH IF NEGATIVE              34200013
         CR    RE,RF                    COMPARE WITH PRECISION          34500013
         BH    FTYPE                    BRANCH IF GREATER THAN PRECISN  34800013
         LA    RG,3(RF)                 SET W=P+3  (3 IN CASE P=Q) ***  35100013
         STH   RG,WCFD                  STORE IN CREATED FED            35400013
         STC   RE,WCFD+2                STORE D=SCALE FACTOR            35700013
         MVI   WCFD+3,NULL              ZERO P                          36000013
         B     CALLF                    GO CALL CONVERSION              36300013
FTYPE    STM   RA,RB,DOPV               SAVE SOURCE PARAMETERS          36600013
         TM    0(RB),BINY               TEST BASE OF SOURCE             36900013
         BO    CONBD                    BRANCH IF BINARY                37200013
SFSWT    OI    PSWT,FSWT                SET F TYPE SWITCH               37500013
         LA    RG,1(RF)                 SET W=P+1                       37800013
         STH   RG,WCFD                  STORE IN CREATED FED            38100013
         MVI   WCFD+2,ZERO              SET D=0                         38400013
         LR    RG,RE                    ADD EXCESS                      38700013
         AH    RG,K128                  TO SOURCE SCALE FACTOR          39000013
         STC   RG,WCFD+3                STORE IN P                      39300013
CALLF    LA    RD,FDED                  SET FOR F OUTPUT                39600013
CALLD    L     BR,DMAA                  CALL ARITHMETIC                 39900013
         BALR  LR,BR                    CONVERSION DIRECTOR             40200013
         AH    RC,WCFD                  INCREMENT TEMP ADDRESS          40500013
         TM    PSWT,FSWT                TEST F TYPE SWITCH              40800013
         BO    APNDF                    BRANCH IF SET                   41100013
TCSWT    TM    PSWT,CSWT                TEST COMPLEX SWITCH             41400013
         BO    APNDI                    BRANCH IF SET                   41700013
         TM    0(RB),CPLX               TEST MODE OF SOURCE             42000013
         BZ    ASSGN                    BRANCH IF REAL                  42300013
         OI    WSWA,UPDO                SET UPDATE ONLY SWITCH          42600013
         OI    PSWT,CSWT                SET COMPLEX SWITCH              42900013
         L     BR,UPAB                  CALL ROUTINE TO GET             43200013
         BALR  LR,BR                    ADDRESS OF IMAGINARY PART       43500013
         L     RA,WRCD                  LOAD ADDRESS OF IMAGINARY PART  43800013
         ST    RC,SAV2                  SAVE ADDRESS OF IMAG RESULT     44100013
TSCAL    TM    0(RB),FLOT               TEST SCALE OF SOURCE            44400013
         BZ    TSCFC                    BRANCH IF FIXED                 44700013
CALLE    STC   RF,WCFD+3                SET S=P                         45000013
         LR    RG,RF                    CALCULATE                       45300013
         BCTR  RG,0                     D=P-1                           45600013
         STC   RG,WCFD+2                AND STORE                       45900013
         LA    RG,7(RG)                 STORE                           46200013
         STH   RG,WCFD                  W=P+6                           46500013
         LA    RD,EDED                  SET FOR E OUTPUT                46800013
         B     CALLD                    GO CALL CONVERSION              47100013
APNDF    MVI   0(RC),C'F'               APPEND LETTER F                 47400013
         ST    RA,SAV3                  SAVE SOURCE ADDRESS ACROSS EDIT 47700013
         LCR   RG,RE                    TURN SCALE FACTOR INTO EXPONENT 48000013
         CVD   RG,WINT                  CONVERT TO DECIMAL              48300013
         MVC   EDIT(4),MASK             PREPARE FOR EDIT                48600013
         LA    RA,EDIT+3                SET SIGNIFICANCE POINTER        48900013
         LR    LR,RA                    SAVE JUNIOR DIGIT ADDRESS       49200013
         EDMK  EDIT(4),WINT+6           EDIT CONVERTED SCALE FACTOR     49500013
         BCTR  RA,0                     GET ADDRESS OF SIGN POSITION    49800013
         BNL   SGNOK                    BRANCH IF RESULT NOT NEGATIVE   50100013
         MVI   0(RA),C'-'               SET SIGN MINUS                  50400013
SGNOK    SR    LR,RA                    GET LENGTH OF EXPONENT          50700013
         EX    LR,MVCH                  MOVE EDITED EXPONENT INTO FIELD 51000013
         LA    RC,2(RC,LR)              INCREMENT TEMP POINTER          51300013
         L     RA,SAV3                  RESTORE SOURCE ADDRESS          51600013
         LM    RA,RB,DOPV               RESTORE SOURCE PARAMETERS       51900013
         B     TCSWT                    GO TEST COMPLEX SWITCH          52200013
APNDI    MVI   0(RC),C'I'               APPEND LETTER I                 52500013
         L     RG,SAV2                  RESTORE START ADDRESS OF IMAG.  52800013
         LR    RI,RC                    CALCULATE LENGTH                53100013
         SR    RI,RG                    OF IMAGINARY PART               53400013
         LA    RC,1(RC)                 BUMP TEMP POINTER               53700013
         MVI   0(RC),C' '               APPEND BLANK                    54000013
         CLI   0(RG),C' '               TEST FIRST CHARACTER            54300013
         BNE   ASSGN                    BRANCH IF NOT BLANK             54600013
TSIGN    CLI   1(RG),C'-'               NEXT CHARACTER MINUS SIGN       54900013
         BE    SHIFT                    YES,BRANCH                      55200013
         CLI   1(RG),C' '               NEXT CHARACTER BLANK            55500013
         BNE   INSRT                    NO,BRANCH                       55800013
         EX    RI,MVCR                  REMOVE LEADING BLANK            56100013
         B     TSIGN                    LOOP                            56400013
INSRT    MVI   0(RG),C'+'               INSERT PLUS SIGN                56700013
         B     ASSGN                                                    57000013
MVCR     MVC   0(0,RG),1(RG)            EXECUTED MOVE CHARACTERS        57300013
SHIFT    EX    RI,MVCR                  REMOVE LEADING BLANK            57600013
ASSGN    LA    RG,PWRK                  LOAD TEMP START ADDRESS         57900013
         ST    RG,DOPV                  STORE IN DOPE VECTOR            58200013
         SR    RC,RG                    CALCULATE LENGTH OF TEMP        58500013
         ST    RC,DOPV+4                STORE IN CURRENT LENGTH         58800013
         LM    RC,RD,SAV1               RESTORE TARGET PARAMETERS       59100013
PICTG    LA    RA,DOPV                  SET DOPE VECTOR POINTER         59400013
         LA    RB,CDED                  SET CHAR STRING DED POINTER     59700013
         TM    0(RD),PICT               TEST TARGET STRING TYPE         60000013
         L     BR,VSCA                  SET FOR CHARACTER               60300013
         BO    CALLS                    BRANCH IF CHARACTER             60600013
         L     BR,VSEA                  SET FOR PICTURED                60900013
CALLS    BALR  LR,BR                    CALL ASSIGNMENT ROUTINE         61200013
ENDRT    L     DR,OFDR(DR)              RESET SAVE AREA POINTER         61500013
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       61800013
         BR    LR                       RETURN                          62100013
TCOMP    SR    R0,R0                    GET FIELD WIDTH                 62400013
         IC    R0,3(RB)                 FROM DED                        62700013
         TM    0(RB),CPLX               TEST MODE OF SOURCE             63000013
         BZ    TBASE                    BRANCH IF REAL                  63300013
         AR    R0,R0                    DOUBLE WIDTH                    63600013
TBASE    ST    R0,DOPV+4                STORE CURRENT LENGTH            63900013
         ST    RA,DOPV                  STORE STRING ADDR IN DOPE VECTR 64200013
         B     PICTG                    GO TEST TARGET TYPE             64500013
CONBD    MVI   EDIT,X'88'               SET DED FOR                     64800013
         STC   RF,EDIT+1                FIXED DECIMAL                   65100013
         LR    RG,RE                    EQUIVALENT OF                   65400013
         AH    RG,K128                  FIXED BINARY                    65700013
         STC   RG,EDIT+2                SOURCE                          66000013
         LA    RD,EDIT                  CALL CONVERSION                 66300013
         L     BR,DMAA                  TO FIXED                        66600013
         BALR  LR,BR                    DECIMAL                         66900013
         LR    RA,RC                    REPLACE ORIGINAL                67200013
         LR    RB,RD                    SOURCE                          67500013
         B     SFSWT                    CONTINUE                        67800013
         SPACE                                                          68100013
QCALL    BALR  LR,BR                    CALL VQC.                       68500015
         B     ENDRT                                                    69000013
         SPACE                                                          69300013
MVCH     MVC   1(0,RC),0(RA)            MOVE EDITED EXPONENT INTO FIELD 69600013
EDED     DC    X'7E'                                                    69900013
FDED     DC    X'7F'                                                    70200013
CDED     DC    X'1C'                                                    70500013
K128     DC    H'128'                                                   70800013
DMAA     DC    V(IHEDMAA)                                               71100013
UPAB     DC    V(IHEUPAB)                                               71400013
VSCA     DC    V(IHEVSCA)                                               71700013
VSEA     DC    V(IHEVSEB)                                               72000013
VQCA     DC    V(IHEVQCA)                                               72300013
K332     DC    X'4D1BC253'                                              72600013
MASK     DC    C'+'                                                     72900013
         DC    X'202021'                                                73200013
ZERO     EQU   X'00'                                                    73500013
CODE     EQU   X'08'                                                    73800013
BINY     EQU   X'04'                                                    74100013
FLOT     EQU   X'02'                                                    74400013
NULL     EQU   X'80'                                                    74700013
FSWT     EQU   X'01'                                                    75000013
CSWT     EQU   X'02'                                                    75300013
PICT     EQU   X'08'                                                    75600013
CPLX     EQU   X'01'                                                    75900013
UPDO     EQU   X'04'                                                    76200013
EDIT     EQU   WORK+72                                                  76500013
DOPV     EQU   EDIT+4                                                   76800013
SAV1     EQU   DOPV+8                                                   77100013
SAV2     EQU   SAV1+8                                                   77400013
SAV3     EQU   SAV2+4                                                   77700013
PSWT     EQU   SAV3+4                                                   78000013
PWRK     EQU   PSWT+1                                                   78300013
         DS    0H                                                       78400001
XFER     DC    X'58FC'                                                  78500001
         END                                                            78600013
