IOF      TITLE '    IHEIOF    RECORD ACCESSOR                          /00300013
               OS/360 PL/I LIBRARY'                                     00600013
*    VERSION   FOURTH VERSION OF F-LEVEL COMPILER                       00900015
*                                                                       01200013
*   STATUS     CHANGE LEVEL - 0                                         01500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOF000-TSS 01600001
*        ----------------------------------------------------IOF000-TSS 01700001
*                                                                       01800013
*   SIZE       472 BYTES                                                02100013
*                                                                       02400013
*   FUNCTION   TO ACCESS, AND PREPARE, LOGICAL RECORD FOR INPUT/OUTPUT  02700013
*                INPUT                                                  03000013
*                 1) INVOKE TRANSMISSION MODULE TO READ RECORD,         03300013
*                 2) RAISE 'ENDFILE' CONDITION IF ENDFILE ENCOUNTERED,  03600013
*                    AND SIGNAL CONDITION TO CALLER.                    03900013
*                 3) UPDATE FCB TO ADDRESS LOGICAL RECORD INITIAL       04200013
*                    DATA BYTE, IF V-FORMAT RECORD (I.E.,  ADD 4 TO     04500013
*                    TCBA, REDUCE TREM BY 4).                           04800013
*                                                                       05100013
*                OUTPUT                                                 05400013
*                 1) INVOKE TRANSMISSION MODULE TO OBTAIN AREA FOR      05700013
*                    LOGICAL RECORD,                                    06000013
*                 2) IF PRINT FILE,      INSERT SINGLE-SPACE ASA        06300013
*                    CODE, INCREMENT LINE-NUMBER, TEST FOR END PAGE     06600013
*                    CONDITION,                                         06900013
*                 3) IF U-FORMAT RECORDS, MOVE PRIOR RECORD TO LOCATED  07200013
*                    OUTPUT AREA, ALTER FCB TO POINT TO WORK AREA.      07500013
*                 4) IF V-FORMAT RECORDS, PREPARE INITIAL 10 BYTES WITH 07800013
*               BLANKS, UPDATING LITTLE LL IN RECORD-CONTROL-WORD, TO   08100013
*               PREVENT POSSIBLE NOISE-RECORD PROBLEMS.                 08400013
*               ALSO, SET LITTLE LL FOR     PRIOR OUTPUT RECORD, IF     08700013
*               PRESENT                                                 09000013
*                                                                       09300013
*   ENTRY POINT                                                         09600013
*              IHEIOFA - PERFORM ABOVE FUNCTIONS FOR CURRENT FILE.      09900013
*                                                                       10200013
*                 (NO EXPLICIT ARGUMENTS)                               10500013
*                                                                       10800013
*   INPUT      CURRENT FILE PSEUDO-REGISTER, DCLCB, FCB.                11100013
*                                                                       11400013
*   OUTPUT     UPDATED FCB, AND PREPARED LOGICAL RECORD AS PER ABOVE    11700013
*              FUNCTIONS.                                               12000013
*                                                                       12300013
*   EXTERNAL MODULES                                                    12600013
*              IHEIT** - TRANSMISSION MODULE, ADDRESSED VIA FCB (TACM)  12900013
*              IHEERRB - ENDFILE CONDITION SIGNAL                       13200013
*                                                                       13500013
*   EXITS      NORMAL                                                   13800013
*               RETURN TO CALLER VIA LINK REGISTER                      14100013
*                RETURN CODE = 0  (NO ENDFILE ENCOUNTERED)              14400013
*                RETURN CODE = 4  (ENDFILE ENCOUNTERED)                 14700013
*              ERROR                                                    15000013
*               (SYSTEM ACTION FOR ENDFILE CONDITION)                   15300013
*               IHE140I  FILE ***  END OF FILE ENCOUNTERED              15600013
*                                                                       15900013
*   TABLES/WORK-AREA                                                    16200013
*              SEE OS/360 PL/I LIBRARY PLM FOR DESCRIPTION OF FCB,      16500013
*              CURRENT-FILE, FILE-REGISTER, ALSO SEE DATA MANAGEMENT    16800013
*              SRL FOR DESCRIPTION OF RECORD FORMATS.                   17100013
*              WORK-AREA IS OBTAINED FROM DYNAMIC STORAGE (ZWS).        17400013
*                                                                       17700013
*   ATTRIBUTES  READ-ONLY AND REENTRANT.                                18000013
*                                                                       18300013
*   PRIVATE MACROS                                                      18600013
*              IHELIB,IHESDR,IHEPRV,IHEZAP                              18900013
*                                                                       19200013
*   ASSEMBLY REQUIREMENTS                                               19500013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   19800013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        20100013
*                                                                       20400013
*   NOTES      SEE OS/360 PL/I LIBRARY PLM FOR LIBRARY MODULE           20700013
*              CONVENTIONS AND STANDARDS.                               21000013
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON        21300013
*              A PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL     21600013
*              CHARACTER SET.                                           21900013
         EJECT                                                          22200013
