DSP      TITLE '   IHEDSP    DISPLAY                                   /00400013
               OS/360 PL/I LIBRARY'                                     00800013
*   VERSION    THIRD VERSION OF F-LEVEL PL/1 COMPILER                   01200013
*                                                                       01600013
*   CHANGE MADE FOR APAR 31659                                          01660020
*        665600,666400                                                  01720020
*        678000,*                                                       01780020
*        969200,969600                                                  01840020
*                                                                       01900020
*   CHANGES MADE FOR APAR 42000 ON RELEASE 21.                          01920021
*                                                                       01940021
*   665600-666400 678000,* 969200,* 969400,*                            01960021
*                                                                       01980021
*   STATUS     CHANGE LEVEL - 0                                         02000013
*                                                                       02400013
*   SIZE       428 BYTES.                                               02800013
*                                                                       03200013
*   FUNCTION                                                            03600013
*              TO WRITE A MESSAGE ON THE OPERATOR DISPLAY CONSOLE       04000013
*              WITH A) NO REPLY                                         04400013
*                   B) REPLY                                            04800013
*              A PARAMETER LIST IS BUILT UP FOR A WTO MACRO(NO REPLY)   05200013
*              OR A WTOR MACRO(REPLY). IN THE LATTER CASE TWO EXTRA     05600013
*              OPERATIONS ARE PERFORMED -                               06000013
*              1) THE REPLY AREA IS CLEARED AND THE CURRENT LENGTH      06400013
*              SET TO THE MAXIMUM LENGTH.                               06800013
*              2) A WAIT MACRO IS ISSUED FOR THE REPLY IF               07200015
*                  NO EVENT OPTION IS SPECIFIED.                        07600015
*                IF THE EVENT OPTION IS SPECIFIED THEN THE WAIT         08000015
*                   AND HOUSEKEEPING WILL BE DONE IN IHEOSW.            08400015
*                                                                       08800013
*   INPUT                                                               09200013
*                                                                       09600013
*   ENTRY POINTS                                                        10000013
*              IHEDSPA                                                  10400013
*                  RA = A(PLIST)                                        10800013
*                  PLIST = A(MESSAGE SDV)                               11200013
*                *        ( A(REPLY SDV)       )                        11600013
*                *        ((A(EVENT VARIABLE) ))                        12000013
*                                                                       12400013
*                * DROP OFF AS REQUIRED (END OF PLIST FLAG ON LAST WORD 12800013
*                                        PRESENT)                       13200013
*                                                                       16000013
*   OUTPUT                                                              16400013
*                                                                       16800013
*   EXTERNAL MODULES                                                    17200013
*              IHESAD - GET CONTROLLED VARIABLE.                        17600013
*              IHESAF - FREE CONTROLLED VARIABLE.                       18000013
*              IHEERR - EXECUTION ERROR PACKAGE.                        18400013
*                                                                       18800013
*   EXITS      NORMAL                                                   19200013
*                  RETURN VIA LINK REGISTER.                            19600013
*              ERROR                                                    20000013
*                  IHE    DISPLAY MESSAGE/REPLY LENGTH IS ZERO          20400013
*                  IHE     EVENT VARIABLE ALREADY ACTIVE.               20800013
*                                                                       21200013
         EJECT                                                          21600013
