IOD      TITLE '    IHEIOD    EDIT DIRECTED DATAFIELD LOCATOR          /00300013
               OS/360 PL/I LIBRARY'                                     00600013
*    VERSION   FOURTH VERSION OF F-LEVEL PL/I COMPILER                  00900015
*                                                                       01200013
*   STATUS     CHANGE LEVEL - 0                                         01500013
*                                                                       01600001
*APARS FIXED                                                            01700001
*        21741                                                          01800001
*                                                                       01900001
*   FUNCTION   INITIALIZATION                                           02100013
*               SUPPLY CALLER WITH ADDRESS OF NEXT DATAFIELD, I.E.,     02400013
*               NEXT W-BYTES WITHIN STREAM, VIA WSDV IN LCA.            02700013
*               SHOULD THERE BE LESS THAN W-BYTES WITHIN THE CURRENT    03000013
*               RECORD, A VDA (W+8 BYTES IN LENGTH) IS ALLOCATED IN     03300013
*               ORDER TO ALLOW THE CALLER TO OPERATE UPON A CONTIGUOUS  03600013
*               FIELD. IF AN INPUT OPERATION, W-BYTES ARE COPIED FROM   03900013
*               THE STREAM INTO THE VDA, AND THE FCB RECORD POINTERS    04200013
*               UPDATED. IF AN OUTPUT OPERATION, THE GENERATED W-BYTES  04500013
*               ARE COPIED FROM THE VDA INTO THE STREAM UPON SUBSEQUENT 04800013
*               ENTRY TO IHEIODT.                                       05100013
*               IF COPY OPTION EXISTS, COPY DATAFIELD TO SYSPRINT.      05400013
*                                                                       05700013
*              TERMINATION                                              06000013
*               1)INCREMENT COUNT VALUE.                                06300013
*               2)CHECK FOR INPUT TRANSMIT ERROR ON DATAFIELD,          06600013
*                 RAISING TRANSMIT CONDITION IF NECESSARY.              06900013
*               3)IF OUTPUT OPERATION WITH VDA ALLOCATED, COPIES VDA    07200013
*                 TO RECORDS.                                           07500013
*               4)FREES ANY ALLOCATED VDA.                              07800013
*               5)IF OUTPUT, UPDATE  FCB RECORD POINTERS.               08100013
*                                                                       08400013
*   ENTRY POINTS                                                        08700013
*              IHEIODG - INITIALIZE FOR INPUT OF W-BYTES                09000013
*                   IMPLICIT PARAMETER = WSDV                           09300013
*                   (CALLER SETS CURRENT LENGTH FROM W-FIELD OF FED,    09600013
*                   RECEIVES A(RECORD-AREA) OR A(VDA) IN BYTES 2-4)     09900013
*              IHEIODP - INITIALIZE FOR OUTPUT OF W-BYTES               10200013
*                   (SEE IHEIODG)                                       10500013
*              IHEIODT - TERMINATES I/O REQUEST                         10800013
*                   (NO ARGUMENTS                                       11100013
*                                                                       11400013
*   INPUT      CURRENT FILE PSEUDO-REGISTER (IHEQCFL),                  11700013
*              FCB, DCLCB, FILE REGISTER, WSDV.                         12000013
*                                                                       12300013
*   OUTPUT     ADDRESS OF NEXT N BYTES IN STREAM,                       12600013
*              UPDATED FCB RECORD POINTERS.                             12900013
*                                                                       13200013
*   EXTERNAL MODULES                                                    13500013
*              IHEIOF - ACCESS NEXT LOGICAL RECORD.                     13800013
*              IHEERR - RAISE ERROR CONDITION.                          14100013
*              IHESAD - OBTAIN VDA.                                     14400013
*              IHESAF - FREE VDA.                                       14700013
*              IHEPRT - PERFORM COPY TO SYSPRINT                        15000013
*                                                                       15300013
*   EXITS      NORMAL                                                   15600013
*               RETURN TO CALLER VIA LINK REGISTER,                     15900013
*                RETURN CODE = 0 (NO ENDFILE CONDITION),                16200013
*                RETURN CODE = 4 (ENDFILE CONDITION EXISTS).            16500013
*              ERROR                                                    16800013
*               IHE012I  GET/PUT STRING EXCEEDS STRING SIZE             17100013
*                                                                       17400013
*   TABLES/WORK-AREA                                                    17700013
*              SEE OS/360 PL/I LIBRARY PLM FOR DESCRIPTION OF           18000013
*              FCB, DCLCB, FILE REGISTER, LIBRARY COMMUNICATION AREA,   18300013
*              AND CURRENT FILE.                                        18600013
*              WORK-AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS).        18900013
*              SPANNING DATAFIELDS CAUSE TEMPORARY ALLOCATION OF VDAS.  19200013
*                                                                       19500013
*   ATTRIBUTES  READ-ONLY AND REENTRANT.                                19800013
*                                                                       20100013
*   PRIVATE MACROS                                                      20400013
*              IHELIB,IHEPRV,IHESDR,IHEZAP                              20700013
*                                                                       21000013
*   ASSEMBLY REQUIREMENTS                                               21300013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   21600013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        21900013
*                                                                       22200013
*   NOTES      SEE OS/360 PL/I LIBRARY PLM FOR LIBRARY MODULE           22500013
*              CONVENTIONS AND STANDARDS.                               22800013
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON        23100013
*              A PARTICULAR  INTERNAL REPRESENTATION OF THE             23400013
*              EXTERNAL CHARACTER SET.                                  23700013
         EJECT                                                          24000013
