DOB      TITLE '   IHEDOB    A AND CP FORMAT OUTPUT DIRECTOR           *00700015
               O/S 360 PL/1 LIBRARY'                                    01400015
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  02100015
         SPACE 1                                                        02300000
* R19    842500                                                  A28506 02500000
*                                                                       02800015
*   STATUS     CHANGE LEVEL - 0                                         03500015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOB000-TSS 03700001
*        ----------------------------------------------------DOB000-TSS 03900001
*                                                                       04200015
*   SIZE       224 BYTES                                                04900015
*                                                                       05600015
*   FUNCTION   TO DIRECT THE CONVERSION OF INTERNAL DATA TO EXTERNAL    06300015
*              CHARACTER REPRESENTATION WITH A OR PICTURED CHARACTER    07000015
*              FORMAT                                                   07700015
*                                                                       08400015
*   ENTRY POINTS                                                        09100015
*              IHEDOBA - A(W)FORMAT OUTPUT                              09800015
*                  RA = A(SOURCE OR SOURCE DV)                          10500015
*                  RB = A(SOURCE DED)                                   11200015
*                  RC = A(FED) (FOR IHEDOBA ONLY)                       11900015
*              IHEDOBB - A FORMAT OUTPUT                                12600015
*                  ARGUMENTS AS FOR IHEDOBA                             13300015
*              IHEDOBC - CHARACTER PICTURE FORMAT OUTPUT                14000015
*                  ARGUMENTS AS FOR IHEDOBA                             14700015
*                                                                       15400015
*   INPUT      N/A                                                      16100015
*                                                                       16800015
*   OUTPUT     N/A                                                      17500015
*                                                                       18200015
*   EXTERNAL MODULES                                                    18900015
*              IHEIOD - TO GET BUFFER ADDRESS FOR EXTERNAL DATA         19600015
*              IHEDNC - ARITHMETIC TO CHARACTER STRING CONVERSION       20300015
*              IHEVSB - BIT STRING TO CHARACTER STRING CONVERSION       21000015
*              IHEVSC - CHARACTER STRING TO CHARACTER STRING            21700015
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              22400015
*                                                                       23100015
*   TABLES/WORK AREA                                                    23800015
*              WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)         24500015
*                                                                       25200015
*   ATTRIBUTES READ ONLY AND REENTRANT                                  25900015
*                                                                       26600015
*   PRIVATE MACROS                                                      27300015
*              IHELIB,IHEPRV,IHESDR                                     28000015
*                                                                       28700015
*   ASSEMBLY REQUIREMENTS                                               29400015
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   30100015
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        30800015
*                                                                       31500015
*   NOTES      SEE OS/360 PL/1 LIBRARY PLM FOR DESCRIPTION OF LIBRARY   32200015
*              CONVENTIONS AND STANDARDS                                32900015
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    33600015
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    34300015
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  35000015
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  35700015
*              CONSTANTS,BY REASSEMBLY,WILL RESULT IN A CORRECT MODULE  36400015
*              FOR THE NEW DEFINITIONS.                                 37100015
         EJECT                                                          37800015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOB001-TSS 38100001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   38500015
         PUNCH     ' LIBRARY *(IHEDNCA,IHEVSCA,IHEVSBA,IHEVSEA,IHEVSFA)/39200015
                                    DOB0000A'                           39900015
*        ----------------------------------------------------DOB001-TSS 40200001
         SPACE                                                          40600015
IHEDOB   CSECT                                                          41300015
         IHELIB                                                         42000015
IHEZLW3  DSECT                                                          42700015
         DS    15D                                                      43400015
WORK     EQU   IHEZLW3                                                  44100015
IHEDOB   CSECT                                                          44800015
         ENTRY IHEDOBA                                                  45500015
         ENTRY IHEDOBB                                                  46200015
         ENTRY IHEDOBC                                                  46900015
         USING IHEZLCA,WR                                               47600015
         USING IHEZLW3,DR                                               48300015