IHEIOF   CSECT                                                          22500013
*     ENTRY POINT.                                                      22800013
         SPACE                                                          23100013
         ENTRY IHEIOFB,IHEIOFA,IHEITAA,IHEITAZ,IHEITAX                  23400016
         SPACE 2                                                        23700013
*     ASSEMBLY PARAMETERS.                                              24000013
         SPACE 2                                                        24300013
         IHELIB                         DEFINE PL/I LIBRARY SYMBOLICS   24600013
         IHEZAP                         DEFINE PL/I FILE CONTROL BLOCK  24900013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOF001-TSS 25000001
         DCBD  DSORG=QS                                                 25200013
*        ----------------------------------------------------IOF001-TSS 25220001
         EJECT                                                          25250016
IHELW1   DSECT                                                          25300016
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOF022-TSS 25320001
         DS    9D                       SAVE AREA                       25350016
WORKS    DS    H                        WORK AREA                       25400016
*        ----------------------------------------------------IOF022-TSS 25420001
         SPACE 3                                                        25450016
PWR      EQU   WR                                                     * 25500013
MEPG     EQU   X'B000'                  ENDPAGE ON-NUMBER               25800013
MEJT     EQU   C'1'                     PAGE EJECT ASA CHARACTER        26100013
ERR1     EQU   X'B800'                  CODE FOR ENDFILE COND.          26400013
BLKD     EQU   X'10'                    BLOCKED RECORD INDICATION       26470016
ERR0     EQU   X'9801'                  ERROR CODE FOR OUTPUT TRANSMIT  26540016
         USING IHELW1,DR                                                26610016
         USING IHEZAPE,RB               DEFINE BASE-REG FOR DCBAPE      26700013
         USING IHADCB,RG                                                27000013
         EJECT                                                          27300013
         SPACE 2                                                        27600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOF002-TSS 27700001
IHEIOF   CSECT                                                        * 27900013
*        ----------------------------------------------------IOF002-TSS 28000001
IHEIOFB  NOPR  0                                                        28200013
IHEIOFA  STM   LR,PWR,OFLR(DR)       .  SAVE CALLER'S REGISTERS.      * 28500013
         IHESDR LW1                     UPDATE SSA POINTER.             28800013
         BALR  PWR,0                    ESTABLISH                       29100013
         USING *,PWR                     ADDRESSIBILITY.                29400013
         LR    RB,RA                    ADDRESS CFL FCB.                29700013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOF003-TSS 29800001
*        ----------------------------------------------------IOF003-TSS 29900001
         TM    TFMD,TMIN             +  INPUT..                         30000015
         BZ    IOF10                 *  NO, PUT.                        30300013
         L     RG,TDCB                  A(DCB)                          30400016
         TM    DCBRECFM,BLKD         +  IS IT BLOCKED                   30500016
         BZ    IOFT3                 *  NO                              30600016
         L     RC,DCBRECAD           +  WILL THIS GET ACCESS            30700016
         AH    RC,DCBLRECL               A NEW BLOCK                    30800016
         CL    RC,DCBEOBAD           +  END OF BUFFER                   30900016
         BNE   IOFT4                 *  NO,LEAVE TRANSMIT FLAG ALONE    31000016
IOFT3    EQU   *                                                        31100016
         NI    TFLX,255-TMIE            CLEAR TRANSMIT FLAG             31200016
