DOA      TITLE '   IHEDOA      F/E FORMAT OUTPUT DIRECTOR              *00700013
               O/S 360 PL/1 LIBRARY'                                    01400013
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  02100013
*                                                                       02800013
*   STATUS     CHANGE LEVEL - 0                                         03500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOA000-TSS 03700001
*        ----------------------------------------------------DOA000-TSS 03900001
*                                                                       04200013
*  APARS FIXED                                                          04300001
*        21741                                                          04400001
*                                                                       04500001
*   SIZE       520 BYTES                                                05000001
*                                                                       05600013
*   FUNCTION   F/E FOMAT OUTPUT OF ANY INTERNAL DATA TYPE               06300013
*                                                                       07000013
*   ENTRY POINTS                                                        07700013
*              IHEDOAA - F FORMAT OUTPUT                                08400013
*                   RA = A(SOURCE/SOURCE SDV)                           09100013
*                   RB = A(SOURCE DED)                                  09800013
*                   RC = A(FED)                                         10500013
*              IHEDOAB - E FORMAT OUTPUT                                11200013
*                   ARGUMENTS AS FOR    IHEDOAA                         11900013
*                                                                       12600013
*   INPUT      N/A                                                      13300013
*                                                                       14000013
*   OUTPUT     N/A                                                      14700013
*                                                                       15400013
*   EXTERNAL MODULES                                                    16100013
*              IHEDBN - BIT STRING TO ARITHMETIC CONVERSION             16800013
*              IHEDCN - CHARACTER STRING TO ARITHMETIC CONVERSION       17500013
*              IHEDMA - ARITHMETIC CONVERSION DIRECTOR                  18200013
*              IHEIOD - TO GET BUFFER ADDRESS FOR EXTERNAL DATA.        18900013
*                                                                       19600013
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              20300013
*   TABLES/WORK AREA                                                    21000013
*              WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)         21700013
*                                                                       22400013
*   ATTRIBUTES READ ONLY AND REENTRANT                                  23100013
*                                                                       23800013
*   PRIVATE MACROS                                                      24500013
*              IHELIB,IHEPRV,IHESDR                                     25200013
*                                                                       25900013
*   ASSEMBLY REQUIREMENTS                                               26600013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   27300013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        28000013
*                                                                       28700013
*   NOTES      SEE OS/360 PL/1 LIBRARY PLM FOR DESCRIPTION OF LIBRARY   29400013
*              CONVENTIONS AND STANDARDS                                30100013
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A      30800013
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL       31500013
*              CHARACTER REPRESENTATION.                                32200013
         EJECT                                                          32900013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOA001-TSS 33200001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   33600013
         PUNCH     ' LIBRARY *(IHEDMAA,IHEDNCA,IHEDBNA,IHEVQCA)        /34300013
                                    DOA0000A'                           35000013
*        ----------------------------------------------------DOA001-TSS 35300001
         SPACE                                                          35700013
IHEDOA   CSECT                                                          36400013
         IHELIB                                                         37100013
         IHEZAP                                                         37200001
TMVD     EQU   X'40'                   VDA USED SWITCH.                 37300001
TCFL     EQU   X'04'                   XMIT STACK FLAG.                 37400001
ERR1     EQU   X'9802'                 ON-CODE FOR INPUT TRANSMIT.      37500001
IHEZLW3  DSECT                                                          37800013
         DS    15D                                                      38500013
WORK     EQU   IHEZLW3                                                  39200013
IHEDOA   CSECT                                                          39900013
         ENTRY IHEDOAA                                                  40600013
         ENTRY IHEDOAB                                                  41300013
         USING IHEZLCA,WR                                               42000013
         USING IHEZLW3,DR                                               42700013
