IOB      TITLE '    IHEIOB    PUT INITIALIZATION/TERMINATION           /00300013
               OS/360 PL/I LIBRARY'                                     00600013
*    VERSION   FOURTH VERSION OF F-LEVEL PL/I COMPILER                  00900015
*                                                                       01200013
* R20 411000,*                                                    32236 01300000
*                                                                 32236 01400000
*   STATUS     CHANGE LEVEL - 0                                         01500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOB000-TSS 01600001
*        ----------------------------------------------------IOB000-TSS 01700001
*                                                                       01800013
*   FUNCTION   INITIALIZATION                                           02100013
*               1) STACK CURRENT FILE INTO CALLER'S DSA,                02400013
*               2) ESTABLISH NEW CURRENT FILE,                          02700013
*               3) CHECK FILE FOR OUTPUT MODE AND OPEN STATE,           03000013
*               4) INITIALIZE FCB FOR CURRENT OPERATION,                03300013
*               5) PERFORM PRINTING OPTIONS, IF ANY.                    03600013
*              TERMINATION                                              03900013
*               1) IF V-FORMAT RECORDS, UPDATE RECORD LENGTH FIELD      04200013
*                  IN CONTROL WORD OF RECORD,                           04500013
*               2) UNSTACK CURRENT FILE.                                04800013
*                                                                       05100013
*   ENTRY POINTS                                                        05400013
*              IHEIOBA - INITIALIZE PUT WITHOUT PRINTING OPTION         05700013
*                  RA = A(PLIST)                                        06000013
*                  PLIST = A(DCLCB)                                     06300013
*                          A(ABNORMAL-RETURN)                           06600013
*              IHEIOBB - INITIALIZE PUT, PERFORM PAGE OPTION            06900013
*                  (CF.IHEIOBA)                                         07200013
*              IHEIOBC - INITIALIZE PUT, PERFORM SKIP OPTION            07500013
*                  RA = A(PLIST)                                        07800013
*                  PLIST = A(DCLCB)                                     08100013
*                          A(ABNORMAL-RETURN)                           08400013
*                          A(FULLWORD-OPTION-VALUE)                     08700013
*              IHEIOBD - INITIALIZE PUT, PERFORM LINE OPTION            09000013
*                  (CF.IHEIOBC)                                         09300013
*              IHEIOBE - INITIALIZE PUT, PERFORM PAGE PLUS LINE OPTIONS 09600013
*                  (CF.IHEIOBC)                                         09900013
*                                                                       10200013
*   INPUT      CURRENT FILE PSEUDO-REGISTER (IHEQCFL),                  10500013
*              FCB, DCLCB, FILE REGISTER.                               10800013
*                                                                       11100013
*   OUTPUT     UPDATED CURRENT FILE PSEUDO-REGISTER,                    11400013
*              UPDATED FCB,                                             11700013
*              UPDATED RECORD LENGTH FIELD, IF V-FORMAT RECORDS.        12000013
*                                                                       12300013
*   EXTERNAL MODULES                                                    12600013
*              IHEOCL - IMPLICIT OPENING OF FILE                        12900015
*              IHEIOP - PERFORM  PAGE, SKIP, LINE OPERATIONS.           13200013
*                                                                       13500013
*   EXITS      NORMAL                                                   13800013
*               RETURN TO CALLER VIA LINK REGISTER.                     14100013
*              ERROR                                                    14400013
*               RETURN TO COMPILED-CODE CALL TO IHEIOBT, EFFECTIVELY    14700013
*               THE NEXT COMPILED STATEMENT, IF IHEIOE SIGNALS          15000013
*               THAT THE CURRENT FILE IS UNUSABLE. THE ADDRESS          15300013
*               OF THIS CALL IS SPECIFIED BY THE SECOND ARGUMENT        15600013
*               OF THE INITIALIZATION CALL.                             15900013
*   TABLES/WORK-AREA                                                    16200013
*              SEE OS/360 PL/I LIBRARY PLM FOR DESCRIPTION OF FCB,      16500013
*              DCLCB, FILE REGISTER, AND CURRENT-FILE.                  16800013
*              WORK-AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS).        17100013
*                                                                       17400013
*   ATTRIBUTES  READ-ONLY AND REENTRANT                                 17700013
*                                                                       18000013
*   PRIVATE MACROS                                                      18300013
*              IHELIB,IHEPRV,IHESDR,IHEZAP                              18600013
*                                                                       18900013
*   ASSEMBLY REQUIREMENTS                                               19200013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   19500013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        19800013
*                                                                       20100013
*   NOTES      SEE OS/360 PL/I LIBRARY PLM FOR LIBRARY MODULE           20400013
*              CONVENTIONS AND STANDARDS.                               20700013
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON        21000013
*              A PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL     21300013
*              CHARACTER SET.                                           21600013
         EJECT                                                          21900013
