ESM4     TITLE '   IHEESM    MESSAGE ROUTINE                           *00200015
               OS/360 PL/I LIBRARY'                                     00400013
*   VERSION    FOURTH VERSION OF F-LEVEL PL/1 COMPILER                  00600015
*                                                                       00800015
*   STATUS     CHANGE LEVEL - 0.                                        01000015
         SPACE 1                                                        01020019
*C440000-442000                                               BPC 45976 01040056
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ESM000-TSS 01060001
*        ----------------------------------------------------ESM000-TSS 01120001
*                                                                       01200013
*   SIZE       XXX BYTES                                                01400013
*                                                                       01600013
*   FUNCTION                                                            01800013
*              TO DETERMINE THE LOCATION OF THE POINT OF INTERRUPT      02000013
*              AND TO PRINT THE STANDARD SNAP MESSAGE, THE STANDARD     02200013
*              SYSTEM ACTION MESSAGE OR A COMBINATION OF BOTH. ALSO TO  02400013
*              PRINT CHECK LABEL SYSTEM ACTION MESSAGE.                 02600013
*                                                                       02800013
*   ENTRY POINTS                                                        03000013
*              IHEESMA - RA = A(FIRST WORD OF A LIBRARY VDA)            03200013
*              IHEESMB - CHECK LABEL RA = A(LABEL LENGTH AND SYMBOL)    03400013
*                                                                       03600013
*   INPUT                                                               03800013
*              RA POINTS AT FIRST WORD OF A LIBRARY VDA USED AS SAVE    04000013
*              AREA AND MESSAGE BUFFER - ALSO PASSED ARE ADDRESS OF     04200013
*              PRINT ROUTINE, GET AND FREE LWS ROUTINES, ADDRESS OF     04400013
*              CURRENT DSA AND FLAGS TO INDICATE TYPE OF MESSAGE        04600013
*              AND THE LENGTH OF THE PRV                                04700015
*                                                                       04800013
*   OUTPUT                                                              05000013
*              SNAP  OR SYSTEM ACTION MESSAGE PRINTED OUT               05200013
*                                                                       05400013
*   EXTERNAL MODULES                                                    05600013
*              IHEPRT,IHESA/IHETSA,IHEERIA,IHEERDA,IHEEREA,IHEEROA,     05700015
*              IHEERPA,IHEERTA                                          05800015
*                                                                       06000013
*   SUPERVISOR MACROS                                                   06200013
*              LOAD - TO LOAD IHEERN COMPLEX                            06400013
*                                                                       06600013
*   EXITS                                                               06800013
*              RETURN TO IHEERR VIA SUPERVISOR                          07000013
*                                                                       07200013
*   TABLES/WORK AREA                                                    07400013
*              LIBRARY VDA                                              07600013
*                                                                       07800013
*   ATTRIBUTES  READ ONLY AND REENTRANT                                 08000013
*                                                                       08200013
*   PRIVATE MACROS                                                      08400013
*              IHELIB,IHEZAP                                            08600013
*                                                                       08800013
*   NOTES                                                               09000013
*              SEE OS/360 PL/I LIBRARY PLM FOR DESCRIPTION OF LIBRARY   09200013
*              CONVENTIONS AND STANDARDS.                               09400013
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    09600013
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    09800013
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  10000013
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  10200013
*              CONSTANTS, BY REASSEMBLY, WILL RESULT IN A CORRECT       10400013
*              MODULE FOR THE NEW DEFINITIONS.                          10600013
         EJECT                                                          10800013
IHEESM   CSECT                                                          11000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ESM001-TSS 11100001
IHEZLWE  DSECT                     DEFINITION OF LWE AREA               11200013
WKAE     DS    18F                 SAVE AREA                            11400013
*        ----------------------------------------------------ESM001-TSS 11500001
ERRCDE   DS    1F                  SEARCH WORD AREA                     11600013
ERRCD2   DS    X                                                        11800013
ESWTCH   DS    X                                                        12000013
ONFLAG   DS    X                                                        12200013
AENTRY   DS    X                                                        12400013
SNAPAR   EQU   ONFLAG                                                   12600013
RASLOT   DS    F                                                        12800013
CFLSLOT  DS    F                                                        13000013
CONVAR   DS    3F                                                       13200013
BUFFER   EQU   CONVAR                                                   13400013
INTFLAG  DS    X                                                        13460015
PRVL     DS    H                                                        13520015
EPLOCK   DS    D                                                        13600013
INTPSW   DS    D                                                        13800013
SPISAV   DS    F                                                        14000013
PRINT    DS    F                                                        14200013
NEWLWS   DS    F                                                        14400013
FREEVDA  DS    F                                                        14600013
CHARAD   EQU   FREEVDA                                                  14700015
LSASLOT  EQU   CFLSLOT                                                  14800013
SIGNLOC  EQU   NEWLWS                                                   15000013
LENAREA  EQU   NEWLWS                                                   15200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ESM002-TSS 15300001
         IHELIB                                                         15400013
