ESS2     TITLE '    IHEESS   SNAP ROUTINE                              *00200013
               OS/360 PL/I LIBRARY'                                     00400013
*    0160-0162,0172,0392,0550                                      8245 00600013
*    0160,0170,0390,0548,0754-0758                                 7104 00800013
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  01000013
*                                                                       01200013
*   STATUS     CHANGE LEVEL - VERSION 2                                 01400013
*                                                                       01600013
*   SIZE       1968BYTES                                                01800013
*                                                                       02000013
*   FUNCTION                                                            02200013
*              TO DETERMINE THE LOCATION OF THE POINT OF INTERRUPT      02400013
*              AND TO PRINT THE STANDARD SNAP MESSAGE, THE STANDARD     02600013
*              SYSTEM ACTION MESSAGE OR A COMBINATION OF BOTH. ALSO TO  02800013
*              PRINT CHECK LABEL SYSTEM ACTION MESSAGE.                 03000013
*                                                                       03200013
*   ENTRY POINTS                                                        03400013
*              IHEESSA - RA = A(THIRD WORD OF A LIBRARY VDA)            03600013
*              IHEESSB - CHECK LABEL RA = A(LABEL LENGTH AND SYMBOL)    03800013
*                                                                       04000013
*   INPUT                                                               04200013
*              RA POINTS AT THIRD WORD OF A LIBRARY VDA USED AS SAVE    04400013
*              AREA AND MESSAGE BUFFER - ALSO PASSED ARE ADDRESS OF     04600013
*              PRINT ROUTINE, GET AND FREE LWS ROUTINES, ADDRESS OF     04800013
*              INTERRUPT VDA IF PRESENT, AND ADDRESS OF CURRENT DSA.    05000013
*                                                                       05200013
*   OUTPUT                                                              05400013
*              SNAP  OR SYSTEM ACTION MESSAGE PRINTED OUT               05600013
*                                                                       05800013
*   EXTERNAL MODULES                                                    06000013
*              IHEPRT                                                   06200013
*                                                                       06400013
*   SUPERVISOR MACROS                                                   06600013
*              LOAD - TO LOAD IHEERNA                                   06800013
*                                                                       07000013
*   EXITS                                                               07200013
*              RETURN TO IHEERR VIA SUPERVISOR                          07400013
*                                                                       07600013
*   TABLES/WORK AREA                                                    07800013
*              LIBRARY VDA                                              08000013
*                                                                       08200013
*   ATTRIBUTES  READ ONLY AND REENTRANT                                 08400013
*                                                                       08600013
*   PRIVATE MACROS                                                      08800013
*              IHELIB,IHEZAP                                            09000013
*                                                                       09200013
*   ASSEMBLY REQUIREMENTS                                               09400013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   09600013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        09800013
*                                                                       10000013
*   NOTES                                                               10200013
*              SEE OS/360 PL/I LIBRARY PLM FOR DESCRIPTION OF LIBRARY   10400013
*              CONVENTIONS AND STANDARDS.                               10600013
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    10800013
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    11000013
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  11200013
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  11400013
*              CONSTANTS, BY REASSEMBLY, WILL RESULT IN A CORRECT       11600013
*              MODULE FOR THE NEW DEFINITIONS.                          11800013
         EJECT                                                          12000013
IHEESS   CSECT                                                          12200013
IHEZLWE  DSECT                     DEFINITION OF LWE AREA               12400013
WKAE     DS    18F                 SAVE AREA                            12600013
ERRCDE   DS    1F                  SEARCH WORD AREA                     12800013
ERRCD2   DS    H                                                        13000013
ESWTCH   DS    H                   FLAG FOR STATUS SWITCHING            13200013
BUFF     DS    2F                  WORKSPACE FOR SNAP                   13400013
SPISAV   DS    F                                                        13600013
SNAPAR   DS    7F                                                       13800013
         IHELIB                                                         14000013
         IHEZAP                                                         14200013
