DOM      TITLE '   IHEDOM    C FORMAT OUTPUT DIRECTOR                  *00020000
               OS/360 PL/1 LIBRARY'                                     00040000
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  00060000
*                                                                       00080000
*   STATUS     CHANGE LEVEL - 0                                         00100000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOM000-TSS 00106001
*        ----------------------------------------------------DOM000-TSS 00112001
*                                                                       00120000
*   SIZE       560 BYTES                                                00140000
*                                                                       00160000
*   FUNCTION   TO DIRECT THE CONVERSION OF INTERNAL DATA TO EXTERNAL    00180000
*              DATA DESCRIBED BY A 'C' FORMAT ITEM.                     00200000
*                                                                       00220000
*   ENTRY POINT                                                         00240000
*              IHEDOMA                                                  00260000
*                   RA = A(SOURCE/SOURCE SDV)                           00280000
*                   RB = A(SOURCE DED)                                  00300000
*                   RC = A(REAL FORMAT OUTPUT/DIRECTOR                  00320000
*                   RD = A(REAL FED                                     00340000
*                   RE = A(IMAGINARY FORMAT OUTPUT/DIRECTOR)            00360000
*                   RF = A(IMAGINARY FED)                               00380000
*                                                                       00400000
*   INPUT      N/A                                                      00420000
*                                                                       00440000
*   OUTPUT     N/A                                                      00460000
*                                                                       00480000
*   EXTERNAL MODULES                                                    00500000
*              IHEDBN - BIT STRING TO ARITHMETIC                        00520000
*              IHEUPA - MODE CONVERSION                                 00540000
*              IHEUPB - MODE CONVERSION                                 00560000
*              IHEVCA - DATA ANALYSIS ROUTINE                           00580000
*              IHEVCS - TO CONVERT CHARACTER STRING TO CODED COMPLEX    00600000
*              IHEDOA - F/E FORMAT OUTPUT DIRECTOR                      00620000
*              IHEDOE - NUMERIC PICTURE OUTPUT DIRECTOR                 00640000
*                                                                       00660000
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              00680000
*                                                                       00700000
*   TABLES/WORKAREA                                                     00720000
*              WORKAREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)          00740000
*                                                                       00760000
*   ATTRIBUTES READ ONLY AND REENTRANT                                  00780000
*                                                                       00800000
*   PRIVATE MACROS                                                      00820000
*              IHELIB,IHEPRV,IHESDR                                     00840000
*                                                                       00860000
*   ASSEMBLY REQUIREMENTS                                               00880000
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   00900000
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        00920000
*                                                                       00940000
*   NOTE       SEE O/S360 PL/1 LIBRARY PLM FOR DESCRIPTION OF LIBRARY   00960000
*              CONVENTIONS AND STANDARDS                                00980000
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    01000000
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    01020000
*              EQUIVALENT TO THAT USED AT ASSEMBLY TIME. THE CODING HAS 01040000
*              BEEN SO ARRANGED THAT REDEFINITION OF ''CHARACTER''      01060000
*              CONSTANTS,BY REASSEMBLY,WILL RESULT IN A CORRECT MODULE  01080000
*              FOR THE NEW DEFINITIONS                                  01100000
         EJECT                                                          01120000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DOM001-TSS 01130001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   01140000
         PUNCH     ' LIBRARY *(IHEVCAA,IHEDBNA,IHEUPAB,IHEUPBB,IHEDOAA,/01160000
               IHEDOEA,IHEVCSB)     DOM0000A'                           01180000
*        ----------------------------------------------------DOM001-TSS 01190001
         SPACE                                                          01200000
IHEDOM   CSECT                                                          01220000
         IHELIB                                                         01240000
IHEZLW4  DSECT                                                          01260000
         DS    15D                                                      01280000
WORK     EQU   IHEZLW4                                                  01300000
IHEDOM   CSECT                                                          01320000
         ENTRY IHEDOMA                                                  01340000
         USING *,RJ                                                     01360000
         USING IHEZLCA,WR                                               01380000
         USING IHEZLW4,DR                                               01400000