IHEIOB   CSECT                                                          22200013
*  ENTRY POINTS                                                         22500013
         SPACE                                                          22800013
         ENTRY IHEIOBA,IHEIOBB,IHEIOBC,IHEIOBD,IHEIOBE,IHEIOBT          23100013
         SPACE 2                                                        23400013
*  ASSEMBLY PARAMETERS                                                  23700013
         SPACE                                                          24000013
         IHELIB                         DEFINE PL/I LIBRARY SYMBOLICS   24300013
         IHEZAP                         DEFINE PL/I FILE CONTROL BLOCK  24600013
IHELW3   DSECT                                                          24900013
         DS    9D                       SAVE AREA                       25200013
         DS    2A                                                       25270015
PENQ     DS    3A                                                       25340015
QN       DS    2A                                                       25410015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOB005-TSS 25440001
*        ----------------------------------------------------IOB005-TSS 25470001
         SPACE                                                          25500013
PWR      EQU   WR                                                     * 25800013
MCFL     EQU   X'01'                    CURRENT-FILE ACTIVE FLAG        26100013
CCFL     EQU   X'02'                    COPY STACK FLAG                 26200016
TCFL     EQU   X'04'                    DATAFIELD STACK FLAG            26300016
OFPW     EQU   PWR*4+OFRA                                               26400013
OFCF     EQU   72                       OFFSET OF CURRENT FILE PR UPDT. 26700013
         SPACE 3                                                        27000013
ERR0     EQU   X'1'                     ATTEMPT TO WRITE INPUT FILE     27300013
ERR3     EQU   X'9'                     ILLIGAL FILE OPERATION          27600013
ERR4     EQU   X'9801'                  TRANSMISSION ERROR              27900013
         EJECT                                                          28200013
         USING IHELW3,DR                                                28500013
         USING IHEZAPE,RH               DEFINE BASE-REG FOR FCB         28800015
         USING IHEZDCL,RA               DEFINE BASE-REG FOR DCLCB       29100013
         SPACE 3                                                        29400013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOB001-TSS 29500001
IHEIOB   CSECT                                                        * 29700013
*        ----------------------------------------------------IOB001-TSS 29800001
         USING *,BR                                                     30000013
IHEIOBA  MVI   OFPR(DR),X'0'         .  PUT.                            30300013
         B     IOB00                                                    30600013
         USING *,BR                                                     30900013
IHEIOBB  MVI   OFPR(DR),X'4'         .  PUT PAGE.                       31200013
         B     IOB00                                                    31500013
         USING *,BR                                                     31800013
IHEIOBC  MVI   OFPR(DR),X'8'         .  PUT SKIP.                       32100013
         B     IOB00                                                    32400013
         USING *,BR                                                     32700013
IHEIOBD  MVI   OFPR(DR),X'C'         .  PUT LINE .                      33000013
         B     IOB00                                                    33300013
         USING *,BR                                                     33600013