*        ----------------------------------------------------ESM002-TSS 15500001
         IHEZAP                                                         15600013
IHEESM   CSECT                                                          15800013
         ENTRY IHEESMA,IHEESMB                                          16000013
         USING IHEZLWE,RI                                               16200013
         USING IHEZDCL,RF                                               16400013
         USING IHEZLCA,RJ                                               16600013
         USING IHEZAPE,RB                                               16800013
         USING *,WR                                                     17000013
IHEESMA  STM   LR,PWR,OFLR(DR)     SAVE REGISTERS                       17200013
         LR    WR,BR               ESTABLISH ADDRESSABILITY             17400013
         LR    RI,DR               RI AT OLD LWE                        17600013
         ST    DR,OFDR+8(RA)       SAVE DR IN SAVE AREA CHAIN BACK      17800013
         LA    DR,8(RA)            POINT DR AT START OF SAVE AREA       18000013
         MVI   0(DR),X'61'         SET FLAGS AT HEAD OF SAVE AREA       18200013
         L     BR,NEWLWS                                                18400013
         BALR  LR,BR               GET NEW LWS                          18600013
         LA    RE,72(DR)           RE AT START OF MESSAGE AREA          18800013
         LR    RA,PR                                                    18830015
         SH    RA,H8                                                    18860015
         TM    1(RA),X'80'           IS IT TASKING                      18890015
         BZ    ISSYS                 NO                                 18920015
         LA    RA,288(DR)            RA AT ENQ/DEQ WORKSPACE            18950015
         LA    RF,1                SET RF TO ENQ                        18980015
         BAL   RC,ENQIT                                                 19010015
ISSYS    TM    SNAPAR,X'10'        IS IT SYSTEM ACTION                  19100015
         BC    8,NOTSYS            BRANCH IF NO                         19200013
         TM    SNAPAR,X'08'        IS IT EXCEPTIONAL                    19400013
         BC    1,NOTSYS            YES                                  19600013
         SR    RF,RF                                                    19800013
         IC    RF,ERRCDE           INSERT ERRCDE                        20000013
         CLI   ERRCDE,X'10'        IS CODE AN ON-TYPE ERROR             20200013
         BC    10,ONTYPE           YES                                  20400015
         SR    RC,RC                                                    20600013
         IC    RC,EPTAB(RF)        INSERT OFFSET TO APPROP CHAR STRG    20800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ESM999-TSS 20900000
         LA    RC,EPLOCT(RC)       POINT RC AT APPROP MODULE NAME       21000013
*        ----------------------------------------------------ESM999-TSS 21100000
         MVC   EPLOCK(8),0(RC)     MOVE NAME TO EPLOCK                  21200013
         SLL   RF,1                MULTIPLY CODE BY 2                   21400013
         BC    15,LOADIT                                                21600013
ONTYPE   SRL   RF,2                DIVIDE INCREMENT BY 4                21800013
         CLI   ERRCDE,X'80'        IS CONDITION I/O                     22000013
         BC    10,IONS1            YES                                  22200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ESM998-TSS 22300000
         MVC   EPLOCK(8),EPON1     NO - NEED IHEEROA                    22400013
*        ----------------------------------------------------ESM998-TSS 22500000
         SH    RF,H4               SUBTRACT 4 FROM INDEX                22600015
         BC    15,LOADIT                                                22800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ESM997-TSS 22900000
IONS1    MVC   EPLOCK(8),EPIO1     NEED IHEERPA                         23000013
*        ----------------------------------------------------ESM997-TSS 23100000
         SH    RF,H32              SUBTRACT 32 FROM INDEX               23200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ESM003-TSS 23300001
LOADIT LOAD  EPLOC=EPLOCK          LOAD IN MESSAGE MODULE               23400013
*        ----------------------------------------------------ESM003-TSS 23500001
         LR    RB,R0               R0 POINTS AT NON-RESIDENT EXEP       23600013
         LR    RA,RE               ADDRESS OF MESSAGE AREA TO RA        23800013
         L     RG,0(RB)            RG POINTS AT EINDEX                  24000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ESM996-TSS 24060000
