IOC      TITLE '    IHEIOC    GET/PUT STRING INITIATE/TERMINATE        /00600015
               OS/360 PL/I LIBRARY'                                     01200015
*    VERSION   FOURTH VERSION OF F-LEVEL PL/I COMPILER                  01800015
*                                                                       02400015
*   STATUS     CHANGE LEVEL - 0                                         03000015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOC000-TSS 03100001
*        ----------------------------------------------------IOC000-TSS 03200001
* 5.5  C 678000                                               MCB 60063 03220072
*A660000                                                                03250021
*3214                                                             18360 03300017
*                                                                       03600015
*   SIZE       288 BYTES                                                04200015
*                                                                       04800015
*   FUNCTION   INITIALIZATION                                           05400015
*               1) STACK CURRENT FILE INTO CALLER'S DSA,                06000015
*               2) ESTABLISH NEW 'CURRENT FILE',                        06600015
*               3) BUILD 'FCB' AND DUMMY 'DCLCB' (FOR FILE-REGISTER     07200015
*                  PRV-OFFSET).                                         07800015
*                                                                       08400015
*              TERMINATION                                              09000015
*               1) IF FIXED-LENGTH STRING, PAD WITH BLANKS.IF OUTPUT,   09600015
*               2) FREE DUMMY FCB,                                      10200015
*               3) UNSTACK CURRENT FILE.                                10800015
*                                                                       11400015
*   ENTRY POINTS                                                        12000015
*              IHEIOCA - INITIALIZE GET STRING                          12600015
*                  RA = A(PLIST)                                        13200015
*                  PLIST = A(SDV)                                       13800015
*                          A(DED)                                       14400015
*              IHEIOCB - INITIALIZE GET/COPY STRING                     15000015
*                 (CF. IHEIOCA)                                         15600015
*              IHEIOCC - INITIALIZE PUT STRING                          16200015
*                 (CF. IHEIOCA)                                         16800015
*              IHEIOCT - TERMINATE GET/PUT STRING                       17400015
*                 (NO ARGUMENTS)                                        18000015
*                                                                       18600015
*   INPUT      CURRENT FILE PSEUDO-REGISTER (IHEQCFL),                  19200015
*              STRING SDV AND DED.                                      19800015
*                                                                       20400015
*   OUTPUT     UPDATED CURRENT FILE PSEUDO-REGISTER,                    21000015
*                                                                       21600015
*              IF FIXED-LENGTH STRING, PADDED STRING,                   22200015
*              IF VARYING-LENGTH STRING, UPDATED SDV (CURRENT LENGTH).  22800015
*                                                                       23400015
*   EXTERNAL MODULES                                                    24000015
*              IHESADF - OBTAIN VDA FOR DUMMY FCB.                      24600015
*              IHESAFD - FREE ABOVE VDA.                                25200015
*                                                                       25800015
*   EXITS      NORMAL                                                   26400015
*               RETURN TO CALLER VIA LINK REGISTER                      27000015
*                                                                       27600015
*   TABLES/WORK-AREA                                                    28200015
*              SEE OS/360 PL/I LIBRARY PLM FOR DESCRIPTION OF FCB,      28800015
*              CURRENT-FILE, FILE REGISTER, SDV, AND DED.               29400015
*              WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS).        30000015
*                                                                       30600015
*   ATTRIBUTES  READ-ONLY AND REENTRANT                                 31200015
*                                                                       31800015
*   PRIVATE MACROS                                                      32400015
*              IHELIB,IHESDR,IHEPRV,IHEZAP                              33000015
*                                                                       33600015
*   ASSEMBLY REQUIREMENTS                                               34200015
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   34800015
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        35400015
*                                                                       36000015
*   NOTES      SEE OS/360 PL/I LIBRARY PLM FOR LIBRARY MODULE           36600015
*              CONVENTIONS AND STANDARDS.                               37200015
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON        37800015
*              A PARTICULAR                INTERNAL REPRESENTATION      38400015
         EJECT                                                          39000015
IHEIOC   CSECT                                                          39600015
*  ENTRY POINTS                                                         40200015
         SPACE                                                          40800015
         ENTRY IHEIOCA,IHEIOCB,IHEIOCC,IHEIOCT                          41400015
         SPACE 2                                                        42000015
*  ASSEMBLY PARAMETERS                                                  42600015
         SPACE                                                          43200015
         IHELIB                         DEFINE PL/I LIBRARY SYMBOLICS   43800015
         IHEZAP                         DEFINE PL/I FILE CONTROL BLOCK  44400015
         USING IHEZAPE,RA                                               45000015
OFCF     EQU   72                       DSA OFFSET OF CURRENT-FILE UPDT 45600015
MCFL     EQU   X'01'                    CURRENT-FILE ACTIVE FLAG        46200015
MVAR     EQU   X'10'                    VARYING STRING DED FLAG         46800015
PWR      EQU   WR                                                       47400015
         EJECT                                                          48000015
         SPACE 2                                                        48600015
IHEIOC   CSECT                                                          49200015
         SPACE                                                          49800015
IHEIOCA  NOPR  0                     .  GET.                            50400015
         SPACE                                                          51000015
IHEIOCB  NOP   0                     .  GET/COPY.                       51600015
         SPACE                                                          52200015