IHEDOMA  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTER           01420000
         IHESDR LW4,WR                  UPDATE SAVE AREA POINTER        01440000
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  01460000
         LR    RJ,BR                    TRANSFER BASE REGISTER          01480000
AGAIN    MVI   PSWT,ZERO                RESET SWITCHES                  01500000
         TM    0(RB),STRG               TEST SOURCE DATA TYPE           01520000
         BZ    STRNG                    BRANCH IF STRING                01540000
CALLR    LR    BR,RC                    LOAD DIRECTOR ADDRESS           01560000
         MVI   PSWT,ZERO                INITIALISE SWITCH               01580000
         IHEPRV ERR,RG,OP=LA                                            01600000
         MVI   0(RG),IOBT               SET ERROR CODE                  01620000
         LR    RC,RD                    SET FED POINTER                 01640000
CALIO    BALR  LR,BR                    CALL OUTPUT DIRECTOR            01660000
         TM    0(RB),CPLX               TEST MODE OF SOURCE             01680000
         BZ    TSWT2                    BRANCH IF REAL                  01700000
         TM    PSWT,SWT1                TEST SWITCH ONE                 01720000
         BO    ENDRT                    BRANCH IF SET                   01740000
         OI    PSWT,SWT1                SET SWITCH ONE                  01760000
         L     BR,UPAB                  SET FOR CODED SOURCE            01780000
         TM    0(RB),CODE               TEST SOURCE TYPE                01800000
         BO    CALUP                    BRANCH IF CODED                 01820000
         L     BR,UPBB                  SET FOR NUMERIC SOURCE          01840000
CALUP    OI    WSWA,UPDO                SET UPDATE ADDRESS ONLY SWITCH  01860000
         BALR  LR,BR                    CALL ROUTINE FOR IMAG PART ADDR 01880000
         L     RA,WRCD                  LOAD UPDATED ADDRESS            01900000
CALLI    LR    BR,RE                    SET PARAMETERS                  01920000
         LR    RC,RF                    FOR IMAGINARY PART              01940000
         B     CALIO                    GO CALL OUTPUT DIRECTOR         01960000
TSWT2    LA    RA,DZRO                  SET FOR                         01980000
         LA    RB,DDED                  ZERO IMAGINARY PART             02000000
         OI    PSWT,SWT1                                                02020000
         B     CALLI                    AND LOOP                        02040000
STRNG    TM    0(RB),CHAR               TEST STRING TYPE                02060000
         BO    CHSTR                    BRANCH IF CHARACTER             02080000
         STM   RC,RD,PSAV               SAVE PARAMETERS                 02100000
         LA    RC,PSAV+8                SET TEMP TARGET                 02120000
         LA    RD,BDED                  SET COMPLEX FLOAT BINARY DED    02140000
         L     BR,DBNA                  CALL BIT STRING TO              02160000
         BALR  LR,BR                    ARITHMETIC CONVERSION           02180000
         LR    RA,RC                    SET PARAMETERS FOR INTERMEDIATE 02200000
         LR    RB,RD                    FLOAT BINARY COMPLEX AS SOURCE  02220000
         LM    RC,RD,PSAV               RESTORE FORMAT PARAMETERS       02240000
         B     CALLR                    GO TO NORMAL OUTPUT LOOP        02260000
CHSTR    MVC   WOFD(8),0(RA)            SET ON-SOURCE PARAMETERS IN LCA 02280000
         LA    LR,RETRY                 STORE RETRY ENTRY POINT AND     02300000
         STM   DR,LR,WCNV               SAVE AREA ADDRESS IN LCA        02320000
         STM   RC,RF,SAV2               SAVE DIRECTOR AND FED POINTERS  02340000
         L     RF,0(RA)                 GET STRING START ADDRESS        02360000
         XC    WCN1(16),WCN1            ZERO CONSTANT DESCRIPTORS       02380000
         LR    RG,RF                    CALCULATE STRING                02400000
         AH    RG,6(RA)                 END ADDRESS                     02420000
TRAIL    BCTR  RG,0                     REMOVE                          02440000
         CLI   0(RG),C' '               TRAILING                        02460000
         BE    TRAIL                    BLANKS                          02480000
