ITM      TITLE '    IHEITM    BISAM INTERFACE'                          00100001
*   VERSION    FIFTH VERSION OF F-LEVEL PL/1 COMPILER.                  00200001
*                                                                       00210056
*C602800-606000                                               MA  49730 00220056
*A552000                                                      BPC 41977 00230021
*D579000,580000                                               BPC 41977 00240021
* R20 222000,*                                                    33906 00250020
* R20    603000,*    622000,*                                    A31198 00330020
* R20    THROUGHOUT THE MODULE                                   A33888 00340020
* R20    212000/215000/225000/244200                             A34396 00350020
* R20    520000,521000                                           A34401 00355020
* R 21 572000,574000                                          A43475    00357021
         SPACE 1                                                        00360020
*   FUNCTION   TO INTERFACE WITH DATA MANAGEMENT BISAM, FOR DIRECT      00400001
*               ACCESS TO VARIABLE LENGTH RECORDS ON INDEXED FILES      00500001
*               IN A NON-TASKING ENVIRONMENT.                           00600001
*                                                                       00700001
*              METHOD                                                   00800001
*                                                                       00900001
*              READ - INPUT MODE -                                      01000001
*                      GET IOCB,                                        01100001
*                      READ K,                                          01200001
*                      WAIT,                                            01300001
*                      IF DELETE BIT ON IN DCB (OPTCD=L) AND 5TH BYTE   01400001
*                       OF RECORD IS X'FF' RECORD TREATED AS NOT FOUND, 01500001
*                      FREE IOCB.                                       01600001
*                                                                       01700001
*                     UPDATE MODE -                                     01800001
*                      EXAMINES IOCB CHAIN CHECKING FOR OUTSTANDING     01900001
*                       READ KU'S,                                      02000001
*                      GET IOCB,                                        02100001
*                      READ KU,                                         02200001
*                      WAIT,                                            02300001
*                      IF DELETE BIT ON IN DCB (OPTCD=L) AND 5TH BYTE   02400001
*                       OF RECORD IS X'FF' RECORD TREATED AS NOT FOUND. 02500001
*                       CANCELS THE READ UPDATE WITH A WRITE K,         02600001
*                      FREE IOCB.                                       02700001
*                                                                       02800001
*             WRITE -                                                   02900001
*                      EXAMINES IOCB CHAIN CHECKING FOR OUTSTANDING     03000001
*                       READ KU'S,                                      03100001
*                      GET IOCB,                                        03200001
*                      WRITE KN,                                        03300001
*                      WAIT,                                            03400001
*                      FREE IOCB.                                       03500001
*                                                                       03600001
*           REWRITE -                                                   03700001
*                      EXAMINES IOCB CHAIN, LOOKS FOR FIRST IOCB GOT    03800001
*                       FOR READ UPDATE. IF KEY IN IOCB IS NOT EQUAL    03900001
*                       TO REWRITE KEY, THEN RAISES 'OUTSTANDING READ   04000001
*                       UPDATE EXISTS'. IF NO IOCB FOR READ UPDATE IS   04100001
*                       FOUND, THE RAISES 'REWRITE NOT PRECEDED BY      04200001
*                       READ'.                                          04300001
*                       ON EQUAL KEY -                                  04400001
*                      WRITE K,                                         04500001
*                      WAIT,                                            04600001
*                      FREE IOCB,                                       04700001
*                                                                       04800001
*            DELETE -                                                   04900001
*                      EXAMINES IOCB CHAIN CHECKING FOR NO OUTSTANDING  05000001
*                       READ KU'S,                                      05100001
*                      GET IOCB,                                        05200001
*                      READ KU,                                         05300001
*                      WAIT,                                            05400001
*                      IF DELETE BIT ON IN DCB (OPTCD=L) AND 5TH BYTE   05500001
*                       OF RECORD IS X'FF' RECORD TREATED AS NOT FOUND. 05600001
*                       CANCELS THE READ UPDATE WITH A WRITE K, FREE    05700001
*                       IOCB.                                           05800001
*                      WRITE K,                                         05900001
*                      FREE IOCB.                                       06000001
*                                                                       06100001
*                                                                       06200001
*                                                                       06300001
*                                                                       06400001
*              THIS MODULE EVOKES THE FOLLOWING MESSAGES -              06500001
*               IHE030I FILE *** - REWRITE NOT PRECEDED BY READ.        06600001
*               IHE031I FILE *** - INEXPLICABLE I/O ERROR.              06700001
*               IHE032I FILE *** - OUTSTANDING READ UPDATE EXISTS.      06800001
*               IHE111I FILE *** - RECORD VARIABLE SMALLER THAN RECORD. 06900001
*               IHE112I FILE *** - RECORD VARIABLE LARGER THAN RECORD.  07000001
*               IHE113I FILE *** - ATTEMT TO WRITE ZERO LENGTH RECORD.  07100001
*               IHE120I FILE *** - TRANSMISSION ERROR ON INPUT.         07200001
*               IHE121I FILE *** - TRANSMISSION ERROR ON OUTPUT.        07300001
*               IHE131I FILE *** - KEYED RECORD NOT FOUND.              07400001
*               IHE132I FILE *** - ATTEMPT TO ADD DUPLICATE KEY.        07500001
*               IHE135I FILE *** - KEY SPECIFICATION.                   07600001
*               IHE137I FILE *** - NO SPACE AVAILABLE TO ADD KEYED REC. 07700001
*                                                                       07800001
*   ENTRY POINTS                                                        07900001
*              IHEITM                                                   08000001
*                 RA = A(FCB)                                           08100001
*                 RB = A(PLIST)                                         08200001
*                 PLIST = A(DCLCB)                                      08300001
*                         A(RDV)                                        08400001
*                         A(EVENT VARIABLE)                             08500001
*                         A(KEY/KEYFROM/KEY SDV)                        08600001
*                         A(REQUEST CODES)                              08700001
*                                                                       08800001
*   INPUT                                                               08900001
*              FCB,DCLCB                                                09000001
*   OUTPUT                                                              09100001
*              FCB,DCLCB,IOCB                                           09200001
*                                                                       09300001
*   EXTERNAL MODULES                                                    09400001
*              LIBRARY                                                  09500001
*                   IHEERR                                              09600001
*                   IHESAF                                              09700001
*                   IHESAD                                              09800001
*              CONTROL SYSTEM                                           09900001
*                   READ                                                10000001
*                   WRITE                                               10100001
*                   CHECK                                               10200001
*                                                                       10300001
*   EXITS                                                               10400001
*              NORMAL                                                   10500001
*               RETURN TO CALLER VIA LINK REGISTER                      10600001
*              ERROR                                                    10700001
*               RAISE KEY/RECORD/TRANSMIT CONDITIONS                    10800001
*               RAISE ERROR CONDITION                                   10900001
*                                                                       11000001
*   TABLES/WORK AREA                                                    11100001
*              SEE OS 360 PL/1 LIBRARY PLM FOR DESCRIPTION OF           11200001
*              FCB,DCLCB,IOCB,FILE REGISTER                             11300001
*                                                                       11400001
*   PRIVATE MACROS                                                      11500001
*              IHELIB,IHEZAP                                            11600001
*                                                                       11700001
*   ASSEMBLY REQUIREMENTS                                               11800001
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   11900001
*              SUPPORT  E.G. OS 360 F-ASSEMBLER.                        12000001
*                                                                       12100001
*   NOTE       SEE OS 360 PL/1 LIBRARY PLM FOR DESCRIPTION OF           12200001
*              LIBRARY CONVENTIONS AND STANDARDS.                       12300001
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A      12400001
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL       12500001
*              CHARACTER SET.                                           12600001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM000-TSS 12630020
*        ----------------------------------------------------ITM000-TSS 12660020
         EJECT                                                          12700001