IHEIOBE  MVI   OFPR(DR),X'10'        .  PUT PAGE AND LINE.              33900013
         SPACE                                                          34200013
IOB00    STM   LR,PWR,OFLR(DR)          SAVE CALLER'S REGISTERS.        34500013
         LR    RD,DR                                                    34800013
         IHESDR LW3                     UPDATE SSA POINTER              35100013
         BALR  PWR,0                    ESTABLISH                       35400013
         USING *,PWR                     ADDRESSIBILTY.                 35700013
         IHEPRV CFL,RB,OP=LA            STACK CURRENT FILE IN           36000013
         MVC   OFCF+1(7,RD),1(RB)        CALLER'S DSA.                  36300013
         OI    OFCF+4(RD),MCFL       /  SET P.R. UPDATE ACTIVE.         36600013
         MVC   0(8,RB),0(RA)            SET NEW CURRENT FILE.           36900013
         IHEPRV LCA,RC,OP=L             GET A(LCA).                     37200013
         MVC   WFIL-WBR1+1(3,RC),1(RA)  SET A(DCLCB) IN LCA FOR ONFILE. 37500013
         L     RF,0(RA)                 A(DCLCB) ESTABLISH ADDR.BILITY  37800013
         LR    RC,RA                    PRESERVE A(P.LIST)              38100013
         LH    RF,0(RF)                 P.R. OFFSET OF FILE REGISTER    38400013
         L     RH,0(RF,PR)              CONTENTS OF FILE REGISTER       38700015
         LA    RH,0(RH)                 LOOSE TOP BYTE                  39000015
         LTR   RH,RH                 +  IS FILE OPEN                    39300015
         BNZ   IOB13                 *  YES                             39600013
         L     RB,0(RA)                 A(DCLCB)                        39700015
         LA    RA,LOCB                  A(OCB)                          39900013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOB999-TSS 40000000
         L     BR,VOCLC                 ALAS NO, A(IMP OPEN).           40200015
*        ----------------------------------------------------IOB999-TSS 40300000
         BALR  LR,BR                 $$ GO TO OPEN FILE                 40500013
         L     RH,0(RF,PR)              A(FCB)                          40800015
         SPACE                                                          41400013
IOB13    EQU   *                                                        41700013
         TM    TTYP,TMRC             +  IS IT STREAM                    42000013
         BO    IOBX3                 ** NO, ERROR                       42300013
         TM    TFLA,TMOP             +  IS IT OUTPUT MODE               42600013
         BZ    IOBX0                 ** NO,  ERROR                      42900013
         TM    TFDV,TMPR             +  IS IT PRINTER                   43200013
         BO    IOB12                 *  YES                             43500013
         TM    TFLX,TMOE             +  HAS XMIT ERROR OCCURED          43800013
         BO    IOBX1                 ** YES, RAISE TRANSMIT ERROR       44100013
         SPACE                                                          44400013
IOB12    EQU   *                                                        44700013
         MVI   TFIO,TMPW             /  SET CURRENT OPERATION FLAG.     45000013
         SR    RE,RE                    WHAT'S UP..                     45300013
         ST    RE,TCNT                  CLEAR COUNT FIELD, THEN       * 45600013
         IC    RE,OFPR(RD)                                              45900013
         CLI   OFPR(RD),X'4'            CALL FOR PAGE..                 46200013
         BE    IOB14                    YES, THIRD ARG. DOES NOT EXIST. 46500013
         L     RA,8(RC)                 PREPARE FOR CALLS TO PRINT OPTS 46800013
         LA    RA,2(RA)                                                 47100013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOB998-TSS 47200000
IOB14    L     BR,IOBTB(RE)             ADDRESS FURTHER ACTION.         47400013
*        ----------------------------------------------------IOB998-TSS 47500000
         BALR  LR,BR                 $$ INVOKE PRINT SPACER, OR EXIT.   47700013
         CH    RE,X010               +  IS THIS PUT PAGE AND LINE.      48000013
         BNE   IOBR2                 *  NO                              48300013
         L     RA,8(RC)                 YES, HAVING DONE PAGE           48600013
         LA    RA,2(RA)                                                 48900013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOB997-TSS 49000000
         L     BR,VIOPC                  NOW DO LINE OPTION.            49200013
