LDI      TITLE '   IHELDI    LIST DIRECTED INPUT                       /00100013
               OS/360 PL/I LIBRARY'                                     00200013
*    VERSION   FOURTH VERSION OF F-LEVEL PL/I COMPILER                  00300015
*                                                                       00400013
*   STATUS     CHANGE LEVEL - 1                                         00500021
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI000-TSS 00530001
* 5.5  C 595000,596000                                         KT 62571 00535072
*A750000                                                     VJH  49771 00540021
*        ----------------------------------------------------LDI000-TSS 00560001
*                                                                       00600013
*   SIZE       1656 BYTES.                                              00700013
*                                                                       00800013
*   FUNCTION                                                            00900013
*              1)READ AN ITEM FROM THE SPECIFIED INPUT STREAM ACCORDING 01000013
*              TO THE RULES SPECIFIED FOR LIST DIRECTED INPUT. IF THE   01100013
*              ITEM SPANS MORE THAN ONE RECORD, THEN THE INFORMATION IN 01200013
*              EACH RECORD IS STACKED BY THE AQUISITION OF VDA'S UNTIL  01300013
*              THE ITEM DELIMITER/DDI TRANSMISSION TERMINATER IS FOUND. 01400013
*              THE ITEM IS THEN CONCATENATED INTO A SINGLE VDA FOR      01500013
*              ANALYSIS.                                                01600013
*              THE ITEM IS SCANNED AS FOLLOWS -                         01700013
*                A) ANY LEADING BLANKS ARE IGNORED.                     01800013
*                B) IF THE FIRST CHARACTER IS A QUOTE MARK THEN A       01900013
*                 STRING CONSTANT IS ASSUMED TO FOLLOW AND A SEARCH IS  02000013
*                 MADE FOR A SUBSEQUENT SINGLE QUOTE MARK.              02100013
*                   THE CHARACTER AFTER IS TESTED FOR A LETTER B. IF IT 02200013
*                 IS THEN THE CONSTANT IS A BIT STRING CONSTANT,        02300013
*                 OTHERWISE IT IS A CHARACTER STRING CONSTANT.          02400013
*                   THE NEXT CHARACTER IS ASSUMED TO BE THE DELIMITER.  02500013
*                   IF THE FIRST CHARACTER WAS NOT A QUOTE MARK THEN AN 02600013
*                 ARITHMETIC CONSTANT IS ASSUMED AND A SEARCH IS MADE   02700013
*                 FOR AN ITEM DELIMITER/DDI TRANSMISSION TERMINATOR     02800013
*                 IS MADE.                                              02900013
*                                                                       03000013
*              2)THE ITEM IS ASSIGNED TO THE INTERNAL VARIABLE. SEE THE 03100013
*              RULES FOR LIST DIRECTED INPUT FOR THE CONVERSION NESSARY 03200013
*                                                                       03300013
*   ENTRY POINTS                                                        03400013
*              IHELDIA                                                  03500013
*                  RA = A(PLIST)                                        03600013
*                  PLIST = A(VARIABLE/SDV)                              03700013
*                          A(DED)                                       03800013
*                           ...                                         03900013
*              IHELDIB                                                  04000013
*                  RA = A(VARIABLE/SDV)                                 04100013
*                  RB = A(DED)                                          04200013
*            * THE NEXT TWO ENTRY POINTS ARE FOR IHEDDI ONLY.           04300013
*              IHELDIC  (SCAN ONLY)                                     04400013
*                  RA = A(CONTROL BLOCK)                                04500013
*                  RB = A(BUFFER DV)                                    04600013
*                  CONTROL BLOCK = H'VDA COUNT SO FAR'                  04700013
*                                  X'FLAG BOX' (ONE BYTE)               04800013
*                  BUFFER DV = A(BUFFER)                                04900013
*                              H'PART OF NAME IN BUFFER'                05000013
*                              H'NUMBER OF BYTES TO END OF BUFFER'      05100013
*              IHELDID  (ASSIGNMENT ONLY)                               05200013
*                  RA = A(VARIABLE/SDV)                                 05300013
*                  RB = A(DED)                                          05400013
*                  RC = A(CONTROL BLOCK)                                05500013
*                  CONTROL BLOCK AS FOR ENTRY POINT IHELDIC.            05600013
*                                                                       05700013
*   INPUT                                                               05800013
*              CURRENT FILE PSEUDO REGISTER (IHEQCFL)                   05900013
*                                                                       06000013
*   OUTPUT                                                              06100013
*              ENTRY POINTS IHELDIA,IHELDIB,IHELDID ONLY.               06200013
*                ASSIGNMENT OF ITEM(S) TO INTERNAL VARIABLE(S).         06300013
*              ENTRY POINT IHELDIC ONLY.                                06400013
*                UPDATED CONTROL BLOCK.                                 06500013
*                                                                       06600013
*   EXTERNAL MODULES                                                    06700013
*              IHEDCN - CHARACTER STRING TO ARITHMETIC.                 06800013
*              IHEDMA - ARITHMETIC CONVERSION PACKAGE FOR BIT STRING    06900013
*                                          TO ARITHMETIC.               07000013
*              IHEDNB - ARITHMETIC TO BIT STRING.                       07100013
*              IHEDNC - ARITHMETIC TO CHARACTER STRING.                 07200013
*              IHEERR - EXECUTION ERROR PACKAGE.                        07300013
*              IHEIOF - ADDRESS INPUT INPUT STREAM.                     07400013
*              IHEKCD - CHARACTER STRING PICTURE CHECK.                 07500013
*              IHEPRT - COPY ITEM ONTO SYSPRINT.                        07600013
*              IHESAD - GET VDA'S AS NECESSARY.                         07700013
*              IHESAF - FREE VDA'S GOTTEN IN THIS PASS.                 07800013
*              IHEVCA - ARITHMETIC CONSTANT ANALYZER.                   07900013
*              IHEVCS - COMPLEX TO STRING.                              08000013
*              IHEVSC - CHARACTER STRING TO CHARACTER STRING.           08100013
*              IHEVSD - CHARACTER TO BIT STRING.                        08200013
*                                                                       08300013
*   EXITS      NORMAL                                                   08400013
*                  RETURN VIA LINK REGISTER                             08500013
*                RETURN CODES (ENTRY POINT IHELDIC ONLY)                08600013
*                  0 - ITEM FOUND BUT NOT THE LAST FOR DATA DIRECTED    08700013
*                       READ                                            08800013
*                  4 - LAST ITEM FOR DATA DIRECTED READ.                08900013
*                  8 - END OF FILE WAS RAISED.                          09000013
*              ERROR                                                    09100013
*                  1. 'CONVERSION'                                      09200013
*                                  INVALID INPUT FIELD. IF CONTROL IS   09300013
*                            RETURNED THE ASSIGNMENT IS RETRIED.        09400013
*                  2. 'GET/PUT STRING SIZE EXCEEDED'                    09500013
*                                                    AN ATTEMPT         09600013
*                            WAS MADE TO GO PAST THE END OF THE SOURCE  09700013
*                            STRING.                                    09800013
*                  3. 'TRANSMIT'                                        09900013
*                                A TRANSMISSION ERROR HAS BEEN NOTED    10000013
*                            DURING THE READING OF THIS ITEM.           10100013
*              NOTE - IF CONTROL IS RETURNED TO THIS MODULE AFTER       10200013
*                  END OF FILE HAS BEEN RAISED AND THE ENTRY POINT TO   10300013
*                  THE MODULE WAS NOT IHELDIC, RETURN IS VIA THE SECOND 10400013
*                  WORD OF IHEQCFL. A NORMAL RETURN, SEE ABOVE, IS MADE 10500013
*                  IF THE ENTRY POINT WAS IHELDIC.                      10600013
         EJECT                                                          10700013