IOFT4    EQU   *                                                        31300016
         LR    RA,RG                    A(DCB)                          31400016
         L     R0,TREC                  (  POSSIBLE PAPER TAPE )        31500016
*                                                                       31600016
         GET   (1)                                                      31700016
*                                                                       31800016
         LH    RC,DCBLRECL              LENGTH OF RECORD                31900016
         STH   RC,TMAX                  MAX. BYTES ON RECORD            32000016
         TM    TFRC,TMVB             +  IS IT V FORMAT                  32100016
         BZ    IOFT5                 *  NO,                             32200016
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOF007-TSS 32250001
         MVC   WORKS,0(RA)              MOVE IT OUT INTO WORK SPACE     32300016
*        ----------------------------------------------------IOF007-TSS 32350001
         LH    RC,WORKS                 LOAD NO. OF BYTES               32400016
         STH   RC,TMAX                  COUNT OF MAXIMUM BYTES          32500016
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOF008-TSS 32530001
*        ----------------------------------------------------IOF008-TSS 32560001
         SH    RC,H004                  ACCOUNT FOR RCW                 32600016
         LA    RA,4(RA)                 SKIP OVER RCW                   32700016
IOFT5    EQU   *                                                        32800016
         STH   RC,TLNZ                  STORE LINESIZE                  32900016
         STH   RC,TREM                  COUNT OF BYTES REMAINING        33000016
         TM    TFDV,TMPA             +  IS IT PAPER TAPE                33100016
         BZ    IOFT6                 *  NO,                             33200016
         L     RA,TREC                  YES, GET A(DUMMY BUFFER )       33300016
IOFT6    EQU   *                                                        33400016
         ST    RA,TCBA                  A(BUFFER )                      33500016
         B     IOFR1                 *  EXIT.                           34200013
         SPACE                                                          34500013
IOF10    TM    TFRC,TMFX             +  F-FORMAT RECORDS..              34800013
         BO    IOF18                 +  YES.                            35100013
         L     RG,TDCB                                                  35400013
         LH    RC,TMAX                  NO, DOES A RECORD EXIST..       35700013
         LTR   RC,RC                                                    36000013
         BZ    IOF12                  * NO.                             36300013
         L     RD,TCBA                  YES, COMPUTE RECORD LENGTH.     36600013
         SR    RD,RC                                                    36900013
         AH    RD,TREM                                                  37200013
         SH    RC,TREM                                                  37500013
         TM    TFRC,TMVB             +  V-FORMAT RECORDS..              37800013
         BZ    IOF14                 *  NO, U-FORMAT.                   38100013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOF009-TSS 38200001
         CH    RC,NOIS                  YES, TOO FEW BYTES..            38400013
*        ----------------------------------------------------IOF009-TSS 38500001
         BNH   IOF20                 *  YES, USE INITIALIZED COUNT.     38700013
         STH   RC,TMAX                  OK, SET BYTE-COUNT (LITTLE LL). 39000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOF010-TSS 39100001
         MVC   0(2,RD),TMAX                                             39300013
*        ----------------------------------------------------IOF010-TSS 39400001
         B     IOF20                 *  DO NEXT RECORD.                 39600013
         SPACE                                                          39900013
IOF12    TM    TFRC,TMVB             +  NO PRIOR RECORD, V-FORMAT..     40200013
         BO    IOF20                 *  YES.                            40500013
         L     RC,TREC                  NO, U-FORMAT, SET RECORD        40800013
         LH    RD,TLNZ                   POINTERS                       40900015
         TM    TFRC,TMAS             +  PRINT OPTION..                  41000015
         BZ    IOF13                    NO                              41100015
         LA    RD,1(RD)                 ACCOUNT FOR CONTROL BYTE        41200015
IOF13    EQU   *                                                        41300015
         STH   RD,TMAX                                                  41400013
         B     IOF30                 *  TEST FOR PRINT FILE.            41700013
         SPACE                                                          42000013
IOF14    EQU   *                                                        42300013
         TM    TFRC,TMAS             +  PRINT FILE                      42600013
         BO    IOF16                    YES                             42700015
         LTR   RC,RC                 +  LENGTH OF ZERO..                42800015
         BNZ   IOF15                    NO                              42900015
         B     IOF19                    YES                             43000015
