IOP      TITLE '    IHEIOP    PAGE, SKIP, LINE FORMAT ITEMS            /00400013
               OS/360 PL/I LIBRARY'                                     00800013
*    VERSION   FOURTH VERSION OF F-LEVEL PL/I COMPILER                  01200015
*                                                                       01600013
*   STATUS     CHANGE LEVEL - 0                                         02000013
* R20      440000                                                A30366 02050000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOP000-TSS 02100001
*        ----------------------------------------------------IOP000-TSS 02200001
*                                                                       02400013
*   SIZE       424 BYTES                                                02800013
*                                                                       03200013
*   FUNCTION   TO PERFORM PAGE, SKIP, LINE FEATURES BY GENERATING       03600013
*              OUTPUT RECORDS, CHECKING FOR ENDPAGE CONDITION AS EACH   04000013
*              'LINE' IS PREPARED FOR OUTPUT TO THE CURRENT FILE.       04400013
*                                                                       04800013
*   ENTRY POINTS                                                        05200013
*              IHEIOPA - PAGE                                           05600013
*                  (NO ARGUMENTS)                                       06000013
*              IHEIOPB - SKIP                                           06400013
*                  RA = A(FED)                                          06800013
*                  FED = HALF-WORD BINARY INTEGER                       07200013
*              IHEIOPC - LINE                                           07600013
*                  (CF.IHEIOPB)                                         08000013
*                                                                       08400013
*   INPUT      CURRENT FILE PSEUDO-REGISTER (IHEQCFL), FCB, DCLCB,      08800013
*              FILE REGISTER, SKIP/LINE VALUE.                          09200013
*                                                                       09600013
*   OUTPUT     UPDATED LINE-NUMBER (TLNN) IN FCB, SPECIFIED PAGE 'LINE' 10000013
*                                                                       10400013
*   EXTERNAL MODULES                                                    10800013
*              IHEIOF - ACCESS NEXT OUTPUT RECORD                       11200013
*              IHEERR - RAISE ENDPAGE CONDITION, ERROR CONDITION        11600013
*                                                                       12000013
*   EXITS      NORMAL                                                   12400013
*               RETURN TO CALLER VIA LINK REGISTER                      12800013
*              ERROR                                                    13200013
*               IHE014I  FILE *** - PRINT OPTION/FORMAT ITEM FOR NON-   13600013
*                        PRINT FILE                                     14000013
*              EXCEPTIONAL                                              14400013
*               INVOKE EXEP (IHEERRB) TO RAISE ENDPAGE CONDITION        14800013
*                                                                       15200013
*   TABLES/WORK-AREA                                                    15600013
*              SEE OS/360 PL/I LIBRARY PLM FOR DESCRIPTION OF FCB,      16000013
*              DCLCB, FILE REGISTER, AND CURRENT FILE.                  16400013
*              WORK-AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS).        16800013
*                                                                       17200013
*   ATTRIBUTES  READ-ONLY AND REENTRANT                                 17600013
*                                                                       18000013
*   PRIVATE MACROS                                                      18400013
*              IHELIB,IHESDR,IHEPRV,IHEZAP                              18800013
*                                                                       19200013
*   ASSEMBLY REQUIREMENTS                                               19600013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   20000013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        20400013
*                                                                       20800013
*   NOTES      SEE OS/360 PL/I LIBRARY PLM FOR LIBRARY MODULE           21200013
*              CONVENTIONS AND STANDARDS.                               21600013
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON        22000013
*              A PARTICULAR INTERNAL REPRESENTATION OF THE              22400013
*              EXTERNAL CHARACTER SET.                                  22800013
         EJECT                                                          23200013
IHEIOP   CSECT                                                          23600013
*  ENTRY POINTS                                                         24000013
         SPACE                                                          24400013
         ENTRY IHEIOPA,IHEIOPB,IHEIOPC                                  24800013
         EJECT                                                          25200013
*  ASSEMBLY PARAMETERS                                                  25600013
         SPACE                                                          26000013
         IHELIB                         DEFINE PL/I LIBRARY SYMBOLICS   26400013
         IHEZAP                         DEFINE PL/I FILE CONTROL BLOCK  26800013