LEADB    CLI   0(RF),C' '               TEST CHARACTER                  02500000
         LA    RF,1(RF)                 BUMP SCAN ADDRESS               02520000
         BE    LEADB                    BRANCH IF CHARACTER BLANK       02540000
         BCTR  RF,0                     RESET SCAN ADDRESS              02560000
SLOOP    ST    RF,WCN1                  STORE CONSTANT START ADDR       02580000
BUMPS    CR    RF,RG                    COMPARE SCAN WITH END ADDRESS   02600000
         BE    STORE                    BRANCH IF SAME                  02620000
         CLI   0(RF),C'+'               TEST CHARACTER                  02640000
         BE    SIGNT                    BRANCH IF PLUS                  02660000
         CLI   0(RF),C'-'               TEST CHARACTER                  02680000
         BE    SIGNT                    BRANCH IF MINUS                 02700000
         OI    PSWT,SWT3                SET SWITCH THREE                02720000
         CLI   0(RF),C'E'               TEST CHARACTER                  02740000
         BE    EXPNT                    BRANCH IF 'E'                   02760000
INCRT    LA    RF,1(RF)                 BUMP SCAN ADDR                  02780000
         B     BUMPS                    LOOP                            02800000
SIGNT    TM    PSWT,SWT3                TEST SWITCH THREE               02820000
         BO    STEND                    BRANCH IF SET                   02840000
         OI    PSWT,SWT3                SET SWITCH THREE                02860000
         B     INCRT                    LOOP                            02880000
EXPNT    NI    PSWT,255-SWT3            RESET SWITCH THREE              02900000
         B     INCRT                    LOOP                            02920000
STEND    STM   RF,RG,WCN2               STORE 2ND CONSTANT START/END    02940000
         BCTR  RF,0                     STORE 1ST CONSTANT              02960000
STORE    ST    RF,WCN1+4                END ADDRESS                     02980000
         NC    WCN2(8),WCN2             TEST 2ND DESCRIPTOR             03000000
         BM    CPLEX                    BRANCH IF SET                   03020000
         CLI   0(RG),C'I'               TEST CONSTANT MODE              03040000
         BNE   REALC                    BRANCH IF REAL                  03060000
         LA    RI,RZRO                  SET 2ND DESCRIPTOR FOR          03080000
         ST    RI,WCN2                  DUMMY ZERO                      03100000
         ST    RI,WCN2+4                CONSTANT                        03120000
SWTCH    LM    RH,RI,WCN1               TRANSPOSE                       03140000
         MVC   WCN1(8),WCN2             DESCRIPTORS                     03160000
         STM   RH,RI,WCN2               IN L.C.A.                       03180000
LESSI    L     RH,WCN2+4                REMOVE LETTER I                 03200000
         BCTR  RH,0                     FROM IMAGINARY                  03220000
         ST    RH,WCN2+4                CONSTANT                        03240000
         B     CVCAA                                                    03260000
RETRY    L     RA,OFDR(DR)              RESTORE ORIGINAL                03280000
         LM    RA,RF,OFRA(RA)           PARAMETERS                      03300000
         B     AGAIN                    AND RETRY CONVERSION            03320000
CPLEX    CLI   0(RG),C'I'               TEST MODE OF SECOND CONSTANT    03340000
         BE    LESSI                    BRANCH IF IMAGINARY             03360000
         B     SWTCH                    GO SWITCH CONSTANTS             03380000
REALC    LA    RI,RZRO                  SET 2ND DESCRIPTOR              03400000
         ST    RI,WCN2                  FOR DUMMY ZERO                  03420000
         ST    RI,WCN2+4                CONSTANT                        03440000
CVCAA    SR    RH,RH                    INITIALISE PARAMETER            03460000
         LR    RI,RH                    LIST INDEXERS                   03480000