IHEESS   CSECT                                                          14400013
         ENTRY IHEESSA,IHEESSB                                          14600013
         USING IHEZLWE,RB                                               14800013
         USING IHEZDCL,RF                                               15000013
         USING IHEZLCA,RJ                                               15200013
         USING *,WR                                                     15400013
IHEESSA  STM   LR,PWR,OFLR(DR)     SAVE REGISTERS                       15600013
         LR    WR,BR               ESTABLISH ADDRESSABILITY             15800013
         LR    RB,DR               SAVE POINTER TO LWE                  16000013
         LA    RC,8(RA)            POINT RC AT START OF SAVE AREA       16200013
         ST    DR,OFDR(RC)         SAVE DR                              16400013
         MVI   0(RC),X'61'         SET FLAGS AT HEAD OF SAVE AREA       16600013
         LR    DR,RC               SET DR AT VDA SAVE AREA              16800013
         L     BR,SNAPAR+12                                        8245 17000013
         BALR  LR,BR               GET NEW LWS                          17200013
         LA    RC,72(DR)           RC AT START OF MESSAGE AREA          17400013
         LR    RA,RC               RESTORE RA TO START OF MESSAGE AREA  17600013
         TM    SNAPAR,X'10'        IS IT SYSTEM ACTION                  17800013
         BC    14,NOTERM           BRANCH IF NO                         18000013
       LOAD  EP=IHEERNA            LOAD NON-RESIDENT EXEP               18200013
         LR    RH,R0               R0 POINTS AT NON-RESIDENT EXEP       18400013
         LR    RA,RC               ADDRESS OF MESSAGE AREA TO RA        18600013
         SR    RF,RF                                                    18800013
         IC    RF,ERRCDE                                                19000013
         CLI   ERRCDE,X'10'        IS CODE AN ON-TYPE ERROR             19200013
         BC    10,ONTYPE           BRANCH IF YES                        19400013
         SLL   RF,1                MULTIPLY CODE BY 2                   19600013
         BC    15,GETEIN           BRANCH                               19800013
ONTYPE   SRL   RF,2                DIVIDE INCREMENT BY 4                20000013
         LA    RF,6(RF)            ADD 6                                20200013
GETEIN   L     RG,0(RH)            RG POINTS AT EINDEX                  20400013
         LH    RG,0(RF,RG)         RG HAS OFFSET INTO ERROR TABLE       20600013
         L     RE,4(RH)            RE POINTS AT ERTABLE                 20800013
         LA    RG,0(RE,RG)         RG POINTS AT ERTABLE SECTOR          21000013
         IC    RF,ERRCD2           PICK UP ERRCD2                       21200013
         SLL   RF,2                MULTIPLY BY 4 TO GIVE OFFSET         21400013
         LA    RG,0(RF,RG)         RG POINTS AT ERROR MESSAGE POINTER   21600013
         LH    RF,0(RG)            RF HAS OFFSET TO MESSAGE             21800013
         L     RC,8(RH)            RC POINTS AT MESTAB                  22000013
         LA    RC,0(RF,RC)         RC POINTS AT MESSAGE IN TABLE        22200013
         LR    RE,RA               SAVE RA                              22400013
         MVC   0(3,RE),IHE         FIXED PART OF ERROR NUMBER           22600013
         MVC   3(3,RE),1(RC)       VARIABLE PART OF ERROR NUMBER        22800013
         MVI   6(RE),C'I'          INSERT ACTION CODE                   23000013
         MVI   7(RE),C' '          INSERT BLANK                         23200013
         LA    RE,8(RE)            BUMP PRINT LINE POINTER              23400013
         TM    ERRCDE,X'81'        IS ERROR CODE C ENTRY I/O            23600013
         BC    4,IOORDP            BRANCH IF YES                        23800013
         CLI   ERRCDE,X'00'        IS ERROR CODE C ENTRY I/O            24000013
         BC    8,IOH               BRANCH IF YES                        24200013