*   TABLES/WORK AREA                                                    10800013
*              SEE OS/360 PL/I LIBRARY PLM FOR DESCRIPTION OF THE FILE  10900013
*               CONTROL BLOCK.                                          11000013
*                                                                       11100013
*   ATTRIBUTES  READ ONLY AND REENTRANT                                 11200013
*                                                                       11300013
*   PRIVATE MACROS                                                      11400013
*              IHELIB,IHEPRV,IHESDR,IHEZAP                              11500013
*                                                                       11600013
*   ASSEMBLY REQUIREMENTS                                               11700013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   11800013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        11900013
*                                                                       12000013
*   NOTES                                                               12100013
*              SEE OS/360 PL/I LIBRARY PLM FOR DESCRIPTION OF LIBRARY   12200013
*               CONVENTIONS AND STANDARDS.                              12300013
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    12400013
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    12500013
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  12600013
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  12700013
*              CONSTANTS, BY REASSEMBLY, WILL RESULT IN A CORRECT       12800013
*              MODULE FOR THE NEW DEFINITIONS.                          12900013
        EJECT                                                           13000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI001-TSS 13050001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   13100013
         PUNCH     ' LIBRARY *(IHEVSCA,IHEDNCA,IHEVCSA,IHEDMAA,IHEKCDB,/13200013
               IHEDNBA,IHEDCNB)     LDI0000A'                           13300013
         PUNCH     ' LIBRARY *(IHEUPAB,IHEUPBB)                        /13400013
                                    LDI0000B'                           13500013
*        ----------------------------------------------------LDI001-TSS 13550001
         SPACE                                                          13600013
IHELDI   CSECT                                                          13700013
         IHELIB                                                         13800013
         IHEZAP                                                         13900013
IHEZLW4  DSECT                                                          14000013
         DS    18F                                                      14100001
RTRY     DS    0B                                                       14200013
WPRA     DS    A                                                        14300013
WSDS     DS    2A                                                       14400013
IVDA     DS    H                                                        14500013
WPFL     DS    B                                                        14600013
WPF2     DS    B                                                        14700013
DED1     DS    3C                                                       14800013
WREL     DS    3C                                                       14900013
WIMG     DS    3C                                                       15000013
TADD     DS    A                                                        15030016
         DS    2A                                                       15060016
WSAV     DS    0A                                                       15100013
WPPT     DS    2A                                                       15200013
WPPL     EQU   WPPT                     PLIST FOR IHEVCS.               15300013
WPCD     EQU   WPPL+16                                                  15400013
WPPF     EQU   WPPL+32                  DUMMY FEDS.                     15500013
         EJECT                                                          15600013
PWR      EQU   WR                                                       15700013
CURL     EQU   6                                                        15800013
MAXL     EQU   4                                                        15900013
BITS     EQU   X'84'                                                    16000013
STRG     EQU   X'80'                                                    16100013
PICT     EQU   X'08'                                                    16200013
BCON     EQU   X'80'                                                    16300013
SCON     EQU   X'40'                                                    16400013
LBLK     EQU   X'20'                    LEADING BLANK FLAG.             16500013
DLIM     EQU   X'10'                                                    16600013
EOFF     EQU   X'08'                                                    16700013
DDTF     EQU   X'01'                                                    16800013
BSCN     EQU   X'C0'                    EQU  BCON OR SCON               16900013
EFLG     EQU   X'20'                                                    17000013
NTRY     EQU   X'06'                                                    17100013
NTR3     EQU   X'04'                                                    17200013
ERCN     EQU   64                       ERROR CODE FOR CONVERSION.      17300013
TCFL     EQU   X'04'                    XMIT STACK FLAG                 17350013
RTRF     EQU   X'80'                    RETRY FLAG.                     17400013
CERR     EQU   X'80'                                                    17500013
ERR1     EQU   X'B800'                  END OF FILE                     17530015
ERR2     EQU   X'0012'                  UNEXPECTED END OF FILE          17560015
         EJECT                                                          17600013
IHELDI   CSECT                                                          17700013
         ENTRY IHELDIA,IHELDIB,IHELDIC,IHELDID                          17800013
IHELDIA  NOPR  0                     .  NORMAL ENTRY.                   17900013
IHELDIB  NOPR  0                     .  ENTRY FOR ONE ITEM.             18000013
IHELDIC  NOPR  0                     .  ENTRY FOR DATA DIRECTED SCAN.   18100013
IHELDID  STM   LR,PWR,OFLR(DR)       .  ENTRY FOR DATA DIRECTED ASSNMT. 18200013
         BALR  PWR-1,0                                                  18300013
         USING *,PWR-1                                                  18400013
         USING IHEZLCA,PWR                                              18500013
         USING IHEZLW4,DR                                               18600013
         USING IHEZAPE,RH                                               18700013
         IHESDR LW4,PWR                 SET UP DR TO SAVE AREA.         18800013
         IHEPRV LCA,PWR                 ADDRESS LIB COMMUNICATIONS AREA 18900013
         ST    RA,WPRA                  SAVE PARAMETER REGISTER.        19000013
         STC   BR,WPFL                  SAVE ENTRY POINT INDEX.         19100013
         LA    LR,RETRY                                                 19200013
         STM   DR,LR,WCNV                                               19300013
         NI    RTRY,255-RTRF         /  CLEAR RETRY FLAG.               19400013
         TM    WPFL,NTRY             +  TEST FOR NORMAL ENTRY           19500013
         BO    LIDAS                    ENTRY TO ASSIGN VALUE.          19600013
         BM    LI010                    ENTRY B OR C                    19700013
LI000    LM    RA,RB,0(RA)                                              19800013
LI010    STM   RA,RB,WPCD               ADDRESS OF TARGET AND ITS DED.  19900013
         BAL   LR,LIFCB              $  ADDRESS CURRENT FILE FCB.       20000013
         TM    WPFL,NTR3             +  ENTRY C..  (DDI)                20100013
         BO    LI012                    YES, LEAVE FLAG AS SET IN DDI.  20200013
         TM    TFLX,TMEF             +  END FILE ALREADY ENCOUNTERED    20230015
         BO    LIDOF                 ** YES, RAISE ENDFILE              20260015
         NI    TFLX,255-TMIT         /  UNSET TRANSMIT ERROR FLAG.      20300013
         IHEPRV CFL,BR,OP=LA                                            20330013
         NI    4(BR),255-TCFL           UNSET XMIT FLAG                 20360013
         OI    WPFL,LBLK             /  SET LEADING BLANK FLAG.         20380015
LI012    SR    RI,RI                    CLEAR FIELD COUNT.              20400013
         SR    LR,LR                    CLEAR VDA INVOC COUNT.          20500013
         TM    WPFL,NTR3             +  TEST FOR ENTRY C.               20600013
         BZ    LI017                    NO.                             20700013
         L     LR,WPCD                  ADDRESS VDA INVOC COUNT FROM DD 20800013
         LH    LR,0(LR)                                                 20900013
LI017    STH   LR,IVDA                  VDA INVOC COUNT SO FAR.         21000013
         LA    RD,LI019                 REUTRN ADDRESS.                 21100013
         NI    WPFL,255-EOFF-DLIM    /  UNSET EOF AND DELIM FLAGS.      21200013
         LH    RG,TREM                  NUMBER OF BYTES LEFT IN BUFFER. 21300013
         LTR   RG,RG                    ARE THERE ANY LEFT IN FACT..    21400013
         BZ    LIGIO                 $  NO, GET ANOTHER RECORD.         21500013
         B     LIGST                 $  YES, SET UP BUFF POINTERS.      21600013
LI019    TM    WPFL,NTR3             +  TEST FOR ENTRY C.               21700013
         BO    LI035                    YES.                            21800013
         ST    RI,WOFD+4                SET FIELD COUNT TO ZERO.        21900013