*   TABLES/WORK AREA                                                    22000013
*              DISPLAY WITHOUT REPLY.                                   22400013
*                                                                       22800013
*                        ...................//....                      23200013
*                        . MM+4 .  00  . MESSAGE .                      23600013
*                        ...................//....                      24000013
*                        .      4      .    MM   .              BYTES   24400013
*                                                                       24800013
*              DISPLAY WITH REPLY.                                      25200013
*                                                                       25600013
* ..........................................//....                      26000013
* . ECB .LL.REPLYAD.ECBAD. MM+4 .  00  . MESSAGE .                      26400013
* ..........................................//....                      26800013
* .  4  . 1    3   .  4  .      4      .    MM   .              BYTES   27200013
*                                                                       27600013
*        WHERE MM IS LENGTH OF MESSAGE - MAX=126.                       28000015
*              LL IS LENGTH OF REPLY - MAX=126.                         28400015
*                                                                       28800013
*   ATTRIBUTES  READ ONLY AND REENTRANT                                 29200013
*                                                                       29600013
*   PRIVATE MACROS                                                      30000013
*              IHELIB,IHESDR                                            30400013
*                                                                       30800013
*   ASSEMBLY REQUIREMENTS                                               31200013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   31600013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        32000013
*                                                                       32400013
*   NOTES                                                               32800013
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    33200013
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    33600013
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  34000013
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  34400013
*              CONSTANTS, BY REASSEMBLY, WILL RESULT IN A CORRECT       34800013
*              MODULE FOR THE NEW DEFINITIONS.                          35200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP000-TSS 35300020
*        ----------------------------------------------------DSP000-TSS 35400020
        EJECT                                                           35600013
IHEDSP   CSECT                                                          36000013
         IHELIB                                                         36400013
         IHEEVT                                                         36800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP016-TSS 37000020
IHEQEVT  DXD   2A                                                       37200015
IHEQATV  DXD   A                                                        37300017
IHEQCTS  DXD   A                                                        37400017
IHEQTCA  DXD   A                                                        37460001
*        ----------------------------------------------------DSP016-TSS 37490020
OFCTECB  EQU   1228                                                     37520001
         SPACE                                                          37600013
IHEZLW0  DSECT                                                          38000013
         DS    18F                                                      38400013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP009-TSS 38500020
*        ----------------------------------------------------DSP009-TSS 38600020
LMSG     EQU   126                    MAXIMUM LENGTH OF MESSAGE TO WTO. 38800015
LREP     EQU   126                    MAXIMUM LENGTH OF REPLY FROM WTOR 39200015
PWR      EQU   WR                                                       39600013
CURL     EQU   6                                                        40000013
MAXL     EQU   4                                                        40400013
DSPW     EQU   2                                                        40800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP010-TSS 40900020
*        ----------------------------------------------------DSP010-TSS 41000020
         EJECT                                                          41200013
IHEDSP   CSECT                                                          41600013
         ENTRY IHEDSPA                                                  42000015
IHEDSPA  STM   LR,PWR,OFLR(DR)       .  DISPLAY                         42600015
         IHESDR LW0                     UPDATE SAVE AREA POINTER.       43200013
         USING IHEZLW0,DR                                               43600013
         BALR  PWR,0                                                    44000013
         USING *,PWR                                                    44400013
         L     RB,0(RA)                 A(SDV OF MESSAGE).              46000013
         LH    RH,CURL(RB)              LENGTH OF MESSAGE.              46400013
         LTR   RH,RH                    IS LENGTH ZERO..                46800013
         BZ    DZ000                    YES, MAY BE AN ERROR.           47200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP001-TSS 47400020
         LA    RH,18(RH)                V FORMAT+CTL+MCS INFO SPACE     47600001
*        ----------------------------------------------------DSP001-TSS 47800020
         LTR   RB,RB                    IS REPLY REQUESTED..            48000013
         BM    DSP01                    NO.                             48400013
         L     RE,4(RA)                 YES, A(SDV FOR REPLY AREA).     48800013
         LTR   RE,RE                                                    49200013
         BM    NEVNT                    NO EVENT OPTION.                49600013
         L     RI,8(RA)                                                 50000013
         USING IHEZEVT,RI                                               50400013
         LR    BR,PR                                                    50420017
         SH    BR,H008                                                  50440017
         TM    1(BR),X'80'         IS IT TASKING                        50460017
         BZ    NTASK               NO                                   50480017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP025-TSS 50500020
         IHEPRV TCA,RD,OP=L          GET TCA ADDRESS                    50520001