MESS     SR    RD,RD                                                    24400013
         IC    RD,0(RC)            LENGTH OF MESSAGE                    24600013
         EX    RD,MOVE             MOVE MESSAGE TO BUFFER               24800013
         LA    RE,1(RD,RE)         RE AT LOCATION AFTER END             25000013
         CLI   ERRCDE,X'03'        IS ERROR CODE SOURCE PROGRAM ERROR   25200013
         BC    7,TCOND             NO                                   25400013
         CLI   ERRCD2,X'00'        IS IT THE ONE REQUIRING STATEMENT NO 25600013
         BC    7,TCOND             NO                                   25800013
         LH    RF,WONC+2           LOAD STATEMENT NUMBER                26000013
         LA    LR,NOSTAT           SET UP RETURN ADDRESS IN LR          26200013
         BC    15,STATNO           STATEMENT NO ROUTINE                 26400013
TCOND    CLI   ERRCDE,X'50'        IS ERROR CODE CONDITION              26600013
         BC    7,SYSNAP            NO                                   26800013
         L     RD,ERRCDE           GET ADDRESS OF IDENTIFYING CSECT     27000013
         SR    RF,RF                                                    27200013
         IC    RF,0(RD)            GET LENGTH OF IDENTIFIER             27400013
         BCTR  RF,0                SUBTRACT ONE                         27600013
         LTR   RF,RF               IS IT FIRST                          27800013
         BM    SYSNAP              BRANCH IF SO                         28000013
         CH    RF,SIX              KEEP ON TESTING                      28200013
         BC    2,SYSNAP            BRANCH IF FIRST RELEASE              28400013
         MVI   0(RE),C' '          INSERT BLANK                         28600013
         EX    RF,MVC5             MOVE CONDITION NAME INTO MESSAGE     28800013
         LA    RE,2(RF,RE)         BUMP PRINT LINE POINTER              29000013
SYSNAP   L     RH,SNAPAR+8         PICK UP ADDRESS OF CURRENT DSA       29200013
         TM    0(RH),X'40'         IS STATEMENT NO REQUIRED             29400013
         BC    14,NOSTAT           NO                                   29600013
         MVC   0(13,RE),INSTAT     INSERT 'IN STATEMENT'                29800013
         LA    RE,13(RE)           BUMP PRINT LINE POINTER              30000013
         L     RF,96(RH)           PICK UP STATEMENT NUMBER             30200013
         BAL   LR,STATNO                                                30400013
NOSTAT   MVC   0(4,RE),AT          MOVE AT IN                           30600013
         LA    RE,4(RE)            BUMP PRINT LINE POINTER              30800013
         ST    RE,SNAPAR+12        SAVE POINTER TO END OF MESSAGE       31000013
         TM    3(RG),X'01'         IS TERMINATION REQUIRED              31200013
         BC    14,NOTERM           BRANCH IF NOT                        31400013
         OI    SNAPAR,X'01'        SET TERMINATION FLAG                 31600013
NOTERM   L     RC,OFDR(RB)         RC AT INTERRUPT SAVE AREA            31800013
         LM    RG,RH,SNAPAR+4      PICK UP PASSED PARAMETERS            32000013
         L     RF,OFLR(RH)         RF CONTAINS INTERRUPT LOCATION       32200013
         CR    RH,RC               IS INTERRUPT SAVE AREA CURRENT DSA   32400013
         BNE   GOTIT               NO                                   32600013
         LTR   RG,RG               IS THERE AN INTERRUPT VDA            32800013
         BZ    GOTIT               NO                                   33000013
         L     RF,12(RG)           RF AT POINT OF INTERRUPT             33200013