LI025    CLI   0(RF),C' '               TEST FOR LEADING BLANK.         22100013
         BNE   LI030                    NO.                             22200013
LI027    BAL   RD,LIGET              $  GET NEXT CHARACTER.             22300013
         B     LI025                                                    22400013
         SPACE                                                          22500013
LI030    CLI   0(RF),C','               IS CHARACTER A COMMA..          22600013
         BNE   LI032                                                    22700013
         TM    TFLX,TMLC                WAS LAST NON-BLANK A COMMA..    22800013
         BZ    LI060                    YES.                            22900013
         NI    TFLX,255-TMLC                                            23000013
         B     LI027                                                    23100013
LI032    ST    RF,WOFD                  SET ONSOURCE START ADDR.        23200013
         ST    RF,WSDS                  SET BUFFER DV.                  23300013
         ST    RE,WSDS+4                                                23400013
         B     LI037                                                    23500013
         SPACE                                                          23600013
LI035    L     BR,WPCD+4                ADDRESS OF BUFF SDV FROM DDI.   23700013
         MVC   WSDS(8),0(BR)            SET LDI BUFFER SDV.             23800013
         LH    RI,WSDS+4                LENGTH OF NAME IN BUFFER.       23900013
         ALR   RF,RI                    BEGINNING OF VALUE FIELD        24000013
         SLR   RE,RI                    NUMBER OF BYTES LEFT.           24100013