*        ----------------------------------------------------DSP025-TSS 50530020
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP022-TSS 50540020
         POST  (RD),00               ENQ REQUEST ON PECB                50560001
*        ----------------------------------------------------DSP022-TSS 50580020
         LA    RA,08(RD)             GET WECB TO WAIT ON                50600001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP023-TSS 50620020
         WAIT  1,ECB=(1)             WAIT UNTIL REQUEST SATISFIED       50640001
*        ----------------------------------------------------DSP023-TSS 50660020
         MVI   08(RD),00             RESET WECB                         50680001
NTASK    EQU   *                                                        50740017
         TM    EFL1,EMAC                IS EVENT VARIABLE ACTIVE..      50800013
         BO    DZ090                    YES OH DEAR.                    51200013
NEVNT    LH    RF,MAXL(RE)              LENGTH OF REPLY AREA.           51600013
         LTR   RF,RF                    IS LENGTH ZERO..                52000013
         BNZ   NZERO               NO                                   52100017
         LTR   RE,RE               RAISE ERROR- EVENT OPTION...         52200017
         BM    DZ011               NO                                   52300017
         B     DZ010               YES                                  52400017
NZERO    EQU   *                                                        52500017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP002-TSS 52600020
         LA    RH,12(RH)                SPACE FOR REPLY INFO AND ECB.   52800013
DSP01    O     RH,SP01                                                  53200015
*        ----------------------------------------------------DSP002-TSS 53400020
         LR    R0,RH                                                    53600015
         GETMAIN R,LV=(0)                                               54000015
         ST    RH,0(RA)                                                 54400015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP003-TSS 54500020
*        ----------------------------------------------------DSP003-TSS 54600020
         LA    RA,4(RA)                                                 54800015
         LR    RG,RA                    ADDRESS OF MESSAGE IF NO REPLY. 55200013
         LTR   RB,RB                    IS REPLY REQUESTED..            55600013
         BM    DSP02                    NO.                             56000013
         LR    RC,RA                    ADDRESS ECB.                    56400013
         LTR   RE,RE                    IS THERE AN EVENT OPTION..      56800013
         BM    DSP0A                    NO.                             57200013
         ST    RC,EVEC                  STORE ADDRESS IN EVENT VARIABLE 57600013
         MVI   EFL1,EMAC+EMIO+EMDS      SET ACTV,I/O AND DISPLAY BITS.  58000013
         ST    PR,EVPR                                                  58050015
         NI    EFL2,255-EMCP       SET INCOMPLETE                       58060015
         SR    BR,BR                                                    58070015
         STH   BR,EVST                  SET STATUS TO ZERO.             58080015
         LR    BR,PR                                                    58100015
         SH    BR,H008                  GET ADDRESS OF PRV VDA.         58200015
         TM    1(BR),X'80'              TEST FOR TASKING ENV.           58300015
         BZ    DSP0A                    NO,DO NOT CHAIN EV.             58400015
         LR    RH,RA                                                    58500015
         IHEPRV EVT,BR,OP=LA                                            58700015
         SH    BR,EVOF                                                  58800015
         L     LR,EVCF-EVBG(BR)                                         58900015
         LTR   LR,LR                                                    59000015
         BZ    DSP0B                                                    59100015
         MVC   EVCF-EVBG(8,BR),EVCF-EVBG(LR)                            59200015
DSP0B    STM   LR,BR,EVCF                                               59300015
         LA    RJ,DSDWN                                                 59309017
UNSET    EQU   *                                                        59318017
         LR    BR,PR                                                    59327017
         SH    BR,H008                                                  59336017
         TM    1(BR),X'80'         TASKING..                            59345017
         BCR   8,RJ                NO                                   59354017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP026-TSS 59394020
         IHEPRV TCA,RA,OP=L        GET TASK CONTROL AREA FOR ENQ FLAG   59434001