LOOP1    LA    RC,WCN1(RH)              GET START/END POINTER           03500000
         ST    RC,WCNP                  STORE IN L.C.A.                 03520000
         ST    RC,PLIST(RH)             AND PARAMETER LIST              03540000
         LA    RA,DED1(RI)              ALLOCATE DED                    03560000
         L     BR,VCAA                  CALL DATA                       03580000
         BALR  LR,BR                    ANALYSIS ROUTINE                03600000
         ST    RA,PLIST+4(RH)           STORE DED POINTER IN PARAM LIST 03620000
         TM    0(RA),BASE               TEST BASE OF CONSTANT           03640000
         BZ    MAKFD                    BRANCH IF DECIMAL               03660000
         L     RD,WCN1+4(RH)            GET END ADDRESS OF BINARY CONST 03680000
         BCTR  RD,0                     REMOVE LETTER B                 03700000
         ST    RD,WCN1+4(RH)            STORE AGAIN                     03720000
TESTL    TM    PSWT,SWT2                TEST SWITCH TWO                 03740000
         BO    COMPL                    BRANCH IF SET                   03760000
         OI    PSWT,SWT2                SET SWITCH TWO                  03780000
         LA    RH,8(RH)                 BUMP PARAMETER LIST             03800000
         LA    RI,4(RI)                 INDEX REGISTERS                 03820000
         B     LOOP1                    LOOP                            03840000
MAKFD    LA    RD,WCN1(RH)              GET CONSTANT START AND          03860000
         LM    RD,RE,0(RD)              END ADDRESSES                   03880000
         SR    RE,RD                    CALCULATE                       03900000
         LA    RE,1(RE)                 FIELD WIDTH                     03920000
         STH   RE,PLIST+32(RI)          STORE IN FED                    03940000
         LH    RE,NULL                  STORE D AND P SPECIFICATION     03960000
         STH   RE,PLIST+34(RI)          INFED                           03980000
         LA    RE,PLIST+32(RI)          STORE FED POINTER               04000000
         ST    RE,PLIST+24(RI)          IN PARAMETER LIST               04020000
         B     TESTL                                                    04040000
COMPL    LA    RC,PLIST                 SET TARGET ADDRESS              04060000
         ST    RC,PLIST+16              IN PARAMETER LIST               04080000
         LA    RA,PLIST                 SET POINTER TO PARAM LIST       04100000
         L     BR,VCSB                  CALL CHARACTER COMPLEX TO       04120000
         BALR  LR,BR                    CODED COMPLEX ROUTINE           04140000
         LA    RA,PLIST                 SET CODED COMPLEX               04160000
         LA    RB,PLIST+16              AS SOURCE                       04180000
         LM    RC,RF,SAV2               RESTORE OUTPUT FORMAT PARAMS    04200000
         B     CALLR                    LOOP                            04220000
ENDRT    SR    RE,RE                    RESET ERROR CODE                04240000
         IHEPRV ERR,RE,OP=STH                                           04260000
         L     DR,OFDR(DR)              RESET SAVE AREA POINTER         04280000
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       04300000
         BR    LR                       RETURN                          04320000
VCAA     DC    V(IHEVCAA)                                               04340000
DBNA     DC    V(IHEDBNA)                                               04360000
UPAB     DC    V(IHEUPAB)                                               04380000
UPBB     DC    V(IHEUPBB)                                               04400000
VCSB     DC    V(IHEVCSB)                                               04420000
NULL     DC    X'0080'                                                  04440000
DZRO     DC    PL1'+0'                                                  04460000
DDED     DC    X'890180'                                                04480000
BDED     DC    X'9F3500'                                                04500000
RZRO     DC    C'0'                                                     04520000
ZERO     EQU   0                                                        04540000
STRG     EQU   X'80'                                                    04560000
CPLX     EQU   X'01'                                                    04580000
CODE     EQU   X'08'                                                    04600000
UPDO     EQU   X'04'                                                    04620000
BASE     EQU   X'04'                                                    04640000
CHAR     EQU   X'04'                                                    04660000
IOBT     EQU   X'80'                                                    04680000
PWRK     EQU   WORK+72                                                  04700000
SWT1     EQU   1                                                        04720000
SWT2     EQU   2                                                        04740000
SWT3     EQU   4                                                        04760000
SAV2     EQU   PWRK                                                     04780000
DED1     EQU   SAV2+16                                                  04800000
PSWT     EQU   DED1+3                                                   04820000
DED2     EQU   DED1+4                                                   04840000
PSAV     EQU   DED2+4                                                   04860000
PLIST    EQU   PSAV                                                     04880000
         END                                                            04900000
