LDO      TITLE '   IHELDO    LIST DIRECTED OUTPUT                      /00200013
               OS/360 PL/I LIBRARY'                                     00400013
*   VERSION    THIRD  VERSION OF F-LEVEL PL/1 COMPILER                  00600013
*                                                                       00800013
*   STATUS     CHANGE LEVEL - 0                                         01000013
*                                                                       01020056
*C660000                                                      SRC 47663 01040056
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDO000-TSS 01060001
*        ----------------------------------------------------LDO000-TSS 01120001
*                                                                       01200013
*   SIZE       568 BYTES.                                               01400013
*                                                                       01600013
*   FUNCTION                                                            01800013
*              TO OUTPUT DATA UNDER THE RULES FOR LIST DIRECTED         02000013
*              OUTPUT.                                                  02200013
*              IF THE SPECIFIED FILE IS A 'PRINT' FILE THE DATA IS      02400013
*              TABBED AND SPANNING OF LINES IS AVOIDED, IF POSSIBLE,    02600013
*              FOR ARITHMETIC DATA.                                     02800013
*                                                                       03000013
*   ENTRY POINTS                                                        03200013
*              IHELDOA - OUTPUT DATA SPECIFIED BY LIST.                 03400013
*                  RA = A(P.LIST)                                       03600013
*                  P.LIST = A(VARIABLE)                                 03800013
*                           A(DED)                                      04000013
*                             ...                                       04200013
*                             ...                                       04400013
*              IHELDOB - OUTPUT SINGLE VARIABLE.                        04600013
*                  RA = A(VARIABLE)                                     04800013
*                  RB = A(DED)                                          05000013
*              IHELDOC - OUTPUT DATA ITEM FOR DATA DIRECTED.            05200013
*                  RA = A(VARIABLE)                                     05400013
*                  RB = A(DED)                                          05600013
*                  RC = A(FCB)                                          05800013
*                  RD = A(BCD FOR NAME)                                 06000013
*                  RE = A(SDV FOR SUBSCRIPTS) - NULL STRING IF NONE.    06200013
*                                                                       06400013
*   INPUT                                                               06600013
*              ENTRY POINTS IHELDOA,IHELDOB ONLY                        06800013
*                CURRENT FILE PSEUDO-REGISTER(IHEQCFL)                  07000013
*                                                                       07200013
*   OUTPUT                                                              07400013
*              SEE FUNCTION.                                            07600013
*                                                                       07800013
*   EXTERNAL MODULES                                                    08000013
*              IHEERRC - EXECUTION ERROR PACKAGE.                       08200013
*              IHEIOFA - ACCESS NEXT RECORD.                            08400013
*              IHEVSBA - BIT TO CHARACTER CONVERSION.                   08600013
*              IHEVSCA - CHARACTER TO CHARACTER ASSIGNMENT.             08800013
*              IHEDNCA - ARITHMETIC TO CHARACTER CONVERSION.            09000013
*                                                                       09200013
*   EXITS                                                               09400013
*   EXITS      NORMAL                                                   09600013
*                  RETURN VIA LINK REGISTER.                            09800013
*              ERROR                                                    10000013
*                  IHE012 GET/PUT STRING SIZE EXCEEDED                  10200013
*                                                AN ATTEMPT WAS MADE    10400013
*                            TO GO PAST THE END OF THE STRING.          10600013
*                                                                       10800013
*   TABLES/WORK AREA                                                    11000013
*                                                                       11200013
*   ATTRIBUTES  READ ONLY AND REENTRANT                                 11400013
*                                                                       11600013
*   PRIVATE MACROS                                                      11800013
*              IHELIB,IHEPRV,IHESDR,IHEZAP                              12000013
*                                                                       12200013
*   ASSEMBLY REQUIREMENTS                                               12400013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   12600013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        12800013
*                                                                       13000013
*   NOTES                                                               13200013
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    13400013
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    13600013
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  13800013
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  14000013
*              CONSTANTS, BY REASSEMBLY, WILL RESULT IN A CORRECT       14200013
*              MODULE FOR THE NEW DEFINITIONS.                          14400013
        EJECT                                                           14600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDO001-TSS 14700001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   14800013
         PUNCH     ' LIBRARY *(IHEDNCA,IHEVSBA,IHEVSCA)                /15000013
                                    LDO0000A'                           15200013