*        ----------------------------------------------------ESM996-TSS 24120000
         LH    RG,0(RF,RG)         RG HAS OFFSET INTO ERROR TABLE       24200013
         L     RD,4(RB)            RD AT ERTABLE                        24400013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ESM995-TSS 24460000
*        ----------------------------------------------------ESM995-TSS 24520000
         LA    RG,0(RD,RG)         RG POINTS AT ERTABLE SECTOR          24600013
         IC    RF,ERRCD2           PICK UP ERRCD2                       24800013
         SLL   RF,2                MULTIPLY BY 4 TO GIVE OFFSET         25000013
         LA    RG,0(RF,RG)         RG POINTS AT ERROR MESSAGE POINTER   25200013
         LH    RF,0(RG)            RF HAS OFFSET TO MESSAGE             25400013
         L     RC,8(RB)            RC POINTS AT MESTAB                  25600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ESM994-TSS 25660000
*        ----------------------------------------------------ESM994-TSS 25720000
         LA    RC,0(RF,RC)         RC POINTS AT MESSAGE IN TABLE        25800013
         MVC   0(8,RE),IHE         FIXED PART OF ERROR NUMBER           26000013
         MVC   3(3,RE),1(RC)       VARIABLE PART OF ERROR NUMBER        26200013
         MVI   6(RE),C'I'          INSERT ACTION CODE                   26400013
         LA    RE,8(RE)            BUMP PRINT LINE POINTER              26600013
         LA    BR,MESSAGE                                               26800013
         TM    WONC,X'80'          IS CODE I/O ON TYPE                  27000013
         BC    1,IOH21             BRANCH IF YES                        27200013
         CLI   WONC,X'01'          IS CODE DP ERROR                     27400013
         BCR   2,BR                NO                                   27600013
         BC    8,DP                YES                                  27800013
IOH      TM    3(RG),X'02'         IS FILENAME REQUIRED                 28000013
         BCR   1,BR                BRANCH IF NO                         28200013
IOH21    L     RF,ERRCDE           A(DCLCB) TO RF                       28400013
         TM    ESWTCH,X'01'        I/O SIZE OR CONVERSION               28600013
         BC    8,SCIO1             BRANCH IF NOT                        28800013
GETCFL   L     RF,CFLSLOT          PICK UP ADDRESS OF CFL               29000013
SCIO1    LTR   RF,RF               DON'T PRINT FILENAME                 29100015
         BCR   8,BR                 IF RF ZERO                          29200015
         MVC   0(5,RE),FILE1       INSERT WORD FILE                     29300015
         SR    RB,RB                                                    29400013
         IC    RB,DFLN             INSERT LENGTH                        29600013
         EX    RB,MVC4X            MOVE FILENAME INTO MESSAGE           29800013
         LA    RE,6(RB,RE)         BUMP BUFFER POINTER                  30000013
         CLI   WONC,X'C0'          IS CONDITION IO CONVERSION           30200013
         BNE   NOTIOC              BRANCH IF NO                         30400013
         LH    RB,DPRO             RB HAS PR OFFSET FRO FCB ADDRESS     30600013
         L     RB,0(RB,PR)         RB AT FCB                            30800013
         TM    TFLX,TMIT           IS IT TRANSMIT                       31000013
         BC    14,NOTIOC           BRANCH IF NOT                        31200013
         MVC   0(14,RE),TRAMT      INSERT TRANSMIT                      31400013
         LA    RE,14(RE)           BUMP PRINT LINE POINTER              31600013
         BCR   15,BR                                                    31800013
NOTIOC   MVC   0(3,RE),DASHIT      HYPHEN BETWEEN FILENAME AND MESSAGE  32000013
         LA    RE,3(RE)            BUMP BUFFER POINTER                  32200013
MESSAGE  TM    3(RG),X'01'         IS TERMINATION REQUIRED              32400013
         BC    8,NOTERM            BRANCH IF NOT                        32600013
         OI    SNAPAR,X'01'        SET TERMINATION FLAG                 32800013
NOTERM   SR    RD,RD                                                    33000013
         IC    RD,0(RC)            LENGTH OF MESSAGE                    33200013
         EX    RD,MOVEX            MOVE MESSAGE TO BUFFER               33400013
         LA    RE,1(RD,RE)         RE AT LOCATION AFTER END             33600013
         CLI   ERRCDE,X'03'        IS ERROR CODE SOURCE PROGRAM ERROR   33800013
         BC    7,TCOND             NO                                   34000013
         CLI   ERRCD2,X'00'        IS IT THE ONE REQUIRING STATEMENT NO 34200013
         BC    7,TCOND             NO                                   34400013
         LH    RF,WONC+2           LOAD STATEMENT NUMBER                34600013
         LA    LR,NOSTAT           SET UP RETURN ADDRESS IN LR          34800013