IHEDOAA  NOPR  0                                                        43400013
IHEDOAB  STM   LR,WR,OFLR(DR)           E FORMAT ENTRY                  44100013
         BALR  RJ,0                     SET BASE ADDRESS                44800013
         USING *,RJ                                                     45500013
         TM    OFBR+3(DR),X'02'         TEST ENTRY POINT                46200013
         IHESDR LW3,WR                  UPDATE SAVE AREA POINTER        46900013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  47600013
         ST    RC,WFDT                  STORE OUTPUT FED POINTER        48300013
         BZ    SFMAT                    BRANCH IF F FORMAT CALL         49000013
         MVI   WORK+80,2                                          21741 49700001
         LA    RD,EDED                  SET FOR E FORMAT OUTPUT         50400013
SIOBT    IHEPRV ERR,RE,OP=LA            SET I/O BIT                     51100013
         OI    0(RE),IOBT               IN ERROR                        51800013
         SR    RF,RF                    GET W SPECIFICATION             52500013
         AH    RF,0(RC)                 FROM FED                        53200013
         BNH   EXITR                    BRANCH IF ZERO OR NEGATIVE      53900013
         STH   RF,WSDV+6                STORE W IN LCA                  54600013
         USING IHEZAPE,RI              DEFINE BASE REG. FOR DCBAPE.     54650001
         IHEPRV CFL,RG                 ADDRESS CFL FCB                  54700001
         LH    RG,DPRO-IHEZDCL(RG)     VIA DCLCB,                       54750001
         L     RI,0(RG,PR)             THEN FILE REGISTER.              54800001
         TM    TFLX,TMEF               ENDFILE ALREADY ENCOUNTERED..    54850001
         BO    CIODP                   YES,CALL IODP.                   54900001
         MVC   WSDV+4(2),WSDV+6                                         54950001
         NI    WONC+2,255-TMVD         CLEAR VDA ALLOCATED FLAG.        55000001
         NI    TFLX,255-TMIT-TMLC      UNSET TMIT AND TMLC FLAGS.       55050001
         IHEPRV CFL,BR,OP=LA                                            55100001
         NI    4(BR),255-TCFL          UNSET XMIT FLAG.                 55150001
         TM    TFLX,TMIE               IS INPUT TRANSMIT ON FOR BLOCK.. 55200001
         BZ    TYPES                   NO.                              55250001
         NC    TREM,TREM               ANY LEFT IN BUFFER..             55300001
         BZ    TYPES                   NO.                              55350001
         OI    TFLX,TMIT               YES,SET DATAFIELD TRANS. ON.     55400001
         OI    4(BR),TCFL              SET XMIT FLAG.                   55450001
TYPES    LH    RC,TREM                 NUMBER OF BYTES LEFT IN RECORD.  55500001
         TM    TTYP,TMST               STRING..                         55550001
         BZ    RECOD                   NO.                              55600001
         CH    RC,WSDV+6               BYTES WANTED GT.CURRENT REC..    55650001
         BL    CIODP                   YES, CALL IODP.                  55700001
         L     RC,TCBA                 SET A(DATAFIELD) WITHIN          55750001
         ST    RC,WSDV                 BUFFER FOR CALLER.               55800001
         B     RETRS                                                    55850001
RECOD    LTR   RC,RC                   IS CURRENT RECORD EXHAUSTED..    55900001
         BNP   CIODP                   YES, CALL IODP.                  55950001
         LH    RC,WSDV+6               NO, COMPUTE TEMPORARY            56000001
         LA    R0,8(RC)                STORAGE REQUIREMENT.             56050001
         LR    RH,RA                   SAVE RA.                         56100001
         IHEPRV VDA,BR                                                  56150001
         BALR  LR,BR                   GET VDA.                         56200001
         LA    RG,8(RA)                COMPUTE VDA TRUE ADDRESS.        56250001
         LR    RA,RH                   RESTORE RA.                      56300001
         ST    RG,WSDV                 SET CALLER'S DATAFIELD ADCON.    56350001
         OI    WONC+2,TMVD             SET VDA ALLOCATED FLAG.          56400001
         B     RETRS                                                    56450001