IHEIOD   CSECT                                                          24300013
*  ENTRY POINTS                                                         24600013
         SPACE                                                          24900013
         ENTRY IHEIODG,IHEIODP,IHEIODT                                  25200013
*  ASSEMBLY PARAMETERS                                                  25500013
         SPACE                                                          25800013
         IHELIB                         DEFINE PL/I LIBRARY SYMBOLICS   26100013
         IHEZAP                         DEFINE PL/I FILE CONTROL BLOCK  26400013
PWR      EQU   WR                       GREATEST REGISTER USED          26700013
TMVD     EQU   X'40'                    VDA USED SWITCH.                27000013
TCFL     EQU   X'04'                    XMIT STACK FLAG                 27300013
         SPACE                                                          27600013
*  ERROR CONDITION CODES                                                27900013
ERR0     EQU   X'0002'                  ERROR-CODE FOR STRING OVERFLOW  28200013
ERR1     EQU   X'9802'                  ON-CODE FOR INPUT TRANSMIT.     28500013
ERR2     EQU   X'B800'                  END OF FILE CODE                28570015
ERR3     EQU   X'0012'                  UNEXPE3TED END OF FILE          28640015
         SPACE 2                                                        28710015
         USING IHEZDCL,RA               DEFINE BASE-REG FOR DCLCB       28800013
         USING IHEZAPE,RB               DEFINE BASE-REG FOR DCBAPE      29100013
         USING IHEZLCA,PWR              DEFINE BASE-REG FOR LIB.COMMUN. 29400013
         EJECT                                                          29700013
*  INITIAL ENTRIES                                                      30000013
         SPACE                                                          30300013
IHEIOD   CSECT                                                          30600013
IHEIODG  NOPR  0                     .  GET DATAFIELD.                  30900013
         SPACE                                                          31200013
IHEIODP  STM   LR,PWR,OFLR(DR)       .  PUT DATAFIELD.                  31500013
IOD00    BALR  PWR-1,0                  ESTABLISH                       31800013
         USING *,PWR-1                   ADDRESSIBILITY.                32100013
         LR    RD,DR                                                    32200015
         IHESDR LW2                     UPDATE SSA POINTER.             32300015
         IHEPRV CFL,RA                  ADDRESS CFL FCB,                32400013
         LH    RA,DPRO                   VIA DCLCB,                     32700013
         L     RB,0(RA,PR)               THEN FILE REGISTER.            33000013
         IHEPRV LCA                     ADDRESS LIB.COMMUN.AREA.        33900013
         TM    TFLX,TMEF             +  ENDFILE ALREADY ENCOUNTERED     34000015
         BO    IODEF                 ** YES, RAISE ENDFILE              34100015
         MVC   WSDV+4(2),WSDV+6                                         34200013
         NI    WONC+2,255-TMVD       /  CLEAR VDA ALLOCATED FLAG.       34500013
         NI    TFLX,255-TMIT-TMLC    /  UNSET TMIT AND TMLC FLAGS.      34800013
         IHEPRV CFL,BR,OP=LA                                            35100013
         NI    4(BR),255-TCFL           UNSET XMIT FLAG                 35400013
         TM    TFLX,TMIE             ;  IS INPUT TRANSMIT ON  FOR BLOCK 35700013
         BZ    IOD05                    NO.                             36000013
         NC    TREM,TREM                ANY LEFT IN THE BUFFER..  14883 36100016
         BZ    IOD05                    NO                        14883 36200016
         OI    TFLX,TMIT             /  YES, SET DATAFIELD TRANS. ON.   36300013
         OI    4(BR),TCFL               SET XMIT FLAG                   36600013