STATNO   CVD   RF,BUFFER           CONVERT TO DECIMAL                   35000013
         MVC   0(6,RE),MASK1       MOVE EDIT MASK TO MESSAGE            35200013
         ED    0(6,RE),BUFFER+5    EDIT STATEMENT NUMBER IN             35400013
         CLI   1(RE),C' '          IS FIRST CHARACTER BLANK             35600013
         BC    7,NOBLANK           BRANCH IF NO                         35800013
         MVI   1(RE),C'0'          MOVE CHARACTER ZERO IN               36000013
NOBLANK  LA    RE,6(RE)            BUMP PRINT LINE POINTER              36200013
         BR    LR                  RETURN                               36400013
TCOND    CLI   ERRCDE,X'50'        IS ERROR CODE CONDITION              36600013
         LA    BR,NOTCON                                                36800013
         BCR   7,BR                NO                                   37000013
         L     RD,ERRCDE           GET ADDRESS OF IDENTIFYING CSECT     37200013
         SR    RF,RF                                                    37400013
         IC    RF,0(RD)            GET LENGTH OF IDENTIFIER             37600013
         BCTR  RF,0                SUBTRACT ONE                         37800013
         LTR   RF,RF               IS IT FIRST RELEASE                  38000013
         BCR   4,BR                YES                                  38200013
         CH    RF,H6               KEEP ON TESTING                      38400013
         BCR   2,BR                BRANCH IF FIRST RELEASE              38600013
         MVI   0(RE),C' '          INSERT BLANK                         38800013
         EX    RF,MVC3X            MOVE CONDITION NAME INTO MESSAGE     39000013
         LA    RE,2(RF,RE)         BUMP PRINT LINE POINTER              39200013
         BR    BR                                                       39400013
NOTSYS   LR    RA,RE               SET RA TO START OF MESSAGE AREA      39600015
         MVC   0(23,RE),SNAPTL     MOVE SNAP PRINT LINE IN              39800013
         BAL   LR,CONDIT           GET CONDITION NAME                   40000013
         MVC   10(4,RE),0(RF)      MOVE CONDITION NAME INTO MESSAGE     40200013
         LA    RE,23(RE)           BUMP PRINT LINE POINTER              40400013
NOTCON   TM    0(RH),X'40'         IS STATEMENT NO REQUIRED             40600013
         BC    8,NOSTAT            NO                                   40800013
         MVC   0(13,RE),INSTAT     INSERT 'IN STATEMENT'                41000013
         LA    RE,13(RE)           BUMP PRINT LINE POINTER              41200013
LHRF     LH    RF,98(RH)           PICK UP STATEMENT NUMBER             41400013
         BAL   LR,STATNO                                                41600013
NOSTAT   TM    ESWTCH,X'40'        IS IT MODEL 91 IMPRECISE INTPT       41800013
         BC    8,NOT91A            NO                                   42000013
         MVC   0(13,RE),ATOFF91                                         42200013
         LA    RE,2(RE)            BUMP PRINT LINE POINTER              42400013
          B    MOVEAT                                                   42600013
NOT91A   MVC   0(11,RE),ATOFF      MOVE AT IN                           42800013
MOVEAT   L     RC,OFDR(RI)         RC AT INTERRUPT SAVE AREA            43000013
         L     RF,OFLR(RH)         RF CONTAINS INTERRUPT LOCATION       43200013
         LA    BR,GOTIT            LOAD BR FOR BRANCH                   43400013
         CR    RH,RC               IS INTERRUPT SAVE AREA CURRENT DSA   43600013
         BCR   7,BR                NO - THEN RF IS CORRECT              43800013
         CLI   INTFLAG,X'FF'           IS IT AN 'A' ENTRY         45976 44000056
         BCR   7,BR                    NO,THEN RF IS CORRECT      45976 44200056
         CLC   INTPSW+5(3),TWO3X   IS ADDRESS IN PSW = 2                44400013
         BCR   8,BR                YES - THEN RF IS CORRECT             44600013
         L     RF,INTPSW+4         ADDRESS IN PSW IS CORRECT            44800013