*        ----------------------------------------------------DSP026-TSS 59474020
         NI    12(RA),X'BF'        SET ENQ FLAG OFF                     59514001
         IHEPRV CTS,RA,OP=L          GET CONTROL TASK STORAGE ADDRESS   59594001
         LA    RA,OFCTECB(RA)        SET RA TO CTECB                    59674001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP018-TSS 59714020
         POST  (1),00                TELL CONTROL TASK TO CONTINUE      59754001
*        ----------------------------------------------------DSP018-TSS 59804020
         BR    RJ                                                       59870017
DSDWN    EQU   *                                                        59880017
         LR    RA,RH                                                    59900015
DSP0A    LA    RA,4(RA)                 SPACE OVER ECB.                 60800013
         XC    0(4,RC),0(RC)            CLEAR ECB.                      61200013
         STC   RF,0(RA)                 LENGTH OF REPLY AREA.           61600013
         ST    RC,4(RA)                 ADDRESS OF ECB.                 62000013
         LA    RG,8(RA)                                                 62400013
DSP02    LH    RF,CURL(RB)              LENGTH OF MESSAGE.              62800013
         CH    RF,MSGL                  MESSAGE GTR THAN MAX..          63200015
         BNH   DSP0C                    NO.                             63600013
         LA    RF,LMSG                  YES, TRUNCATE.                  64000015
DSP0C    LA    RH,4(RF)                                                 64400013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP004-TSS 64600020
         XC    2(2,RG),2(RG)                                            64800013
         STH   RH,0(RG)                 STORE IN V-FORMAT IMFORMATION.  65200013
         MVC   2(2,RG),MCSF             MOVE MCS FLAGS                  65400001
*        ----------------------------------------------------DSP004-TSS 65500020
         L     RH,0(RB)                                                 65600013
         BCTR  RF,0                                                     66000013
         EX    RF,MVCH                  MOVE MESSAGE TO RECORD AREA.    66400013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP024-TSS 66440020
         LA    RG,5(RG,RF)              POSITION OF CODES               66480001
         MVC   0(2,RG),DS03            DESC CODE INTO PARM.       42000 66560021
         MVC   2(2,RG),RT02            ROUTE CODE INTO PARM.      42000 66640021
         XC    4(2,RG),4(RG)            ZERO MCS TYPE FIELD             66720001
*        ----------------------------------------------------DSP024-TSS 66760020
         LTR   RB,RB                    IS REPLY REQUESTED..            66800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP020-TSS 67000020
         BP    DSP03                    YES.                            67200013
*        ----------------------------------------------------DSP020-TSS 67400020
         LR    RC,RA                                                    67600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP005-TSS 67700020
         WTO   MF=(E,(1))            $$ WRITE-TO-OPERATOR.              68000013
         B     DSP04                                                    68400013
*        ----------------------------------------------------DSP005-TSS 68600020
DSP03    LH    RF,MAXL(RE)               MAX LENGTH OF PL/I REPLY AREA. 68800013
         STH   RF,CURL(RE)              SET CURRENT TO MAX LENGTH       69200013
         L     BR,0(RE)                 ADDRESS REPLY AREA.             69600013
         LR    LR,RF                                                    70000013
         ST    BR,0(RA)                 SET ADDRESS OF REPLY AREA.      70400013
         CH    RF,REPL                  REPLY LENGTH GTR THAN MAX..     70800015
         BNH   DSP00                    NO.                             71200013
         LA    RF,LREP                                                  71600015
DSP00    STC   RF,0(RA)                 SET LENGTH OF REPLY AREA.       72000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP021-TSS 72100020
*        ----------------------------------------------------DSP021-TSS 72200020
* BLANK OUT REPLY AREA.                                                 72400013
         MVI   0(BR),C' '                                               72800013
         BCTR  LR,0                                                     73200013
         LTR   LR,LR                    WAS REPLY LENGTH 1..            73600013
         BZ    DSP06                    YES, REPLY AREA BLANKED OUT.    74000013
         LA    R0,256                                                   74400013