CIODP    L     BR,IODP                 CALL ROUTINE TO GET              56500001
         BALR  LR,BR                   BUFFER ADDRESS.                  56550001
RETRS    L     RG,WFDT                 SAVE FED POINTER.                56950001
         L     RC,WSDV                  LOAD BUFFER POINTER             57400013
         MVC   WSWB(1),WORK+80                                    21741 57700001
         TM    0(RB),STRG               TEST SOURCE DATA TYPE           58100013
         BZ    TSBIT                    BRANCH IF STRING                58800013
         CLI   3(RG),X'80'              P MUST EQUAL 0.                 59500013
         BNE   QGONE                                                    60200013
         L     BR,VQCA                  DOES VQC EXIST?                 60900013
         LTR   BR,BR                                                    61600013
         BZ    QGONE                                                    62300013
         LH    BR,0(BR)                 GET TOP TWO BYTES OF VCON.      62350001
         CH    BR,XFER               +  IS IT A TRANSFER VECTOR.        62400001
         L     BR,VQCA                  GET VCON ONCE AGAIN.            62450001
         BNE   SHRLIB                *  NO. MUST BE A(CONV MODULE).     62500001
         LR    R0,RA                    SAVE REGISTER ONE.              62550001
         LH    LR,2(BR)                 STEP DOWN TRANSFER              62600001
         LH    RA,6(BR)                  VECTOR UNTILL THE              62650001
         L     BR,0(LR,PR)               REAL VCON IS                   62700001
         L     BR,0(RA,BR)               LOADED INTO BR.                62750001
         LR    RA,R0                    RESTORE REGISTER ONE.           62800001
         LTR   BR,BR                 +  IS THE MODULE PRESENT.          62850001
         BZ    QGONE                 *  NO. USE IHEDMA.                 62900001
SHRLIB   EQU   *                                                        62950001
         CLI   0(RB),X'88'              FIXED DECIMAL SOURCE?           63000013
         BE    QTEST                                                    63700013
         CLI   0(RB),X'8C'              FIXED BINARY SOURCE?            64400013
         BNE   QGONE                                                    65100013
QTEST    CLI   2(RB),X'80'              FIXED BINARY INTEGER?           65800013
         BE    QCALL                                                    66500013
QGONE    L     BR,DMAA                  SET TO CALL ARITHMETIC CONV.    67200013
CALLS    BALR  LR,BR                    CALL CONVERSION ROUTINE         67900013
QBACK    TM    TFLX,TMIT               INPUT TRANSMIT ON DATAFIELD..    67940001
         BNZ   CIODT                   YES, CALL IODT.                  67980001
ALLOC    TM    WONC+2,TMVD             VDA ALLOCATED.                   68020001
         BZ    IODRA                   NO.                              68060001
         NI    WONC+2,TMVD             YES,UNSET FLAG.                  68100001
         L     RG,WSDV                 ADDRESS VDA.                     68140001
         LH    RC,WSDV+6               OBTAIN LENGTH.                   68180001
         L     RH,TCBA                 ADDRESS RECORD AREA.             68220001
         LH    RF,TREM                 OBTAIN AVAILABLE BYTE COUNT.     68260001
         CR    RC,RF                   REQUIREMENT GT. AVAILABLE..      68300001
         BH    CIODT                   YES, CALL IODT.                  68340001
         LR    RY,RC                   AVAILABLE BYTES LTE. REQ.        68380001
         LA    RZ,255                  MOVE AVAILABLE BYTES.            68420001
IOD8B    CR    RY,RZ                   MORE THAN 255 BYTES TO MOVE..    68460001
         BNH   IOD8C                   NO.                              68500001
         EX    0,IODMY                 YES.                             68540001
         SR    RY,RZ                   REDUCE REQUIREMENT.              68580001
         AR    RG,RZ                   BUMP.                            68620001
         AR    RH,RZ                   MOVE ADDRESSES.                  68660001
         B     IOD8B                   CONTINUE.                        68700001