IHEITM   CSECT                                                          12800001
         IHELIB                                                         12900001
         EJECT                                                          13000001
         IHEZAP                                                         13100001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM001-TSS 13150020
         DCBD  DSORG=(IS)                                               13200001
*        ----------------------------------------------------ITM001-TSS 13250020
         EJECT                                                          13300001
IHEITM   CSECT                                                          13400001
         SPACE 2                                                        13500001
*  USINGS                                                               13600001
         USING IHEZIOB,RB               TO ADDRESS IOCB.                13700001
         USING IHEZADC,RC               TO ADDRESS ADCON LIST.          13800001
         USING IHEZAPE,RD               TO ADDRESS FCB.                 13900001
         USING IHEZEVT,RE               TO ADDRESS EVENT VARIABLE.      14000001
         USING IHEZREQ,RG               TO ADDRESS REQUEST CODES.       14100001
         USING IHEZLCA,LR               TO ADDRESS LCA.                 14200001
         USING IHADCB,BR                TO ADDRESS DCB.                 14300001
         SPACE 2                                                        14400001
*  ASSEMBLY PARAMETERS                                                  14500001
         SPACE                                                          14600001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM019-TSS 14650020
ISMO     EQU   16                       ISAM BUFFER OVERHEAD - LINK+BL  14700001
*        ----------------------------------------------------ITM019-TSS 14750020
BLKD     EQU   X'10'                                                    14800001
         SPACE 2                                                        14900001
*  LEVEL 1 WORKSPACE MAP                                                15000001
         SPACE                                                          15100001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM012-TSS 15150020
OPVB     EQU   OFPR+4                   RL SAVE AREA FOR V-FORMAT.      15200001
*        ----------------------------------------------------ITM012-TSS 15250020
OPSV     EQU   OPVB+4                   TEMP SAVE OF A(SDV)             15300001
OPLE     EQU   OPSV+4                                                   15400001
OPTL     EQU   OPLE+4                                                   15500001
         SPACE 2                                                        15600001
*  ERROR-CODES FOR EXEP                                                 15700001
         SPACE                                                          15800001
ERR1     EQU   X'A801'                  KEYED RECORD NOT FOUND.         15900001
ERR2     EQU   X'A802'                  ATTEMPT TO ADD DUPLICATE KEY.   16000001
ERR3     EQU   X'A807'                  NO SPACE AVL. TO ADD KEYED REC. 16100001
ERR4     EQU   X'9802'                  TRANSMIT (INPUT).               16200001
ERR5     EQU   X'9801'                  TRANSMIT (OUTPUT).              16300001
ERR6     EQU   X'A805'                  KEY SPECIFICATION.              16400001
ERR7     EQU   X'9002'                  RECORD VARY. GT LRECL.          16500001
ERR8     EQU   X'9001'                  RECORD VARY. LT LRECL.          16600001
ER10     EQU   X'000A'                  REWRITE NOT PRECEDED BY READ.   16700001
ER11     EQU   X'000B'                  INEXPLICABLE I/O ERROR.         16800001
ER12     EQU   X'000C'                  OUTSTANDING READ UPDATE EXISTS. 16900001
ER13     EQU   X'9003'                  ATTEMPT TO WRITE ZERO LEN. REC. 17000001
ER14     EQU   X'0003'       ERROR -    UNACCEPTABLE TRANSMIT.          17100001
         EJECT                                                          17200001
         ENTRY IHEITMA                                                  17300001
IHEITMA  EQU   *                                                        17400001
         SPACE                                                          17500001
         DC    AL2(ITM01-*)             ENTRY OFFSET                    17600001
         SPACE 2                                                        17700001
ITM01    EQU   *                                                        17800001
         L     RC,TADC-TBEG(RA)         ADDRESS ADCON LIST.             17900001
         LM    RE,RG,PEVT-PDCL(RB)      OBTAIN  PLIST POINTERS.         18000001
         BALR  WR,0                     ESTABLISH                       18100001
         USING *,WR                      ADDRESSIBILITY.                18200001
         SPACE                                                          18300001
         LR    RD,RA                    ADDRESS FCB.                    18400001
         CLI   OPER,OUNL             +  IS IT WAIT OR NOLOCK...         18500001
         BE    ITME9                 *  NOLOCK TREAT AS NO-OP.          18600001
         BH    ITM81                 *  WAIT ENTRY.                     18700001
         L     RH,PRDV-PDCL(RB)         LOAD RDV ADDRESS.               18800001
         L     BR,TDCB                  ADDRESS DCB.                    18900001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM028-TSS 18930020
*        ----------------------------------------------------ITM028-TSS 18960020
         TM    TFMD,TMUP             +  UPDATE FILE...                  19000001
         BZ    ITM21                 *  NO.                             19100001
         SPACE                                                          19200001
*                                       EXAMINE IOCB CHAIN FOR          19300001
*                                        OUTSTANDING READ UPDATES.      19400001
         SPACE                                                          19500001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM030-TSS 19550020
         L     RB,TLAB                  LOAD IOCB ANCHOR.               19600001
         L     RI,KEYA(RF)              LOAD A(PL/1 KEY SDV).           19700001
         SR    RJ,RJ                                                    19800001
         IC    RJ,DCBKEYLE              LOAD DCBKEYLE.                  19900001
         CH    RJ,KEYL(RF)              FIND MIN(DCBKEYLE,PL/1KEYLEN).  20000001
         BNH   ITM11                 *                                  20100001
         LH    RJ,KEYL(RF)              USE MINIMUM KEY LENGTH.         20200001
ITM11    EQU   *                                                        20300001
         LR    R0,RJ                    SAVE MINIMUM LENGTH AND         20400001
ITM12    EQU   *                                                        20500001
         BCTR  RJ,0                      REDUCE BY 1 FOR EX. QUIRK      20600001
         TM    BACT,X'FF'            +  IS IOCB IN USE...               20700001
         BZ    ITM15                 *  NO.                             20800001
         TM    BERR,BMDF             +  YES. USED FOR READ UPDATE...    20900001
         BZ    ITM15                 *  NO.                             21000001
         CLI   OPER,OREW             +  YES. CURRENT OP REWRITE...      21100001
         BNE   ITM14B                ** NO. REUSE CURRENT IOCB.  A34396 21200020
         L     LR,BKEY                  YES. LOAD ADDRESS KEY IN IOCB.  21300001
         EX    RJ,ITMS3              +  COMPARE IOCB KEY AND NEW KEY... 21400001
         BNE   ITMC1                 ** BAD. REWR NOT PREC BY RD A34396 21500020
         SPACE                                                          21600001
*                                       EQUAL TO LENGTH OF SHORTER KEY. 21700001
         IC    RJ,DCBKEYLE              LOAD LENGTH KEY IN IOCB.        21800001
         CR    RJ,R0                 +  IS IOCB KEY THE SHORTEST...     21900001
         BE    ITM14                 *  YES.                            22000001
         SR    RJ,R0                    NO. COMPUTE EXCESS LENGTH.      22100001
         ALR   LR,R0                   FIND START OF EXCESS       33906 22200020
