DOE      TITLE '   IHEDOE    NUMERIC PICTURE OUTPUT DIRECTOR           *00700013
               O/S 360 PL/1 LIBRARY'                                    01400013
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  02100013
*                                                                       02800013
*   STATUS     CHANGE LEVEL - 0                                         03500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOE000-TSS 03700001
*        ----------------------------------------------------DOE000-TSS 03900001
*                                                                       04200013
*   SIZE                                                                04900013
*                                                                       05600013
*   FUNCTION   TO DIRECT THE CONVERSION OF ANY INTERNAL DATA TYPE       06300013
*              TO EXTERNAL DATA DESCRIBED BY A NUMERIC PICTURE          07000013
*              SPECIFICATION                                            07700013
*                                                                       08400013
*   ENTRY POINTS                                                        09100013
*              IHEDOEA                                                  09800013
*                   RA = A(SOURCE/SOURCE SDV)                           10500013
*                   RB = A(SOURCE DED)                                  11200013
*                   RC = A(FED)                                         11900013
*                                                                       12600013
*   INPUT      N/A                                                      13300013
*                                                                       14000013
*   OUTPUT     N/A                                                      14700013
*                                                                       15400013
*   EXTERNAL MODULES                                                    16100013
*              IHEDBN - BIT STRING TO ARITHMETIC CONVERSION             16800013
*              IHEDCN - CHARACTER STRING TO ARITHMETIC CONVERSION       17500013
*              IHEDMA - ARITHMETIC CONVERSION DIRECTOR                  18200013
*              IHEIOD - TO GET BUFFER POINTER FOR RESULT                18900013
*              IHEVSB - BIT STRING TO CHARACTER STRING CONVERSION       19600013
*                                                                       20300013
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              21000013
*                                                                       21700013
*   TABLES/WORKAREA                                                     22400013
*              WORKAREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)          23100013
*                                                                       23800013
*   ATTRIBUTES READ ONLY AND REENTRANT                                  24500013
*                                                                       25200013
*   PRIVATE MACROS                                                      25900013
*              IHELIB,IHEPRV,IHESDR                                     26600013
*                                                                       27300013
*   ASSEMBLY REQUIREMENTS                                               28000013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   28700013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        29400013
*                                                                       30100013
*   NOTES      SEE O/S360 PL1 LIBRARY PLM FOR DESCRIPTION OF LIBRARY    30800013
*              CONVENTIONS AND STANDARDS                                31500013
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A      32200013
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL       32900013
*              CHARACTER SET.                                           33600013
         EJECT                                                          34300013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOE001-TSS 34600001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   35000013
         PUNCH     ' LIBRARY *(IHEDMAA,IHEVSBA,IHEDCNA,IHEDBNA)        /35700013
                                    DOE0000A'                           36400013
*        ----------------------------------------------------DOE001-TSS 36700001
         SPACE                                                          37100013
IHEDOE   CSECT                                                          37800013
         IHELIB                                                         38500013
IHEZLW3  DSECT                                                          39200013
         DS    15D                                                      39900013
WORK     EQU   IHEZLW3                                                  40600013
IHEDOE   CSECT                                                          41300013
         ENTRY IHEDOEA                                                  42000013
         USING *,RJ                                                     42700013
         USING IHEZLCA,WR                                               43400013
         USING IHEZLW3,DR                                               44100013
IHEDOEA  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          44800013
         IHESDR LW3,WR                  UPDATE AREA POINTER             45500013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  46200013
         LR    RJ,BR                    TRANSFER BASE REGISTER          46900013
         IHEPRV ERR,RE,OP=LA            GET ADDRESS OF ERROR CODE       47600013
         OI    0(RE),IOBT               SET FOR                         48300013
         SR    RF,RF                    GET                             49000013
         IC    RF,3(RC)                 WIDTH FROM FED                  49700013
         STH   RF,WSDV+6                STORE IN DOPE VECTOR            50400013
         L     BR,IODP                  GET BUFFER                      51100013
         BALR  LR,BR                    ADDRESS                         51800013
         LR    RD,RC                    LOAD TARGET DED                 52500013
         L     RC,WSDV                  LOAD BUFFER ADDRESS             53200013