LI037    NI    WPFL,NTRY             /  UNSET ALL FLAGS EXCEPT ENTRY.   24200013
         MVI   WPF2,0                                                   24300013
         CLI   0(RF),C''''              TEST FOR LEADING QUOTE.         24400013
         BE    LIST1                    YES-SCAN FOR STRING CONSTANT.   24500013
         OI    WPFL,DLIM                                                24600013
LI040    BAL   LR,LIDLM              $  TEST FOR DELIMITOR.             24700013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI002-TSS 24730056
*        ----------------------------------------------------LDI002-TSS 24760056
         AR    RI,RG                    NO  INCREMENT FIELD COUNT.      24800013
         BAL   RD,LIGET              $  GET NEXT CHARACTER.             24900013
         B     LI040                                                    25000013
         SPACE                                                          25100013
LI050    OI    WPFL,DDTF                DATA DIRECTED TERMINATOR.       25200013
LI060    TM    RTRY,RTRF             +  TEST FOR RETRY.                 25300013
         BO    LIASS                    YES.                            25400013
         LR    RA,RE                                                    25500013
         AR    RF,RG                    ADDRESS OF NEXT FRE BYTE.       25600013
         ST    RF,TCBA                  NEW BUFFER POSITION.            25700013
         BCTR  RA,0                                                     25800013
         STH   RA,TREM                  NUMBER OF BYTES LEFT IN BUFFER. 25900013
LI065    ST    RI,WSDS+4                                                26000013
         AH    RI,WOFD+CURL                                             26100013
         BZ    LINLL                    BRANCH IF NULL SOURCE.          26200013
         LH    RD,IVDA                                                  26300013
         LTR   RD,RD                    IS IT ZERO..                    26400013
         BZ    LIASS                    YES.                            26500013
         AR    RD,RG                    INCREMENT COUNT BY 1 FOR VDA    26600013
         STH   RD,IVDA                   TO BE GOTTEN.                  26700013
         LA    R0,8(RI)                                                 26800013
         IHEPRV VDA,BR               $$ GET VDA                         26900015
         BALR  LR,BR                                                    27000013
         LR    RH,RA                    ADDRESS OF VDA.                 27100013
         LA    RA,8(RA)                 SPACE OVER CONTROL FIELD.       27200013
         ST    RA,WOFD                  SET ONSOURCE SDV ADDRESS FIELD. 27300013
         AR    RA,RI                                                    27400013
         CH    RI,WOFD+CURL                                             27500013
         BE    MOVT2                                                    27600013
         S     RF,WSDS                  LENGTH OF ITEM IN BUFFER.       27700013
         SR    RA,RF                    ADDRESS FOR LAST BIT OF ITEM.   27800013
         LA    RC,WSDS                  ADDRESS OF BUFFER               27900013
MOVET    ST    RA,WSAV                  SAVE CURRENT VDA POSITION.      28000013
         BAL   LR,LIMOV                 MOVE FROM BUFFER/VDA TO TARGET. 28100013
         L     RA,WSAV                  RESTORE VDA POSITION.           28200013
MOVT2    L     RH,4(RH)                 ADDRESS PREVIOUS VDA.           28300013
         LA    RC,8(RH)                 ADDRESS SDV.                    28400013
         SH    RA,CURL(RC)              SET VDA POSITION BACK BY LENGTH 28500013
         BCT   RD,MOVET                 LOOP ON INVOCATION COUNT.       28600013
LIASS    ST    RI,WOFD+4                SET ONSOURCE SDV LENGTH FIELD.  28700013
         L     RH,WOFD                                                  28800013
         TM    RTRY,RTRF             +  TEST FOR RETRY.                 28900013
         BO    LIAS0                    YES.                            29000013
         BAL   LR,LIFCB              $  ADDRESS CURRENT FILE FCB.       29100013
         TM    TFIO,TMCY             +  TEST FOR COPY OPTION.           29200013
         BZ    LINCP                    NONE.                           29300013
         L     RA,WOFD                  ADDRESS OF DATA ITEM.           29400013
         LA    RB,WOFD+CURL             ADDRESS OD LENGTH OF DATA ITEM. 29500013
         IHEPRV ADC,BR                  CALL ROUTINE                    29560016
         L     BR,IPRTA-IHEZADC(BR)      FOR COPY                       29620016
         BALR  LR,BR                                                    29700013
LINCP    L     RH,WOFD                                                  29800013
         TM    WPFL,NTR3             +  TEST FOR ENTRY C.               29900013
         BO    LIDXT                    YES.                            30000013
         EJECT                                                          30100013
*      ASSIGNMENT                                                       30200013
         SPACE                                                          30300013
LIAS0    STH   RI,WOFD+4                SET MAX LENGTH.                 30400013
         TM    WPFL,EOFF+DLIM        +  TEST FOR DLIM OR EOF.           30500013
         BNL   LIASZ                    BRANCH IF NEITHER OR BOTH.      30600013
         BCTR  RI,0                                                     30700013
LIASZ    STM   RH,RI,WSDS                                               30800013
         LH    RE,ERIO                                                  30900013
         IHEPRV ERR,RE,OP=STH           SET ERROR CODE FOR I/O.         31000013
         TM    WPF2,CERR                TEST FOR SCAN ERROR.            31100013
         BZ    LIASY                                                    31200013
         BAL   LR,LIER2                                                 31300013
LIASY    LM    RC,RD,WPCD                                               31400013
         ST    RC,TADD                  SAVE ADDRESS OF TARGET          31406016
         MVI   TADD,0                   ZERO LENGTH SLOT                31412016
         TM    0(RD),X'88'           +  CAD..                           31418016
         BNO   LIAT2                    NO                              31424016
         TM    0(RD),X'06'           +  DECIMAL..                       31430016
         BZ    LIAT2                    YES                             31436016
        LA    RC,2                    ASSUME HALFWORD BINARY.           31438001
        TM    0(RD),X'01'             TEST FOR REAL/COMPLEX.            31440001
        BZ    SKIP1                   SKIP IF REAL.                     31442001
        AR    RC,RC                   DOUBLE UP IF COMPLEX.             31444001
SKIP1   TM    0(RD),X'02'             TEST FOR FIXED/FLOAT.             31446001
        BZ    SKIP2                   BRANCH IF FIXED.                  31448001
        AR    RC,RC                   DOUBLE UP IF FLOAT.               31450001
        TM    0(RD),X'10'             TEST FOR SHORT/LONG.              31452001
        BZ    LIAT4                   SKIP IF SHORT.                    31454001
        AR    RC,RC                   DOUBLE UP IF LONG.                31456001
        B     LIAT4                                                     31458001
SKIP2   TM    0(RD),X'10'             TEST FOR HALFWORD BINARY.         31460001
        BO    LIAT4                   SKIP IF HALFWORD BINARY.          31462001
        AR    RC,RC                   DOUBLE UP IF FULLWORD.            31464001
LIAT4    STC   RC,TADD                                                  31478016
         ST    RA,TADD+4                SAVE SOURCE ADDRESS             31479016
         ST    BR,TADD+8                SAVE CONV. ROUTINE ADDRESS      31480016
         IHEPRV VDA,BR                  GET VDA FOR TEMP.               31481016
         LA    R0,8(RC)                 ROOM FOR IT                     31482016
         BALR  LR,BR                    GET IT                          31483016
         LA    RC,8(RA)                 A(RESULT)                       31484016
         L     BR,TADD+8                A(CONV. ROUTINE)                31485016
         LH    RA,IVDA                  UPDATE COUNT FOR VDA'S          31486016
         LA    RA,1(RA)                                                 31487016
         STH   RA,IVDA                                                  31488016
         L     RA,TADD+4                RELOAD SOURCE ADDRESS           31489016
LIAT2    EQU   *                                                        31490016
         LM    RE,RF,WSDS                                               31500013
         TM    WPFL,BSCN             +  IS SOURCE A STRING CONSTANT..   31600013
         BZ    LIARI                    NO, ARITHMETIC.                 31700013
         LA    RE,1(RE)                 UPDATE ADDRESS TO IGNORE QUOTE. 31800013
         BCTR  RF,0                     REDUCE FIELD COUNT TO IGNORE    31900013
         BCTR  RF,0                      FIRST AND LAST QUOTES.         32000013
         BO    LIBTS                    BIT STRING CONSTANT.            32100013
         STM   RE,RF,WSDS                                               32200013
         TM    0(RD),BITS            +  IS TARGET A BIT STRING..        32300013
         BZ    LIPRS                    YES DO A PRESCAN.               32400013
         TM    0(RD),STRG            +  IS TARGET A CHAR STRING..       32500013
         BZ    LIASC                    YES ASSIGN CHAR CONST.          32600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI999-TSS 32650056
ASSGN    L     BR,VDCNB              $$ CHARACTER TO ARITHMETIC.        32700013
*        ----------------------------------------------------LDI999-TSS 32750056
ASGN2    LA    RA,WSDS                  ADDRESS SOURCE SDV.             32800013
         LA    RB,VDED                  ADDRESS DED FIR SOURCE.         32900013
ASGN3    BALR  LR,BR                                                    33000016
         SPACE                                                          33100013
*   AN ITEM HAS BEEN ASSIGNED TO THE INTERNAL VARIABLE.                 33200013
         SPACE                                                          33300013
LINXT    CLI   TADD,0                +  TEMPORARY..                     33320016
         BE    LINXX                    NO                              33340016
         IC    LR,TADD                  LENGTH                          33360016
         LR    RA,RC                    A(TEMP.)                        33370016
         L     RC,TADD                  A(TARGET)                       33380016
         BCTR  LR,0                                                     33400016
         EX    LR,MVCAD                 MOVE IT IN                      33420016
LINXX    BAL   LR,LIFCB              $  ADDRESSS FCB                    33440016
         L     RI,TCNT                                                  33500013
         AR    RI,RG                    INCREMENT DATA ITEM COUNT       33600013
         ST    RI,TCNT                                                  33700013
LINLL    BAL   RD,LIVDA              $  FREE VDA'S IF NECESSARY.        33800013
         BAL   LR,LIFCB                 ADDRESS FCB FOR FILE.           33900013
         TM    TFLX,TMIT             +  TEST FOR TRANSMIT ERROR.        34000013
         BZ    LINTR                    NO.                             34100013
         LH    RA,TRER                  GET TRANSMIT ERROR CODE.        34200013
         IHEPRV ERR,RA,OP=STH                                           34300013
         L     RA,TDCL                  ADDRESS OF DCLCB.               34400013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI998-TSS 34450056
         L     BR,VERRB                                                 34500013
*        ----------------------------------------------------LDI998-TSS 34550056
         BALR  LR,BR                                                    34600013
LINTR    TM    WPFL,EOFF             +  WAS EOF CONDITION RAISED.       34700013
         BO    LIEFF                    YES - END TRANSMISSION.         34800013
LIEFS    TM    WPFL,NTRY             +  TEST FOR ENTRY A.               34900013
         BNE   LIEXT                    NO, END OF ROUTINE.             35000013
         L     RA,WPRA                  RESTORE PARAMETER POINTER.      35100013
         TM    4(RA),X'80'           +  LAST ENTRY IN LIST..            35200013
         BO    LIEXT                    YES,END OF ROUTINE.             35300013
         LA    RA,8(RA)                 NEXT ENTRY PAIR.                35400013
         ST    RA,WPRA                  SAVE CLEARING WPFL.             35500013
         B     LI000                    LOOP TO DO NEW ITEM.            35600013
LIEXT    SR    RE,RE                                                    35700013
         IHEPRV ERR,RE,OP=STH           CLEAR ERROR CODE.               35800013
         LA    BR,4                     SET RETURN CODE FOR DDI TERM.   35900013
LIEOF    TM    WPFL,DDTF+EOFF        +  TEST FOR DDI TERM OR EOF.       36000013
         L     DR,OFDR(DR)              RESTORE DR.                     36100013
         L     LR,OFLR(DR)                                              36200013
LIEF2    LM    RB,PWR,OFRB(DR)                                          36300013
         BCR   5,LR                  X  EXIT IF DDI TERM OR EOF FOUND.  36400013
         SR    BR,BR                    SET RETURN CODE FOR NO TERM.    36500013
         BR    LR                    X  EXIT                            36600013
         SPACE                                                          36700013
*  RETURN TO DATA DIRECTED INPUT.                                       36800013
         SPACE                                                          36900013
LIDXT    L     RA,WPCD                                                  37000013
         MVC   0(4,RA),IVDA                                             37100013
         B     LIEXT                                                    37200013
         EJECT                                                          37300013
* ROUTINE TO SCAN STRING CONSTANT.                                      37400013
         SPACE                                                          37500013
LISTR    NI    WPFL,255-DLIM-SCON    /  UNSET DLIM AND STR CONST FLAGS. 37600013
LIST1    AR    RI,RG                    COUNT INITIAL QUOTE.            37700013
         BAL   RD,LIGET              $  GET NEXT CHARACTER.             37800013
         CLI   0(RF),C''''              TEST FOR QUOTE.                 37900013
         BNE   LISTR                                                    38000013
         OI    WPFL,DLIM+SCON        /  SET DLIM AND STR CONST FLAGS.   38100013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI003-TSS 38130056