GOTIT    LA    RF,0(RF)            CLEAR TOP BYTE                       45000013
         L     RD,OFDR(RH)         RD AT SAVE AREA PRIOR TO DSA         45200013
         CLI   0(RD),X'25'         LWS VDA                              45400013
         BC    8,ONMESS            YES                                  45600013
         SR    R0,R0               INITIALISE R0                        45650015
         SR    BR,BR               SET BR FOR NO TASKNEME               45700015
         BAL   14,CHAIN            RI LENGTH, RC AT NAME                45800013
         SR    RF,RD               RF EQUALS OFFSET                     46000013
         BAL   14,CONVERT          RE AT CONVERTED OFFSET               46200013
         MVC   11(6,RE),CONVAR+4   MOVE OFFSET TO MESSAGE               46400013
         MVC   17(5,RE),SPLN2      MOVE MORE MESSAGE IN                 46600013
         MVC   22(13,RE),SPLN2+20                                       46800013
         EX    RG,MVC2X            AND MOVE ENTRY POINT NAME IN         47000013
         LA    RE,36(RE,RG)                                             47200013
         TM    SNAPAR,X'20'        IS SNAP REQUIRED                     47203015
         BZ    CALCLEN             NO TASKNAME IF NOT SNAP              47206015
         LTR   BR,BR               ANY TASKNAME                         47210015
         BZ    CALCLEN             NO                                   47220015
TASKNM   SR    RG,RG                                                    47230015
         IC    RG,0(BR)            RG = LENGTH                          47240015
         BCTR  RG,0                SUBTRACT 1                           47250015
         LA    RC,1(BR)            RC AT TASKNAME                       47260015
         MVC   0(7,RE),TASK        MOVE ' (TASK ' IN                    47270015
         EX    RG,MVC5X            MOVE IN TASKNAME                     47280015
         LA    RE,8(RE,RG)                                              47290015
         MVI   0(RE),C')'                                               47300015
         LA    RE,1(RE)                                                 47310015
CALCLEN  SR    RE,RA               CALCULATE LENGTH OF MESSAGE          47400013
         STH   RE,LENAREA          STORE LENGTH                         47600013
         LA    RB,LENAREA          RB AT LENGTH FOR PRINT               47800013
PRTRT    L     BR,PRINT                                                 48000013
         LR    RE,R0               SAVE R0                              48100015
         BALR  LR,BR               PRINT LINE                           48200013
         LR    R0,RE               RESTORE R0                           48300015
         TM    SNAPAR,X'20'        TRACE REQUIRED                       48400013
         BC    8,OUT               NO                                   48600013
         LA    RA,72(DR)           RESET RA AT START OF MESSAGE         48800013
         MVC   0(10,RA),SPLN1      MOVE SECOND SNAP LINE IN (PART 1)    49000013
         LA    RE,9(RA)            RESET RE                             49200013
         TM    0(RH),X'40'         IS STATEMENT NO REQUIRED             49400013
         BC    1,STNOSN            YES                                  49600013
GETPNAM  MVC   1(33,RE),SPLN2      MOVE PART 2 OF SNAP LINE IN          49800013
         SR    R0,R0               INITIALISE R0                        49850015
         SR    BR,BR                 SET BR NO TASKNAME                 49900015
         BAL   LR,CHAIN            GET ENTRY POINT NAME                 50000013
         EX    RG,MVC1X            MOVE IT IN                           50200013
         LA    RE,35(RE,RG)        BUMP PRINT LINE POINTER              50400013
         LTR   BR,BR               ANY TASKNAME                         50460015
         BNZ   TASKNM              YES                                  50520015
         BC    15,CALCLEN          GO TO PRINT                          50600013
STNOSN   MVC   1(21,RE),STNOPTL    MOVE STATEMENT NO CHAR STRING IN     50800013
         LTR   R0,R0               HAVE WE CROSSED A TASK BOUNDARY      50870015
         BZ    LOADNO              NO                                   50940015
         LR    BR,R0               YES, LOAD STATEMENT                  51010015
         LH    RF,EVST+2-EVBG(BR)   NUMBER FROM EVENT VARIABLE          51080015
         B     BPPTR                                                    51150015
LOADNO   LH    RF,98(RH)           LOAD STATEMENT NO FROM DSA           51220015
BPPTR    LA    RE,15(RE)           BUMP PRINT LINE POINTER              51290015
         BAL   LR,STATNO           CONVERT AND INSERT STATEMENT NO      51400013
          BC   15,GETPNAM                                               51600013