IOF16    EQU   *                                                        43100015
         BCT   RC,IOF17                 LENGTH GREATER THAN ONE         43200013
         LA    RC,1(RC)                 INCREMENT BYTE COUNT            43500013
IOF19    EQU   *                                                        43600015
         L     RD,TCBA                  A(DUMMY BUFFER)                 43800013
         MVI   0(RD),C' '               MOVE BLANK                      44100013
IOF17    EQU   *                                                        44400013
         LA    RC,1(RC)                 INCREMENT BYTE COUNT            44700013
IOF15    EQU   *                                                        45000013
         STH   RC,DCBLRECL              EXISTENT U-FORMAT RECORD, SET  /45300013
                                         RECORD LENGTH USED.            45600013
         B     IOF20                                                    45900013
IOF18    EQU   *                                                        46200013
         LH    BR,TREM                  NUMBER OF BYTES LEFT            46500013
         L     LR,TCBA                  A(NEXT FREE BYTE)               46800013
         LA    RC,256                                                   47100013
         LTR   BR,BR                 +  TEST IF ZERO                    47400013
         BZ    IOF20                 *  YES                             47700013
         MVI   0(LR),C' '               MOVE BLANK BYTE                 48000013
IOF21    EQU   *                                                        48300013
         CR    BR,RC                    IS BYTE COUNT GREATER THAN 256  48600013
         BNH   IOF23                    NO                              48900013
         MVC   1(256,LR),0(LR)          YES,  MOVE BLANK BYTES          49200013
         SR    BR,RC                    NUMBER OF BYTES LEFT            49500013
         AR    LR,RC                    BUMP UP TARGET ADDR.            49800013
         B     IOF21                    LOOP                            50100013
IOF23    EQU   *                                                        50400013
         BCTR  BR,0                     REDUCE COUNT BY ONE             50700013
         BCTR  BR,0                     REDUCE COUNT BY ONE             51000013
         LTR   BR,BR                    IS IT POSITIVE                  51300013
         BM    IOF20                    NO                              51600013
         EX    BR,BLANKOUT              BLANK OUT REMAINING BYTES       51900013
IOF20    EQU   *                                                        51960016
         L     RG,TDCB                  A( DCB )                        52020016
         LR    RA,RG                    A( DCB ) INTO PARAM REGISTER    52080016
*                                                                       52140016
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOF012-TSS 52160001
*        ----------------------------------------------------IOF012-TSS 52180001
         PUT   (1)                   $$ LOCATE NEXT LOGICAL RECORD      52200016
*                                                                       52260016
         LR    RC,RA                    A( BUFFER )                     52320016
         LH    RD,DCBLRECL              INITIALISE FCB                  52380016
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOF019-TSS 52400001
*        ----------------------------------------------------IOF019-TSS 52420001
         STH   RD,TREM                  REMAINDER AND                   52440016
         STH   RD,TMAX                  MAXIMUM COUNTS                  52500016
         ST    RC,TCBA                  A( LOGICAL RECORD )             52560016
         TM    TFLX,TMOE             +  TRANSMIT TO BE RAISED           52620016
         BZ    IOFT2                 *  NO,                             52680016
         LH    RA,ERRA                  OUTPUT ERROR FLAG               52740016
         IHEPRV ERR,RA,OP=STH           STORE INTO ERROR SLOT           52800016
         L     RA,TDCL                  A(DCLCB)                        52860016
         L     BR,VERRB                 AERROR ROUTINE)                52920016
         BALR  LR,BR                 $$ RAISE XMIT ERROR                52980016
         TM    TFDV,TMPR             +  IS IT PRINTER DEVICE            53040016
         BO    IOFT1                 *  YES,                            53100016
         L     BR,VERRC                                                 53160016
         BALR  RA,BR                    PERMANENT OUTPUT ERROR          53220016
         DC    X'0003'                                                  53280016
IOFT1    EQU   *                                                        53340016
         NI    TFLX,255-TMOE            TURN OFF OUTPUT TRANSMIT        53400016