*        ----------------------------------------------------LDI003-TSS 38160056
         AR    RI,RG                    COUNT QUOTE.                    38200013
         BAL   RD,LIGET              $  GET NEXT CHARACTER.             38300013
         CLI   0(RF),C''''              TEST FOR SECOND QUOTE.          38400013
         BE    LISTR                    YES, NOT END OF CONSTANT.       38500013
         CLI   0(RF),C'B'               TEST FOR B FOR BIT STR.CON.     38600013
         BNE   LIS10                    NO                              38700013
         OI    WPFL,BCON             /  SET BIT CONSTANT FLAG.          38800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI004-TSS 38830056
*        ----------------------------------------------------LDI004-TSS 38860056
         AR    RI,RG                                                    38900013
         BAL   RD,LIGET              $  GET NEXT CHARACTER.             39000013
LIS10    BAL   LR,LIDLM              $  TEST FOR DELIMITOR.             39100013
         OI    WPF2,CERR                                                39200013
         ST    RF,WOCH                  FOR WRONG CHARACTER             39300015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI005-TSS 39350056
LISER    AR    RI,RG                                                    39400013
*        ----------------------------------------------------LDI005-TSS 39450056
         BAL   RD,LIGET                                                 39500013
         BAL   LR,LIDLM                                                 39600013
         B     LISER                                                    39700013
         SPACE                                                          39800013
*  PREAMBLE FOR DATA DIRECTED ASSIGNMENT.                               39900013
         SPACE                                                          40000013
LIDAS    STM   RA,RB,WPCD                                               40100013
         MVC   IVDA(2),0(RC)            VDA INVOCATION COUNT            40200013
         LM    RH,RI,WOFD                                               40300013
         LA    RG,1                                                     40400013
         NI    WPFL,NTRY             /  CLEAR FLAGS OTHER THAN ENTRY.   40500013
         MVI   WPF2,0                   RESTORE TO CONDITION AT FIRST   40600013
         OC    WPFL(2),2(RC)              RETURN TO IHEDDI.             40700013
         B     LIAS0                    GO AND ASSIGN VALUE.            40800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI006-TSS 40830056
*        ----------------------------------------------------LDI006-TSS 40860056
         EJECT                                                          40900013
*  BIT STRING CONSTANT ASSIGNMENT.                                      41000013
         SPACE                                                          41100013
LIBTS    BCTR  RF,0                                                     41200013
         TM    0(RD),STRG            +  IS TARGET A STRING.             41300013
         BZ    LIPRS                                                    41400013
         LTR   RF,RF                    IS BIT STRING NULL..            41500013
         BZ    LIBTN                    YES.                            41600013
         LA    RB,BCDD                  ADDRESS BIT CON DED (7D)        41700013
         AR    RF,RE                                                    41800013
         BCTR  RF,0                                                     41900013
         STM   RE,RF,WCN1               SET TO START,END ADDRESSES.     42000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI997-TSS 42050056
         L     BR,VDMAA              $$ BIT CON TO ARITH USING ARITH    42100013
*        ----------------------------------------------------LDI997-TSS 42150056
         BALR  LR,BR                      CONVERSION DIRECTOR.          42200013
         TM    0(RD),X'01'           +  IS TARGET COMPLEX..             42300013
         BZ    LINXT                    NO, END OF ASSIGNMENT.          42400013
         LR    RA,RC                    YES, ZREO IMAG PART.            42500013
         LR    RB,RD                                                    42600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI996-TSS 42650056
         L     BR,VUPBB                 SET TO ZERO IMAG PART NF.       42700013
*        ----------------------------------------------------LDI996-TSS 42750056
         TM    0(RD),X'08'              IS TARGET NF.                   42800013
         BZ    ASGN3                    YES, GO TO ZERO IT.             42900013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI995-TSS 42950056
         L     BR,VUPAB                 SET TO ZERO IMAG PART CAD.      43000013
*        ----------------------------------------------------LDI995-TSS 43050056
         B     ASGN3                    GO TO ZERO IT.                  43100013
         SPACE                                                          43200013
LIBTN    STM   RE,RF,WSDS               SET UP SDV.                     43300013
         B     ASSGN                    ASSIGN TO TARGET.               43400013
         EJECT                                                          43500013
*  PRESCAN TO CHECK FOR A VALID BIT STRING CONSTANT.                    43600013
         SPACE                                                          43700013
LIPRS    STM   RE,RF,WSDS               SAVE FOR CALLED MODULE          43800013
         LTR   RF,RF                    IS STRING NULL..                43900013
         BZ    LIP25                    YES, NO PRESCAN.                44000013
LIP10    CLI   0(RE),C'1'               TEST FOR CHAR 1.                44100013
         BE    LIP20                    YES, OK.                        44200013
         CLI   0(RE),C'0'               TEST FOR CHAR 0.                44300013
         BE    LIP20                    YES.                            44400013
         IHEPRV ERR,RA,OP=LA                                            44420015
         MVI   1(RA),CHBT               SET SECONDARY CONV. CODE.       44440015
CHBT     EQU   X'05'                                                    44460015
         BAL   LR,LIERR               ** NO - ERROR.                    44500013
LIP20    AR    RE,RG                    NEXT CHARACTER.                 44600013
         BCT   RF,LIP10                 LOOP TO END.                    44700013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI994-TSS 44750056
LIP25    L     BR,VVSDB                 CHAR TO BIT.                    44800013
*        ----------------------------------------------------LDI994-TSS 44850056
         TM    0(RD),X'84'           +  IS TARGET BIT STRING.           44900013
         BZ    ASGN2                    YES                             45000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI993-TSS 45050056
         L     BR,VVSCA                 CHAR TO CHAR                    45100013
*        ----------------------------------------------------LDI993-TSS 45150056
LIP30    LA    RA,WSDS                  ADDRESS SOURCE.                 45200013
         LA    RB,VDED                  DED FOR SOURCE.                 45300013
         BALR  LR,BR                 $$ CALL ROUTINE                    45400013
         B     LIPIC                    GO CHECK FOR CHAR WITH PICTURE  45500013
         EJECT                                                          45600013
*  ARITHMETIC CONSTANT ASSIGNMENT.                                      45700013
         SPACE                                                          45800013
LIARI    TM    0(RD),STRG            +  TEST FOR STRING TARGET.         45900013
         BNE   ASSGN                    NO.                             46000013
LIAST    LM    LR,BR,WSDS               COPY OF SOURCE FIELD SDV.       46100013
         NI    WPFL,X'1F'            /  CLEAR FLAGS.                    46200013
LIASA    ST    RE,WOCH                  SET ONCHAR POINTER TO START.    46300013
LIAS1    AR    RE,RG                    NEXT CHARACTER                  46400013
         BCT   RF,LIAS2                 COUNT                           46500013
         B     LIAS3                    END OF SOURCE                   46600013
LIAS2    CLI   0(RE),C'+'               TEST FOR +.                     46700013
         BE    LIAS3                    YES END OF VALUE.               46800013
         CLI   0(RE),C'-'               TEST FOR -.                     46900013
         BE    LIAS3                    YES END OF VALUE.               47000013
         CLI   0(RE),C'E'               TEST FOR E.                     47100013
         BNE   LIAS1                    NO, CONTINUE SCAN.              47200013
         TM    WPFL,EFLG             +  WAS E FLAG ON.                  47300013
         BZ    LINEF                    NO.                             47400013
         BAL   LR,LIERR              ** YES - ERROR.                    47500013
LINEF    OI    WPFL,EFLG             /  SET E FLAG.                     47600013
         AR    RE,RG                    SKIP NEXT CHAR(MUST BE + OR -). 47700013
         BCT   RF,LIAS1                                                 47800013
         BAL   LR,LIER2              ** NO MORE CHARS.                  47900013
LIAS3    AR    BR,LR                                                    48000013
         SR    BR,RF                                                    48100013
         BCTR  BR,0                     END ADDRESS OF VALUE.           48200013
         STM   LR,BR,WPPT                                               48300013
         LA    RA,WPPT                                                  48400013
         ST    RA,WCNP                                                  48500013
         LA    RA,DED1                                                  48600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI992-TSS 48650056
         L     BR,VVCAA              $$ CALL SCAN ROUTINE               48700013
*        ----------------------------------------------------LDI992-TSS 48750056
         BALR  LR,BR                                                    48800013
         LM    LR,BR,WPPT                                               48900013
         TM    DED1,X'04'            +  TEST FOR DECIMAL CONSTANT.      49000013
         BZ    DECML                    YES.                            49100013
         BCTR  BR,0                     NO, IGNORE BINARY MARKER 'B'.   49200013
DECML    TM    DED1,X'01'            +  IS CONSTANT IMAGINARY.          49300013
         BZ    LIAS4                    NO, REAL.                       49400013
         TM    WPFL,X'40'            +  IS IMAG FLAG ON..               49500013
         BZ    LINIM                    NO.                             49600013
         BAL   LR,LIER2              ** YES - ERROR.                    49700013
LINIM    BO    LIER2                 ** YES.                            49800013
         OI    WPFL,X'40'            /  SET IMAG FLAG.                  49900013
         BCTR  BR,0                     IGNORE THE 'I'.                 50000013
         STM   LR,BR,WCN2               SET IMAG FIELD LIMITS.          50100013
         MVC   WIMG(3),DED1             SET IMAG DED.                   50200013
         B     LIAS5                                                    50300013
         SPACE                                                          50400013
LIAS4    TM    WPFL,X'80'            +  IS REAL FLAG ON..               50500013
         BZ    LINRL                    NO.                             50600013
         BAL   LR,LIER2              ** YES - ERROR                     50700013
LINRL    OI    WPFL,X'80'            /  SET REAL FLAG.                  50800013
         STM   LR,BR,WCN1                                               50900013
         MVC   WREL(3),DED1             SET REAL DED                    51000013
LIAS5    LTR   RF,RF                    ANY MORE..                      51100013
         BZ    LIAS6                    NO                              51200013
         LR    LR,RE                    SET FOR MORE SOURCE TO BE       51300013
         LR    BR,RF                     SCANNED.                       51400013
         NI    WPFL,X'DF'            /  UNSET E FLAG.                   51500013
         B     LIASA                    SCAN REST OF FIELD.             51600013
         SPACE                                                          51700013
LIAS6    LA    RC,WCN2                  ADDRESS IMAG DED.               51800013
         LA    RD,WIMG                  ADDRESS IMAG LIMITS.            51900013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI981-TSS 51950056
         LA    RA,SEDD                  ADDRESS DUMMY REAL START/END.   52000013
*        ----------------------------------------------------LDI981-TSS 52050056
         LA    RB,FDDD                  ADDRESS DUMMY REAL DED.         52100013
         TM    WPFL,X'80'            +  WAS THERE A REAL PART           52200013
         BZ    LIAS7                    NO                              52300013
         LA    RB,WREL                  ADDRESS TRUE REAL DED.          52400013
         LA    RA,WCN1                  ADDRESS REAL LIMITS             52500013
LIAS7    ST    RA,WCNP                                                  52600013
         STM   RA,RD,WPPL               SOURCE FIELDS AND DEDS ADDRS.   52700013
         L     RD,4(RA)                                                 52800013
         SL    RD,0(RA)                                                 52900013
         ALR   RD,RG                    LENGTH OF REAL FIELD.           53000013
         L     RE,4(RC)                                                 53100013
         SL    RE,0(RC)                                                 53200013
         ALR   RE,RG                    LENGTH OF IMAGINARY FIELD.      53300013
         SLDL  RD,16                                                    53400013
         STM   RD,RE,WPPF               W PART OF FEDS.                 53500013
         MVI   WPPF+3,X'80'             SET S = 0  (REAL)               53600013
         MVI   WPPF+7,X'80'             SET S = 0  (IMAGINARY).         53700013
         MVI   WPPF+2,X'0'              ENSURE REAL D = 0.              53800013
         LA    RD,WPPF            A(REAL FED).                          53900013
         ST    RD,WFED                                                  54000013
         LA    RE,WPPF+4                A(IMAGINARY FED).               54100013
         STM   RD,RE,WPPL+24            PUT IN VCS PLIST.               54200013
         TM    WPFL,X'40'            +  REAL PART ONLY..                54300013
         BZ    LIREL                    YES.                            54400013
         LA    RA,WPPL                                                  54500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI991-TSS 54550056
         L     BR,VVCSA              $$ CALL COMPLEX TO STRING.         54600013
*        ----------------------------------------------------LDI991-TSS 54650056
         B     ASGN3                                                    54700013
         SPACE                                                          54800013
LIREL    LM    RC,RD,WPCD                                               54900013
         L     RA,WSDS                                                  55000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI990-TSS 55050056
         L     BR,VDNBA              $$ ARITH TO BIT STRING.            55100013
*        ----------------------------------------------------LDI990-TSS 55150056
         TM    0(RD),BITS            +  IS TARGET A BIT STRING..        55200013
         BZ    ASGN3                    YES.                            55300013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI989-TSS 55350056
         L     BR,VDNCA              $$ ARITH TO CHARACTER STRING.      55400013
*        ----------------------------------------------------LDI989-TSS 55450056
         B     ASGN3                                                    55500013
         EJECT                                                          55600013
*  CHARACTER STRING CONSTANT TO CHARACTER STRING.                       55700013
         SPACE                                                          55800013
LIASC    LM    RE,RF,WSDS               ADDRESS AND LENGTH OF SOURCE    55900013
         L     LR,0(RC)                 ADDRESS OF TARGET               56000013
         LH    BR,MAXL(RC)              LENGTH OF TARGET.               56100013
         AR    BR,RG                    INITIALIZE TARGET L TO L+1.     56200013
         AR    RF,RG                    INITIALIZE SOURCE L TO L+1.     56300013
LIA10    SR    BR,RG                    DECREMENT TARGET LENGTH.        56400013
         BZ    LIAND                    IF 0 END OF TARGET.             56500013
         SR    RF,RG                    DECREMENT SOURCE LENGTH.        56600013
         BZ    LIAFL                    IF 0 END OF SOURCE.             56700013
         CLI   0(RE),C''''              IS CHARACTER A QUOTE MARK..     56800013
         BNE   LIA20                    NO  GO TO MOVE.                 56900013
         AR    RE,RG                    POSITION TO NEXT CHAR - MUST BE 57000013
         BCTR  RF,0                     2ND QUOTE OF PAIR.              57100013
