DOD      TITLE '   IHEDOD    B FORMAT OUTPUT DIRECTOR                  *00020000
               O/S 360 PL/1 LIBRARY'                                    00040000
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  00060000
*                                                                       00080000
*   STATUS     CHANGE LEVEL - 0                                         00100000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOD000-TSS 00106001
*        ----------------------------------------------------DOD000-TSS 00112001
*                                                                       00120000
*   SIZE       296 BYTES                                                00140000
*                                                                       00160000
*   FUNCTION   TO DIRECT THE CONVERSION OF INTERNAL DATA TO EXTERNAL    00180000
*              B FORMAT REPRESENTATION                                  00200000
*                                                                       00220000
*   ENTRY POINTS                                                        00240000
*              IHEDODA - B(W) FORMAT OUTPUT                             00260000
*                  RA = A(SOURCE OR SOURCE DV)                          00280000
*                  RB = A(SOURCE DED)                                   00300000
*                  RC = A(FED) (FOR IHEDODA ONLY)                       00320000
*              IHEDODB - B FORMAT OUTPUT                                00340000
*                  ARGUMENTS AS FOR IHEDODA                             00360000
*                                                                       00380000
*    INPUT     N/A                                                      00400000
*                                                                       00420000
*    OUTPUT    N/A                                                      00440000
*                                                                       00460000
*    EXTERNAL MODULES                                                   00480000
*              IHEIOD - TO GET BUFFER ADDRESS FOR EXTERNAL DATA         00500000
*              IHEDNB - ARITHMETIC TO BIT STRING CONVERSION             00520000
*              IHEVSB - BIT STRING TO CHARACTER STRING CONVERSION       00540000
*              IHEVSC - CHARACTER STRING TO CHARACTER STRING            00560000
*                       CONVERSION                                      00580000
*              IHEERR - EXECUTION ERROR PACKAGE                         00600000
*                                                                       00620000
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              00640000
*                                                                       00660000
*   TABLES/WORK AREA                                                    00680000
*              WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)         00700000
*                                                                       00720000
*   ATTRIBUTES READ ONLY AND REENTRANT                                  00740000
*                                                                       00760000
*   PRIVATE MACROS                                                      00780000
*              IHELIB,IHEPRV,IHESDR                                     00800000
*                                                                       00820000
*   ASSEMBLY REQUIREMENTS                                               00840000
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   00860000
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        00880000
*                                                                       00900000
*   NOTES      SEE OS/360 PL/1 LIBRARY PLM FOR DESCRIPTION OF LIBRARY   00920000
*              CONVENTIONS AND STANDARDS                                00940000
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A      00960000
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL       00980000
*              CHARACTER SET.                                           01000000
         EJECT                                                          01020000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOD001-TSS 01030001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   01040000
         PUNCH     ' LIBRARY *(IHEDNBA,IHEVSCA,IHEVSBA)                /01060000
                                    DOD0000A'                           01080000
*        ----------------------------------------------------DOD001-TSS 01090001
         SPACE                                                          01100000
IHEDOD   CSECT                                                          01120000
         IHELIB                                                         01140000
IHEZLW3  DSECT                                                          01160000
         DS    15D                                                      01180000
WORK     EQU   IHEZLW3                                                  01200000
IHEDOD   CSECT                                                          01220000
         ENTRY IHEDODA                                                  01240000
         ENTRY IHEDODB                                                  01260000
         USING IHEZLCA,WR                                               01280000
         USING IHEZLW3,DR                                               01300000
IHEDODA  NOPR  0                                                        01320000
IHEDODB  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          01340000
         BALR  RJ,0                     SET UP ADDRESSABILITY           01360000
         USING *,RJ                                                     01380000
         LR    RI,DR                    SAVE ENTRY POINT REFERENCE      01400000
         IHESDR LW3,WR                  UPDATE SAVE AREA POINTER        01420000
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  01440000
         IHEPRV ERR,RE,OP=LA            GET ADDRESS OF ERROR CODE       01460000
         OI    0(RE),IOBT               SET FOR                         01480000
         TM    OFBR+3(RI),X'02'         TEST ENTRY POINT                01500000
         BO    NOWDH                    BRANCH IF NO WIDTH SPEC         01520000
         SR    RF,RF                    GET W                           01540000
         AH    RF,0(RC)                 FROM FED                        01560000
         BNH   FINIS                    BRANCH IF W ZERO OR MINUS       01580000