IHEDOBA  NOPR  0                        A-FORMAT                        49000015
IHEDOBB  NOPR  0                        A-FORMAT-W NOT SPECIFIED        49700015
IHEDOBC  STM   LR,WR,OFLR(DR)           CP FORMAT  SAVE CALLERS REGS.   50400015
         BALR  RJ,0                     SET UP ADDRESS ABILITY          51100015
         USING *,RJ                                                     51800015
         LR    RI,DR                    SAVE ENTRY POINT REFERENCE      52500015
         IHESDR LW3,WR                  UPDATE SAVE AREA POINTER        53200015
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  53900015
         IHEPRV ERR,RE,OP=LA            GET ADDRESS OF ERROR CODE       54600015
         OI    0(RE),IOBT               SET FOR                         55300015
         SR    RG,RG                    SET FORMAT INDEX                56000015
         TM    OFBR+3(RI),X'02'         TEST ENTRY POINT                56700015
         BO    NOWDH                    BRANCH IF NO WIDTH SPEC         57400015
         MVC   WSDV+6(2),0(RC)          GET W FROM 'A' FED              58100015
         TM    OFBR+3(RI),X'04'         TEST ENTRY POINT                58800015
         BZ    NOTPC                    BRANCH IF NOT PICTURE ENTRY     59500015
         LA    RG,4(RG)                 SET FORMAT INDEX                60200015
         MVC   WSDV+6(2),1(RC)          GET W FROM 'CP' FED             60900015
NOTPC    SR    RF,RF                    GET W                           61600015
         AH    RF,WSDV+6                FROM LCA.                       62300015
         BNH   FINIS                    BRANCH IF W ZERO OR MINUS       63000015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOB999-TSS 63300000
NOWRT    L     BR,IODP                  GET FIELD ADDRESS               63700015
*        ----------------------------------------------------DOB999-TSS 64000000
         BALR  LR,BR                    WITHIN BUFFER                   64400015
         LR    RD,RC                    SET DED AS FED IN CASE          65100015
         LTR   RG,RG                    TEST ENTRY POINT                65800015
         BNZ   PICTI                    BRANCH IF PICTURE FORMAT        66500015
         LA    RD,CDED                  SET UP CHARACTER DED            67200015
PICTI    LA    RC,WSDV                  SET UP TARGET SDV               67900015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOB998-TSS 68200000
         L     BR,DNCA                  SET FOR ARITHMETIC SOURCE       68600015
*        ----------------------------------------------------DOB998-TSS 68900000
         TM    0(RB),STRG               TEST FOR STRING SOURCE          69300015
         BO    CALLS                    BRANCH NOT STRING               70000015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOB997-TSS 70300000
         L     BR,VSCA(RG)              SET FOR CHAR.STR.SOURCE         70700015
*        ----------------------------------------------------DOB997-TSS 71000000
         TM    0(RB),CHAR               TEST SOURCE TYPE                71400015
         BO    CALLS                    BRANCH IF CHARACTER             72100015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOB996-TSS 72400000
         L     BR,VSBA(RG)              SET FOR BIT.STR.SOURCE          72800015
*        ----------------------------------------------------DOB996-TSS 73100000
CALLS    BALR  LR,BR                    CALL CONVERSION ROUTINE         73500015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOB995-TSS 73800000
ENDRT    L     BR,IODT                  TERMINAL CALL                   74200015
*        ----------------------------------------------------DOB995-TSS 74500000
         BALR  LR,BR                    TO FREE ANY VDA                 74900015
FINIS    SR    RE,RE                    ZERO REGISTER                   75600015
         IHEPRV ERR,RE,OP=STH           RESET ERROR CODE                76300015
         L     DR,OFDR(DR)              RESET SAVE AREA POINTER         77000015
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       77700015
         BR    LR                       RETURN                          78400015
NOWDH    TM    0(RB),STRG               TEST SOURCE TYPE                79100015
         BO    ARNWD                    BRANCH IF NOT STRING.           79800015
         MVC   WSDV+6(2),6(RA)          GET W FROM SOURCE SDV           80500015
         B     NOTPC                                                    81200015