LIA20    MVC   0(1,LR),0(RE)            MOVE CHAR TO TARGET STRING.     57200013
         AR    RE,RG                    BUMP SOURCE ADDRESS.            57300013
         AR    LR,RG                    BUMP TARGET ADDRESS.            57400013
         B     LIA10                    CONTINUE.                       57500013
LIAFL    TM    0(RD),X'10'           +  IS TARGET A VARYING CS.         57600013
         BO    LIAN1                    YES.                            57700013
LIAF1    MVI   0(LR),C' '               NO. FILL TO END WITH BLANKS     57800013
         AR    LR,RG                                                    57900013
         BCT   BR,LIAF1                                                 58000013
LIAND    TM    0(RD),X'10'           +  IS TARGET A VARYING CS.         58100013
         BZ    LIPIC                    NO. CHECK FOR CHAR WITH PICTURE 58200013
LIAN1    SH    BR,MAXL(RC)              -CURL = NO. LEFT-MAXL           58300013
         LPR   BR,BR                    +CURL                           58400013
         STH   BR,CURL(RC)              SET CURRENT LENGTH.             58500013
LIPIC    TM    0(RD),PICT            +  TEST FOR PICTURE.               58600013
         BO    LINXT                    NO. END OF ITEM.                58700013
         L     RA,0(RC)                 ADDR CHAR STRING DIRECTLY.      58800013
         LR    RB,RD                                                    58900013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI988-TSS 58950056
         L     BR,VKCDB              $$ DO PICTURE CHECK IN SITU.       59000013