ITM13    EQU   *                                                        22300001
         CLI   0(LR),C' '            +  IS EXCESS ALL BLANKS.           22400001
         BNE   ITMC1                 ** NO. REWR NOT PREC BY RD. A34396 22500020
         LA    LR,1(LR)                                                 22600001
         BCT   RJ,ITM13                 CHECK ALL EXCESS KEY.           22700001
ITM14    EQU   *                                                        22800001
         TM    BERR,BMCH             +  HAS READ BEEN WAITED ON...      22900001
         BZ    ITMC1                 ** NO. REWRITE NOT PREC BY READ.   23000001
         L     RI,RECA(RH)              YES. LOAD A(RECORD VARY).       23100001
         LH    RJ,RECL+2(RH)            LOAD L(RECORD VARY).            23200001
         ST    RI,BBF1                  SAVE A(RECORD VARY).            23300001
         STH   RJ,BBF2                  SAVE L(RECORD VARY).            23400001
         MVC   BREQ,0(RG)               COPY REQUEST CODES.             23500001
         MVI   BERR,0                /  CLEAR BERR IN IOCB.             23600001
         LR    RA,RH                    SAVE RDV ADDRESS         A33888 23650020
         SR    RH,RH                                                    23700001
         ST    RH,BERC               /  CLEAR ERROR CODE SLOT IN IOCB.  23800001
         ST    RE,BEVN                  SAVE A(EVENT VARIABLE).         23900001
         L     RH,BLOG                  LOAD A(RECORD LENGTH) IN BUFFER 24000001
         BAL   LR,ITM42              $  INITIALIZE EVENT VARIABLE.      24100001
         MVC   OPTL(2,DR),0(RH)                                         24200001
         LH    LR,OPTL(DR)              LOAD RL = RECORD LENGTH.        24300001
         SR    RI,RI                                             A33888 24310020
         CLC   DCBRKP,H004              RKP = 4?                 A33888 24320020
         BNE   ITM14A                   NO.                      A33888 24330020
         IC    RI,DCBKEYLE              YES. GET KEY LENGTH.     A33888 24340020
ITM14A   EQU   *                                                 A33888 24350020
         LA    RI,4(RI,RJ)              GET L(REC TO REWRITE)    A33888 24360020
         CR    RI,LR                    REWRITE SAME LENGTH ?    A33888 24370020
         BE    ITM621                   YES. DO A NORMAL REWRITE A33888 24380020
         MVI   BREQ,OWRT                NO. INDICATE A WRITE OP. A33888 24390020
         STH   RI,BLEN                  SET BLEN TO SHOW REWRITE.A33888 24400020
         LR    RH,RA                    RESTORE RDV ADDRESS      A33888 24410020
         B     ITM24A                   DO A PSEUDO WRITE.       A33888 24420020
         SPACE                                                          24430020
ITM14B   EQU   *                                                        24440020
         TM    BERR,BMCH             +  HAS RD BEEN WAITED ON.   A34396 24450020
         BZ    ITMC2                 ** NO. OUTSTANDING READ.    A34396 24460020
         B     ITM24                 ** YES. CONTINUE.           A34396 24470020
         SPACE                                                          24480020
ITM15    EQU   *                                                        24500001
         L     RB,BNIO                  LOAD CHAIN FOWARD.              24600001
         LR    RJ,R0                    RELOAD MIN(DCBKEYLE,PL/1KEYLEN) 24700001
         LTR   RB,RB                 +  IS THERE ANOTHER IOCB...        24800001
         BNZ   ITM12                 *  YES.                            24900001
         CLI   OPER,OREW             +  NO. IS CURRENT OP REWRITE...    25000001
         BE    ITMC1                 *  YES.REWRITE NOT PREC. BY READ.  25100001
*        ----------------------------------------------------ITM030-TSS 25150020
         SPACE 3                                                        25200001
*                                       GET IOCB AND INITIALIZE.        25300001
ITM21    EQU   *                                                        25400001
         L     RB,TLAB                  STEP OUT ALONG CHAIN.           25500001
ITM22    EQU   *                                                        25600001
         LTR   RB,RB                 +  IS THERE A CHAIN FOWARD...      25700001
         BZ    ITM23                 *  NO.                             25800001
         TS    BACT                  +  YES. IS IT FREE...              25900001
         BZ    ITM24                 *  YES. USE IT.                    26000001
         LR    RI,RB                    NO. SAVE CHAIN FOWARD ADDRESS.  26100001
         L     RB,BNIO                  LOAD NEW CHAIN FOWARD ADDRESS.  26200001
         B     ITM22                 *  CHECK NEW IOCB.                 26300001
         SPACE 2                                                        26400001
ITM23    EQU   *                        GENERATE  NEW IOCB.             26500001
         L     R0,TBBZ                  OBTAIN IOCB SIZE.               26600001
         GETMAIN R,LV=(0)            $$ SET SPACE FOR NEW IOCB.         26700001
         LR    RB,RA                    SAVE ADDRESS NEW IOCB.          26800001
         ST    RB,BNIO-BBEG(RI)         SET CHAIN FOWARD FROM OLD IOCB. 26900001
         MVI   BACT,X'FF'            /  SET NOT-FREE FLAG.              27000001
         SR    RI,RI                    CLEAR CHAIN FOWARD IN NEW IOCB. 27100001
         ST    RI,BNIO                   IE. LAST IN CHAIN.             27200001
         SPACE                                                          27300001
*                                       INITIALIZE IOCB.                27400001
ITM24    EQU   *                                                        27500001
         XC    BLEN,BLEN                ZERO BLEN TO SHOW WRITE. A33888 27520020
         L     RI,0(RG)                                          A33888 27540020
         ST    RI,BREQ               /  SET REQ CODE IN IOCB.    A33888 27560020
ITM24A   EQU   *                                                 A33888 27580020
         ST    RD,BFCB               /  SET A(FCB).                     27600001
         SR    RI,RI                                                    27900001
         ST    RI,BERC               /  CLEAR EXCEP. CODES.             28000001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM015-TSS 28050020
         ST    RI,BEXI               /                                  28100001
*        ----------------------------------------------------ITM015-TSS 28150020
         ST    RE,BEVN               /  SET A(EVENT VARY) OR ZERO.      28200001
         ST    RH,BRVS               /  SAVE A(RECORD VARY SDV).        28300001
         MVC   BBF1+1(3),RECA+1(RH)  /  SAVE A(RECORD VARY).            28400001
         TM    BREQ+OATR-REQ1,OINT   +  IS INTO STRING VARYING...       28500001
         BZ    ITM25                 *  NO.  USE L(REC VAR) AS IS.      28600001
         MVC   BBF2,4(RH)            /  YES. SET L(REC VAR) FIELD=MAX L 28700001
         B     ITM26                                                    28800001
ITM25    EQU   *                                                        28900001
         MVC   BBF2,RECL+2(RH)       /  SET L(RECORD VARY).             29000001
ITM26    EQU   *                                                        29100001
         STH   RI,BTYP               /  CLEAR TYPE FIELD.               29200001
         L     BR,TDCB                                                  29300001
         ST    BR,BDCB               /  SET A(DCB).                     29400001
         LA    RI,BBBF                                                  29500001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM016-TSS 29530020
*        ----------------------------------------------------ITM016-TSS 29560020
         ST    RI,BKEY               /  SET A(KEY IN BUFFER).           29600001
         SPACE 2                                                        29700001