GOTIT    L     RD,OFDR(RH)         RD AT SAVE AREA PRIOR TO DSA         33400013
         LA    RF,0(RF)            CLEAR TOP BYTE                       33600013
         CLI   0(RD),X'25'         LWS VDA                              33800013
         BC    8,ONMESS            YES                                  34000013
         LR    RG,RH               SAVE POINTER TO CURRENT DSA          34200013
         BAL   14,CHAIN            RI LENGTH, RC AT NAME                34400013
         SR    RF,RD               RF EQUALS OFFSET                     34600013
         BAL   14,CONVERT          RE AT CONVERTED OFFSET               34800013
         BAL   14,COND             RF AT CONDITION NAME                 35000013
         TM    SNAPAR,X'10'        IS IT SYSTEM ACTION                  35200013
         BO    SYSACT1             YES                                  35400013
         TM    0(RG),X'40'         IS STATEMENT NO REQUIRED             35600013
         BC    14,NOSTA            NO                                   35800013
         MVC   0(124,RA),PTLS1     MOVE PRINT LINE IN                   36000013
         MVC   10(4,RA),0(RF)      MOVE CONDITION NAME IN               36200013
         MVC   53(6,RA),0(RE)      MOVE OFFSET IN                       36400013
         EX    RI,MVC4             MOVE PROCEDURE NAME IN               36600013
         L     RF,96(RG)           PICK UP STATEMENT NO                 36800013
         LA    RE,36(RA)           RE AT STATEMENT NO AREA IN MESSAGE   37000013
         BAL   LR,STATNO           INSERT STATEMENT NO                  37200013
         LA    RB,LPTSL1           RB CONTAINS ADDRESS OF LENGTH        37400013
         BC    15,PRTRT            BRANCH TO PRINT ROUTINE              37600013
NOSTA    MVC   0(91,RA),PTL1       MOVE PRINT LINE IN                   37800013
         MVC   10(4,RA),0(RF)      MOVE CONDITION NAME IN               38000013
         MVC   34(6,RA),0(RE)      MOVE OFFSET IN                       38200013
         EX    RI,MVC1             MOVE PROCEDURE NAME IN               38400013
         LA    RB,LPTL1            RB CONTAINS ADDRESS OF LENGTH        38600013
PRTRT    LR    RG,RA               SAVE RA                              38800013
         DROP  RB                                                  8245 39000013
         USING IHEZLWE,LR                                          8245 39200013
         L     LR,OFDR(DR)                                         8245 39400013
         L     BR,SNAPAR+20                                        8245 39600013
         DROP  LR                                                  8245 39800013
         USING IHEZLWE,RB                                          8245 40000013
         BALR  LR,BR               PRINT LINE                           40200013
         LR    RA,RG               RESTORE RA                           40400013
         BC    15,SECLINE                                               40600013
ONMESS   LA    RD,16(RD)           RD AT LSA                            40800013
         L     RD,OFBR(RD)         RD AT ON UNIT ENTRY                  41000013
         LA    RD,0(RD)            CLEAR TOP BYTE                       41200013
         SR    RF,RD               RF CONTAINS OFFSET                   41400013
         BAL   14,CONVERT          RE AT CONVERTED OFFSET               41600013
         BAL   14,COND             RF AT CONDITION NAME                 41800013
         LR    RC,RF               RC AT CURRENT CONDITION NAME         42000013
         LR    RD,RB               SAVE RB                              42200013
         L     RB,OFDR(RH)         RB AT LSA                            42400013
         LA    RB,16(RB)           RB AT LSA                            42600013
         L     RB,OFDR(RB)         RB AT OLD LWE                        42800013
         BAL   14,COND             RF AT OLD CONDITION NAME             43000013
         LR    RB,RD               RESTORE RB                           43200013
         TM    SNAPAR,X'10'        IS IT SYSTEM ACTION                  43400013
         BO    SYSACT2             YES                                  43600013
         TM    0(RH),X'40'         IS STATEMENT NO REQUIRED             43800013
         BC    14,NOST             NO                                   44000013
         MVC   0(92,RA),ONPTSL     MOVE ON PRINT LINE IN                44200013
         MVC   10(4,RA),0(RC)      MOVE CONDITION NAME IN               44400013
         MVC   53(6,RA),0(RE)      MOVE OFFSET IN                       44600013
         MVC   80(4,RA),0(RF)      MOVE OLD CONDITION NAME IN           44800013
         L     RF,96(RH)           PICK UP STATEMENT NO                 45000013
         LA    RE,36(RA)           RE AT STATEMENT NO SLOT              45200013
         BAL   LR,STATNO           INSERT STATEMENT NO                  45400013