ERCAL    LA    RA,EROR                  SET TO RAISE                    81900015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOB994-TSS 82200000
         L     BR,ERRC                  ERROR CONDITION                 82600015
*        ----------------------------------------------------DOB994-TSS 82900000
         BALR  LR,BR                    ERROR PACKAGE                   83300015
         B     FINIS                                                    84000015
         SPACE                                                          84010015
ARNWD    TM    0(RB),PICC               PICTURE SOURCE?                 84020015
         BZ    PCNWD                    YES.                            84030015
         LA    RD,CVDD                  SET UP VARIABLE CHAR TARGET.    84040015
         LA    RC,PWRK+8                ADDRESS OF TARGET.              84050015
         ST    RC,PWRK                  IN SDV.                         84060015
         LA    RC,72                    MAXIMUM LENGTH.                 84070015
         STH   RC,PWRK+4                IN BOTH                         84080015
         STH   RC,PWRK+6                SLOTS OF SDV.                   84090015
         LA    RC,PWRK                  POINT AT SDV.                   84100015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOB993-TSS 84105000
         L     BR,DNCA                  ARITHMETIC TO CHARACTER.        84110015
*        ----------------------------------------------------DOB993-TSS 84115000
         BALR  LR,BR                                                    84120015
         MVC   WSDV+6(2),PWRK+6         MOVE CURRENT LENGTH OF TEMP.    84130015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOB992-TSS 84135000
         L     BR,IODP                  GET FIELD ADDRESS.              84140015
*        ----------------------------------------------------DOB992-TSS 84145000
         BALR  LR,BR                                                    84150015
         LR    RA,RC                    SHIFT PARAMETERS.               84160015
         LR    RB,RD                    FROM SOURCE TO TARGET.          84170015
         LA    RC,WSDV                  TARGET FIELD IN BUFFER.         84180015
         LA    RD,CDED                  FIXED CHARACTER DED.            84190015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOB991-TSS 84195000
         L     BR,VSCA                  MOVE CHARACTERS.                84200015
*        ----------------------------------------------------DOB991-TSS 84205000
         BALR  LR,BR                                                    84210015
         B     ENDRT                                                    84220015
         SPACE                                                          84230015
PCNWD    SR    RF,RF                                                    84240015
         IC    RF,3(RB)                GET W IN SOURCE DED       A28506 84250000
         STH   RF,WSDV+6                SET AS FIELD LENGTH.            84260015
         TM    0(RB),CPLX               COMPLEX SOURCE..                84270015
         BZ    NOTPC                    NO.                             84280015
         AR    RF,RF                    DOUBLE LENGTH..                 84290015
         STH   RF,WSDV+6                SET AS FIELD LENGTH.            84300015
         B     NOTPC                                                    84310015
         SPACE                                                          84320015
PICC     EQU   X'08'                                                    84330015
CVDD     DC    X'1C'                                                    84340015
CPLX     EQU   X'01'                                                    84350015
PWRK     EQU   WORK+72                                                  84360015
EROR     DC    X'0402'                                                  84700015
CDED     DC    X'0C'                                                    85400015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOB990-TSS 85700000
ERRC     DC    V(IHEERRC)                                               86100015
IODP     DC    V(IHEIODP)                                               86800015
IODT     DC    V(IHEIODT)                                               87500015
DNCA     DC    V(IHEDNCA)                                               88200015
VSCA     DC    V(IHEVSCA)                                               88900015
VSEA     DC    V(IHEVSEA)                                               89600015
VSBA     DC    V(IHEVSBA)                                               90300015
VSFA     DC    V(IHEVSFA)                                               91000015
*        ----------------------------------------------------DOB990-TSS 91300000
IOBT     EQU   X'80'                                                    91700015
CHAR     EQU   X'04'                                                    92400015
STRG     EQU   X'80'                                                    93100015
ZERO     EQU   X'00'                                                    93800015
         END                                                            94500015