*                                       MOVE KEY INTO IOCB.             29800001
         LR    RH,RI                    A(WHERE TO PUT KEY).            29900001
         L     RI,KEYA(RF)              LOAD PL/1 KEY ADDRESS.          30000001
         LH    RJ,KEYL(RF)              LOAD PL/1 KEY LENGTH (L).       30100001
         SR    RF,RF                                                    30200001
         IC    RF,DCBKEYLE              LOAD HARDWARE KEY LENGTH (K).   30300001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM017-TSS 30350020
         LA    R0,BBBF(RF)              FIND START OF LINK FIELD.       30400001
         TM    DCBKEYLE,1            +  IS KEYLENGTH ODD (BISAM BUG)    30500001
         BZ    ITM29                 *  NO                              30600001
         AH    R0,H001                  YES. ROUND UP TO HALFWORD       30700001
*        ----------------------------------------------------ITM017-TSS 30750020
ITM29    EQU   *                                                        30800001
         ST    R0,BARE               /  SET A(LINK IN BUFFER).          30900001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM018-TSS 30950020
         ST    R0,BLOG                  SET DEFAULT ADDR FOR NOT READ   31000001
*        ----------------------------------------------------ITM018-TSS 31050020
         CR    RJ,RF                 +  COMPARE L WITH K...             31100001
         BNL   ITM31                 *  L GE K.                         31200001
         MVI   0(RH),C' '               L LT K. SET KEY AREA OF IOCB    31300001
         BCTR  RF,0                      BUFFER TO BLANKS.              31400001
         BCTR  RF,0                                                     31500001
         EX    RF,ITMS2                                                 31600001
         LTR   RJ,RJ                 +  IS L ZERO LENGTH...             31700001
         BZ    ITM33                 *  YES. KEY SPECIFICATION ERROR.   31800001
         BCTR  RJ,0                     NO.                             31900001
         EX    RJ,ITMS1              /  MOVE L BYTES OF KEYSTRING.      32000001
         B     ITM32                                                    32100001
ITM31    EQU   *                                                        32200001
         BCTR  RF,0                     L GE K.                         32300001
         EX    RF,ITMS1              /  MOVE K BYTES OF KEYSTRING       32400001
         SPACE 2                                                        32500001
ITM32    EQU   *                        CHECK EMBEDDED KEY=SOURCE KEY.  32600001
         CLI   BREQ,OWRT             +  BUT ONLY FOR             A33888 32700020
         BL    ITM41                 *   WRITE OR                       32800001
         CLI   BREQ,OREW             +  REWRITE                  A33888 32900020
         BH    ITM41                 *   AND RKP                        33000001
         CLC   DCBRKP,H004           +   GREATER THAN 4.                33100001
         BNH   ITM41                 *                                  33200001
         SR    RJ,RJ                                                    33300001
         IC    RJ,DCBKEYLE              LOAD KEYLEN.                    33400001
         LH    RI,BBF2                  LOAD L(RECORD VARY).            33500001
         SR    RI,RJ                                                    33600001
         SH    RI,DCBRKP                CHECH THAT RECORD VARY IS       33700001
         AH    RI,H004                   LARGE ENOUGH TO HOLD KEY...    33800001
         LTR   RI,RI                 +                                  33900001
         BM    ITM33                 *  NO. KEY SPECN ERROR.            34000001
         L     RI,BBF1                  LOAD A(RECORD VARY),            34100001
         AH    RI,DCBRKP                ADD RKP TO FIND EMBEDDED KEY.   34200001
         SH    RI,H004                  ALLOW FOR RKP RELATIVE TO LRECL 34300001
         L     LR,BKEY                  LOAD A(KEY IN BUFFER).          34400001
         BCTR  RJ,0                                                     34500001
         EX    RJ,ITMS3              +  COMP KEY/KEYFROM + EMBEDDED KEY 34600001
         BE    ITM41                 *  EQUAL.                          34700001
ITM33    EQU   *                        NOT EQUAL.                      34800001
         MVC   BKYC,ERRF             /  KEY SPECIFICATION ERROR.        34900001
         OI    BERR,BMCH+BMER        /  IND ERROR AND NO TRANSMISSION.  35000001
         SPACE 2                                                        35100001
ITM41    EQU   *                        CHECK FOR EVENT OPTION.         35200001
         LA    LR,ITM43                 SET BRANCH REG FOR END SUBRTN.  35300001
ITM42    EQU   *                                                        35400001
         LTR   RE,RE                 +  EVENT OPTION...                 35500001
         BZ    0(LR)                 *  NO. SKIP EVENT VARIABLE         35600001
         SPACE                                                          35700001
*                                       YES. INITIALIZE EVENT VARIABLE. 35800001
         LA    RA,BECB                                                  35900001
         ST    RA,EVEC               /  SET A(DECB).                    36000001
         MVI   EFL1,EMAC+EMIO        /  SET FLAG1 TO ACTIVE.            36100001
         MVI   EFL2,0                /  SET FLAG2 TO INCOMPLETE.        36200001
         ST    PR,EVPR               /  SET A(PRV).                     36300001
         SR    RA,RA                                                    36400001
         STH   RA,EVST               /  SET STATUS TO NORMAL.           36500001
         BR    LR                    X  RETURN.                         36600001
ITM43    EQU   *                                                        36700001
         TM    BERR,BMCH             +  TRANSMISSION TO BE ATTEMPTED... 36800001
         BZ    ITM44                 *  YES.                            36900001
         LTR   RE,RE                 +  NO. EVENT OPTION...             37000001
         BZ    ITM91                 *  NO. SKIP TRANSMISSION.          37100001
         OI    EFL1,EMNW             /  YES. SET FLAG1 TO NO-WAIT.      37200001
         B     ITM91                 *  SKIP TRANSMISSION.              37300001
         SPACE 2                                                        37400001
ITM44    EQU   *                        ANALYSE OPERATION.              37500001
         SR    RI,RI                                                    37600001
         IC    RI,BREQ                  LOAD OPERATION CODE.     A33888 37700020
         LA    RA,BECB                  LOAD A(DECB).                   37800001
         NI    BERR,255-BMDF         /  CLEAR READ-UPDATE SWITCH.       37900001
         B     ITM45(RI)             *  BRANCH ON OPERATION CODE.       38000001
ITM45    EQU   *                                                        38100001
         B     ITM51                 *  READ.                           38200001
         B     ITM61                 *  WRITE.                          38300001
         B     ITM61                 *  REWRITE.                        38400001
         B     ITM71                 *  DELETE.                         38500001
         EJECT                                                          38600001
ITM51    EQU   *             READ                                       38700001
         SPACE                                                          38800001
         TM    TFMD,TMUP             +  UPDATE MODE...                  38900001
         BZ    ITM52                 *  NO.                             39000001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM010-TSS 39050020
         READ  (1),KU,,,'S',MF=E     $$ YES. READ FOR UPDATE.           39100001
         OI    BERR,BMDF             /  DO NOT FREE IOCB.               39200001
*        ----------------------------------------------------ITM010-TSS 39250020
         B     ITM91                 *  GO TO CHECKOUT ROUTINE.         39300001
ITM52    EQU   *                                                        39400001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM011-TSS 39450020
         READ  (1),K,,,'S',MF=E      $$ READ A RECORD.                  39500001