IOD05    LH    RC,TREM                  NUMBER OF BYTES LEFT IN RECORD  36900013
         TM    TTYP,TMST             +  STRING..                        37200013
         BO    IOD10                 *  YES                             37500013
         TM    OFBR+3(RD),X'02'      +  PUT..                           37800013
         BO    IOD11                 *  YES.                            38100013
IOD10    CH    RC,WSDV+6                BYTES WANTED GT. CURRENT REC..  38400013
         BNL   IOD30                    NO. USE CURRENT RECORD          38700013
         TM    TTYP,TMST             +  YES, IS THIS GET/PUT STRING..   39000013
         BZ    IOD11                    NO,                             39300013
         L     BR,VERRC              ** YES, HOW SILLY.                 39600013
         BALR  RA,BR                 $$ GET/PUT STRING EXCEEDS SIZE.    39900013
         DC    AL2(ERR0)                                                40200013
IOD11    LTR   RC,RC                    IS CURRENT RECORD EXHAUSTED..   40500013
         BP    IOD20                    NO, USE TEMPORARY STORAGE.      40800013
         BAL   RE,IOD90              $  ACCESS NEXT RECORD.             41100013
         B     IOD05                 *  TRY AGAIN.                      41400013
         SPACE                                                          41700013
IOD20    LH    RC,WSDV+6                COMPUTE TEMPORARY STORAGE       42000013
         LA    R0,8(RC)                  REQUIREMENT.                   42300013
         IHEPRV VDA,BR                                                  42600015
         BALR  LR,BR                 $$ GET VDA.                        42900013
         LA    RA,8(RA)                 COMPUTE VDA TRUE DATA ADDRESS.  43200013
         ST    RA,WSDV                  SET CALLER'S DATAFIELD ADCON.   43500013
         OI    WONC+2,TMVD           /  SET VDA ALLOCATED FLAG.         43800013
         TM    OFBR+3(RD),X'02'      +  GET OR PUT CALL..               44100013
         BO    IODR1                 *  PUT, PREPARE TO EXIT.           44400013
         BAL   RD,IOD80              $  GET, COPY RECORDS TO VDA.       44700013
         B     IOD50                 *  TEST FOR COPY OPTION.           45000013
         SPACE                                                          45300013
IOD30    L     RC,TCBA                  SET A(DATAFIELD) WITHIN         45600013
         ST    RC,WSDV                   BUFFER FOR CALLER.             45900013
         TM    OFBR+3(RD),X'02'      +  PUT..                           46200013
         BO    IODR1                 *  YES, PREPARE TO EXIT.           46500013
         SPACE 3                                                        46800013
IOD50    TM    TFIO,TMCY             +  GET WITH COPY OPTION..          47100013
         BZ    IOD52                 *  TEST FOR UPDATING.              47400013
         IHEPRV ADC,BR                  YES                             47600016
         L     BR,IPRTA-IHEZADC(BR)     A(COPY PRINTER)                 47800016
         LR    RC,RB                                                    48000013
         L     RA,WSDV                   SUPPLY A(DATAFIELD) AND        48300013
         LA    RB,WSDV+6                 LENGTH TO                      48600013
         BALR  LR,BR                 $$ COPY DATAFIELD TO SYSPRINT.     48900013
         LR    RB,RC                                                    49200013
IOD52    TM    WONC+2,TMVD           +  VDA ALLOCATED..                 49500013
         BO    IODR1                 *  YES.                            49800013
         B     IODRA                 *  NO, UPDATE BUFFER PTRS.         50100013
         EJECT                                                          50400013
*  TERMINAL ENTRY                                                       50700013
         SPACE                                                          51000013
IHEIODT  STM   LR,PWR,OFLR(DR)       .  SAVE CALLER'S REGISTERS.        51300013
         BALR  PWR-1,0                  ESTABLISH                       51600013
         USING *,PWR-1                   ADDRESSIBILITY.                51900013
         IHEPRV CFL,RA                  ADDRESS CFL FCB.                52200013
         LH    RA,DPRO                                                  52500013
         L     RB,0(RA,PR)                                              52800013
         IHESDR LW2                     UPDATE SSA POINTER.             53100013
         IHEPRV LCA                     ADDRESS LIBRARY  COMM.          53400013
         L     RC,TCNT                  BUMP COUNT VALUE.               53700013
         LA    RC,1(RC)                                                 54000013
         ST    RC,TCNT                                                  54300013
         TM    TFLX,TMIT             ;  INPUT TRANSMIT ON DATAFIELD..   54600013
         BZ    IOD60                 *  NO.                             54900013
         LH    RC,ERRB                  YES, SET ERROR CODE.            55200013
         IHEPRV ERR,RC,OP=STH                                           55500013
         L     RA,TDCL                  GET A(DCLCB).                   55800013
         L     BR,VERRB                                                 56100013
         BALR  LR,BR                 $$ TELL EXEP.                      56400013