LOADRH   L     RH,OFDR(RH)         RH AT NEXT SAVE AREA BACK            45600013
         TM    0(RH),X'80'         IS IT A DSA                          45800013
         BC    14,LOADRH                                                46000013
         LA    RB,LONPTSL          RB AT ADDRESS OF LENGTH              46200013
         BC    15,PRTRT            BRANCH TO PRINT ROUTINE              46400013
NOST     MVC   0(73,RA),ONPTL      MOVE ON PRINT LINE IN                46600013
         MVC   10(4,RA),0(RC)      MOVE CURRENT CONDITION NAME IN       46800013
         MVC   34(6,RA),0(RE)      MOVE OFFSET IN                       47000013
         MVC   61(4,RA),0(RF)      MOVE OLD CONDITION NAME IN           47200013
         LA    RB,LONPTL           RB HAS ADDRESS OF LENGTH             47400013
         BC    15,PRTRT                                                 47600013
SECLINE  LTR   RH,RH               IS IT END OF SNAP                    47800013
         BZ    OUT                 YES                                  48000013
         TM    0(RH),X'40'         IS STATEMENT NO REQUIRED             48200013
         BC    1,STNOSN            YES                                  48400013
         MVC   0(72,RA),PTL2       MOVE SECOND PRINT LINE IN            48600013
         BAL   LR,CHAIN                                                 48800013
         EX    RI,MVC2             MOVE PROCEDURE NAME IN               49000013
         LA    RB,LPTL2                                                 49200013
         BC    15,PRTRT                                                 49400013
STNOSN   MVC   0(93,RA),PTL3                                            49600013
         L     RF,96(RH)           LOAD STATEMENT NO                    49800013
         LA    RE,24(RA)           LOAD ADDRESS OF STATEMENT NO SLOT    50000013
         L     RB,OFDR(DR)         PICK UP ADDRESS OF LWE (OLD)         50200013
         BAL   LR,STATNO           CALL STATEMENT NO ROUTINE            50400013
         BAL   14,CHAIN            RI LENGTH, RC AT NAME                50600013
         EX    RI,MVCY             MOVE PROCEDURE NAME IN               50800013
         LA    RB,LPTL3                                                 51000013
         BC    15,PRTRT                                                 51200013
SYSACT1  LA    RB,SNAPAR           RB AT SNAPAR, NOT LWE                51400013
         L     RG,12(RB)           RG  AT OLD MESSAGE POINTER           51600013
         MVC   0(31,RG),PTL1+27    MOVE CHARACTER STRING IN             51800013
         MVC   7(6,RG),0(RE)       MOVE OFFSET IN                       52000013
         LA    RG,31(RG)           BUMP PRINT LINE POINTER              52200013
         EX    RI,MVC3             MOVE PROCEDURE NAME IN               52400013
         SR    RG,RA               GET LENGTH OF MESSAGE                52600013
         LA    RG,1(RG,RI)         LENGTH OF MESSAGE                    52800013
         BC    15,STORRG                                                53000013
SYSACT2  LA    RB,SNAPAR           RB AT SNAPAR                         53200013
         L     RG,12(RB)           RG CONTAINS MESSAGE POINTER          53400013
         MVC   0(46,RG),ONPTL+27   MOVE IN CHARACTER STRING             53600013
         MVC   7(6,RG),0(RE)       MOVE OFFSET IN                       53800013
         MVC   34(4,RG),0(RF)      MOVE CONDITION NAME IN               54000013
         SR    RG,RA               LENGTH OF MESSAGE                    54200013
         LA    RG,46(RG)                                                54400013