*        ----------------------------------------------------ITM011-TSS 39550020
         B     ITM91                 *  GO TO CHECKOUT ROUTINE.         39600001
         SPACE 3                                                        39700001
ITM61    EQU   *           WRITE/REWRITE                                39800001
         SPACE                                                          39900001
         L     RH,BARE                  LOAD ADDRESS LINK FIELD.        40000001
         LA    RH,ISMO(RH)              GET ADDRESS RL FIELD.           40100001
         LH    RJ,BBF2                  LOAD L(RECORD VARY).            40300001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM024-TSS 40350020
         TM    DCBRECFM,BLKD         +  BLOCKED...                      40400001
         BO    ITM62                 *  YES. USE LRECL-4.               40500001
         LH    LR,DCBBLKSI              NO. USE BLOCKSIZE-8.            40600001
         SH    LR,H008                                                  40700001
         B     ITM63                 *                                  40800001
*        ----------------------------------------------------ITM024-TSS 40850020
ITM62    EQU   *                                                        40900001
         LH    LR,DCBLRECL              LOAD MAX RECORD LENGTH.         41000001
ITM621   EQU   *                                                        41100001
         SH    LR,H004                  REDUCE BY 4 FOR RL.             41200001
ITM63    EQU   *                                                        41300001
         L     RI,BBF1                  LOAD A(RECORD VARY)      A33888 41350020
         LTR   RJ,RJ                 +  ZERO LENGTH RECORD...           41400001
         BP    ITM64                 *  NO.                             41500001
         OI    BERR,BMCH+BMER        /  YES. IND ERROR AND NO TRANSMIT. 41600001
         LTR   RE,RE                 +  EVENT OPTION ...                41700001
         BZ    ITM631                *  NO.                             41800001
         OI    EFL1,EMNW             /  SET NO-WAIT FLAG IN EVENT VARY. 41900001
ITM631   EQU   *                                                        42000001
         MVC   BRCC,ERRM             /  ATTEMPT TO WRITE ZERO LEN REC.  42100001
         B     ITM91                 *                                  42200001
         SPACE                                                          42300001
ITM64    EQU   *                        CHECK L(REC VARY) LE MAXIMUM.   42400001
         SR    RA,RA                                                    42500001
         STH   RA,OPVB+2(DR)         /  CLEAR RL SAVE AREA.             42600001
         CLC   DCBRKP,H004           +  RKP=4...                        42700001
         BNE   ITM65                 X  NO.                             42800001
         IC    RA,DCBKEYLE              YES. REC VARY NOT INCLUDE KEY.  42900001
         SR    LR,RA                    SUBTR KEYLEN FROM MAX REC LEN.  43000001
ITM65    EQU   *                                                        43100001
         CR    RJ,LR                 +  COMPARE L(REC VARY) WITH MAX... 43200001
         BNH   ITM66                 *  L(REC VARY) LE MAX.             43300001
         OI    BERR,BMER             /  L(REC VARY) GET MAX.            43400001
         MVC   BRCC,ERRG             /  SAVE ERROR CODE.                43500001
         LR    RJ,LR                    MOVE ONLY MAX BYTES RECORD.     43600001
ITM66    EQU   *                        CHECK L(REC VARY) GE KEY+DATA.  43700001
         LA    RJ,4(RA,RJ)              CALCULATE RL                    43800001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM020-TSS 43850020
         STH   RJ,OPVB(DR)           /  SAVE RL.                        43900001
         CLI   BREQ,OWRT             +  IS THIS A WRITE OP...    A33888 44000020
         BNE   ITM69                 *  NO. REWRITE DOES NOT UPDATE RL. 44100001
*        ----------------------------------------------------ITM020-TSS 44150020
         MVC   0(4,RH),OPVB(DR)      /  YES. SET UP RL IN BUFFER        44200001
         SPACE                                                          44300001
ITM69    EQU   *                        INSERT KEY IF RKP=4.            44400001
         AH    RH,H004                  JUMP RH OVER RL IN BUFFER.      44500001
         CLC   DCBRKP,H004           +  RKP=4...                        44600001
         BNE   ITM67                 *  NO.                             44700001
         L     RI,BKEY                  YES. LOAD A(KEY IN IOCB).       44800001
         BCTR  RA,0                                                     44900001
         EX    RA,ITMS1              /  MOVE KEY IN BEFORE RECORD.      45000001
         LA    RH,1(RA,RH)              JUMP RH OVER KEY IN BUFFER.     45100001
         L     RI,BBF1                  RESTORE A(REC VARY) IN RH.      45200001
         LA    RA,1(RA)                 RESTORE L(KEY)                  45300001
         SPACE                                                          45400001
ITM67    EQU   *                        MOVE RECORD TO BUFFER.          45500001
         SR    RJ,RA                                                    45600001
         SH    RJ,H004                  RESTORE L(REC VARY) IN RJ.      45700001
         BAL   LR,ITMF1              $  MOVE REC VARY TO BUFFER SUBR.   45800001
         LA    RA,BECB                  SET A(DECB) WITHIN IOCB.        45900001
         CLI   BREQ,OWRT             +  WRITE OR REWRITE OP..    A33888 46000020
         BNE   ITM68                 *  REWRITE.                        46100001
         SPACE                                                          46200001
*                                       ADD A RECORD.                   46400001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM002-TSS 46450020
         WRITE (1),KN,,,'S',MF=E     $$                                 46500001
*        ----------------------------------------------------ITM002-TSS 46550020
         B     ITM91                 *  GO TO CHECKOUT ROUTINE.         46600001
         SPACE                                                          46700001
ITM68    EQU   *                        REPLACE A RECORD.               46800001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM003-TSS 46850020
         WRITE (1),K,,,'S',MF=E      $$                                 46900001
*        ----------------------------------------------------ITM003-TSS 46950020
         B     ITM91                 *  GO TO CHECKOUT ROUTINE.         47000001
         EJECT                                                          47100001
ITM71    EQU   *             DELETE                                     47200001
         SPACE                                                          47300001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM004-TSS 47350020
         READ  (1),KU,,,'S',MF=E     $$ READ A RECORD FOR UPDATE.       47400001
*        ----------------------------------------------------ITM004-TSS 47450020
         LA    RA,BECB                                                  47500001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM005-TSS 47550020
         WAIT  1,ECB=(1)             $$ WAIT FOR IT.                    47600001
         TM    BEXI,X'FD'            +  ANY ERRORS...                   47700001
         BZ    ITM72                 *  NO.                             47800001
         BAL   RH,ITMB1              $  ANALYSE ERRORS.                 47900001
         B     ITMD1                 ** RAISE THEM.                     48000001
*        ----------------------------------------------------ITM005-TSS 48050020
ITM72    EQU   *                                                        48100001
         L     BR,TDCB                  ADDRESS DCB.                    48200001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM006-TSS 48250020
         TM    DCBOPTCD,X'02'        +  OPTCD=L...                      48300001
         BZ    ITM73                 *  NO.                             48400001
         L     LR,BLOG                  YES. LOAD ADDRESS RL.           48500001
         CLI   4(LR),X'FF'           +  IS FIRST BYTE RECORD FF...      48600001
         BE    ITM95                 *  YES. RECORD ALREADY DELETED.    48700001
ITM73    EQU   *                                                        48800001
         L     RA,BLOG                                                  48900001
         MVI   4(RA),X'FF'           /  SET DELETE CODE IN RECORD.      49000001
         LA    RA,BECB                  SET A(DECB) WITHIN IOCB.        49100001
         WRITE (1),K,,,'S',MF=E      $$ REWRITE RECORE  IE DELETE IT.   49200001