IOD60    TM    WONC+2,TMVD           +  VDA ALLOCATED..                 56700013
         BZ    IODR0                 *  NO.                             57000013
         NI    WONC+2,255-TMVD                                    21741 57300001
         TM    TFIO,TMPW             +  PUT OPERATION..                 57600013
         BZ    IOD70                 *  NO.                             57900013
         L     RA,WSDV                  YES, ADDRESS VDA,               58200013
         LH    RC,WSDV+6                 OBTAIN LENGTH.                 58500013
         BAL   RD,IOD82              $  MOVE VDA TO RECORDS.            58800013
IOD70    IHEPRV FVD,BR                                                  59100015
         BALR  LR,BR                 $$ FREE VDA.                       59400013
         B     IODR1                                                    59700013
         SPACE 2                                                        60000013
IODR0    TM    TFIO,TMGR             +  GET..                           60300013
         BO    IODR1                 *  YES, DON'T BOTHER.              60600013
IODRA    L     RC,TCBA                  NO, UPDATE BUFFER PTRS.         60900013
         AH    RC,WSDV+6                                                61200013
         ST    RC,TCBA                                                  61500013
         LH    RC,TREM                                                  61800013
         SH    RC,WSDV+6                                                62100013
         STH   RC,TREM                                                  62400013
         SPACE                                                          62700013
IODR1    L     DR,OFDR(DR)              READDRESS CALLER'S SSA.         63000013
         LM    LR,PWR,OFLR(DR)          RESTORE HIS REGISTERS.          63300013
         SR    BR,BR                    SIGNAL NO ENDFILE.              63600013
         BR    LR                    X  RETURN.                         63900013
         SPACE                                                          64200013
IODR2    L     DR,OFDR(DR)              READDRESS CALLER'S SSA.         64500013
         LM    LR,PWR,OFLR(DR)          RESTORE HIS REGISTERS.          64800013
         BR    LR                    X  RETURN WITH ENDFILE SIGNAL.     65100013
         EJECT                                                          65400013
*  COPY RECORDS TO VDA                                                  65700013
         SPACE                                                          66000013
IOD80    LA    RG,0                  .  PREPARE FOR REC TO VDA MOVE.    66300013
         USING IOD00+2,PWR-1                                            66600013
         B     IOD84                                                    66900013
         SPACE                                                          67200013
*  COPY VDA TO RECORDS                                                  67500013
         SPACE                                                          67800013
IOD82    LA    RG,6                  .  PREPARE FOR VDA TO REC MOVE.    68100013
         SPACE                                                          68400013
IOD84    BALR  RH,0                                                     68700013
         USING *,RH                                                     69000013
IOD86    L     RE,TCBA                  ADDRESS RECORD AREA.            69300013
         LH    RF,TREM                  OBTAIN AVAILABLE BYTE COUNT.    69600013
         CR    RC,RF                    REQUIREMENT GRTR AVAILABLE..    69900013
         BNH   IOD88                 *  NO.                             70200013
         LTR   RY,RF                    ANY LEFT IN THE BUFFER..        70400016
         BZ    IOD87                    NO                              70600016
         BAL   RZ,IOD8A              $  MOVE AVAILABLE BYTES.           70800013
         SR    RC,RF                    REDUCE REQUIREMENT.             71100013
         ST    RE,TCBA                  STORE AVAILABLE RECORD ADDR.    71400013
         SR    RF,RF                    REDUCE RECORD REMAINDER COUNT   71700013
         STH   RF,TREM                                                  72000013
IOD87    EQU   *                                                        72100016
         BAL   RE,IOD90              $  ACCESS RECORD.                  72300013
         B     IOD86                 *  USE IT.                         72600013
         SPACE                                                          72900013
IOD88    LR    RY,RC                    AVAILABLE BYTES LTE. REQ        73200013
         BAL   RZ,IOD8A              $  MOVE REQUIRED BYTES.            73500013
         SR    RF,RC                    REDUCE AVAILABLE RECORD COUNT.  73800013
         STH   RF,TREM                                                  74100013
         ST    RE,TCBA                  STORE AVAILABLE RECORD ADDR.    74400013
         BR    RD                    X  RETURN.                         74700013
         SPACE                                                          75000013