IOFT2    EQU   *                                                        53460016
         TM    TFRC,TMFX             +  F-FORMAT RECORDS..              53700013
         BO    IOF30                 *  YES, JUST TEST FOR PRINT FILE   54000013
         TM    TFRC,TMVB             +  V-FORMAT RECORDS..              54300013
         BO    IOF26                 *  YES.                            54600013
         LH    RA,DCBLRECL              NO, MUST BE U-FORMAT,           54900013
         L     RC,TREC                   MOVE WORK-AREA TO RECORD       55200013
         L     RD,TCBA                   LOCATED.                       55500013
         LA    RE,255                                                   55800013
IOF22    CR    RA,RE                    MORE THAN 255 BYTES..           56100013
         BNH   IOF24                    NO                              56400013
         MVC   0(255,RD),0(RC)          YES, MOVE 255 BYTES.            56700013
         SR    RA,RE                    REDUCE REQUIREMENT.             57000013
         AR    RC,RE                    BUMP SOURCE,                    57300013
         AR    RD,RE                     TARGET ADDRESSES.              57600013
         B     IOF22                    CONTINUE.                       57900013
IOF24    BCTR  RA,0                     MOVE UNDER 255 BYTES.           58200013
         EX    RA,IOFM2                                                 58500013
         L     RC,TREC                  RESET 'CURRENT BUFFER ADDR',    58800013
         LH    RD,TLNZ                   LENGTH FIELDS                  58900015
         TM    TFRC,TMAS             +  PRINT OPTION..                  59000015
         BZ    IOF25                    NO                              59100015
         LA    RD,1(RD)                 ACCOUNT FOR CONTROL BYTE        59200015
IOF25    EQU   *                                                        59300015
         STH   RD,TMAX                                                  59400013
         B     IOF30                 *  TEST FOR PRINT FILE.            59700013
         SPACE                                                          60000013
IOF26    MVC   0(4,RC),NOIS             V-FORMAT, INITIALIZE LITTLE LL. 60300013
         MVI   4(RC),C' '               AND FIRST 10 CHARACTERS,        60600013
         MVC   5(9,RC),4(RC)            TO PREVENT NOISE ERRORS.        60900013
         LA    RC,4(RC)                 BUMP BUFFER ADDRESS BEYOND CTL. 61200013
         SH    RD,H004                  REDUCE AVAILABLE BYTE COUNT.    61500013
IOF30    TM    TFRC,TMAS             +  PRINT FILE..                    61800013
         BZ    IOF34                 *  NO.                             62100013
         LA    RC,1(RC)                 BUMP BUFFER ADDRESS,            62400013
         BCTR  RD,0                     REDUCE AVAILABLE BYTE COUNT.    62700013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOF021-TSS 62800001
*        ----------------------------------------------------IOF021-TSS 62900001
IOF34    ST    RC,TCBA                  UPDATE BUFFER INFO.             63000013
         STH   RD,TREM                  (NB. TMAX INCLUDES ALL BYTES)   63300013
         TM    TFRC,TMAS             +  PRINT FILE..                    63600013
         BZ    IOFR1                 *  NO.                             63900013
         BCTR  RC,0                                                     64200013
         MVI   0(RC),C' '               YES, INITIALIZE FOR SPACING 1.  64500013
         LH    RA,TLNN                  BUMP LINE NUMBER.               64800013
         LA    RA,1(RA)                                                 65100013
         STH   RA,TLNN                                                  65400013
         CH    RA,TPGZ                  PAGE SPILL CONDITION..          65700013
         BNH   IOFR1                    NO.                             66000013
         TM    TFLX,TMEP             +  YES, BUT WAS ENDPAGE RAISED..   66300013
         BO    IOFR1                    YES, DO NOT RAISE ENDPAGE.      66600013
         OI    TFLX,TMEP             /  SET ENDPAGE RAISED FLAG.        66900013
         LH    RA,HEPG                  SET EXEP ON-NUMBER.             67200013
         IHEPRV ERR,RA,OP=STH                                           67500013
         L     RA,TDCL                  GET A(DCLCB).                   67800013
         L     BR,VERRB                                                 68100013
         BALR  LR,BR                 $$  RAISE ENDPAGE CONDITION.       68400013
         LTR   BR,BR                    SYSTEM ACTION REQUIRED..        68700013
         BZ    IOFR1                 * NO, JUST USE CURRENT LINE.       69000013
         MVI   0(RC),MEJT               YES, SET EJECT CHARACTER.       69300013
         LA    RA,1                     INITIALIZE LINE-NUMBER TO 1.    69600013
         STH   RA,TLNN                                                  69900013
         NI    TFLX,255-TMEP         /  UNSET ENDPAGE FLAG.             70200013