*        ----------------------------------------------------LDO001-TSS 15300001
         SPACE                                                          15400013
IHELDO   CSECT                                                          15600013
         IHELIB                                                         15800013
         IHEZAP                                                         16000013
IHEZLW3  DSECT                                                          16200013
         DS    18F                      SAVE AREA.                      16400013
WPFL     DS    0A                                                       16600013
WPRA     DS    A                                                        16800013
LSD1     DS    2A                       SOURCE SDV.                     17000013
LSD2     DS    2A                       TARGET SDV.                     17200013
WDNM     DS    A                        )-1 MUST BE TOGETHER IH THIS    17400013
WDSD     DS    A                        )-2  ORDER                      17600013
CSDV     DS    2A                                                       17800013
LSDV     DS    2A                                                       18000013
WSAV     DS    A                                                        18200013
TEMP     DS    2D                       SPACE FOR UNALIGNED SOURCE      18300016
CHAR     EQU   WFCS                     AREA FOR A TO C TARGET.         18400013
PWR      EQU   WR                                                       18600013
STRG     EQU   B'10000000'                                              18800013
BITS     EQU   B'00000100'                                              19000013
PRNT     EQU   B'00000001'              PRINT FILE FLAG.                19200013
CURL     EQU   6                                                        19400013
MAXL     EQU   4                                                        19600013
         EJECT                                                          19800013
IHELDO   CSECT                                                          20000013
         ENTRY IHELDOA,IHELDOB,IHELDOC                                  20200013
IHELDOA  NOPR  0                     .  NORMAL ENTRY.                   20400013
IHELDOB  NOP   0                                                        20600013
IHELDOC  STM   LR,PWR,OFLR(DR)                                          20800013
         BALR  PWR-1,0                                                  21000013
         USING *,PWR-1                                                  21200013
         USING IHEZLW3,DR                                               21400013
         USING IHEZLCA,PWR                                              21600013
         USING IHEZDCL,RF                                               21800013
         IHESDR LW3                     SET DR TO WORKAREA 3.           22000013
         IHEPRV LCA,PWR                 SET PWR TO LCA.                 22200013
       LR      RF,RC                                                    22400013
LO010    ST    RA,WPRA                                                  22600013
         STC   BR,WPFL                SAVE ENTRY POINT FLAG.            22800013
         STM   RD,RE,WDNM                                               23000013
         TM    WPFL,X'06'            +  TEST FOR DATA DIRECTED.         23200013
         BO    LODDO                    YES, RF POINTS TO FCB.          23400013
         IHEPRV CFL,RF                  ADDRESS DCLCB FOR CURRENT FILE. 23600013
         LH    RF,DPRO                                                  23800013
         L     RF,0(RF,PR)              ADDRESS FCB.                    24000013
         USING IHEZAPE,RF                                               24200013
         BM    LO020                    ENTRY POINT LDOB.               24400013
LO019    LM    RA,RB,0(RA)              ADDRESS OF SOURCE AND DED.      24600013
LO020    TM    TTYP,TMST             +  TEST FOR STRING PUT.            24800013
         BO    LO030                    YES.                            25000013
         TM    TFRC,TMAS             +  TEST FOR PRINT FILE.            25200013
         BZ    LO030                    NO.                             25400013
         OI    WPFL,PRNT             /  SET PRINT FILE FLAG.            25600013
         LR    RC,RA                    SAVE REGISTER AROUND CALL.      25800013
         LR    RA,RF                    ADDRESS OF FCB.                 26000013
         LA    BR,IHELDOT               TEMP  CHANGE TO L VADCON******  26200013
         BALR  LR,BR                                                    26400013
         LR    RA,RC                    RESTORE REGISTER.               26600013