STRNG    TM    0(RB),STRG               SOURCE TYPE STRING              53900013
         BZ    TWINE                   YES BRANCH                       54600013
COMPR    CLC   0(1,RB),0(RD)            SPOT TEST FOR PIC SOURCE.       55300013
         BNE   ARITH                                                    56000013
         IC    RF,4(RB)                GET LENGTH OF PICTURE            56700013
         LA    RF,4(RF)                PLUS FOUR                        57400013
         EX    RF,COMPR                PICTURE COMPARE FOR EQUAL        58100013
         BNE   ARITH                   NO CALL DMAA                     58800013
         L     RC,WSDV                  GET TARGET ADDRESS.             59500013
         IC    RF,3(RB)                GET SOURCE WIDTH                 60200013
         BCTR  RF,0                     REDUCE FOR MVC                  60900013
         EX    RF,MOVER                MOVE SOURCE TO TARGET DIRECTLY   61600013
         B     CALLS                   TNEN CONTINUE                    62300013
ARITH    L     BR,DMAA                 SET FOR AITH SOURCE              63000013
         B     CALLR                   BRANCH TO CALL                   63700013
TWINE    L     BR,DCNA                  SET FOR CHAR.STR.SOURCE         64400013
         TM    0(RB),CHAR               TEST SOURCE TYPE                65100013
         BO    CALLR                    BRANCH IF CHAR.STRING           65800013
         L     BR,DBNA                  SET FOR BIT STR.SOURCE          66500013
CALLR    BALR  LR,BR                    CALL CONVERSION                 67200013
CALLS    TM    0(RD),BINY               TEST TARGET BASE                67900013
         BZ    ENDRT                    BRANCH NOT BINARY               68600013
         LA    RA,PWORK                 SET DOPE VECTOR POINTER         69300013
         MVC   PWORK+4(4),WSDV+4        SET LENGTHS                     70000013
         LA    RB,BITD                  SET FOR BIT STRING              70700013
         LA    RC,WSDV                  SET BUFFER POINTER              71400013
         LA    RD,CHRD                  SET FOR CHAR.OUTPUT             72100013
         L     BR,VSBA                  CALL BIT TO CHARACTER           72800013
         BALR  LR,BR                    ASSIGNMENT                      73500013
ENDRT    L     BR,IODT                  TERMINAL CALL                   74200013
         BALR  LR,BR                    TO FREE ANY VDA                 74900013
         SR    RE,RE                                                    75600013
         IHEPRV ERR,RE,OP=STH           RESET ERROR CODE                76300013
         L     DR,OFDR(DR)              RESET SAVE AREA POINTER         77000013
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       77700013
         BR    LR                       RETURN                          78400013
MOVER    MVC   0(0,RC),0(RA)                                            79100013
VSBA     DC    V(IHEVSBA)                                               79800013
DMAA     DC    V(IHEDMAA)                                               80500013
IODP     DC    V(IHEIODP)                                               81200013
IODT     DC    V(IHEIODT)                                               81900013
DCNA     DC    V(IHEDCNA)                                               82600013
DBNA     DC    V(IHEDBNA)                                               83300013
CHRD     DC    X'1C'                                                    84000013
BITD     DC    X'18'                                                    84700013
IOBT     EQU   X'80'                                                    85400013
ZERO     EQU   X'00'                                                    86100013
BINY     EQU   X'04'                                                    86800013
STRG     EQU   X'80'                                                    87500013
CHAR     EQU   X'04'                                                    88200013
PWORK    EQU   WORK+72                                                  88900013
         END                                                            89600013