*        ----------------------------------------------------IOB997-TSS 49300000
         LH    LR,0(RA)                 BUT IF LINE N LE ONE,           49500013
         CH    LR,H001                                                  49800013
         BNH   IOBR2                 *  IGNORE.                         50100013
         BALR  LR,BR                 $$ SKIP N LINES ON NEW PAGE.       50400013
         B     IOBR2                 *  EXIT.                           50700013
         SPACE 2                                                        51000013
*  NORMAL RETURN                                                        51300013
         SPACE                                                          51600013
IOBR2    LR    DR,RD                    READDRESS CALLER'S SSA.         51900013
         LM    LR,PWR,OFLR(DR)          RESTORE HIS REGS.               52200013
         BR    LR                    X  RETURN.                         52500013
         EJECT                                                          52800013
*  ILLIGAL OPERATION ON  RECORD FILE                                    53100013
         SPACE 2                                                        53400013
IOBX3     EQU   *                                                       53700013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOB996-TSS 53800000
          L     BR,VERRC                A(ERROR ROUTINE)                54000013
*        ----------------------------------------------------IOB996-TSS 54100000
          BALR RA,BR                 $$ GO TO ERROR                     54300013
          DC    AL2(ERR3)               NO RETURN                       54600013
         SPACE 2                                                        54900013
*  ATTEMPT TO PUT INPUT FILE                                            55200013
         SPACE 2                                                        55500013
IOBX0     EQU   *                                                       55800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOB995-TSS 55900000
          L     BR,VERRC                A(ERROR ROUTINE)                56100013