LO030    TM    0(RB),STRG            +  IS SOURCE A STRING..            26800013
         BZ    LP000                    YES.                            27000013
         LA    RD,VDED                  ADRESS TARGET DED FOR VAR CHAR. 27200013
         LA    RC,CSDV                  ADDRESS CHAR STRING FOR RESULT. 27400013
         SR    RE,RE                                                    27600013
         TM    0(RB),X'08'           +  TEST FOR NUMERIC FIELD          27800013
         BZ    LONFD                    YES                             28000013
         LA    RE,CHAR                                                  28200013
         ST    RE,CSDV                                                  28400013
         LA    RE,150                                                   28600013
         STH   RE,CSDV+MAXL                                             28800013
         TM    0(RB),X'88'           +  CAD..                           28810016
         BNO   LO034                    NO                              28820016
         TM    0(RB),X'06'           +  DECIMAL..                       28830016
         BZ    LO034                    YES                             28840016
         TM    0(RB),X'11'           +  FLOAT LONG AND/OR COMPLEX..     28850016
         BZ    LO033                    NEITHER - MOVE 4 BYTES          28860016
         BM    LO032                    JUST ONE - MOVE 8 BYTES         28870016
         MVC   TEMP+8(8),8(RA)          IMAG PART OF LONG COMPLEX       28880016
LO032    MVC   TEMP+4(4),4(RA)          2ND 4 BYTES                     28890016
LO033    MVC   TEMP(4),0(RA)            1ST 4 BYTES                     28900016
         LA    RA,TEMP                  TRANSFER OUR ATTENTIONS         28910016
LO034    EQU   *                                                        28920016
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDO999-TSS 28960020
         L     BR,VDNCA              $$ ARITHMETIC TO CHARACTER STRING. 29000013
*        ----------------------------------------------------LDO999-TSS 29100020
         BALR  LR,BR                                                    29200013
LO035    EQU   *                                                        29400013
         LR    RB,RD                                                    29600013
         TM    WPFL,PRNT             +  TEST FOR PRINT FILE.            29800013
         BZ    LS010                    NO.                             30000013
         LH    RI,CSDV+CURL             LENGTH OF VARIABLE.             30200013
         TM    WPFL,X'04'            +  TEST FOR DATA DIRECTED.         30400013
         BZ    LO040                    NO.                             30600013
         LH    BR,LSDV+CURL             GET LENGTH OF NAME.             30800013
         L     LR,WDSD                  SDV OF SUBCRIPT STRING.         31000013
         AH    RI,CURL(LR)              ADD IN LENGTH OF SUBSCRIPTS.    31200013
         LA    RI,1(BR,RI)              ADD L'NAME AND ALLOW FOR =.     31400013
LO040    EQU   *                                                        31600013
         MVC   WSAV(4),WONC             SAVE INFO AT WONK               31800013
         CH    RI,TREM                  IS THERE ROOM IN CURRENT BUFFER 32000013
         BL    LS010                    YES, EVERYTHING HUNKY DORY.     32200013
LO050    CLC   TREM,TLNZ                IS CURRENT BUFFER A NEW ONE..   32400013
****                        (NOTE- WE HAVE NOT ACCOUNTED FOR MARGINS.)  32600013
         BE    LS010                    YES, ITEM WILL SPAN ANYWAY.     32800013
LO070    LR    RA,RF                                                    33000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDO998-TSS 33100020
         L     BR,VIOFA              $$ GET A NEW BUFFER.               33200013
*        ----------------------------------------------------LDO998-TSS 33300020
         BALR  LR,BR                                                    33400013
         LR    RA,RF                                                    33600013
         LA    BR,IHELDOT                                               33800013
         BALR  LR,BR                 $$ ALLIGN ON TAB BOUNDARY AND GO   34000013
         MVC   WONC(4),WSAV             RESTORE WONC                    34200013
         B     LO040                     TO CHECK FOR ROOM.             34400013