STORRG   STH   RG,12(RB)           STORE LENGTH                         54600013
         TM    0(RB),X'20'         TRACE REQUIRED                       54800013
         BC    1,TRACE                                                  55000013
         SR    RH,RH                                                    55200013
TRACE    LA    RB,12(RB)           POINT RB AT LENGTH                   55400013
         BC    15,PRTRT                                                 55600013
OUT      L     RB,OFDR(DR)                                         8245 55800013
         L     BR,SNAPAR+16                                        8245 56000013
         BALR  LR,BR               FREE LWS                             56200013
         L     DR,OFDR(DR)         CHAIN DR                             56400013
         LM    LR,PWR,OFLR(DR)     RESTORE REGISTERS                    56600013
         BR    LR                  RETURN                               56800013
IOORDP   TM    WONC,X'01'          IS ERROR OF DP TYPE                  57000013
         BC    1,DP                BRANCH IF YES                        57200013
IOH      TM    3(RG),X'02'         IS FILENAME REQUIRED                 57400013
         BC    1,MESS              BRANCH IF NO                         57600013
         CLI   WONC,X'A0'          IS IT I/O SIZE                       57800013
         BC    8,GETCFL            BRANCH IF YES                        58000013
         CLI   WONC,X'C0'          IS IT I/O CONVERSION                 58200013
         BC    7,NORMIO            BRANCH IF NOT                        58400013
GETCFL   L     RF,SNAPAR+24        PICK UP ADDRESS OF CFL               58600013
         BC    15,SCIO                                                  58800013
NORMIO   L     RF,ERRCDE           RF AT DECLARE CONTROL BLOCK          59000013
SCIO     MVC   0(5,RE),FILE        INSERT WORD FILE                     59200013
         LA    RE,5(RE)            BUMP BUFFER POINTER                  59400013
         SR    RH,RH                                                    59600013
         IC    RH,DFLN             INSERT LENGTH                        59800013
         EX    RH,MVCX             MOVE FILENAME INTO MESSAGE           60000013
         LA    RE,1(RH,RE)         BUMP BUFFER POINTER                  60200013
         USING IHEZAPE,RH                                               60400013
         CLI   WONC,X'C0'          IS CONDITION IO CONVERSION           60600013
         BNE   NOTIOC              BRANCH IF NO                         60800013
         L     RF,SNAPAR+24        PICK UP ADDRESS OF CFL               61000013
         LH    RH,DPRO                                                  61200013
         L     RH,0(RH,PR)         RH AT FCB                            61400013
         TM    TFLX,TMIT           IS IT TRANSMIT                       61600013
         BC    14,NOTIOC           BRANCH IF NOT                        61800013
         MVC   0(14,RE),TRAM       INSERT TRANSMIT                      62000013
         LA    RE,14(RE)           BUMP PRINT LINE POINTER              62200013
         BC    15,MESS                                                  62400013
NOTIOC   MVC   0(3,RE),DASH        HYPHEN BETWEEN FILENAME AND MESSAGE  62600013
         LA    RE,3(RE)            BUMP BUFFER POINTER                  62800013
         BC    15,MESS                                                  63000013
DP       TM    WONC,X'02'          SOURCE PROGRAM ERROR                 63200013
         BC    1,MESS              BRANCH BACK IF YES                   63400013
         SR    RD,RD                                                    63600013
         IC    RD,2(RG)            OFFSET TO ROUTINE                    63800013
         L     RF,12(RH)           RF POINTS AT ROUTINE TABLE           64000013
         LA    RD,0(RF,RD)         RD POINTS AT ROUTINE'S LAST 3 CHARS  64200013
         MVC   0(3,RE),IHE         MOVES ROUTINE NAME IHEXXX            64400013
         MVC   3(3,RE),0(RD)          INTO PRINT AREA                   64600013
         MVI   6(RE),C' '          BLANK BETWEEN NAME AND MESSAGE       64800013
         LA    RE,7(RE)            BUMP POINTER                         65000013
         BC    15,MESS                                                  65200013