*        ----------------------------------------------------ITM006-TSS 49250020
         B     ITM91                 *  GO TO CHECKOUT ROUTINE.         49300001
         SPACE 3                                                        49400001
ITM81    EQU   *             WAIT                                       49500001
         SPACE                                                          49600001
         L     RB,PIOB-PDCL(RB)         ADDRESS IOCB.                   49700001
         B     ITM92                                                    49800001
         EJECT                                                          49900001
         SPACE                                                          50000001
*                                       CHECKOUT ROUTINE                50100001
*                                       AFTER BISAM HAS BEEN CALLED     50200001
ITM91    EQU   *                                                        50300001
         LTR   RE,RE                 +  EVENT OPTION...                 50400001
         BNZ   ITME9                 *  YES. RETURN                     50500001
ITM92    EQU   *                                                        50600001
         TM    BERR,BMCH             +  NO. WAS THERE A TRANSMISSION... 50700001
         BO    ITMD1                 *  NO.                             50800001
         SPACE                                                          50900001
*                                       AWAIT COMPLETION OF OPERATION.  51000001
         SPACE                                                          51100001
         LA    RA,BECB                  YES. ADDRESS DECB.              51200001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM007-TSS 51250020
         WAIT  1,ECB=(1)             $$ AWAIT COMPLETION.               51300001
         L     BR,TDCB                  READDRESS DCB.                  51400001
         TM    BEXI,X'FD'            +  ANY ERRORS...                   51500001
         BZ    ITM93                 *  NO.                             51600001
         BAL   RH,ITMB1              $  YES. ANALYSE ERRORS.            51700001
         SPACE                                                          51800001
         CLI   BREQ,ORED             +  WAS IT A READ OP.               51900001
         BNE   ITMD1                 *  NO. RAISE ERROR.         A34401 51980020
         B     ITMA2                 *  YES. CHK FOR RECORD COND A34401 52060020
*        ----------------------------------------------------ITM007-TSS 52150020
ITM93    EQU   *                                                        52200001
         CLI   BREQ,ORED             +  WAS IT A READ OP...             52300001
         BNE   ITMD1                 *  NO. GOOD WRITE/REWRITE/DELETE.  52400001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM026-TSS 52450020
         TM    DCBOPTCD,X'02'        +  YES. READ DELETED RECORD...     52500001
         BZ    ITMA2                 *  NO.                             52600001
         L     RI,BLOG                  YES. LOAD ADDRESS RL.           52700001
         CLI   4(RI),X'FF'           +  IS FIRST BYTE RECORD FF...      52800001
         BNE   ITMA2                 *  NO.                             52900001
         SPACE                                                          53000001
*                                       REWRITE DELETED RECORD.         53100001
ITM95    EQU   *                                                        53200001
         NI    BERR,255-BMDF         /  YES. CLEAR SWITCH.              53300001
         TM    TFMD,TMUP             +  UPDATE MODE...                  53400001
         BZ    ITMA1                 *  NO. IND RECORD NOT FOUND.       53500001
         LA    RA,BECB                  YES. REWRITE RECORD TO REMOVE   53600001
         WRITE (1),K,,,'S',MF=E      $$  OUTSTANDING READ UPDATE.       53700001
         LA    RA,BECB                                                  53800001
         WAIT  1,ECB=(1)             $$ WAIT FOR COMPLETION.            53900001
         L     BR,TDCB                  READDRESS DCB.                  54000001
         TM    BEXI,X'FD'            +  ANY ERRORS...                   54100001
         BZ    ITMA1                 *  NO.                             54200001
         BAL   RH,ITMB1              $  YES. ANALYSE ERROR.             54300001
ITMA1    EQU   *                                                        54400001
         OI    BERR,BMER             /  INDICATE ERROR.                 54500001
         MVC   BKYC,ERRA             /  RECORD NOT FOUND CONDITION.     54600001
         B     ITMD1                 **                                 54700001
*        ----------------------------------------------------ITM026-TSS 54750020
         SPACE                                                          54800001
*                                       CHECK FOR RECORD CONDITION AND  54900001
*                                        MOVE RECORD FROM BUFFER.       55000001
         SPACE                                                          55100001
ITMA2    EQU   *                                                        55200001
         LTR   LR,LR                   RECORD NOT FOUND?          41977 55220021
         BZ    ITMD1                   YES.DO NOT TEST FOR RECORD 41977 55240021
*                                      CONDITITON OR MOVE RECORD  41977 55260021
         L     RH,BBF1                  LOAD A(RECORD VARY).            55300001
         LH    RJ,BBF2                  LOAD L(RECORD VARY).            55400001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM021-TSS 55450020
         L     RI,BLOG                  LOAD ADDRESS RL IN BUFFER       55500001
         MVC   OPLE(2,DR),0(RI)                                         55600001
         LH    RI,OPLE(DR)              GET RL                          55700001
*        ----------------------------------------------------ITM021-TSS 55750020
         SH    RI,H004                  CALCULATE LENGTH OF RECORD.     55800001
         SR    R0,R0                                                    55900001
         CLC   DCBRKP,H004           +  RKP=4...                        56000001
         BNE   ITMA3                 *  NO. RECORD INCLUDES KEY.        56100001
         IC    R0,DCBKEYLE              YES. KEY OUTSIDE RECORD.        56200001
         SR    RI,R0                    SUBTRACT KEYLEN FROM REC LEN.   56300001
ITMA3    EQU   *                                                        56400001
         CR    RJ,RI                 +  COMP L(REC VARY) WITH REC LEN.. 56500001
         BE    ITMA6                 *  EQUAL.                          56600001
         BH    ITMA4                 *  L(REC VARY) GT REC LEN.         56700001
         MVC   BRCC,ERRH             /  L(REC VARY) LT REC LEN. ERROR   56800001
         B     ITMA5                 *  SET ERROR CONDITION.            56900001
ITMA4    EQU   *                                                        57000001
         LR    RJ,RI                    MOVE ONLY REC LEN BYTES.        57100001
         B     ITMA6                   CONTINUE                  43475  57300021
ITMA5    EQU   *                                                        57500001
         OI    BERR,BMER             /  SET I/O CONDITION TO RAISE.     57600001
         SPACE                                                          57700001
ITMA6    EQU   *                                                        57800001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM033-TSS 57850020
*        ----------------------------------------------------ITM033-TSS 57920020
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM022-TSS 58050020
         L     RI,BLOG                  NO. LOAD ADDRESS RL IN BUFFER.  58100001
*        ----------------------------------------------------ITM022-TSS 58150020
         LA    RI,4(R0,RI)              LOAD A(FIRST BYTE RECORD).      58200001
         CLC   DCBRKP,H004           +  RKP = 4 ...                     58300001
         BNE   ITMA8                 *  NO.                             58400001
         AR    RI,R0                    SKIP KEY IF RKP = 4 .           58500001
ITMA8    EQU   *                                                        58600001
         TM    BREQ+OATR-REQ1,OINT   +  IS INTO STRING VARYING.         58700001
         BZ    ITMA7                 *  NO.                             58800001
         L     RA,BRVS                  YES. LOAD A(INTO SDV).          58900001
         STH   RJ,6(RA)              /  SET CURRENT LENGTH IN SDV.      59000001