LS010    TM    WPFL,X'04'            +  TEST FOR DATA DIRECTED.         34600013
         BZ    LS020                    NO.                             34800013
         LA    RA,LSDV                                                  35000013
         BAL   RI,LSPTC              $  OUTPUT NAME.                    35200013
         L     RA,WDSD                  ADDRESS SUBSCRIPTS SDV.         35400013
         BAL   RI,LSPUT              $  OUTPUT SUBSCRIPTS.              35600013
         LA    RG,C'='                                                  35800013
         BAL   RH,LSTRC              $  OUTPUT EQUATE SIGN.             36000013
         SPACE                                                          36200013
LS020    TM    0(RB),BITS               IS SOURCE A BIT STRING          36400013
         BZ    LB000                    YES.                            36600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDO997-TSS 36700020
         L     RH,VVSCA                 CHAR TO CHAR ASSIGNMENT.        36800013
*        ----------------------------------------------------LDO997-TSS 36900020
         BAL   RG,LS030                 RG IS NEGATIVE FOR CHAR SOURCE. 37000013
         SPACE                                                          37200013
LS030    LA    RA,CSDV                  ADDRESS VALUE SDV               37400013
         BAL   RI,LSPUT                 OUTPUT VALUE                    37600013
         LTR   RG,RG                    TEST FOR CHAR OR BIT SOURCE.    37800013
         BP    LB020                    BIT.                            38000013
LS060    LA    RG,C' '                  PUT A BLANK ON OUTPUT.          38200013
         BAL   RH,LSTRC              $  OUTPUT CHARACTER.               38400013
         L     RB,TCNT                                                  38600013
         LA    RB,1(RB)                 INCREMENT DATA ITEM COUNT.      38800013
         ST    RB,TCNT                                                  39000013
         TM    WPFL,X'06'            +  IS IT STANDARD ENTRY POINT..    39200013
         BNE   LOEXT                    NO.                             39400013
         L     RA,WPRA                                                  39600013
         TM    4(RA),X'80'                                              39800013
         BO    LOEXT                                                    40000013
         LA    RA,8(RA)                                                 40200013
         ST    RA,WPRA                                                  40400013
         B     LO019                                                    40600013
LONFD    EQU   *                                                        40800013
         IC    RE,3(RB)                 GET LENGTH OF REAL PIC          41000013
         ST    RA,CSDV                                                  41200013
         TM    0(RB),X'01'              TEST FOR COMPLEX                41400013
         BZ    LONF1                    NO                              41600013
         AR    RE,RE                    DOUBLE LENGTH                   41800013
LONF1    EQU   *                                                        42000013
         STH   RE,CSDV+CURL             STORE LENGTH OF NUMERIC FIELD   42200013
         B     LO035                                                    42400013
         SPACE                                                          42600013
LP000    MVC   CSDV(8),0(RA)                                            42800013
         TM    0(RB),BITS               IS SOURCE A BIT STRING          43000013
         BZ    LS010                    YES.                            43200013
         TM    WPFL,X'04'            +  TEST FOR DDO MODE.              43400013
         BO    LP010                    YES.                            43600013
         TM    WPFL,PRNT             +  TEST FOR PRINT FILE.            43800013
         BO    LS010                    YES.                            44000013
         B     LP015                                                    44200013
LP010    LA    RA,LSDV                                                  44400013
         BAL   RI,LSPTC              $  OUTPUT NAME.                    44600013
         L     RA,WDSD                                                  44800013
         BAL   RI,LSPUT              $  OUTPUT SUBSCRIPTS IF ANY.       45000013
         LA    RG,C'='                                                  45200013
         BAL   RH,LSTRC              $  OUTPUT EQUATE SIGN.             45400013
LP015    LA    RG,C''''                                                 45600013
         BAL   RH,LSTRC              $  OUTPUT LEADING QUOTE.           45800013
         L     RI,CSDV                  ADDRESS SOURCE.                 46000013
         LH    RH,CSDV+CURL             LENGTH OF SOURCE.               46200013
         LA    RH,1(RH)                 ADD 1 FOR COUNT ALGORITHM.      46400013
LP020    ST    RI,LSDV                  SET START ADDRESS.              46600013
         SR    RC,RC                    INITIALIZE MOVE LENGTH.         46800013
LP030    BCT   RH,LP040                 COUNT ON SOURCE.                47000013
         LA    RE,LS060                 END OF SOURCE-SET RETURN ADDR.  47200013
         SPACE                                                          47400013
LP100    STM   RH,RI,WSDV                                               47600013
         STH   RC,LSDV+CURL             SET CURRENT LENGTH.             47800013
         LA    RA,LSDV                                                  48000013
         BAL   RI,LSPTC              $  PUT THIS BIT OF STRING.         48200013
         LA    RG,C''''                                                 48400013
         BAL   RH,LSTRC              $  PUT SECOND/TERMINAL QUOTE.      48600013
         LM    RH,RI,WSDV                                               48800013
         BR    RE                                                       49000013
         SPACE                                                          49200013