CHAIN    TM    0(RH),X'80'         IS SAVE AREA A DSA                   65400013
         BC    1,DSAY              BRANCH IF YES                        65600013
NODS     L     RH,4(RH)            GET NEXT SAVE AREA                   65800013
         BC    15,CHAIN                                                 66000013
DSAY     TM    0(RH),X'10'         IS DSA A PROCEDURE DSA               66200013
         BC    1,NODS              BRANCH IF NOT                        66400013
DSN      L     RH,4(RH)            GET NEXT SAVE AREA                   66600013
         L     RD,OFBR(RH)         RD AT ENTRY                          66800013
         TM    0(RH),X'80'         IS IT A DSA                          67000013
         BC    1,DSYES             BRANCH IF YES                        67200013
         TM    0(RH),X'FF'         IS IT THE SUPVSR SAVE AREA           67400013
         BC    7,DSN               BRANCH IF NOT                        67600013
         SR    RH,RH               FLAG FOR END OF SNAP                 67800013
DSYES    SR    RI,RI                                                    68000013
         IC    RI,4(RD)            RI LENGTH                            68200013
         BCTR  RI,0                DECREASE BY UNITY                    68400013
         LA    RC,5(RD)            RC AT NAME                           68600013
         BR    LR                                                       68800013
COND     SR    RF,RF               ZERO RF                              69000013
         IC    RF,ERRCDE           INSERT ERROR CODE                    69200013
         SH    RF,H24              SUBTRACT 24                          69400013
         SRA   RF,1                DIVIDE BY 2                          69600013
         LA    RF,CODES(RF)                                             69800013
         BR    LR                                                       70000013
CONVERT  MVI   199(RA),C'+'        SET POSITIVE FLAG                    70200013
         LTR   RF,RF               IS OFFSET NEGATIVE                   70400013
         BNL   POS                 NO                                   70600013
         LCR   RF,RF               COMPLEMENT                           70800013
         MVI   199(RA),C'-'        SET NEGATIVE FLAG                    71000013
POS      SLL   RF,8                SHIFT OFFSET                         71200013
         ST    RF,188(RA)          STORE IT FOR CONVERTING              71400013
         UNPK  192(7,RA),188(4,RA)                                      71600013
         MVZ   192(6,RA),191(RA)                                        71800013
         TR    193(5,RA),TABLE                                          72000013
         MVC   192(1,RA),199(RA)   MOVE IN SIGN                         72200013
         LA    RE,192(RA)          RE AT OFFSET                         72400013
         BR    LR                                                       72600013
STATNO   CVD   RF,BUFF             CONVERT TO DECIMAL                   72800013
         MVC   0(6,RE),MASK        MOVE EDIT MASK TO MESSAGE            73000013
         ED    0(6,RE),BUFF+5      EDIT STATEMENT NUMBER IN             73200013
         CLI   1(RE),C' '          IS FIRST CHARACTER BLANK             73400013
         BC    7,NOBLANK           BRANCH IF NO                         73600013
         MVI   1(RE),C'0'          MOVE CHARACTER ZERO IN               73800013
NOBLANK  LA    RE,6(RE)            BUMP PRINT LINE POINTER              74000013
         BR    LR                  RETURN                               74200013
IHEESSB  STM   LR,RD,OFLR(DR)      STORE REGISTERS                      74400013
         LR    RB,DR               ADDRESS OF LWE                       74600013
         L     RD,SNAPAR+4         PICK UP ADDRESS OF LSA               74800013
         ST    DR,OFDR(RD)         STORE DR IN LSA CHAINN BACK          75000013
         LR    DR,RD               LOAD DR TO POINT AT LSA              75200013
         L     BR,SNAPAR+20        ADDRESS OF PRINT ROUTINE             75400013
         LA    RB,ESWTCH                                                75600013
         BALR  LR,BR               PRINT MESSAGE                        75800013
         L     DR,OFDR(DR)         RESTORE DR                           76000013
         LM    LR,RD,OFLR(DR)      RESTORE REGISTERS                    76200013
         BR    LR                  RETURN                               76400013
         SPACE                                                     7104 76600013