IOD8C    BCTR  RY,0                    ACCOUNT FOR MVC BONUS.           68740001
         EX    RY,IODMV                MOVE LAST FEW BYTES.             68780001
         LA    RH,1(RY,RH)             BUMP AVAILABLE ADDRESS.          68820001
         LA    RG,1(RY,RG)             BUMP VDA ADDRESS.                68860001
         SR    RF,RC                   REDUCE AVAILABLE RECORD COUNT.   68900001
         STH   RF,TREM                                                  68940001
         ST    RH,TCBA                 STORE AVAILABLE RECORD ADDRESS.  68980001
         IHEPRV FVD,BR                                                  69020001
         BALR  LR,BR                   FREE VDA.                        69060001
FINIT    L     RC,TCNT                 BUMP COUNT VALUE.                69100001
         LA    RC,1(RC)                                                 69140001
         ST    RC,TCNT                                                  69180001
         B     EXITR                   PREPARE TO EXIT.                 69220001
IODRA    L     RC,TCBA                 UPDATE BUFFER PTRS.              69260001
         AH    RC,WSDV+6                                                69300001
         ST    RC,TCBA                                                  69340001
         LH    RC,TREM                                                  69380001
         SH    RC,WSDV+6                                                69420001
         STH   RC,TREM                                                  69460001
         B     FINIT                   BUMP COUNT VALUE.                69500001
IODMV    MVC   0(*-*,RH),0(RG)         MOVE TO RECORD.                  69540001
IODMY    MVC   0(255,RH),0(RG)         MOVE TO RECORD.                  69580001
CIODT    L     BR,IODT                 CALL ROUTINE TO FREE ANY         69620001
         BALR  LR,BR                   VDA'S REQUIRED ON OUTPUT.        69660001
EXITR    SR    RE,RE                    RESET ERROR CODE                70000013
         IHEPRV ERR,RE,OP=STH                                           70700013
         L     DR,OFDR(DR)              RESET SAVE AREA POINTER         71400013
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       72100013
         BR    LR                       RETURN                          72800013
SFMAT    LA    RD,FDED                  SET FOR F FORMAT OUTPUT         73500013
         MVI   WORK+80,1                                          21741 74200001
         B     SIOBT                                                    74900013
TSBIT    L     BR,DCNA                  SET FOR CHARACTER STRING SOURCE 75600013
         TM    0(RB),CHAR               TEST SOURCE STRING TYPE         76300013
         BO    CALLS                    BRANCH IF CHARACTER             77000013
         L     BR,DBNA                  SET FOR BIT STRING SOURCE       77700013
         B     CALLS                    GO CALL STRING ARITH CONVERSION 78400013
QCALL    LA    RD,CDED                                                  79100013
         BALR  LR,BR                    CALL VQC.                       79800013
         B     QBACK                                                    80500013
EDED     DC    X'7E'                                                    81200013
FDED     DC    X'7F'                                                    81900013
CDED     DC    X'0C'                                                    82600013
IODP     DC    V(IHEIODP)                                               83300013
IODT     DC    V(IHEIODT)                                               84000013
DMAA     DC    V(IHEDMAA)                                               84700013
DCNA     DC    V(IHEDCNA)                                               85400013
DBNA     DC    V(IHEDBNA)                                               86100013
VQCA     DC    V(IHEVQCA)                                               86800013
IOBT     EQU   X'80'                                                    87500013
ZERO     EQU   X'00'                                                    88200013
STRG     EQU   X'80'                                                    88900013
CHAR     EQU   X'04'                                                    89600013
         DS    0H                                                       89800001
XFER     DC    X'58FC'                                                  90000001
         END                                                            90300013