*        ----------------------------------------------------IOB995-TSS 56200000
          BALR RA,BR                 {{ GO TO ERROR                     56400013
          DC    AL2(ERR0)              ERROR CODE                       56700013
         SPACE 2                                                        57000013
*  TRANSMISSION ERROR HAS OCCURED                                       57300013
         SPACE 2                                                        57600013
IOBX1     EQU   *                                                       57900013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOB994-TSS 58000000
          L    BR,VERRC                 OUTPUT TRANSMIT RAISE ERROR     58200013
*        ----------------------------------------------------IOB994-TSS 58300000
          BALR RA,BR                 $$ RAISE ERROR CONDITION           58500013
          DC   X'0003'                  NO RETURN                       58800013
         EJECT                                                          59100013
         SPACE 3                                                        59400013
*  TERMINAL ENTRY                                                       59700013
         SPACE                                                          60000013
         USING IHEIOBT,BR                                               60300013
IHEIOBT  STM   LR,PWR,OFLR(DR)       .  SAVE CALLER'S REGISTERS.        60600013
         LR    RD,DR                                                    60700015
         IHESDR LW3                                                     60900013
         IHEPRV CFL,RA                  ADDRESS CFL FCB.                61200013
         LH    RH,DPRO                                                  61500015
         L     RH,0(RH,PR)                                              61800015
         TM    TFRC,TMVB             +  V-FORMAT RECORDS..              62100013
         BZ    IOBT1                    NO.                             62400013
         TM    TFMD,TMOP             +  YES, OUTPUT..                   62700013
         BZ    IOBT1                    NO.                             63000013
         L     RA,TCBA                  YES, RAISE L...                 63300013
         LH    RC,TMAX                                                  63600013
         SR    RA,RC                                                    63900013
         AH    RA,TREM                  ADDRESS LITTLE LL BYTES.        64200013
         SH    RC,TREM                  COMPUTE LL AND SET.             64500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOB002-TSS 64600001
         CH    RC,NOIS                  BUT ONLY IF NECESSARY.          64800013
*        ----------------------------------------------------IOB002-TSS 64900001
         BNH   IOBT1                 *  NOT YET NECESSARY.              65100013
         STH   RC,OFPW(DR)              IT IS NOW,                      65400013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOB006-TSS 65500000
         MVC   0(2,RA),OFPW(DR)          SET THEM.                      65700013
*        ----------------------------------------------------IOB006-TSS 65800000
         SPACE                                                          66000013
IOBT1    EQU   *                                                        66300013
         IHEPRV LCA,RC,OP=L             GET A(LCA)                      66600013
         SPACE                                                          67500013
         IHEPRV CFL,RA,OP=LA            UNSTACK CFL                     67800013
         MVC   1(7,RA),OFCF+1(RD)       UNSTACK CFL                     67900015
         MVC   WFIL-IHEZLCA+1(3,RC),1(RA)  SET WFIL TO UNSTACKED VALUE  68000015
         MVI   WFIL-IHEZLCA(RC),X'00'   ZERO ITS TOP BYTE               68100015
         NI    OFCF+4(RD),255-MCFL   /  UNSET UPDATE ACTIVE             68200015
         TM    OFCF+4(RD),CCFL+TCFL     ANY FLAGS STACKED..             68230016
         BZ    IOBT4                    NO                              68260016
         L     RA,0(RA)                 A(DCLCB)                        68290016
         LH    RH,DPRO                  P.R. OFFSET                     68320016
         L     RH,0(RH,PR)              A(FCB)                          68350016
         LTR   RH,RH                 +  IS FILE CLOSED                  68360001
         BZ    IOBT4                 *  YES,  BYPASS                    68370001
         TM    OFCF+4(RD),CCFL          COPY STACKED..                  68380016
         BZ    IOBT3                    NO                              68410016
         OI    TFIO,TMCY                SET IT                          68440016
IOBT3    TM    OFCF+4(RD),TCFL          DATAFIELD STACKED..             68470016
         BZ    IOBT4                    NO                              68500016
         OI    TFLX,TMIT                SET IT                          68530016
IOBT4    EQU   *                                                        68560016
         L     DR,OFDR(DR)                                              68600016
         LM    LR,PWR,OFLR(DR)          RESTORE CALLER'S REGISTERS.     69000013
         BR    LR                    X  RETURN.                         69300013
         SPACE                                                          69310015
         EJECT                                                          69600013
         SPACE 3                                                        69900013
*  CONSTANTS                                                            70200013
         SPACE                                                          70500013
         DS    0F                                                       70800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOB993-TSS 70900000
IOBTB    EQU   *                        FOLLOWING ADCONS ARE ORDERED.   71100013
         DC    A(IOBR2)                 PLAIN PUT                       71400013
         DC    V(IHEIOPA)               PUT PAGE                        71700013
         DC    V(IHEIOPB)                   SKIP                        72000013
VIOPC    DC    V(IHEIOPC)                   LINE                        72300013
         DC    V(IHEIOPA)                   PAGE AND LINE               72600013
         SPACE                                                          72900013
VOCLC    DC    V(IHEOCLC)               IMPLICIT OPEN ENTRY.            73200015
*        ----------------------------------------------------IOB993-TSS 73300000
LOCB     DC    X'00020000'              OCB FOR OUTPUT                  73500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOB003-TSS 73600001
NOIS     DC    H'14',H'00'                                              73800013
*        ----------------------------------------------------IOB003-TSS 73900001
X010     DC    X'0010'                                                * 74100013
H001     DC    H'1'                                                     74400013
ERRA     DC    AL2(ERR4)                                                74700013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOB992-TSS 74800000
VERRB     DC    V(IHEERRB)                                              75000013
VERRC    DC    V(IHEERRC)                                               75300013
*        ----------------------------------------------------IOB992-TSS 75350000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOB004-TSS 75400001
*        ----------------------------------------------------IOB004-TSS 75500001
         END                                                            75600013