MOVE     MVC   0(1,RE),4(RC)       MOVE INSTRUCTION TO BE EXECUTED      76800013
MVC5     MVC   1(0,RE),1(RD)                                            77000013
MVCX     MVC   0(0,RE),DFIL        MOVE INSTRUCTION TO BE EXECUTED      77200013
MVC1     MVC   58(0,RA),0(RC)                                           77400013
MVC2     MVC   43(0,RA),0(RC)                                           77600013
MVC3     MVC   0(0,RG),0(RC)                                            77800013
MVC4     MVC   77(0,RA),0(RC)                                           78000013
MVCY     MVC   64(0,RA),0(RC)                                           78200013
SIX      DC    H'6'                                                     78400013
LPTSL1   DC    H'110'                                                   78600013
LONPTSL  DC    H'92'                                                    78800013
H24      DC    H'24'                                                    79000013
LPTL1    DC    H'91'                                                    79200013
LPTL2    DC    H'72'                                                    79400013
LPTL3    DC    H'93'                                                    79600013
LONPTL   DC    H'73'                                                    79800013
PTL1     DC    C'CONDITION      OCCURRED AT OFFSET'                     80000013
         DC    CL58'        FROM ENTRY POINT'                           80200013
PTLS1    DC    C'CONDITION      OCCURRED IN STATEMENT       AT'         80400013
         DC    CL65' OFFSET        FROM ENTRY POINT'                    80600013
PTL2     DC    CL72'    CALLED FROM PROCEDURE WITH ENTRY POINT'         80800013
PTL3     DC    C'    CALLED, IN STATEMENT      , FROM PROCEDURE WITH '  81000013
         DC    CL41'ENTRY POINT'                                        81200013
ONPTL    DC    C'CONDITION      OCCURRED AT OFFSET'                     81400013
         DC    CL40'        FROM ENTRY POINT OF      ON UNIT'           81600013
ONPTSL   DC    C'CONDITION      OCCURRED IN STATEMENT       AT'         81800013
         DC    C' OFFSET        FROM ENTRY POINT OF      ON UNIT'       82000013
INSTAT   DC    C' IN STATEMENT'                                         82200013
TABLE    DC    C'0123456789ABCDEF' TRANSLATION TABLE                    82400013
IHE      DC    C'IHE'              FIXED PART OF ROUTINE NAME           82600013
FILE     DC    C'FILE '                                                 82800013
DASH     DC    C' - '                                                   83000013
AT       DC    C' AT '               *                                  83200013
TRAM     DC    C' (TRANSMIT) - '                                        83400013
MASK     DC    X'402120202020'                                          83600013
CODES    DC    C'OFL '                                                  83800013
         DC    C'SIZE'                                                  84000013
         DC    C'FOFL'                                                  84200013
         DC    C'SUBR'                                                  84400013
         DC    C'CHCK'                                                  84600013
         DC    C'CONV'                                                  84800013
         DC    C'CHCK'                                                  85000013
         DC    C'COND'                                                  85200013
         DC    C'FIN '                                                  85400013
         DC    C'ERR '                                                  85600013
         DC    C'ZDIV'                                                  85800013
         DC    C'UFL '                                                  86000013
         DC    C'    '                                                  86200013
         DC    C'    '                                                  86400013
         DC    C'NAME'                                                  86600013
         DC    C'REC '                                                  86800013
         DC    C'TMIT'                                                  87000013
         DC    C'    '                                                  87200013
         DC    C'KEY '                                                  87400013
         DC    C'ENDP'                                                  87600013
         DC    C'ENDF'                                                  87800013
         DC    C'    '                                                  88000013
         DC    C'UNDF'                                                  88200013
         DC    C'    '                                                  88400013
         DC    C'    '                                                  88600013
PWR      EQU   WR                                                       88800013
         END                                                            89000013