NOWRT    STH   RF,WSDV+6                SET UP FIELD WIDTH              01600000
         L     BR,IODP                  GET FIELD ADDRESS               01620000
         BALR  LR,BR                    WITHIN BUFFER                   01640000
         LA    RD,CDED                  SET UP CHARACTER DED            01660000
         LA    RC,WSDV                  SET UP TARGET SDV               01680000
         TM    0(RB),STRG               TEST FOR STRING SOURCE          01700000
         BZ    STRNG                    BRANCH IF STRING                01720000
         L     BR,DNBA                  CALL ARITH TO BIT               01740000
         LA    RC,TEMP                  LOAD ADDR OF TEMP BIT STRING    01760000
         ST    RC,DOPV                  STORE IN DOPE VECTOR            01780000
         MVC   DOPV+4(4),LNGT           PUT LENGTHS IN DOPE VECTOR      01800000
         LA    RC,DOPV                  SET DOPE VECTOR POINTER         01820000
         LA    RD,BITD                  SET FIXED LEN.BIT STR.DED       01840000
         BALR  LR,BR                    CALL ARITH.TO BIT CONVERSION    01860000
         LR    RA,RC                    MAKE TEMP BIT STRING SOURCE     01880000
         LR    RB,RD                    FOR CALL                        01900000
         LA    RC,WSDV                  SET BUFFER AS TARGET            01920000
         LA    RD,CDED                  CHARACTER REPRESENTATION        01940000
STRNG    L     BR,VSBA                  SET FOR BIT STRING              01960000
         TM    0(RB),CHAR               TEST SOURCE TYPE                01980000
         BZ    CALLS                    BRANCH IF BIT                   02000000
         MVC   WOFD(8),0(RA)            SET ON-SOURCE PARAMETERS        02020000
SCANS    L     RG,0(RA)                 LOAD ADDRESS OF SOURCE STRING   02040000
         LH    RF,6(RA)                 AND LENGTH                      02060000
CHECK    ST    RG,WOCH                  SET ERROR ADDRESS               02080000
         CLI   0(RG),C'0'               TEST SOURCE CHARACTER           02100000
         BE    COUNT                    BRANCH IF ZERO                  02120000
         CLI   0(RG),C'1'               TEST SOURCE CHARACTER           02140000
         BE    COUNT                    BRANCH IF ONE                   02160000
         OI    0(RE),CONV               SET CONVERSION ERROR            02180000
         OI    1(RE),CHBT               SET UP CHAR TO BIT TYPE SOURCE  02200000
         LA    LR,RETRY                 STORE RETRY ENTRY POINT AND     02220000
         STM   DR,LR,WCNV               SAVE AREA ADDRESS IN LCA.       02240000
         LR    RH,RA                    SAVE PARAMETER REGISTER         02260000
         L     BR,ERRB                  CALL EXECUTION                  02280000
         BALR  LR,BR                    ERROR PACKAGE                   02300000
         LR    RA,RH                    RESTORE PARAMETER REGISTER      02320000
COUNT    LA    RG,1(RG)                 BUMP SCAN ADDRESS               02340000
         BCT   RF,CHECK                 DECREMENT LENGTH AND LOOP       02360000
         L     BR,VSCA                  SET FOR CHAR.STR.SOURCE         02380000
CALLS    BALR  LR,BR                    CALL ASSIGNMENT ROUTINE         02400000
ENDRT    L     BR,IODT                  TERMINAL CALL                   02420000
         BALR  LR,BR                    TO FREE ANY VDA                 02440000
FINIS    SR    RE,RE                    ZERO REGISTER                   02460000
         IHEPRV ERR,RE,OP=STH           RESET ERROR CODE                02480000
         L     DR,OFDR(DR)              RESET SAVE AREA POINTER         02500000
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       02520000
         BR    LR                       RETURN                          02540000
RETRY    LR    RA,RH                   RESTORE PARAMETER REGISTER       02560000
         B     SCANS                    GO RETRY CONVERSION             02580000
NOWDH    TM    0(RB),STRG               TEST FOR STRING SOURCE          02600000
         BO    ERCAL                    BRANCH NOT STRING               02620000
         LH    RF,6(RA)                 GET LENGTH OF SOURCE            02640000
         LTR   RF,RF                    TEST IT FOR ZERO                02660000
         BP    NOWRT                    BRANCH NON-ZERO                 02680000
         B     FINIS                                                    02700000
ERCAL    L     BR,ERRC                  CALL EXECUTION                  02720000
         BALR  RA,BR                    ERROR PACKAGE                   02740000
EROR     DC    X'0403'                                                  02760000
CDED     DC    X'0C'                                                    02780000
BITD     DC    X'18'                                                    02800000
LNGT     DC    X'00200020'                                              02820000
IODP     DC    V(IHEIODP)                                               02840000
DNBA     DC    V(IHEDNBA)                                               02860000
IODT     DC    V(IHEIODT)                                               02880000
VSCA     DC    V(IHEVSCA)                                               02900000
VSBA     DC    V(IHEVSBA)                                               02920000
ERRB     DC    V(IHEERRB)                                               02940000
ERRC     DC    V(IHEERRC)                                               02960000
CHAR     EQU   X'04'                                                    02980000
STRG     EQU   X'80'                                                    03000000
CHBT     EQU   X'05'                                                    03020000
IOBT     EQU   X'80'                                                    03040000
ZERO     EQU   X'00'                                                    03060000
CONV     EQU   X'40'                                                    03080000
TEMP     EQU   WORK+72                                                  03100000
DOPV     EQU   TEMP+4                                                   03120000
         END                                                            03140000