ITMA7    EQU   *                                                        59100001
         BAL   LR,ITMF1              $  MOVE RECORD TO REC VARY.        59200001
         OI    BERR,BMCH             /  INDICATE READ WAITED ON.        59300001
         B     ITMD1                 *                                  59400001
         EJECT                                                          59500001
         SPACE                                                          59600001
*                                       SUBROUTINE TO ANALYSE ERROR     59700001
*                                       CODES GIVEN BY BISAM.           59800001
*                                       RH HOLDS RETURN ADDRESS.        59900001
         SPACE                                                          60000001
ITMB1    EQU   *                                                        60100001
         OI    BERR,BMER             /  SET I/O CONDITION TO RAISE.     60200001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM027-TSS 60250020
         TM    BEXI,X'84'              IS IT UNREACHABLE BLOCK    49730 60290056
*                                      OR  RECORD NOT FOUND ?     49730 60330056
         BZ    ITMB2                   NO CARRY ON                49730 60370056
         SR    LR,LR                   IND NO RECORD BE MOVED TO  49730 60410056
*                                      RECEIVER                   49730 60450056
         NI    BERR,255-BMDF           CLEAR RECORD FOR UPDATE    49730 60490056
*                                      SWITCH                     49730 60530056
         TM    BEXI,X'04'              IS IT UNREACHABLE BLOCK    49730 60570056
         BO    ITERX                   YES,TREAT AS TRANSMIT      49730 60610056
*                                      NO, RECORD NOT FOUND       49730 60650056
         MVC   BKYC,ERRA             /  SET RECORD NOT FOUND.           60700001
         BR    RH                    X  RETURN.                         60800001
ITMB2    EQU   *                                                        60900001
         TM    BEXI,X'01'            +  DUPLICATE RECORD...             61000001
         BZ    ITMB3                 *  NO.                             61100001
         MVC   BKYC,ERRB             /  YES. SET DUPLICATE RECORD       61200001
         BR    RH                    X  RETURN.                         61300001
ITMB3    EQU   *                                                        61400001
         TM    BEXI,X'20'            +  SPACE NOT AVAILABLE...          61500001
         BZ    ITMB4                 *  NO.                             61600001
         MVC   BKYC,ERRC             /  YES. SET SPACE NOT AVAILABLE.   61700001
         BR    RH                    X  RETURN.                         61800001
ITMB4    EQU   *                                                        61900001
         TM    BEXI,X'08'            +  UNCORRECTABLE I/O ERROR...      62000001
         BZ    ITMB6                 *  NO.                             62100001
ITERX    CLI   BREQ,ORED             + TRANSMIT, BUT IN OR OUT   A31198 62200020
         BNE   ITMB5                 *  OUTPUT.                         62300001
         MVC   BXTC,ERRD             /  INPUT. SET INPUT TRANSMIT ERROR 62400001
         BR    RH                    X  RETURN.                         62500001
ITMB5    EQU   *                                                        62600001
         MVC   BXTC,ERRE             /  SET OUTPUT TRANSMIT ERROR.      62700001
         BR    RH                    X  RETURN.                         62800001
*        ----------------------------------------------------ITM027-TSS 62850020
ITMB6    EQU   *                                                        62900001
         LTR   RE,RE                 +  EVENT OPTION...                 63000001
         BZ    ITMB7                 *  NO.                             63100001
         NC    EVST,EVST             +  YES. IS STATUS ABNORMAL...      63200001
         BNZ   ITMB7                 *  YES.                            63300001
         MVC   EVST,H001             /  NO. SET STATUS ABNORMAL.        63400001
ITMB7    EQU   *                                                        63500001
         BAL   RF,ITMD2              $  SET UP LCA SLOTS.               63600001
         L     BR,IERRC                 LOAD ADDRESS ERROR-C ROUTINE.   63700001
         BALR  RA,BR                 $$ RAISE ERROR.                    63800001
         DC    AL2(ER11)                INEXPLICABLE I/O ERROR.         63900001
         EJECT                                                          64000001
         SPACE                                                          64100001
*                                       ROUTINE TO RAISE ERROR          64200001
*                                       CONDITION FOR ERRORS DETECTED   64300001
*                                       BEFORE BISAM WAS INVOKED.       64400001
         SPACE                                                          64500001
ITMC1    EQU   *                                                        64600001
         LA    RA,ERRJ                  REWRITE NOT PRECEEDED BY READ.  64700001
         B     ITMC3                 *                                  64800001
ITMC2    EQU   *                                                        64900001
         LA    RA,ERRL                  OUTSTANDING READ UPDATE.        65000001
ITMC3    EQU   *                                                        65100001
         BAL   RG,ITMD3              $  SET UP SOME LCA SLOTS.          65200001
         L     BR,PKEY-PDCL(BR)         LOAD A(KEY SDV) FROM PLIST.     65300001
         MVC   WOFD(8),0(BR)         /  SET KEY SDV IN WOFD FOR ONKEY.  65400001
         L     BR,IERRC                 LOAD ADDRESS ERROR-C ROUTINE.   65500001
         BR    BR                    $$ RAISE ERROR.                    65600001
         EJECT                                                          65700001
         SPACE                                                          65800001
*                                       RAISE ERROR CONDITIONS IF       65900001
*                                       NECESSARY AND RETURN.           66000001
         SPACE                                                          66100001
ITMD1    EQU   *                                                        66200001
         TM    BERR,BMER             +  ANY ERRORS...                   66300001
         BZ    ITME7                 *  NO.                             66400001
         LA    RF,ITME0                 YES. SET EXIT ADDR FROM SUBR.   66500001
         SPACE                                                          66600001
*                                       SET UP LCA SLOTS FOR ONKEY.     66700001
ITMD2    EQU   *                                                        66800001
         L     BR,TDCB                  LOAD DCB BASE REGISTER.         66900001
         SR    RJ,RJ                                                    67000001
         IC    RJ,DCBKEYLE              GET KEYLENGTH.                  67100001
         LA    R0,8(RJ)                 ROUND IT OFF.                   67200001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM029-TSS 67250020
         L     BR,ISADF                 LOAD ADDRESS VDA ROUTINE.       67300001
*        ----------------------------------------------------ITM029-TSS 67350020
         BALR  LR,BR                 $$ GET VDA FOR KEY.                67400001
         LA    RG,ITMD5                 SET EXIT FOR WFIL ROUTINE.      67500001
ITMD3    EQU   *                                                        67600001
         LH    LR,IQLCA                                                 67700001
         L     LR,0(PR,LR)              SET LIB COMM AREA BASE REG.     67800001
         USING IHEZLCA,LR                                               67900001
         MVC   WFIL(4),TDCL          /  MOVE A(DCLCB) TO WFIL.          68000001
         BR    RG                    X  RETURN                          68100001
ITMD5    EQU   *                                                        68200001
         ST    RE,WEVT               /  MOVE A(EVENT VARY) TO WEVT.     68300001
         LA    RH,8(RA)                                                 68400001
         ST    RH,WOFD               /  CREATE KEY SDV IN WOFD          68500001
         STH   RJ,WOFD+4             /   POINTING AT KEY VDA.           68600001
         STH   RJ,WOFD+6             /                                  68700001
         LA    RI,BBBF                  ADDRESS KEY IN IOCB.            68800001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM023-TSS 68830020