LP040    LA    RC,1(RC)                                                 49400013
         CLI   0(RI),C''''              IS CHARACTER A QUOTE MARK..     49600013
         LA    RI,1(RI)                 (NEXT CHARACTER).               49800013
         BNE   LP030                    NO, GO TO TEST FOR MORE.        50000013
         BAL   RE,LP100                 YES, PUT STRING SO FAR ADDING   50200013
         B     LP020                     SECOND QUOTE THEN CONTINUE.    50400013
         SPACE                                                          50600013
LB000    LA    RG,C''''                 QUOTE - RG POSITIVE FOR BIT.    50800013
         BAL   RH,LSTRC                                                 51000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDO996-TSS 51100020
         L     RH,VVSBA                 BIT TO CHAR ASSIGNMENT.         51200013
*        ----------------------------------------------------LDO996-TSS 51300020
         B     LS030                                                    51400013
         SPACE                                                          51600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDO995-TSS 51700020
LSPTC    L     RH,VVSCA              .  SET UP FOR CHAR STRING MOVE.    51800013
*        ----------------------------------------------------LDO995-TSS 51900020
         BAL   RG,LSPUT                                                 52000013
LSPUT    MVC   LSD1(8),0(RA)         .  SET SOURCE SDV.                 52200013
         LH    BR,LSD1+CURL          L'CHAR STRING TO BE MOVED.         52400013
         LTR   BR,BR                                                    52600013
         BCR   8,RI                     NO CHARACTERS RETURN.           52800013
         LH    RA,TREM                                                  53000013
         LTR   RA,RA                                                    53200013
         BNE   LS035                                                    53400013
LS032    LR    RA,RF                    ADDRESS OF FCB.                 53600013
         TM    TTYP,TMST             +  IS THIS STRING I/O..            53800013
         BO    ENDST                    YES,  YOU'VE GONE TOO FAR.      54000013
         MVC   WSAV(4),WONC             SAVE INFO AT WONC               54200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDO994-TSS 54300020
         L     BR,VIOFA              $$ PUT LAST BUFFER.                54400013
*        ----------------------------------------------------LDO994-TSS 54500020
         BALR  LR,BR                                                    54600013
         MVC   WONC(4),WSAV             RESTORE WONC                    54800013
LS035    MVC   LSD2(6),TCBA                                             55000013
         LA    RC,LSD2                  TARGET SDV.                     55200013
         LA    RD,VDED                  TARGET DED FOR VAR CHAR STRING. 55400013
         LA    RA,LSD1                  SOURCE SDV.                     55600013
         LR    BR,RH                 $$ CHAR TO CHAR OR BIT TO CHAR.    55800013
         BALR  LR,BR                                                    56000013
         LH    R1,LSD1+CURL                                             56200013
         SH    R1,LSD2+CURL                                             56400013
         BNH   LS050                    END OF SOURCE.                  56600013
         STH   R1,LSD1+CURL             LENGTH OF SOURCE LEFT.          56800013
         L     R1,TCBA                                                  57000013
         AH    R1,TREM                                                  57200013
         ST    R1,TCBA                  SET BUFFER ADDRESS AND          57400013
         SR    R1,R1                     COUNT TO INDICATE FULL         57600013
         STH   R1,TREM                   BUFFER.                        57800013
         L     R1,LSD1                                                  58000013
         LTR   RG,RG                    TEST FOR CHAR OR BIT SOURCE.    58200013
         BP    LB010                    BIT.                            58400013
         AH    R1,LSD2+CURL                                             58600013