*        ----------------------------------------------------LDI988-TSS 59050056
         BALR  LR,BR                                                    59100013
         LTR   BR,BR                    WAS ASSIGNMENT VALID..          59200013
         BZ    LINXT                    YES, NO CONFLICT WITH PICTURE.  59300013
         TM    WPFL,BSCN             +  TEST FOR CHAR STRING SOURCE.    59400013
         BNM   LIA22                                              62571 59500072
         BCTR  BR,R0                   * TRANSLATE FROM POS TO OFFSET 1 59508072
         A     BR,WSDS                 * POINT AT INVALID         62571 59516072
         ST    BR,WOCH                 * SOURCE CHARACTER         62571 59524072
         LA    BR,RETRY                * SET RETURN REG FOR RETRY 62571 59532072
         B     LIER2                   * GO RAISE CONVERSION      62571 59540072
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI987-TSS 59550056
LIA22    L     BR,VERRC              $$ 'UNABLE TO ASSIGN TO PIC  62571 59600072
*        ----------------------------------------------------LDI987-TSS 59650056
         BALR  RA,BR                     CHARACTER STRING'.             59700013
         DC    X'0406'                                                  59800013
         EJECT                                                          59900013
*  ROUTINE TO ADDRESS NEXT BYTE.                                        60000013
         SPACE                                                          60100013
LIGET    AR    RF,RG                    NEXT CHARACTER, RETURN UNLESS   60200013
         BCTR  RE,RD                                                    60300013
         TM    RTRY,RTRF             +  TEST FOR RETRY..                60400013
         BO    TDLIM                    YES.                            60500013
         BAL   LR,LIFCB              $  ADDRESS CURRENT FILE FCB.       60600013
         TM    WPFL,LBLK             +  ARE WE HANDLING LEADING BLANKS. 60700013
         BO    LIGIO                    YES,   IGNORE THEM.             60800013
         LA    R0,16                     END OF BUFFER.                 60900013
         AH    R0,WSDS+CURL             ADD LENGTH OF FIELD IN BUFFER.  61000013
         IHEPRV VDA,BR               $$ GET VDA                         61100015
         BALR  LR,BR                                                    61200013
         MVC   8(8,RA),WSDS             MOVE SDV TO VDA.                61300013
         LA    RH,16(RA)                                                61400013
         ST    RH,8(RA)                                                 61500013
         LR    RA,RH                                                    61600013
         LH    RH,IVDA                                                  61700013
         AR    RH,RG                    INCREMENT INVOCATION COUNT      61800013
         STH   RH,IVDA                                                  61900013
         LA    RC,WSDS                  ADDRESS SOURCE SDV.             62000013
         BAL   LR,LIMOV              $  MOVE BUFFER TO VDA.             62100013
         LH    RA,WSDS+CURL                                             62200013
         AH    RA,WOFD+CURL                                             62300013
         STH   RA,WOFD+CURL             LENGTH SO FAR.                  62400013
LIGIO    BAL   LR,LIFCB              $  ADDRESS FCB FOR FILE.           62500013
         LR    RA,RH                    ADDRESS OF FCB.                 62600013
         TM    TTYP,TMST             +  IS THIS STRING I/O..            62700013
         BO    ENDST                    YES,  YOU'VE GONE TOO FAR.      62800013
         SR    RI,RI                    CLEAR BUFFER COUNT.             62900013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI986-TSS 62950056
         L     BR,VIOFA              $$ GET A BUFFER.                   63000013
*        ----------------------------------------------------LDI986-TSS 63050056
         BALR  LR,BR                                                    63100013
         LTR   BR,BR                    TEST RETURN CODE                63200013
         BZ    LIGOK                    NOT END OF FILE RETURN.         63300013
         SPACE                                                          63400013
*  END OF FILE HAS BEEN RAISED.                                         63500013
         SPACE                                                          63600013
         OI    WPFL,EOFF+DDTF        /  SET DDI TERM AND EOF FLAGS.     63700013
         TM    WPFL,DLIM             +  TEST FOR DELIM                  63800013
         BO    LI065                                                    63900013
         BAL   RD,LIVDA              $  FREE ANY VDA'S GOTTEN.          64000013
LIEFF    TM    TTYP,TMST             +  TEST FOR GET STRING.            64100013
         BO    LIEFS                    YES, RETURN NORMALLY.           64200013
         TM    WPFL,NTR3             +  TEST FOR ENTRY C.               64300013
         BZ    LILDI                    NO.                             64400013
         LA    BR,8                     SET RC=8 FOR EOF TOO EARLY      64500015
         B     LIEOF                                                    64600013
*  RETURN TO ERROR RETURN POINT IN CALLER.                              64700013
LILDI    EQU   *                                                        64710015
         TM    WPFL,LBLK             +  SCANNING LEADING BLANKS         64720015
         BZ    LIER3                 ** NO, GO RAISE ERROR              64730015
LIDOF    EQU   *                                                        64740015
         LH    RA,ERRA                  END OF FILE CODE                64750015
         IHEPRV ERR,RA,OP=STH                                           64760015
         L     RA,TDCL                  GET A(DCLCB)                    64770015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI985-TSS 64775056
         L     BR,VERRB                                                 64780015
*        ----------------------------------------------------LDI985-TSS 64785056
         BALR  LR,BR                 $$ RAISE ENDFILE CONDITION         64790015
         IHEPRV CFL,RE,OP=LA                                            64840015
         L     LR,4(RE)                 GET RETURN ADDRESS.             64900013
         L     DR,OFDR(DR)                                              65000013
         B     LIEF2                                                    65100013
         SPACE                                                          65200013
LIGOK    LH    RG,TREM                  LENGTH OF BUFFER.               65300013
LIGST    L     RF,TCBA                  ADDRESS OF BUFFER.              65400013
         TM    TFLX,TMIE             +  HAS A TRANSMIT ERROR OCCURRED.. 65500013
         BZ    LIGNT                    NO.                             65600013
         OI    TFLX,TMIT             /  SET TRANSMIT ERROR FLAG.        65700013
         IHEPRV CFL,BR,OP=LA                                            65730013
         OI    4(BR),TCFL               SET XMIT FLAG                   65760013
LIGNT    STM   RF,RG,WSDS               SET BUFFER DV.                  65800013
         LR    RE,RG                                                    65900013
         LA    RG,1                     INCREMENT                       66000013
         SR    RI,RI                    CLEAR BUFFER COUNT.             66100013
         BR    RD                                                       66200013
         SPACE 3                                                        66210015
*    RAISE ERROR                                                        66220015
         SPACE                                                          66230015
LIER3    EQU   *                                                        66240015
         LA    RA,EROF                  LOAD ERROR CODE                 66250015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI984-TSS 66255056
         L     BR,VERRC                 A( ERROR ROUTINE )              66260015
*        ----------------------------------------------------LDI984-TSS 66265056
         BR    BR                    $$ RAISE ERROR                     66270015
         SPACE                                                          66300013
*  ROUTINE TO MOVE INFORMATION FROM HERE TO THERE.                      66400013
         SPACE                                                          66500013
LIMOV    LA    RB,256                   MOVE LENGTH.                    66600013
         LH    BR,CURL(RC)              LENGTH OF SOURCE.               66700013
         L     RC,0(RC)                 ADDRESS OF SOURCE.              66800013
TESTC    CR    BR,RB                    COMPARE LENGTHS.                66900013
         BNH   MVRST                    SOURCE LESS THAN OR EQUAL 256.  67000013
         MVC   0(256,RA),0(RC)          MOVE 256 BYTES.                 67100013
         AR    RA,RB                    INCREMENT TARGET ADDRESS.       67200013
         AR    RC,RB                    INCREMENT SOURCE ADDRESS.       67300013
         SR    BR,RB                    DECREMENT COUNT.                67400013
         B     TESTC                                                    67500013