*        ----------------------------------------------------ITM023-TSS 68860020
         BCTR  RJ,0                                                     68900001
         EX    RJ,ITMS1              /  MOVE KEY TO VDA.                69000001
         BR    RF                    X  RETURN.                         69100001
         SPACE                                                          69200001
*                                       RAISE ON CONDITIONS.            69300001
ITME0    EQU   *                                                        69400001
         LTR   RE,RE                 +  EVEN OPTION...                  69500001
         BZ    ITME1                 *  NO.                             69600001
         NC    EVST,EVST             +  YES. EVENT STATUS NORMAL...     69700001
         BNZ   ITME1                 *  NO.                             69800001
         MVC   EVST,H001             /  YES. SET IT ABNORMAL.           69900001
ITME1    EQU   *                                                        70000001
         LH    RG,IQERR                 LOAD PRV ERROR SLOT OFFSET.     70100001
         LH    RH,BERC                  LOAD ERROR CODE IN IOCB.        70200001
         LH    RI,BRCC                  LOAD REC-ERROR CODE IN IOCB.    70300001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM031-TSS 70350020
         TM    BERR,BMDF             +  READ FOR UPDATE.                70400001
         BO    ITME2                 *  YES.                            70500001
*        ----------------------------------------------------ITM031-TSS 70550020
         MVI   BACT,0                /  NO. FREE IOCB.                  70600001
ITME2    EQU   *                                                        70700001
         LTR   RH,RH                 +  TRANSMIT/KEY CONDITION...       70800001
         BNZ   ITME3                 *  YES.                            70900001
         LA    RF,ITME6              /  NO. IND LAST COND TO BE RAISED. 71000001
         B     ITME4                 *                                  71100001
ITME3    EQU   *                                                        71200001
         BAL   RF,ITME5                                                 71300001
ITME4    EQU   *                                                        71400001
         LTR   RH,RI                 +  ANOTHER CONDITION TO RAISE...   71500001
         BZ    ITME6                 *  NO.                             71600001
ITME5    EQU   *                                                        71700001
         STH   RH,0(RG,PR)           /  YES. STORE ERROR CODE IN PRV.   71800001
         L     RA,TDCL                  LOAD A(DCLCB).                  71900001
         L     BR,IERRB                 LOAD ADDRESS ERROR-B ROUTINE    72000001
         BALR  LR,BR                 $$ RAISE ERROR.                    72100001
         BALR  RF,RF                 +  LOOP IF ANOTHER CONDITION.      72200001
         SPACE                                                          72300001
*                                       CLEAR LCA SLOTS.                72400001
ITME6    EQU   *                                                        72500001
         L     BR,ISAFD                 LOAD ADDRESS FREE VDA ROUTINE.  72600001
         BALR  LR,BR                 $$ FREE VDA GOT FOR KEY.           72700001
         LH    LR,IQLCA                                                 72800001
         L     LR,0(LR,PR)              SET UP LIB COMM AREA BASE REG.  72900001
         SR    BR,BR                                                    73000001
         ST    BR,WEVT               /  CLEAR WEVT.                     73100001
         ST    BR,WOFD+4             /  CLEAR KEY SDV IN WOFD.          73200001
         LH    BR,IQCFL                                                 73300001
         L     BR,0(BR,PR)                                              73400001
         MVI   WFIL,0                /  CLEAR WFIL.                     73500001
         MVC   WFIL+1(3),1(BR)       /                                  73600001
         B     ITME8                 *                                  73700001
         SPACE                                                          73800001
ITME7    EQU   *                                                        73900001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ITM032-TSS 73950020
         TM    BERR,BMDF             +  READ FOR UPDATE...              74000001
         BO    ITME8                 *  YES.                            74100001
*        ----------------------------------------------------ITM032-TSS 74150020
         MVI   BACT,0                /  NO. FREE IOCB.                  74200001
ITME8    EQU   *                                                        74300001
         LTR   RE,RE                 +  EVENT OPTION...                 74400001
         BZ    ITME9                 *  NO.                             74500001
         OI    EFL2,EMCP                YES. SET EVENT VARY COMPLETE.   74600001
         SPACE                                                          74700001
ITME9    EQU   *                                                        74800001
         L     DR,OFDR(DR)              GET IHEION SAVE AREA.           74900001
         LM    LR,RX,OFLR(DR)           RESTORE REGISTERS.              75000001
         BR    LR                    X  RETURN TO COMPILED CODE.        75100001
         EJECT                                                          75200001
*                                       RECORD MOVE SUBROUTINE          75300001
*                                       RH = A(TO)                      75400001
*                                       RI = A(FROM)                    75500001
*                                       RJ = LENGTH                     75600001
         SPACE                                                          75700001
ITMF1    EQU   *                                                        75800001
         LA    BR,256                   SET UP COUNTER.                 75900001
ITMF2    EQU   *                                                        76000001
         CR    RJ,BR                 +  MORE THAN 256 BYTES...          76100001
         BNH   ITMF3                 *  NO.                             76200001
         MVC   0(256,RH),0(RI)       /  YES. MOVE 256 BYTE CHUNK.       76300001
         AR    RH,BR                    BUMP-UP TO ADDRESS.             76400001
         AR    RI,BR                    BUMP-UP FROM ADDRESS.           76500001
         SR    RJ,BR                    REDUCE LENGTH TO MOVE.          76600001
         B     ITMF2                 *  MOVE NEXT CHUNK.                76700001
ITMF3    EQU   *                                                        76800001
         LTR   RJ,RJ                 +  ANY MORE TO MOVE...             76900001
         BZ    ITMF4                 *  NO.                             77000001
         BCTR  RJ,0                     YES. SET LENGTH TO MOVE.        77100001
         EX    RJ,ITMS1              /  MOVE REMAINDER.                 77200001
ITMF4    EQU   *                                                        77300001
         BR    LR                    X  RETURN.                         77400001
         EJECT                                                          77500001
*                                       CONSTANTS                       77600001
         SPACE                                                          77700001
ERRA     DC    AL2(ERR1)                KEY NOT FOUND.                  77800001
ERRB     DC    AL2(ERR2)                DUPLICATE KEY.                  77900001
ERRC     DC    AL2(ERR3)                NO SPACE AVAILABLE.             78000001
ERRD     DC    AL2(ERR4)                TRANSMIT (INPUT).               78100001
ERRE     DC    AL2(ERR5)                TRANSMIT (OUTPUT).              78200001
ERRF     DC    AL2(ERR6)                KEY SPECIFICATION.              78300001
ERRG     DC    AL2(ERR7)                REC VARY GT MAXIMUM PERMITTED.  78400001
ERRH     DC    AL2(ERR8)                REC VARY LT MINIMUM PERMITTED.  78500001
ERRJ     DC    AL2(ER10)                REWRITE NOT PRECEDED BY READ.   78600001
ERRL     DC    AL2(ER12)                OUTSTANDING READ UPDATE.        78700001
ERRM     DC    AL2(ER13)                ATTEMPT TO WRITE ZERO LEN REC.  78800001
         SPACE                                                          78900001
H008     DC    H'8'                                                     79000001
H004     DC    H'4'                                                     79100001
H001     DC    H'1'                                                     79200001
         SPACE                                                          79300001
ITMS1    MVC   0(*-*,RH),0(RI)                                          79400001
ITMS2    MVC   1(*-*,RH),0(RH)                                          79500001
ITMS3    CLC   0(*-*,RI),0(LR)                                          79600001
         SPACE                                                          79700001
         END                                                            79900001