ONMESS   LA    RD,16(RD)           RD AT LSA                            51800013
         L     RB,OFBR(RD)         RB AT ON UNIT ENTRY                  52000013
         LA    RB,0(RB)            CLEAR TOP BYTE                       52200013
         SR    RF,RB               RF CONTAINS OFFSET                   52400013
         BAL   14,CONVERT          RE AT CONVERTED OFFSET               52600013
         MVC   11(6,RE),CONVAR+4   MOVE OFFSET IN                       52800013
         MVC   17(33,RE),ONPLN     MOVE CHAR STRING IN                  53000013
         LR    RB,RI               SAVE RI                              53200013
         L     RI,OFDR(RD)         RI AT LSA                            53400013
         BAL   14,CONDIT           RF AT CONDITION NAME                 53600013
         MVC   38(4,RE),0(RF)      MOVE CONDITION NAME IN               53800013
         LA    RE,50(RE)           BUMP PRINT LINE POINTER              54000013
         LR    RI,RB               RESTORE RI                           54200013
         SR    R0,R0                                                    54300015
LOADRH   L     RH,OFDR(RH)         RH AT NEXT SAVE AREA BACK            54400013
         TM    0(RH),X'80'         IS IT A DSA                          54600013
         BC    8,LOADRH            NO                                   54800013
         BC    15,CALCLEN          GO TO PRINT                          55000013
OUT      OI    ESWTCH,X'08'        PREVENT ZEROING OF LCA FIELDS        55400013
         LR    RA,PR                                                    55450015
         SH    RA,H8                                                    55500015
         TM    1(RA),X'80'           IS IT TASKING                      55550015
         BZ    FREEV                 NO                                 55600015
         LA    RA,288(DR)            RA AT ENQ/DEQ WORKSPACE            55650015
         SR    RF,RF               SET RF TO DEQ                        55700015
         BAL   RC,ENQIT                                                 55750015
FREEV    L     BR,FREEVDA                                               55800013
         BALR  LR,BR               FREE LWS                             56000013
         NI    ESWTCH,X'F7'        CLEAR FREE LWS SWITCH                56200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ESM004-TSS 56300001
         DELETE EPLOC=EPLOCK       DELETE THE ERROR MESSAGE MODULE      56400013
*        ----------------------------------------------------ESM004-TSS 56500001
         L     DR,OFDR(DR)         CHAIN DR                             56600013
         LM    LR,PWR,OFLR(DR)     RESTORE REGISTERS                    56800013
         BR    LR                  RETURN                               57000013
DP       SR    RD,RD                                                    57200013
         IC    RD,2(RG)            OFFSET TO ROUTINE                    57400013
         L     RF,12(RB)           RF POINTS AT ROUTINE TABLE           57600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ESM993-TSS 57660000
*        ----------------------------------------------------ESM993-TSS 57720000
         LA    RD,0(RF,RD)         RD POINTS AT ROUTINE'S LAST 3 CHARS  57800013
         MVC   0(7,RE),IHE         MOVES ROUTINE NAME IHEXXX            58000013
         MVC   3(3,RE),0(RD)          INTO PRINT AREA                   58200013
         LA    RE,7(RE)            BUMP POINTER                         58400013
         BCR   15,BR                                                    58600013
NODSA    L     RH,OFDR(RH)         GET NEXT SAVE AREA                   58800013
         TM    0(RH),X'80'         IS SAVE AREA A DSA                   59000013
         BC    8,NODSA             NO                                   59200013
CHAIN    TM    0(RH),X'10'         IS DSA A PROCEDURE DSA               59400013
         BC    1,NODSA             NO                                   59600013
DSN      L     RH,OFDR(RH)         GET NEXT SAVE AREA                   59800013
         TM    0(RH),X'80'         IS IT A DSA                          60000013
         BC    1,DSYES             BRANCH IF YES                        60200013
         CLI   0(RH),X'29'         IS IT PRV VDA                        60400013
         BE    MAJPRV              YES                                  60440015
         CLI   0(RH),X'2F'         SUBTASK PRV                          60480015
         BE    SUBPRV              YES                                  60520015
         CLI   0(RH),X'2D'         SUBTASK PRV                          60560015
         BNE   DSN                 NO                                   60600015
SUBPRV   LH    BR,PRVL                                                  60620015
         L     RD,OFDR(RH)         RD AT ESA                            60640015
         L     RD,OFBR(RD)         RD AT ENTRY                          60660015
         L     R0,8(RH,BR)         R0 AT ATTACHORS DSA                  60680015
         L     BR,16(RH,BR)        BR AT TV                             60720015
         LR    RH,R0               RH AT ATTACHORS DSA                  60760015
         L     R0,12(BR)                                                60780015
         L     BR,8(BR)            BR AT A(SYMTAB ENTRY)                60800015
         B     GETLN                                                    60840015
MAJPRV   L     RH,OFDR(RH)                                              60880015
         NI    SNAPAR,X'DF'        CLEAR SNAP FLAG                      61000013