IHEIOCC  STM   LR,PWR,OFLR(DR)       .  PUT.                            52800015
         SPACE                                                          53400015
         LR    RD,DR                                                    54000015
         IHESDR LW3                     UPDATE SSA POINTER.             54600015
         BALR  PWR,0                    ESTABLISH                       55200015
         USING *,PWR                     ADDRESSIBILITY.                55800015
         IHEPRV CFL,RB,OP=LA            STACK CURRENT-FILE.             56400015
         MVC   OFCF+1(7,RD),1(RB)        IN CALLER'S DSA.               57000015
         OI    OFCF+4(RD),MCFL       /  SET PR. UPDATE ACTIVE.          57600015
         L     RE,0(RA)                 ADDRESS SDV,                    58200015
         L     RF,4(RA)                  AND DED.                       58800015
         LA    R0,TEND-TBEG+4+8         PREPARE TO                      59400015
         IHEPRV VDA,BR                                                  60000015
         BALR  LR,BR                 $$ GET VDA FOR FCB/DCLCB.          60600015
         LA    RA,8(RA)                                                 61200015
         IHEPRV CFL,RA,OP=ST            SET CURRENT FILE<               61800015
         LA    RC,*-*                   PLACE DUMMY DCLCB ON TOP FCB.   62400015
         ORG   *-2                                                      63000015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOC001-TSS 63300001
         DC    QL2(IHEQCFL)                                             63600015
*        ----------------------------------------------------IOC001-TSS 63900001
         LA    RC,4(RC)                                                 64200015
         STH   RC,0(RA)                                                 64800015
         LA    RA,4(RA)                 SET 'FILE-REGISTER'             65400015
         ST    RA,0(RC,PR)               TO A(DUMMY-FCB).               66000015
         IHEPRV  LCA,RC,OP=L                                      49796 66200021
         XC    WFIL-WBR1(4,RC),WFIL-WBR1(RC)   ZERO WFIL          497   66400021
         MVI   TBEG,0                   CLEAR FCB.                      66600015
         MVC   TBEG+1(TEND-TBEG-1),TBEG                                 67200015
         MVC   TCBA+1(3),1(RE)         SET A(NEXT CHARACTER)      60063 67800072
         MVC   TMAX,4(RE)                MAXIMUM LENGTH.                69000015
         ST    RE,TACM                  PRESERVE A(SDV).                69600015
         MVI   TTYP,TMST             /  SET STRING-FCB FLAG.            70200015
         MVC   TFRC(1),0(RF)         /  SET STRING DED IN RECORD-FMT.   70800015
         NI    TFRC,MVAR               RETAIN VARYING STATUS            71100017
         TM    OFBR+3(RD),X'06'         WHAT TYPE ENTRY..               71400015
         BO    IOC20                    PUT.                            72000015
         BZ    IOC10                    GET.                            72600015
         MVI   TFIO,TMCY             /  GET/COPY, SET COPY FLAG.        73200015
IOC10    OI    TFIO,TMGR             /  SET GET FLAG.                   73800015
         OI    TFMD,TMIN               INDICATE INPUT                   73900017
         MVC   TREM,6(RE)               CURRENT LENGTH                  74100015
         B     IOCR2                 *  PREPARE TO EXIT.                74400015
IOC20    MVI   TFIO,TMPW             /  SET PUT FLAG.                   75000015
         OI    TFMD,TMOP               INDICATE OUTPUT                  75100017
         MVC   TREM,TMAX                REMAINING EQ ALL                75300015
         B     IOCR2                 *  PREPARE TO EXIT.                75600015
         SPACE 3                                                        76200015
*  TERMINATION ENTRY                                                    76800015
         SPACE                                                          77400015
IHEIOCT  STM   LR,PWR,OFLR(DR)       .  SAVE CALLER'S REGISTERS.        78000015
         LR    RD,DR                                                    78600015
         IHESDR LW3                     UPDATE SSA POINTER.             79200015
         BALR  PWR,0                    ESTABLISH ADDRESSIBILITY.       79800015
         USING *,PWR                                                    80400015
         IHEPRV CFL,RG,OP=LA            ADDRESS DUMMY FCB.              81000015
         L     RA,4(RG)                                                 81600015
         TM    TFIO,TMGR             +  INPUT OPERATION..               82200015
         BO    IOCR1                 *  YES.                            82800015
         L     RB,TACM                  NO, ADDRESS SDV.                83400015
         TM    TFRC,MVAR             +  VARYING OR FIXED STRING..       84000015
         BZ    IOC50                 *  FIXED.                          84600015
         LH    RC,TMAX                  VARYING,                        85200015
         SH    RC,TREM                   COMPUTE                        85800015
         STH   RC,6(RB)                  AND SET CURRENT-LENGTH FIELD.  86400015
         B     IOCR1                 *  PREPARE TO EXIT.                87000015
IOC50    LH    RC,TREM                  BLANK OUT REMAINING CHARACTERS. 87600015
         LTR   RC,RC                    ANY REMAINING..                 88200015
         BZ    IOCR1                    NO.                             88800015
         L     RF,TCBA                  YES, BLANK OUT REMAINDER.       89400015
IOC52    MVI   0(RF),C' '                                               90000015
         LA    RF,1(RF)                                                 90600015
         BCT   RC,IOC52                                                 91200015
         SPACE 3                                                        91800015
IOCR1    IHEPRV FVD,BR                                                  92400015
         BALR  LR,BR                 $$ FREE FCB VDA.                   93000015
         MVC   1(7,RG),OFCF+1(RD)       UNSTACK CURRENT FILE.           93600015
         NI    OFCF+4(RD),255-MCFL   /  UNSET ACTIVE FLAG.              94200015
         SPACE                                                          94800015
IOCR2    LR    DR,RD                    READDRESS CALLER'S SSA.         95400015
         LM    LR,PWR,OFLR(DR)          RESTORE HIS REGISTERS.          96000015
         BR    LR                    X  RETURN.                         96600015
         SPACE 3                                                        97200015
*  CONSTANTS                                                            97800015
         SPACE                                                          98400015
         END                                                            99000015