COMPR    CR    LR,R0                    ARE THERE MORE THAN 256 CHARS.. 74800013
         BNH   MVRST                    NO.                             75200013
         MVC   1(256,BR),0(BR)                                          75600013
         AR    BR,R0                                                    76000013
         SR    LR,R0                                                    76400013
         B     COMPR                                                    76800013
MVRST    BCTR  LR,0                                                     77200013
         EX    LR,MVCHR                                                 77600013
* REPLY AREA NOW BLANKED OUT                                            78000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP006-TSS 78200020
DSP06    WTOR  MF=(E,(1))            $$ WRITE-TO-OPERATOR-WITH-REPLY.   78400013
*        ----------------------------------------------------DSP006-TSS 78600020
         LTR   RE,RE                    IS THERE AN EVENT OPTION..      78800013
         BP    DSP05                    YES  WAIT TO BE DONE LATER.     79200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP007-TSS 79400020
DSP0W    WAIT  ECB=0(RC)             $$ WAIT FOR REPLY.                 79600013
*        ----------------------------------------------------DSP007-TSS 80000020
DSP04    SH    RC,H004                 ADDRESS BEGINNING OF AREA.       80500015
         L     R0,0(RC)                PICK UP SP AND LENGTH.           81400015
         FREEMAIN R,LV=(0),A=(RC)       FREE THE GOTTEN CORE.           82300015
DSP05    L     DR,OFDR(DR)              RESTORE SAVE AREA POINTER.      83200013
         LM    LR,PWR,OFLR(DR)                                          83600013
         BR    LR                    X  RETURN TO CALLER.               84000013
         EJECT                                                          88800013
*      MESSAGE LENGTH ZERO.                                             89200013
DZ000    LTR   RB,RB                    IS REPLY EXPECTED..             89600013
         BM    DSP05                    NO, DISPLAY REQUEST IGNORED.    90000013
         B     DZ011                                                    90200017
*      REPLY AREA LENGTH ZERO.                                          90400013
DZ010    BAL   RJ,UNSET                                                 90600017
DZ011    EQU   *                                                        90800017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP999-TSS 90900020
         L     BR,VERRC                                                 91000017
*        ----------------------------------------------------DSP999-TSS 91100020
         BALR  RA,BR                 X  NO RETURN.                      91200013
         DC    H'7'                     DISPLAY ERROR.                  91600013
*   ERROR EVENT VARIABLE IS STILL ACTIVE                                92000013
DZ090    BAL   RJ,UNSET                                                 92200017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP998-TSS 92300020
         L     BR,VERRC                                                 92400017
*        ----------------------------------------------------DSP998-TSS 92600020
         BALR  RA,BR                                                    92800013
         DC    H'15'                    ATTEMPT TO USE ACTIVE E V.      93200013
 SPACE                                                                  93260017
         EJECT                                                          93600013
MVCHR    MVC   1(*-*,BR),0(BR)                                          94000013
MVCH     MVC   4(*-*,RG),0(RH)                                          94400013
H004     DC    H'4'                                                     94460015
H008     DC    H'8'                                                     94520015
EVOF     DC    AL2(EVCF-EVBG)                                           94580015
MSGL     DC    AL2(LMSG)                                                94640015
REPL     EQU   MSGL                     SINCE LREP =LMSG                94700015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP997-TSS 95700020
VERRC    DC    V(IHEERRC)                                               96800013
*        ----------------------------------------------------DSP997-TSS 96820020
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*DSP008-TSS 96850020
SP01     DC    AL1(1),AL3(0)            MUST BE WORD ALIGNED.           96900015
*        ----------------------------------------------------DSP008-TSS 96910020
RT02     DC    B'0100000000000000'      ROUTE TWO FOR WTO         31659 96930020
DS03     DC    B'0010000000000000'     DESC CODE.                 42000 96950021
MCSF     DC    B'1000000000000000'      MCS FLAGS                       96980001
         END                                                            97200013