DSYES    L     RD,OFBR(RH)         RD AT ENTRY                          61200013
GETLN    SR    RG,RG                                                    61400015
         IC    RG,4(RD)            GET LENGHT OF ENTRY NAME             61600013
         BCTR  RG,0                DECREASE BY UNITY                    61800013
         LA    RC,5(RD)            RC AT NAME                           62000013
         BR    LR                  RETURN                               62200013
CONDIT   SR    RF,RF               ZERO RF                              62400013
         IC    RF,ERRCDE           INSERT ERROR CODE                    62600013
         SH    RF,H16              SUBTRACT 16                          62800015
         SRA   RF,1                DIVIDE BY 2                          63000013
         LA    RF,CODES(RF)        ADDRESS APPROPRIATE CODE             63200013
         BR    LR                  RETURN                               63400013
CONVERT  MVI   SIGNLOC,C'+'        SET POSITIVE FLAG                    63600013
         LTR   RF,RF               IS OFFSET NEGATIVE                   63800013
         BC    11,POS              NO                                   64000013
         LCR   RF,RF               COMPLEMENT                           64200013
         MVI   SIGNLOC,C'-'        SET NEGATIVE FLAG                    64400013
POS      SLL   RF,8                SHIFT OFFSET                         64600013
         ST    RF,CONVAR           STORE IT FOR CONVERTING              64800013
         UNPK  CONVAR+4(7),CONVAR(4) CONVERT                            65000013
         MVZ   CONVAR+4(6),CONVAR+3    OFFSET                           65200013
         TR    CONVAR+5(5),TABLE         INTO                           65400013
         MVC   CONVAR+4(1),SIGNLOC         CHAR STRING                  65600013
         BR    LR                  RETURN                               65800013
IHEESMB  STM   LR,PWR,OFLR(DR)     STORE REGISTERS                      66000013
         LR    RI,DR               ADDRESS OF LWE                       66200013
         L     RD,LSASLOT          PICK UP ADDRESS OF LSA               66400013
         ST    DR,OFDR(RD)         STORE DR IN LSA CHAINN BACK          66600013
         LR    DR,RD               LOAD DR TO POINT AT LSA              66800013
         BALR  WR,0                                                     66820015
         USING *,WR                                                     66840015
         LR    RH,PR                                                    66860015
         SH    RH,H8                                                    66880015
         TM    1(RH),X'80'           IS IT TASKING                      66900015
         BZ    LPRNT                 NO                                 66920015
         L     RJ,CHARAD           A(VDA)                               66940015
         ST    RA,CHARAD           SAVE RA ACROSS ENQ                   66960015
         LA    RA,8(RJ)            RA AT ENQ/DEQ WORKSPACE              66980015
         LA    RF,1                SET RF TO ENQ                        67000015
         BAL   RC,ENQIT              GO AND ENQ                         67020015
         L     RA,CHARAD           PICK UP A(CHAR STRING)               67040015
LPRNT    L     BR,PRINT                                                 67060015
         LA    RB,LENAREA          RB POINTS AT LENGTH                  67200013
         BALR  LR,BR               PRINT MESSAGE                        67400013
         TM    1(RH),X'80'           IS IT TASKING                      67450015
         BZ    RSTDR                 NO                                 67500015
         LA    RA,8(RJ)              RA AT ENQ/DEQ WORKSPACE            67550015
         SR    RF,RF               SET RF TO DEQ                        67600015
         BAL   RC,ENQIT                                                 67650015
RSTDR    L     DR,OFDR(DR)                                              67700015
         LM    LR,PWR,OFLR(DR)     RESTORE REGISTERS                    67800013
         BR    LR                  RETURN                               68000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ESM005-TSS 68002001
 SPACE                                                                  68005015
ENQIT    BALR  RG,0                                                     68010015
         USING *,RG                                                     68015015
BASENQ   L     BR,0(RA)              LOAD QSPR                          68020015
         L     BR,0(BR)                                                 68025015
         LTR   BR,BR                                                    68030015
         BCR   12,RC               RETURN IF SYSPRINT CLOSED            68035015
         LA    BR,0(BR)                                                 68040015
         LA    RA,4(RA)                                                 68045015
         ST    BR,12(RA)                                                68050015
         ST    BR,16(RA)                                                68055015
         MVC   0(4,RA),QWORD                                            68060015
         LA    BR,12(RA)                                                68065015
         ST    BR,4(RA)                                                 68070015
         LR    BR,DR                                                    68075015