MVRST    BCTR  BR,0                                                     67600013
         EX    BR,MOVEC                 MOVE REST TO TARGET.            67700013
         BR    LR                       RETURN.                         67800013
MOVEC    MVC   0(*-*,RA),0(RC)                                          67900013
         SPACE                                                          68000013
*  ROUTINE TO FREE ANY VDA'S GOTTEN.                                    68100013
         SPACE                                                          68200013
LIVDA    LH    RI,IVDA                  VDA INVOCATION COUNT.           68300013
         LTR   RI,RI                                                    68400013
         BCR   8,RD                     BRANCH IF NOT ZERO.             68500013
LIFRE    IHEPRV FVD,BR               $$ FREE VDA                        68600015
         BALR  LR,BR                                                    68700013
         BCT   RI,LIFRE                                                 68800013
         BR    RD                                                       68900013
         SPACE                                                          69000013
*  CONVERSION ERROR.                                                    69100013
         SPACE                                                          69200013
LIERR    ST    RE,WOCH               SET ONCHAR ADDRESS.                69300013
LIER2    IHEPRV ERR,RA,OP=LA                                            69400013
         OI    0(RA),ERCN               SET ERROR CODE FOR CONVERSION.  69500013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI983-TSS 69550056
         L     BR,VERRB              $$ RAISE CONVERSION ERROR.         69600013
*        ----------------------------------------------------LDI983-TSS 69650056
         BR    BR                       REUTRN ADDRESS ALREADY SET.     69700013
         SPACE                                                          69800013
**  RETURN FROM CONVERSION UNIT.                                        69900013
         SPACE                                                          70000013
RETRY    OI    RTRY,RTRF             /  SET RETRY FLAG.                 70100013
         SR    RI,RI                                                    70200013
         STH   RI,WOFD+4                                                70300013
         BAL   LR,LIFCB              $  ADDRESS FCB.                    70400013
         L     RF,WOFD                  ADDRESS OF NEW SOURCE.          70500013
         LH    RE,WOFD+CURL             LENGTH OF NEW SOURCE.           70600013
         LA    RG,1                     INCREMENTER.                    70700013
         B     LI037                    GO AND TRY AGAIN.               70800013
         SPACE                                                          70900013
*  TEST FOR DELIMITER/DDI END-TRANSMISSION CHAR.                        71000013
         SPACE                                                          71100013
LIDLM    OI    TFLX,TMLC                                                71200013
         AR    RI,RG                                                    71300013
         CLI   0(RF),C' '               TEST FOR DELIMITOR.             71400013
         BE    LI060                    YES  IT WAS A BLANK.            71500013
         NI    TFLX,255-TMLC         /  UNSET TMLC.                     71600013
         CLI   0(RF),C','               TEST FOR DELIMITER.             71700013
         BE    LI060                    YES DELIMITER WAS COMMA.        71800013
         BCTR  RI,0                                                     71900013
         TM    WPFL,NTR3             +  IS THIS DATA DIRECTED INPUT..   72000013
         BCR   8,LR                     NO.                             72100013
         AR RI,RG                                                       72200013
         CLI   0(RF),C';'               TEST FOR SEMI-COLON.            72300013
         BE    LI050                    YES DDI TERMINATOR FOUND.       72400013
         BCTR  RI,0                                                     72500013
         BR    LR                                                       72600013
         SPACE 5                                                        72700013
* ROUTINE TO ADDRESS FILE CONTROL BLOCK.                                72800013
         SPACE                                                          72900013
         USING IHEZDCL,RE                                               73000013
LIFCB    IHEPRV CFL,RE                                                  73100013
         LH    RE,DPRO                                                  73200013
         L     RH,0(RE,PR)              ADDRESS OF FCB.                 73300013
         BR    LR                                                       73400013
         SPACE                                                          73500013
ENDST    OI    WPFL,EOFF+DDTF        /  SET DDI TERM AND EOF FLAGS.     73600013
         SR    RI,RI                    CLEAR BUFFER COUNT.             73700013
         STH   RI,TREM                  ENSURE TREM IS ZERO.            73800013
         TM    WPFL,DLIM             +  TEST DELIM FLAG.                73900013
         BO    LI065                    ON  GO TO ASSIGN ITEM.          74000013
         LA    RA,NDST                  'GET/PUT STRING SIZE EXCEEDED'. 74100013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI980-TSS 74150056
         L     BR,VERRC              $$ EXECUTEION ERROR  NO RETURN.    74200013
*        ----------------------------------------------------LDI980-TSS 74250056
         BR    BR                                                       74300013
         SPACE                                                          74400013
*  END OF NEW FIELD TEST IF LOGICAL END OF ITEM.                        74500013
         SPACE                                                          74600013
TDLIM    TM    WPFL,DLIM             +  TEST FOR DELIMITER SEARCH.      74700013
         BNO   SCERR                    NO - ERROR                49771 74800021
*  LOGICAL END OF ITEM REACHED                                    49771 74810021
         NI    WPFL,255-DLIM            TURN OFF DLIM FLAG TO GET 49771 74820021
*                                       CORRECT SOURCE LENGTH.    49771 74830021
*                                       (EOFF IS OFF ON RETRY)    49771 74840021
         B     LIASS                                              49771 74850021
*  ERROR IN STRING SCAN                                           49771 74860021
SCERR    EQU   *                                                  49771 74870021
         BCTR  RF,0                                                     74900013
         LR    RE,RF                                                    75000013
         LH    RA,ERIO                  SET ERROR CODE FOR I/O    49771 75030021
         IHEPRV  ERR,RA,OP=STH                                    49771 75060021
         BAL   LR,LIERR              ** NO RAISE ANOTHER CONVERION ERR. 75100013
         B     LIASS                                                    75200013
         SPACE                                                          75300013
*              CONSTANTS                                                75400013
         SPACE                                                          75500013
K003     DC    H'3'                                                     75600013
NDST     DC    H'2'                     GET/PUT STRING SIZE EXCEEDED.   75700013
ERIO     DC    X'8000'                  ERROR CODE FOR I/O.             75800013
TRER     DC    X'9802'                                                  75900013
VDED     DC    X'14'                                                    76000013
FDDD     DC    X'C80180'                F-INPUT DED.                    76100013
BCDD     DC    X'7D'                                                    76200013
ZERO     DC    C'0'                                                     76300013
ERRA     DC    AL2(ERR1)                END OF FILR                     76330015
EROF     DC    AL2(ERR2)                ENDFILE RAISED UNEXPECTEDLY     76360015
         SPACE                                                          76370016
MVCAD    MVC   0(0,RC),0(RA)            ASSIGN TO UNALIGNED DATA        76380016
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDI982-TSS 76390056
SEDD     DC    2A(ZERO)                                                 76400013
VUPAB    DC    V(IHEUPAB)                                               76500013
VUPBB    DC    V(IHEUPBB)                                               76600013
VVCAA    DC    V(IHEVCAA)                                               76700013
VDCNB    DC    V(IHEDCNB)                                               77000013
VVSCA    DC    V(IHEVSCA)                                               77100013
VVSDB    DC    V(IHEVSDB)                                               77200013
VDNCA    DC    V(IHEDNCA)                                               77300013
VDNBA    DC    V(IHEDNBA)                                               77400013
VIOFA    DC    V(IHEIOFA)                                               77500013
VVCSA    DC    V(IHEVCSA)                                               77600013
VDMAA    DC    V(IHEDMAA)                                               77700013
VERRB    DC    V(IHEERRB)                                               77800013
VKCDB    DC    V(IHEKCDB)                                               78000013
VERRC    DC    V(IHEERRC)                                               78100013
*        ----------------------------------------------------LDI982-TSS 78150056
         END                                                            78200013