PWR      EQU   WR                                                     * 27200013
ERR0     EQU   X'0005'                 ERROR-CODE ILLEGAL PRINT OPTION  27600013
MEPG     EQU   X'B000'                  ENDPAGE ON-NUMBER               28000013
MEOF     EQU   X'B800'                  END OF FILE                     28200016
MEJT     EQU   C'1'                     ASA EJECT                       28400013
M0SP     EQU   C'+'                         SUPPRESS SPACE              28800013
M1SP     EQU   C' '                         SINGLE SPACE                29200013
M2SP     EQU   C'0'                         DOUBLE SPACE                29600013
M3SP     EQU   C'-'                         TRIPLE SPACE                30000013
         USING IHEZAPE,RB               DEFINE BASE-REG FOR FCB         30400013
         USING IHEZDCL,RA               DEFINE BASE-REG FOR DCLCB       30800013
         EJECT                                                          31200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOP001-TSS 31400001
IHEIOP   CSECT                                                        * 31600013
*        ----------------------------------------------------IOP001-TSS 31800001
IHEIOPA  NOPR  0                     .  PAGE.                           32000013
         SPACE                                                          32400013
IHEIOPB  NOP   0                     .  SKIP.                           32800013
         SPACE                                                          33200013
IHEIOPC  STM   LR,PWR,OFLR(DR)       .  LINE.                           33600013
         LR    RD,DR                                                    34000013
         IHESDR LW2                     UPDATE SSA POINTER.             34400013
         BALR  PWR,0                    ESTABLISH                       34800013
         USING *,PWR                     ADDRESSIBILITY.                35200013
         LR    RH,RA                    SAVE P.LIST ADDRESS.            35600013
         IHEPRV CFL,RA                  ADDRESS CFL FCB.                36000013
         LH    RB,DPRO                                                  36400013
         L     RB,0(RB,PR)                                              36800013
         TM    TFRC,TMAS             +  PRINT FILE..                    37200013
         BZ    IOP25                    NO                              37600015
         BAL   RE,IOP60              $  WHIP UP A RECORD.               38000013
         L     RA,TCBA                  ADDRESS ASA BYTE WITHIN RECORD  38400013
         BCTR  RA,0                                                     38800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOP002-TSS 38900001
*        ----------------------------------------------------IOP002-TSS 39000001
         TM    OFBR+3(RD),X'06'         WHAT'S UP..                     39200013
         BZ    IOP40                 *  PAGE                            39600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOP003-TSS 39700001
*        ----------------------------------------------------IOP003-TSS 39800001
         LH    RC,0(RH)                 OBTAIN LINE/SKIP ARGUMENT.      40000013
         BM    IOP30                 *  SKIP                            40400013
         SPACE 2                                                        40800013
*  LINE                                                                 41200013
         SPACE                                                          41600013
         LTR   RC,RC                    LINE VALUE GTR ZERO..           42000013
         BP    IOP00                    YES.                            42400013
         LA    RC,1                     NO, TREAT AS LINE(1).           42800013
IOP00    LH    RE,TLNN                  DESIRED LINE GTR CURRENT LINE.. 43200013
         CR    RC,RE                                                    43600013
         BNL   IOP20                 *  YES, BY ONE OR MORE.            44000013
         BCTR  RE,0                    REDUCE LINE NO. BY 1      A30366 44050000
         CR    RC,RE                   IS THIS A REQUEST FOR THE A30366 44100000
         BNE   IOP01                   CURRENT LINE. NO BRANCH   A30366 44150000
         SR    RC,RC                   YES, TREAT AS SKIP(0)     A30366 44200000
         B     IOP30                                             A30366 44250000
IOP01    EQU   *                                                 A30366 44300000
         TM    TFLX,TMEP             +  NO, BUT IS ENDPAGE STATUS ON..  44400013
         BO    IOP40                 *  YES, TREAT AS PAGE.             44800013
         LH    RC,TPGZ                  NO, FORCE ENDPAGE CONDITION,    45200013
         B     IOP32                 *  SKIP ONE LINE TOO MANY.         45600013
         SPACE                                                          46000013
IOP20    SR    RC,RE                    COMPUTE SKIP REQUIREMENT.       46400013
         LA    RC,1(RC)                                                 46800013
         B     IOP32                 *  SKIP N LINES.                   47200013
         SPACE 2                                                        47600013
*  SKIP                                                                 48000013
         SPACE                                                          48020015
IOP25    EQU   *                                                        48028017
         TM    TFTY,TMST             +  IS IT A STRING                  48036017
         BO    IOPX0                 ** YES,RAISE ERROR                 48044017
         TM    OFBR+3(RD),X'06'      +  SKIP OPTION                     48052017
         BNM   IOPX0                                                    48060015
         LH    RI,0(RH)                 NO. TO SKIP                     48080015
         CH    RI,H001               +  TOO FEW..                       48100015
         BL    IOPX0                    YES - RAISE ERROR               48130015