IOD8A    LA    RI,255                                                   75300013
IOD8B    CR    RY,RI                    MORE THAN 255 BYTES TO MOVE..   75600013
         BNH   IOD8C                 *  NO.                             75900013
         EX    0,IODMY(RG)              YES,                            76200013
         SR    RY,RI                    REDUCE REQUIREMENT              76500013
         AR    RA,RI                    BUMP                            76800013
         AR    RE,RI                     MOVE ADDRESSES.                77100013
         B     IOD8B                    CONTINUE.                       77400013
IOD8C    BCTR  RY,0                     ACCOUNT FOR MVC BONUS.          77700013
         EX    RY,IODMV(RG)             MOVE LAST FEW BYTES.            78000013
         LA    RE,1(RY,RE)              BUMP AVAILABLE RECORD ADDR.     78300013
         LA    RA,1(RY,RA)              BUMP VDA ADDRESS.               78600013
IOD8D    BR    RZ                    *  RETURN.                         78900013
         SPACE 2                                                        79200013
IODMV    MVC   0(*-*,RA),0(RE)          MOVE TO VDA                     79500013
         MVC   0(*-*,RE),0(RA)          MOVE TO REC                     79800013
IODMY    MVC   0(255,RA),0(RE)           MOVE TO VDA                    80100013
         MVC   0(255,RE),0(RA)           MOVE TO REC                    80400013
         EJECT                                                          80700013
*  ACCESS NEXT RECORD                                                   81000013
         SPACE                                                          81300013
IOD90    LR    RI,RA                                                    81600013
         LR    RA,RB                                                    81900013
         BALR  LR,0                                                     82200013
         USING *,LR                                                     82500013
         L     BR,VIOFA                                                 82800013
         BALR  LR,BR                 $$ ACCESS NEXT RECORD .            83100013
         USING *,LR                                                     83400013
         TM    TFER,TMIE                INPUT TRANSMIT..          14883 83440016
         BZ    IOD97                    NO                        14883 83480016
         OI    TFER,TMIT             YES,PUT ITEM XMIT FLAG ON    14883 83520016
         IHEPRV CFL,RA,OP=LA                                      14883 83560017
         OI    4(RA),TCFL                                         14883 83600017
IOD97    EQU   *                                                  14883 83640016
         LR    RA,RI                                                    83700013
         LTR   BR,BR                    ENDFILE ENCOUNTERED..           84000013
         BCR   8,RE                  *  NO, RETURN                      84050015
         TM    WONC+2,TMVD              YES, IS VDA ALLOCATED           84100015
         BO    IODER                 ** YES, ERROR. FIELD NOT SCANNED   84150015
IODEF    EQU   *                                                        84200015
          BALR LR,0                                                     84210015
         USING *,LR                                                     84220015
         LH    RA,ERRA                  END OF FILE CODE                84250015
         IHEPRV ERR,RA,OP=STH                                           84300015
         L     RA,TDCL                  GET A(DCLCB)                    84350015
         L     BR,VERRB                                                 84400015
         BALR  LR,BR                 $$ RAISE ENDFILE CONDITION         84450015
         B     IODR2                                                    84500015
         BR    RE                    *  NO, RETURN.                     84600013
         DROP  LR                                                       84900013
         SPACE 3                                                        85200013
*  ATTEMPT TO GO BEYOND STRING LENGTH                                   85500013
         SPACE                                                          85800013
IODX0    L     BR,VERRC                                                 86100013
         BALR  RA,BR                 $$ RAISE 'ERROR' CONDITION.        86400013
         DC    AL2(ERR0)                (NO RETURN)                     86700013
         SPACE 3                                                        86730015
*   ENDFILE BEFORE END OF DATA ITEM                                     86760015
         SPACE                                                          86790015
IODER    EQU   *                                                        86820015
         LA    RA,EROF                  LOAD ERROR CODE                 86850015
         L     BR,VERRC                 A( ERROR ROUTINE )              86880015
         BR    BR                    $$ RAISE ERROR                     86910015
         SPACE 3                                                        87000013
*  CONSTANTS                                                            87300013
         SPACE                                                          87600013
VIOFA    DC    V(IHEIOFA)               ACCESS RECORD                   87900013
VERRB    DC    V(IHEERRB)               EXEP (ON CONDITIONS)            88800013
VERRC    DC    V(IHEERRC)               EXEP ('ERROR' CONDITION)        89100013
ERRB     DC    AL2(ERR1)                                                89700013
ERRA     DC    AL2(ERR2)                END OF FILE                     89800015
EROF     DC    AL2(ERR3)                END FILE RAISED UNEXPECTEDLY    89900015
         END                                                            90000013