IOFR1    L     DR,OFDR(DR)              READDRESS CALLER'S SSA.         70500013
         LM    LR,PWR,OFLR(DR)          RESTORE HIS REGISTERS.          70800013
         SR    BR,BR                    SIGNAL NO ENDFILE.              71100013
         BR    LR                    X  RETURN.                         71400013
         SPACE 3                                                        71700013
*  ENDFILE ENCOUNTERED                                                  72000013
         SPACE                                                          72300013
         SPACE                                                          75300013
IOFX2    EQU   *                                                        75600013
         L     DR,OFDR(DR)              RETURN FROM ON UNIT,            75900013
         LM    LR,PWR,OFLR(DR)          RESTORE REGISTERS AND           76200013
         LA    BR,4                     SIGNAL ENDFILE ENCOUNTERED.     76500013
         BR    LR                    X  RETURN TO CALLER.               76800013
         SPACE 2                                                        77100013
BLANKOUT MVC   1(*-*,LR),0(LR)          BLANK OUT REST OF BUFFER        77400013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOF016-TSS 77500001
*        ----------------------------------------------------IOF016-TSS 77600001
         SPACE 3                                                        77700013
         EJECT                                                          77710016
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOF017-TSS 77713001
*        ----------------------------------------------------IOF017-TSS 77716001
*   END OF DATA SET ROUTINE  (EODAD EXIT FROM QSAM )                    77720016
*                                                                       77730016
IHEITAZ  EQU   *                                                        77740016
         OI    TFLX,TMEF             /  SET EOF FLAG IN FCB             77750016
         NI    TFLX,255-TMIE-TMOE    /  CLEAR TRANSMIT FLAGS            77760016
         B     IOFX2                                                    77770016
         SPACE 3                                                        77780016
*   SYNAD EXIT FROM QSAM                                                77790016
*                                                                       77800016
IHEITAX  EQU   *                                                        77810016
         USING IHEITAX,BR                                               77820016
         TM    TFMD,TMIN             +  IS IT INPUT                     77830016
         BO    ITAX1                 *  YES,                            77840016
         OI    TFLX,TMOE             /  NO,SET OUTPUT TRANSMIT FLAG     77850016
         BR    LR                    X  RETURN TO DATA MANAGEMENT       77860016
ITAX1    EQU   *                                                        77870016
         OI    TFLX,TMIE             /  SET INPUT TRANSMIT FLAG ON      77880016
         BR    LR                    X  RETURN TO DATA MANAGEMENT       77890016
         DROP  BR                                                       77900016
         SPACE 3                                                        77910016
IHEITAA  EQU   *                                                        77920016
         BR    LR                       DUMMY ENTRY POINT               77930016
         EJECT                                                          77940016
*  CONSTANTS                                                            78000013
         SPACE                                                          78300013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOF018-TSS 78400001
NOIS     DC    H'14',H'00'              LITTLE LL ANTI-NOISE CAMPAIGNER 78600013
*        ----------------------------------------------------IOF018-TSS 78700001
H004     DC    H'4'                                                     78900013
ERRB     DC    AL2(ERR1)                ENDFILE CODE                    79200016
HEPG     DC    AL2(MEPG)                                                79500013
VERRB    DC    V(IHEERRB)                                               79800013
VERRC    DC    V(IHEERRC)               EXEP.  (ERROR CONDITION )       79900016
ERRA     DC    AL2(ERR0)                                                80000016
IOFM2    MVC   0(*-*,RD),0(RC)                                          80100013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOF020-TSS 80200001
*        ----------------------------------------------------IOF020-TSS 80300001
         END   IHEIOF                                                   80400013