IOP26    EQU   *                                                        48160015
         LR    RA,RB                    A(FCB) FOR CURRENT FILE         48180015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOP999-TSS 48190000
         L     BR,VIOFA                                                 48200015
*        ----------------------------------------------------IOP999-TSS 48210000
         BALR  LR,BR                    GET NEXT RECORD                 48220015
         CH    BR,H004               +  EOF..                           48240015
         BE    IOPX1                    YES                             48260016
         BCT   RI,IOP26                 DO ANOTHER SKIP                 48280015
         B     IOPR1                                                    48300015
         SPACE                                                          48400013
IOP30    LTR   RC,RC                    SPECIAL SPACE SUPPRESS.         48800013
         BP    IOP32                    NO.                             49200013
         LH    RE,TLNN                  YES, REDUCE CURRENT LINE NUMBER 49600013
         BCTR  RE,0                                                     50000013
         STH   RE,TLNN                                                  50400013
         LA    RF,M0SP                  PREPARE TO                      50800013
         B     IOP50                 *   SUPPRESS SPACING.              51200013
         SPACE                                                          51600013
IOP32    CH    RC,H002                  SKIP TWO..                      52000013
         BE    IOP36                 *  YES.                            52400013
         BL    IOP34                 *  SKIP ONE..                      52800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOP004-TSS 52900001
*        ----------------------------------------------------IOP004-TSS 53000001
         LR    RD,RC                    NO, THREE OR MORE.              53200013
         LA    RC,3                                                     53600013
         BAL   RE,IOPPM              $  OBTAIN PERMISSION FOR 3 LINES.  54000013
         MVI   0(RA),M3SP               GRANTED.                        54400013
         LR    RC,RD                    REDUCE SKIP REQUIREMENT BY 3.   54800013
         SH    RC,H003                                                  55200013
         BZ    IOPR1                 *  STILL MORE, NO..                55600013
         BAL   RE,IOP60              $  WHIP UP A RECORD.               56000013
         L     RA,TCBA                  ADDRESS ASA BYTE.               56400013
         BCTR  RA,0                                                     56800013
         B     IOP32                    CONTINUE.                       57200013
IOP34    LA    RF,M1SP                  PREPARE FOR SINGLE SPACE.       57600013
         B     IOP38                                                    58000013
IOP36    LA    RF,M2SP                  PREPARE FOR DOUBLE SPACE.       58400013
IOP38    BAL   RE,IOPPM              $  OBTAIN PERMISSION FOR SPACING.  58800013
         B     IOP50                 *  GRANTED.                        59200013
         SPACE                                                          59600013
         SPACE                                                          60000013
*  PAGE                                                                 60400013
         SPACE                                                          60800013
IOP40    LA    RF,MEJT                  PREPARE FOR EJECT.              61200013
         LA    RE,1                     REINITIALIZE LINE COUNTER.      61600013
         STH   RE,TLNN                                                  62000013
         NI    TFLX,255-TMEP            CLEAR ENDPAGE FLAG.             62400013
IOP50    STC   RF,0(RA)                 PLACE ASA CONTROL IN RECORD.    62800013
IOPR1    L     DR,OFDR(DR)              READDRESS CALLER'S SSA.         63200013
         LM    LR,PWR,OFLR(DR)          RESTORE HIS REGS.               63600013
         BR    LR                    X  RETURN.                         64000013
         SPACE 3                                                        64400013
*  CHECK FOR ENDPAGE CONDITION                                          64800013
         SPACE                                                          65200013
IOPPM    SR    RG,RG                 .  INITIALIZE SPACING FACTOR.      65600013
         LH    RH,TLNN                  CURRENT LINE BEYOND PAGESIZE..  66000013
IOPP1    CH    RH,TPGZ                                                  66400013
         BNH   IOPP2                    NO.                             66800013
         TM    TFLX,TMEP             +  YES, BUT WAS ENDPAGE RAISED..   67200013
         BZ    IOPPE                 *  NO, RAISE IT.                   67600013
IOPP2    BCT   RC,IOPP3                 ANY MORE DESIRED..              68000013
IOPPR    BR    RE                    X  NO, RETURN.                     68400013
IOPP3    LA    RH,1(RH)                 YES, BUMP CURRENT LINE NUMBER.  68800013
         STH   RH,TLNN                                                  69200013
         LA    RG,1(RG)                  AND LAST LINE SPACING FACTOR.  69600013
         B     IOPP1                 *  CONTINUE CHECKING.              70000013
         SPACE                                                          70400013