LS040    ST    R1,LSD1                  UPDATE SOURCE ADDRESS.          58800013
         B     LS032                    GO TO MOVE SOME MORE.           59000013
         SPACE                                                          59200013
LS050    L     RD,LSD2                  END OF SOURCE - SET             59400013
         AH    RD,LSD2+CURL              BUFFER ADDRESS TO NEXT FREE    59600013
         ST    RD,TCBA                   BYTE AND SET NUMBER OF         59800013
         LH    RD,LSD2+MAXL              BYTES LEFT.                    60000013
         SH    RD,LSD2+CURL                                             60200013
         STH   RD,TREM                                                  60400013
         BR    RI                    RETURN.                            60600013
         SPACE                                                          60800013
LB010    LR    R0,R1                    UPDATE BIT ADDRESS.             61000013
         SLDL  R0,3                                                     61200013
         AH    R0,LSD2+CURL                                             61400013
         LR    R1,R0                                                    61600013
         SRDL  R0,3                                                     61800013
         B     LS040                                                    62000013
         SPACE                                                          62200013
LB020    LA    RG,C''''                 PUT A QUOTE ON OUTPUT.          62400013
         BAL   RH,LSTRC              $  OUTPUT CHARACTER.               62600013
         LA    RG,C'B'                  PUT THE LETTER B ON OUTPUT.     62800013
         BAL   RH,LSTRC              $  OUTPUT CHARACTER.               63000013
         B     LS060                                                    63200013
         SPACE                                                          63400013
LOEXT    L     DR,OFDR(DR)                                              63600013
         LM    LR,PWR,OFLR(DR)                                          63800013
         BR    LR                    X  THAT'S ALL - RETURN TO CALLER.  64000013
         SPACE                                                          64200013
LSTRC    LH    RD,TREM                  NUMBER OF BYTES REMAINING.      64400013
         LTR   RD,RD                    TEST FOR ZERO.                  64600013
         BNE   LSTR1                    NO.                             64800013
         TM    TTYP,TMST             +  IS THIS STRING I/O..            65000013
         BO    ENDST                    YES,  YOU'VE GONE TOO FAR.      65200013
         LR    RA,RF                    ADDRESS OF FCB.                 65400013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDO993-TSS 65500020
         L     BR,VIOFA              $$ YES OUTPUT LAST BUFFER AND      65600013
*        ----------------------------------------------------LDO993-TSS 65700020
         BALR  LR,BR                     GET ANOTHER.                   65800013
         B     LSTRC                                              47663 66000056
LSTR1    L     BR,TCBA                  ADDRESS OF NEXT FREE BYTE.      66200013
         STC   RG,0(BR)                 MOVE IN CHARACTER.              66400013
         LA    BR,1(BR)                                                 66600013
         ST    BR,TCBA                  ADDRESS NEXT BYTE.              66800013
         BCTR  RD,0                                                     67000013
         STH   RD,TREM                  DECREMENT COUNT REMAINING.      67200013
         BR    RH                       RETURN.                         67400013
         SPACE                                                          67600013
LODDO    SR    BR,BR                    LET US CREATE SDV FOR DDO NAME. 67800013
         L     LR,WDNM                  PICK UP NAME FIELD.             68000013
         IC    BR,0(LR)                 LENGTH OF NAME.                 68200013
         LA    LR,1(LR)                 BUMP TO NAME.                   68400013
         STM   LR,BR,LSDV               CREATE SDV.                     68600013
         B     LO020                    NOW CONTINUE AS NORMAL          68800013
         SPACE                                                          69000013
ENDST    LA    RA,NDST                  GET/PUT STRING SIZE EXCEEDED.   69200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDO992-TSS 69300020
         L     BR,VERRC              $$ EXECUTEION ERROR  NO RETURN.    69400013
*        ----------------------------------------------------LDO992-TSS 69500020
         BR    BR                                                       69600013
         SPACE                                                          69800013
         DROP  RF                                                       70000013
         EJECT                                                          70200013
*  ROUTINE TO POSITION TO NEXT FREE TAB.                                70400013
*              CALL SEQUENCE.                                           70600013
*                RA - A(FCB)                                            70800013
         SPACE 3                                                        71000013
IHELDOT  STM   LR,PWR,OFLR(DR)          SAVE CALLER'S REGISTERS.        71200013
         USING IHELDOT,PWR                                              71400013
         USING IHEZAPE,RA                                               71600013
         LR    PWR,BR                                                   71800013
         IHESDR LW2,RC                  SET UP SAVE AREA.               72000013
         TM    TFLF,TMTB             +  TEST FOR TAB TABLE              72200013
         BZ    LDOTR                    NONE.                           72400013
LDOT0    L     RC,TTAB                  ADDRESS TAB CONTROL TABLE       72600013
         LA    RC,4(RC)                 SKIP OVER PAGE AND LINE SIZE.   72700001
         LH    RH,TREM                                                  72800013
         LH    RD,TLNZ                  COMPUTE BYTE OFFSET OF          73000013
         SR    RD,RH                      FIRST FREE BYTE.              73200013
         BZ    LDOTR                    THIS A CLEAN RECORD.            73400013
****                        (NOTE- WE HAVE NOT ACCOUNTED FOR MARGINS.)  73600013
         SR    RF,RF                                                    73800013
         IC    RF,2(RC)                 NUMBER OF TAB POSITIONS.        74000013
         SR    RG,RG                                                    74200013
LDOT1    IC    RG,3(RC)                 GET A TAB VALUE.                74400013
         CLR   RD,RG                    IS IT GTR THAN BYTE OFFSET..    74600013
         BL    LDOT2                    YES  THEN USE IT.               74800013
         LA    RC,1(RC)                NEXT TAB .                       75000013
         BCT   RF,LDOT1                 LOOP UNTIL TABS EXHAUSTED.      75200013
LDOT4    EQU   *                                                        75400013
LDOT6    LR    RH,RA                                                    75600013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDO991-TSS 75700020
         L     BR,VIOFA                 NO MORE TABS.                   75800013
*        ----------------------------------------------------LDO991-TSS 75900020
         BALR  LR,BR                 $$ SKIP TO NEXT RECORD.            76000013
         LR    RA,RH                                                    76200013
         B     LDOT0                                                    76400013
LDOT2    BCTR  RG,0                     CONV TAB POS TO BYTE OFFSET.    76600013
         SR    RG,RD                    NUMBER OF SPACES.               76800013
         BZ    LDOTR                    IF 0 ALREADY AT TAB.            77000013
         L     RC,TCBA                  ORIGINAL FREE POSITION.         77200013
         CR    RH,RG                     IS TAB POS WITHIN RECORD..     77400013
         BNH   LDOT4                    TAB IS BEYOND RECORD GET NEXT   77600013
         SR    RH,RG                    NEW REMAINDER.                  77800013
         STH   RH,TREM                                                  78000013
         AR    RC,RG                    NEW FREE POSITION.              78200013
         ST    RC,TCBA                                                  78400013
LDOT3    BCTR RC,0                      BLANK OUT POSITIONS SKIPPED.    78600013
         MVI   0(RC),C' '                                               78800013
         BCT   RG,LDOT3                                                 79000013
LDOTR    L     DR,OFDR(DR)              RESTORE CALLER'S DR.            79200013
         LM    LR,PWR,OFLR(DR)          RESTORE OTHER REGISTERS.        79400013
         BR    LR                                                       79600013
         EJECT                                                          79800013
VDED     DC    B'00011100'                                              80000013
NDST     DC    H'2'                     GET/PUT STRING SIZE EXCEEDED.   80200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LDO990-TSS 80300020
VERRC    DC    V(IHEERRC)                                               80400013
VIOFA    DC    V(IHEIOFA)                                               80600013
VVSBA    DC    V(IHEVSBA)                                               80800013
VVSCA    DC    V(IHEVSCA)                                               81000013
VDNCA    DC    V(IHEDNCA)                                               81200013
*        ----------------------------------------------------LDO990-TSS 81300020
         END                                                            81400013