FINDDSA  L     BR,4(BR)                                                 68080015
         TM    0(BR),X'80'           FIND CURRENT DSA                   68085015
         BZ    FINDDSA                                                  68090015
         LTR   RF,RF                                                    68095015
         BZ    ITSDEQ                                                   68100015
         LA    RF,72(BR)                                                68105015
         ST    RF,8(RA)                                                 68110015
         ENQ   ,MF=(E,(1))                                              68115015
         SR    LR,LR                                                    68120015
         IC    LR,0(RF)                                                 68125015
         LA    LR,1(LR)            BUMP COUNT IN DSA                    68130015
         STC   LR,0(RF)                                                 68135015
         BR    RC                                                       68140015
 SPACE                                                                  68145015
ITSDEQ   SR    LR,LR                                                    68150015
         IC    LR,72(BR)                                                68155015
         BCTR  LR,0                                                     68160015
         STC   LR,72(BR)                                                68165015
         LA    BR,72(BR)                                                68170015
         ST    BR,8(RA)                                                 68175015
         DEQ   ,MF=(E,(1))                                              68180015
         BR    RC                                                       68185015
*        ----------------------------------------------------ESM005-TSS 68192001
H6       DC    H'6'                                                     68200013
H4       DC    H'4'                                                     68300015
H16      DC    H'16'                                                    68400015
H32      DC    H'32'                                                    68600013
H8       DC    H'8'                                                     68660015
QWORD    DC    X'FF010000'                                              68720015
MOVEX    MVC   0(1,RE),4(RC)       MOVE INSTRUCTION TO BE EXECUTED      68800013
MVC1X    MVC   34(0,RE),0(RC)                                           69000013
MVC2X    MVC   35(0,RE),0(RC)                                           69200013
MVC3X    MVC   1(0,RE),1(RD)                                            69400013
MVC4X    MVC   5(0,RE),DFIL                                             69600013
MVC5X    MVC   7(0,RE),0(RC)                                            69700015
TWO3X    DC    X'000002'                                                69800013
EPTAB    DC    X'000810101010101018'                                    70000015
MASK1    DC    X'402120202020'                                          70200013
TABLE    DC    C'0123456789ABCDEF' TRANSLATION TABLE                    70400013
FILE1    DC    C'FILE '                                                 70600013
IHE      DC    CL8'IHE'            FIXED PART OF ROUTINE NAME           70800013
TRAMT    DC    C' (TRANSMIT)'                                           71000013
DASHIT   DC    C' - '                                                   71200013
SNAPTL   DC    C'CONDITION      OCCURRED'                               71400013
INSTAT   DC    C' IN STATEMENT'                                         71600013
ATOFF    DC    C' AT OFFSET '                                           71800013
ATOFF91  DC    C' NEAR OFFSET '                                         72000013
SPLN1    DC    C'    CALLED'                                            72200013
SPLN2    DC    C' FROM PROCEDURE WITH ENTRY POINT '                     72400013
STNOPTL  DC    C', IN STATEMENT      ,'                                 72600013
ONPLN    DC    C' FROM ENTRY POINT OF      ON UNIT'                     72800013
TASK     DC    C' (TASK '                                               72900015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ESM006-TSS 72950019
EPLOCT   DC    CL8'IHEERIA'                                             73000013
         DC    CL8'IHEERDA'                                             73200013
         DC    CL8'IHEEREA'                                             73400013
         DC    CL8'IHEERTA'                                             73500015
EPON1    DC    CL8'IHEEROA'                                             73600013
EPIO1    DC    CL8'IHEERPA'                                             73800013
*        ----------------------------------------------------ESM006-TSS 73850019
CODES    DC    C'STRG'                                                  73900015
         DC    C'OFLO'                                                  74000015
         DC    C'SIZE'                                                  74200013
         DC    C'FOFL'                                                  74400013
         DC    C'SUBR'                                                  74600013
         DC    C'CHCK'                                                  74800013
         DC    C'CONV'                                                  75000013
         DC    C'CHCK'                                                  75200013
         DC    C'COND'                                                  75400013
         DC    C'FIN '                                                  75600013
         DC    C'ERR '                                                  75800013
         DC    C'ZDIV'                                                  76000013
         DC    C'UFLO'                                                  76200013
         DC    C'AREA'                                                  76400015
         DC    C'    '                                                  76600013
         DC    C'NAME'                                                  76800013
         DC    C'RECD'                                                  77000013
         DC    C'TMIT'                                                  77200013
         DC    C'    '                                                  77400013
         DC    C'KEY '                                                  77600013
         DC    C'ENDP'                                                  77800013
         DC    C'ENDF'                                                  78000013
         DC    C'    '                                                  78200013
         DC    C'UNDF'                                                  78400013
         DC    C'PEND'                                                  78500001
PWR      EQU   WR                                                       78600013
         END                                                            78800013