IOPPE    IC    RH,IOPSP(RG)             INSERT SPACING CHARACTER        70800013
         STC   RH,0(RA)                  TO FORCE LINE AT PAGESIZE+1.   71200013
         LR    RC,RA                                                    71600013
         OI    TFLX,TMEP             /  SET ENDPAGE RAISED FLAG.        72000013
         LH    RH,HEPG                  SET EXEP CODE                   72400013
         IHEPRV ERR,RH,OP=STH            FOR 'ENDPAGE' ON CONDITION.    72800013
         L     RA,TDCL                  GET A(DCLCB).                   73200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOP998-TSS 73400000
         L     BR,VERRB                                                 73600013
*        ----------------------------------------------------IOP998-TSS 73800000
         BALR  LR,BR                $$  RAISE CONDITION.                74000013
         LR    RA,RC                                                    74400013
         LTR   BR,BR                    SYSTEM ACTION REQUIRED..        74800013
         BP    IOP40                 *  YES, FORCE NEW PAGE.            75200013
         B     IOPR1                 *  NO, JUST USE CURRENT LINE.      75600013
         SPACE 2                                                        76000013
         SPACE 2                                                        76400013
IOP60    EQU   *                                                        76800013
         SPACE                                                          77200013
IOP64    LH    RF,TLNN                  PREVENT PREMATURE RAISING       77600013
         SR    BR,BR                     OF ENDPAGE CONDITION.          78000013
         STH   BR,TLNN                                                  78400013
         LR    RA,RB                                                    78800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOP997-TSS 79000000
         L     BR,VIOFA                                                 79200013
*        ----------------------------------------------------IOP997-TSS 79400000
         BALR  LR,BR                 $$WHIP UP A RECORD.                79600013
         LA    RF,1(RF)                 NOW UPDATE LINENUMBER.          80000013
         STH   RF,TLNN                                                  80400013
         BR    RE                    X  RETURN                          80800013
*  ILLEGAL USE OF PRINT CONTROLS ON NON-PRINT FILE                      81200013
         SPACE                                                          81600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOP996-TSS 81800000
IOPX0    L     BR,VERRC                                                 82000013
*        ----------------------------------------------------IOP996-TSS 82200000
         BALR  RA,BR                 $$ RAISE 'ERROR' CONDITION.        82400013
         DC    AL2(ERR0)                (NO RETURN)                     82800013
         SPACE                                                          82820016
*  END OF FILE FOR SKIP                                                 82840016
         SPACE                                                          82860016
IOPX1    LH    RA,HEOF                  ERROR CODE                      82880016
         IHEPRV ERR,RA,OP=STH                                           82900016
         L     RA,TDCL                                                  82920016
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOP995-TSS 82930000
         L     BR,VERRB                 ERROR PACKAGE                   82940016
*        ----------------------------------------------------IOP995-TSS 82950000
         BALR  LR,BR                 $$ INVOKED                         82960016
IOPX2    L     DR,OFDR(DR)              CHAIN BACK                      82980016
         TM    0(DR),X'80'               TO A DSA                       83000016
         BZ    IOPX2                                                    83020016
         LM    BR,PWR,OFBR(DR)          PICK UP REGS                    83040016
         IHEPRV CFL,LR,OP=LA            ABNORNAL RETURN TO MAKE         83060016
         L     LR,4(LR)                                                 83080016
         BR    LR                       RETURN TO CC                    83100016
         SPACE 3                                                        83200013
*  CONSTANTS                                                            83600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOP994-TSS 83800000
         SPACE                                                          84000013
VIOFA    DC    V(IHEIOFA)               RECORD ACCESSOR                 84400013
VERRB    DC    V(IHEERRB)               EXEP (ENDPAGE CONDITION)        84800013
VERRC    DC    V(IHEERRC)                                               85200013
*        ----------------------------------------------------IOP994-TSS 85400000
H001     DC    H'1'                                                     85600013
H002     DC    H'2'                                                     86000013
H003     DC    H'3'                                                     86400013
H004     DC    H'4'                                                     86600015
HEPG     DC    AL2(MEPG)                                                86800013
HEOF     DC    AL2(MEOF)                                                87000016
IOPSP    DC    C' 0-'                                                   87200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*IOP005-TSS 87300001
*        ----------------------------------------------------IOP005-TSS 87400001
         SPACE 3                                                        87600013
         END                                                            88000013
