MZV      TITLE '   IHEMZV    COMPLEX DECIMAL FIXED MULT. AND DIVISION  *00020000
               OS/360 PL/I LIBRARY'                                     00040000
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  00060000
*                                                                       00080000
*   STATUS     CHANGE LEVEL - 0.                                        00100000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*MZV000-TSS 00106001
*        ----------------------------------------------------MZV000-TSS 00112001
*                                                                       00120000
*   SIZE       672 BYTES                                                00140000
*                                                                       00160000
*   FUNCTION   Z1*Z2, Z1/Z2 WHERE Z1 AND Z2 ARE FIXED DECIMAL COMPLEX.  00180000
*              LET Z1 = A+BI AND Z2 = C+DI, WITH PRECISIONS (P,Q) AND   00200000
*              (R,S) RESPECTIVELY. THEN THE RESULTS ARE OBTAINED AS     00220000
*              FOLLOWS-                                                 00240000
*                              REAL PART          IMAGINARY PART        00260000
*              MULTIPLICATION  A*C-B*D             B*C+A*D              00280000
*              DIVISION       (A*C+B*D)/(C*C+D*D) (B*C-A*D)/(C*C+D*D)   00300000
*              FOR DIVISION, IF THE DENOMINATOR HAS 15 SIGNIFICANT      00320000
*              DIGITS OR LESS, IT IS RIGHT-JUSTIFIED IN AN 8-BYTE FIELD 00340000
*              AND THE NUMERATORS ARE RIGHT-JUSTIFIED IN 16-BYTE FIELDS 00360000
*              IF THE DENOMINATOR HAS MORE THAN 15 SIGNIFICANT DIGITS   00380000
*              IT IS TRUNCATED ON THE RIGHT (D LOW ORDER DIGITS LOST).  00400000
*              TO LEAVE 15 SIGNIFICANT DIGITS. TO OBTAIN THE REQUIRED   00420000
*              SCALE FACTOR ON DIVISION (15-P+Q-S), THE NUMERATORS ARE  00440000
*              SHIFTED LEFT (15-P-D) DIGITS. IF (15-P-D) IS NEGATIVE    00460000
*              THEN THE SHIFT IS TO THE RIGHT. THE DIVISIONS ARE THEN   00480000
*              PERFORMED. THE REAL AND IMAGINARY PARTS OF THE RESULT    00500000
*              ARE EACH 8 BYTES LONG (15 DIGITS AND A SIGN).            00520000
*                                                                       00540000
*   ENTRY POINTS                                                        00560000
*              IHEMZVM - Z1*Z2                                          00580000
*                  RA = A(Z1)                                           00600000
*                  RB = A(DED FOR Z1)                                   00620000
*                  RC = A(Z2)                                           00640000
*                  RD = A(DED FOR Z2)                                   00660000
*                  RE = A(TARGET)                                       00680000
*                  RF = A(DED FOR TARGET)                               00700000
*              IHEMZVD - Z1/Z2                                          00720000
*                  LINKAGE AS FOR IHEMZVM                               00740000
*                                                                       00760000
*   INPUT      N/A                                                      00780000
*                                                                       00800000
*   OUTPUT     N/A                                                      00820000
*                                                                       00840000
*   EXTERNAL MODULES                                                    00860000
*              N/A                                                      00880000
*                                                                       00900000
*   EXITS      NORMAL                                                   00920000
*               RETURN TO CALLER VIA LINK REGISTER.                     00940000
*                                                                       00960000
*   TABLES/WORK-AREA                                                    00980000
*              WORK-AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS).        01000000
*                                                                       01020000
*   ATTRIBUTES  READ-ONLY AND REENTRANT.                                01040000
*                                                                       01060000
*   PRIVATE MACROS                                                      01080000
*              IHELIB,IHESDR                                            01100000
*                                                                       01120000
*   ASSEMBLY REQUIREMENTS                                               01140000
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   01160000
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        01180000
*                                                                       01200000
*   NOTES      SEE OS/360 PL/I LIBRARY PLM FOR LIBRARY CONVENTIONS AND  01220000
*              STANDARDS.                                               01240000
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON        01260000
*              A PARTICULAR INTERNAL REPRESENTATION OF THE              01280000
*              EXTERNAL CHARACTER SET.                                  01300000
         EJECT                                                          01320000
IHEMZV   CSECT                                                          01340000
 SPACE 2                                                                01360000
         IHELIB                                                         01380000
*                  PRIVATE REGISTER ASSIGNMENTS                         01400000
         SPACE                                                          01420000
*                                       MAIN USE.                       01440000
         SPACE                                                          01460000
ADA      EQU   RA                  ADDR OF REAL PART OF 1ST ARGUMENT.   01480000
ADB      EQU   RI                          IMAG         1ST             01500000
ADC      EQU   RC                          REAL         2ND             01520000
ADD      EQU   RF                          IMAG         2ND             01540000
DDD      EQU   RB                                                       01560000
DVM      EQU   RG                  DIVIDE OR MULTIPLY SWITCH.           01580000
LC1      EQU   RB                  LENGTH CODE FOR ONE PART OF 1ST ARG. 01600000
LC2      EQU   RH                                              2ND ARG  01620000
LCD      EQU   RG                  L.C. INTERMEDIATE RESULT DENOMINATOR 01640000
LCN      EQU   RF                                           NUMERATOR.  01660000
LCS      EQU   RD                  L.C. USED IN EX-ING DEC INSTRUCTIONS 01680000
LCT      EQU   RJ                  LENGTH CODE FOR RESULT.              01700000
PFA      EQU   RE                                                       01720000
PTD      EQU   RC                  POINTER TO 1ST BYTE OF     DENOMNTR. 01740000
PTI      EQU   RJ                     ..                 IMAG NUMERATOR 01760000
PTR      EQU   RI                     ..                 REAL NUMERATOR 01780000
PTX      EQU   RH                                                       01800000
SNM      EQU   RE                                                       01820000
TGT      EQU   RE                  TARGET ADDRESS.                      01840000
*              R0                  USED EXPLICITLY.                     01860000
         SPACE 1                                                   COPY 01880000
*                  PRIVATE OFFSETS                                      01900000
         SPACE                                                          01920000
OPTG     EQU   72                                                       01940000
OPAC     EQU   OPTG+4                                                   01960000
OPBC     EQU   OPAC+16                                                  01980000
OPBD     EQU   OPBC+16                                                  02000000
OPAD     EQU   OPBD+16                                                  02020000
OPCC     EQU   OPAC                                                     02040000
OPDD     EQU   OPAD                                                     02060000
         EJECT                                                          02080000
IHEMZV   CSECT                                                          02100000
 SPACE                                                                  02120000
         ENTRY IHEMZVM,IHEMZVD                                          02140000
         SPACE 2                                                        02160000
*                                  ***********************************  02180000
*                                  * ENTRY POINT FOR MULTIPLICATION. *  02200000
*                                  ***********************************  02220000
         SPACE                                                          02240000
         USING *,BR                                                     02260000
IHEMZVM  STM   LR,WR,OFLR(DR)                                           02280000
         LA    DVM,MULTI           SET SWITCH TO INDICATE MULTIPLY.     02300000
         BAL   BR,COMMN                                                 02320000
         SPACE 3                                                        02340000
*                                  ***********************************  02360000
*                                  *    ENTRY POINT FOR DIVISION.    *  02380000
*                                  ***********************************  02400000
         SPACE                                                          02420000
         USING *,BR                                                     02440000
IHEMZVD  STM   LR,WR,OFLR(DR)      SAVE CALLERS REGISTERS               02460000
         LA    DVM,DIVID           SET SWITCH TO INDICATE DIVIDE.       02480000
         SPACE                                                          02500000
COMMN    IHESDR LW0,WR                                                  02520000
         SPACE                                                          02540000
*   LET 1ST AND 2ND ARGUMENTS BE A+IB AND C+ID RESPECTIVELY, WITH       02560000
*   PRECISIONS (P,Q) AND (R,S).                                         02580000
*   THEN (A+IB)*(C+ID)= A*C-B*D + I(B*C+A*D),                           02600000
*   AND  (A+IB)/(C+ID)= (A*C+B*D)/(C**2+D**2) + I(B*C-A*D)/(C**2+D**2). 02620000
         SPACE                                                          02640000
         ST    TGT,OPTG(WR)        SAVE TARGET ADDRESS                  02660000
         SR    LCT,LCT                                                  02680000
         IC    LCT,1(RB)           CALCULATE LENGTH CODE FOR FIRST      02700000
         LR    LC1,LCT               ARGUMENT.    LC1 = FLOOR(P/2).     02720000
         LCR   PFA,LCT             SAVE P (COMPLEMENTED).               02740000
         SRL   LC1,1                                                    02760000
         SR    LC2,LC2                                                  02780000
         IC    LC2,1(RD)           CALCULATE LENGTH CODE FOR SECOND     02800000
         AR    LCT,LC2               ARGUMENT.    LC2 = FLOOR(R/2)      02820000
         SRL   LC2,1                                                    02840000
         LA    LCT,1(LCT)                                               02860000
         SRL   LCT,1               LCT NOW CONTAINS THE LENGTH CODE     02880000
*                                    FOR THE RESULT OF THE COMPLEX MULT 02900000
*                                    = FLOOR((P+R+1)/2).                02920000
         SPACE                                                          02940000
         LA    ADB,1(ADA,LC1)      CALC ADDRS OF IMAG PARTS OF ARGS.    02960000
         LA    ADD,1(ADC,LC2)                                           02980000
         LA    R0,1(LC1,LC2)                                            03000000
         LR    LCS,R0              SET LENGTH CODES FOR LOADING THE     03020000
         SLL   LCS,4                 MULTIPLICANDS FOR THE CROSS        03040000
         AR    LCS,LC1               PRODUCTS. L1 = 1+LC1+LC2           03060000
*                                              L2 = LC1                 03080000
         EX    LCS,LDMAC           LOAD MULTIPLICANDS.                  03100000
         EX    LCS,LDMBC                                                03120000
         EX    LCS,LDMBD                                                03140000
         EX    LCS,LDMAD                                                03160000
         SR    LCS,LC1             SET LENGTH CODES FOR COMPUTING CROSS 03180000
         AR    LCS,LC2               PRODUCTS. L1 = 1+LC1+LC2           03200000
*                                              L2 = LC2                 03220000
         EX    LCS,MPAXC           COMPUTE -  A*C                       03240000
         EX    LCS,MPBXC                      B*C                       03260000
         EX    LCS,MPBXD                      B*D                       03280000
         EX    LCS,MPAXD                      A*D                       03300000
         SPACE                                                          03320000
         LA    LCS,1(LCS,LC1)      SET LENGTH CODES FOR ADDING AND      03340000
*                                    SUBRACTING THE CROSS PRODUCTS.     03360000
*                                    L1=L2=1+LC1+LC2                    03380000
         SPACE 2                                                        03400000
         BCR   15,DVM              QUERY COMPLEX MULTIPLICATION OR      03420000
*                                    DIVISION. (GO TO MULTI OR DIVID.)  03440000
         SPACE                                                          03460000
*                  MULTIPLICATION ROUTINE.                              03480000
         SPACE                                                          03500000
*                                  HERE IF MULTIPLICATION.              03520000
MULTI    EX    LCS,SACBD           CALCULATE - REAL PART = A*C-B*D.     03540000
         EX    LCS,ABCAD                       IMAG PART = B*C+A*D.     03560000
         SPACE                                                          03580000
*                                  STORE ANSWER IN TARGET FIELD.        03600000
*     LENGTH OF ANSWER TO BE STORED IS       MIN(P+R+1),15) DIGITS.     03620000
*     THEREFORE LENGTH CODE IS MIN(FLOOR((P+R+1)/2),7).                 03640000
         CH    LCT,H007            IS FLOOR((P+R+1)/2) LE 7.            03660000
         BC    12,NOCHP            BRANCH IF YES.                       03680000
ZVSVN    LA    LCT,7                                                    03700000
NOCHP    L     TGT,OPTG(WR)        RELOAD TARGET ADDRESS.               03720000
         LR    LCS,R0                                                   03740000
         LR    LC1,LCT                                                  03760000
         SLL   LCT,4               SET LENGTH CODES FOR STORING RESULT. 03780000
         OR    LCT,R0                L1=    MIN(FLOOR(P+R+1)/2),7)      03800000
         EX    LCT,STORE             L2=1+LC1+LC2                       03820000
         LA    WR,OPBC-OPAC(WR)      AND STORE REAL & IMAG PARTS WITH   03840000
         LA    TGT,1(TGT,LC1)        A ZAP WHICH MAY GIVE DEC OVFLOW.   03860000
         EX    LCT,STORE                                                03880000
         BC    15,RTURN            RETURN TO CALLER.                    03900000
         EJECT                                                          03920000
*                  DIVISION ROUTINE.                                    03940000
         SPACE                                                          03960000
DIVID    EX    LCS,ABDAC           CALCULATE NUMERATORS - REAL PART     03980000
         EX    LCS,SBCAD             = A*C+B*D,         - IMAG PART     04000000
*                                    = B*C-A*D.                         04020000
         LA    LCS,1(LC2,LC2)      SET LENGTH CODES FOR LOADING C AND D 04040000
         SLL   LCS,4                 INTO PRODUCT FIELDS. L1=1+2*LC2.   04060000
         AR    LCS,LC2                                    L2=LC2        04080000
         EX    LCS,LDMCC           LOAD MULTIPLICANDS C & D.            04100000
         EX    LCS,LDMDD                                                04120000
         EX    LCS,MPCXC           COMPUTE C**2.                        04140000
         EX    LCS,MPDXD           COMPUTE D**2.                        04160000
*                                  SET LENGTH CODE TO ADD D**2 TO C**2. 04180000
         LA    LCS,1(LCS,LC2)                      L1= 1+2*LC2          04200000
*                                                  L2= 1+2*LC2          04220000
         EX    LCS,ACCDD           ADD D**2 TO C**2.                    04240000
         SPACE                                                          04260000
         LA    PTR,OPBD(WR)        SET POINTERS TO   - REAL NUMERATOR,  04280000
         LA    PTI,OPBC(WR)                          - IMAG NUMERATOR,  04300000
         LA    PTD,OPCC(WR)                          - DENOMINATOR.     04320000
         LR    LCN,R0              SET LENGTH CODES FOR NUMERATORS AND  04340000
         LA    LCD,1(LC2,LC2)        DENOMINATOR.                       04360000
         SPACE                                                          04380000
         LA    R0,1                SET R0 = 1 FOR LATER USE.            04400000
         SPACE                                                          04420000
         LA    SNM,15(PFA)         SNM = 15-P                           04440000
         LR    LCS,LCD                                                  04460000
         SH    LCS,H007            QUERY LENGTH OF DENOMINATOR.         04480000
         BC    2,TRUNC             BRANCH IF GT 8 BYTES.                04500000
         BC    8,RADJN             BRANCH IF EQ 8 BYTES.                04520000
         SPACE                                                          04540000
         LA    LCS,X'70'(LCD)      HERE IF LT 8 BYTES.                  04560000
         EX    LCS,EXPDN           RIGHT JUSTIFY DENOM IN 8 BYTE FIELD. 04580000
         BC    15,RADJN                                                 04600000
         SPACE                                                          04620000
TRUNC    LA    PTX,0(PTD,LCD)      HERE IF DENOM GT 8 BYTES.            04640000
         SH    PTX,H007            PTX = DENOM SIGN POSN - 7            04660000
         EX    LCD,COMP9                                                04680000
         BC    4,DGT15             BRANCH IF DENOM HAS GT 15 SIG DIGITS 04700000
         LR    PTD,PTX             RESET POINTER TO GIVE DENOM A LENGTH 04720000
         BC    15,RADJN              OF 8 BYTES.                        04740000
         EJECT                                                          04760000
*                                  HERE IF DENOM. HAS MORE THAN 15      04780000
*                                    SIGNIFICANT DIGITS.                04800000
*                                    FIND 1ST SIG. DIGIT AND TRUNCATE   04820000
*                                    DENOM ON RIGHT TO 8 BYTES.         04840000
DGT15    BCTR  PTD,0                                                    04860000
DGTLP    AR    PTD,R0                                                   04880000
         TM    0(PTD),X'FF'        TEST IF BYTE ALL ZERO.               04900000
         BC    8,DGTLP             BRANCH IF ALL ZERO.                  04920000
         SR    DDD,DDD             HERE IF NOT ZERO.                    04940000
         TM    0(PTD),X'F0'        IS 1ST DIGIT IN BYTE NOT ZERO.       04960000
         BC    7,MVNDS             BRANCH IF NOT ZERO.                  04980000
ODDDD    LR    DDD,R0              SET DDD =1.                          05000000
         MH    LCD,H017            MOVE DENOM 1 DIGIT RIGHT TO PUT MOST 05020000
         BCTR  LCD,0                 SIGNIFICANT DIGIT ONTO A BYTE      05040000
         EX    LCD,SHFT1             BOUNDARY.                          05060000
         AR    PTD,R0              INCREASE PTD BY 1.                   05080000
MVNDS    MVN   7(1,PTD),7(PTX)     NOW MOVE SIGN LEFT TO MAKE DENOM 8   05100000
*                                    BYTES LONG.                        05120000
         SR    PTX,PTD             PTX = NO OF BYTES SIGN MOVED.        05140000
         AR    PTX,PTX             PTX = NO OF DIGITS SIGN MOVED.       05160000
         AR    DDD,PTX             DDD = NO OF DIGITS DENOM TRUNCATED.  05180000
         SR    SNM,DDD             SNM = NO OF DIGITS THE NUMERATORS    05200000
*                                    HAVE TO BE SHIFTED LEFT.           05220000
         SPACE                                                          05240000
RADJN    LA    LCN,X'F0'(LCN)      RIGHT JUSTIFY NUMERATORS IN 16 BYTE  05260000
         EX    LCN,SHFRN             FIELDS.                            05280000
         EX    LCN,SHFIN                                                05300000
         SPACE                                                          05320000
SHIFT    LTR   SNM,SNM                                                  05340000
         BC    8,ATLST             BRANCH IF NO SHIFT.                  05360000
         BC    2,LEFTS             BRANCH IF LEFT SHIFT.                05380000
         LCR   LC1,SNM             HERE IF RIGHT SHIFT.                 05400000
         AR    LC1,R0                                                   05420000
         SRL   LC1,1                                                    05440000
         LA    LCS,X'F'                                                 05460000
         SR    LCS,LC1                                                  05480000
         EX    LCS,SHFRR                                                05500000
         EX    LCS,SHFRI                                                05520000
*                                  TEST WHETHER SHIFT ODD OR EVEN NO.   05540000
         NR    SNM,R0                OF DIGITS.                         05560000
         BC    4,ATLST             BRANCH IF ODD (SHIFT COMPLETE).      05580000
         MVO   0(16,PTR),0(15,PTR) EVEN, SHIFT ONE MORE DIGIT.          05600000
         MVO   0(16,PTI),0(15,PTI)                                      05620000
         BC    15,ATLST                                                 05640000
         EJECT                                                          05660000
*                                  HERE FOR SHIFT LEFT - EFFECTED BY    05680000
*                                    EXTENDING THE NUMERATORS ON THE    05700000
*                                    RIGHT BY ZEROS AND MOVING THE SIGN 05720000
LEFTS    LR    LCS,SNM             CALC LENGTH CODE FOR CLEARING THE    05740000
         SR    LCS,R0                EXTENSION.                         05760000
         SRL   LCS,1                                                    05780000
         LR    PTX,PTR             EXTEND REAL NUMERATOR.               05800000
         EX    LCS,ZEROT             ZERO NEW BYTES.                    05820000
         AR    PTR,LCS               SET REAL POINTER TO NEW ADDRESS.   05840000
         MVN   16(1,PTR),15(PTX)     MOVE SIGN TO NEW POSITION.         05860000
         NI    15(PTX),X'F0'         CLEAR SIGN FROM OLD POSITION.      05880000
         NR    SNM,R0                TEST WHETHER SHIFT ODD OR EVEN.    05900000
         BC    8,LFTIM               BRANCH IF EVEN.                    05920000
         MVO   1(16,PTR),0(16,PTR)   SHIFT RIGHT ONE DIGIT IF ODD.      05940000
         LR    SNM,R0                                                   05960000
LFTIM    LR    PTX,PTI             EXTEND IMAG NUMERATOR.               05980000
         EX    LCS,ZEROT                                                06000000
         AR    PTI,LCS                                                  06020000
         MVN   16(1,PTI),15(PTX)                                        06040000
         NI    15(PTX),X'F0'                                            06060000
         BCT   SNM,ADJPS             BRANCH IF SHIFT EVEN.              06080000
         MVO   1(16,PTI),0(16,PTI)   SHIFT RIGHT ONE DIGIT IF ODD.      06100000
ADJPS    AR    PTR,R0              ADJUST POINTERS.                     06120000
         AR    PTI,R0                                                   06140000
         SPACE                                                          06160000
ATLST    DP    0(16,PTR),0(8,PTD)  DIVIDE TO PRODUCE - REAL PART.       06180000
         DP    0(16,PTI),0(8,PTD)                    - IMAG PART.       06200000
         SPACE                                                          06220000
         L     TGT,OPTG(WR)        RELOAD TARGET ADDRESS                06240000
         MVC   0(8,TGT),0(PTR)     MOVE REAL PART TO TARGET.            06260000
         MVC   8(8,TGT),0(PTI)     MOVE IMAG PART TO TARGET.            06280000
         SPACE                                                          06300000
RTURN    L     DR,OFDR(DR)                                              06320000
         LM    RB,WR,OFRB(DR)                                           06340000
         MVI   OFLR(DR),X'FF'                                           06360000
         BCR   15,LR               RETURN TO CALLER.                    06380000
         EJECT                                                          06400000
*                  EXECUTED INSTRUCTIONS.                               06420000
         SPACE                                                          06440000
LDMAC    ZAP   OPAC(0,WR),0(0,ADA)                                      06460000
LDMBC    ZAP   OPBC(0,WR),0(0,ADB)                                      06480000
LDMBD    ZAP   OPBD(0,WR),0(0,ADB) (PTR = ADB).                         06500000
LDMAD    ZAP   OPAD(0,WR),0(0,ADA)                                      06520000
LDMCC    ZAP   OPCC(0,WR),0(0,ADC) (PTD = ADC).                         06540000
LDMDD    ZAP   OPDD(0,WR),0(0,ADD)                                      06560000
SHFIN    ZAP   0(0,PTI),0(0,PTI)                                        06580000
SHFRN    EQU   LDMBD                                                    06600000
SHFT1    MVO   OPCC(0,WR),OPCC(0,WR)                                    06620000
SHFRR    MVO   0(16,PTR),0(0,PTR)                                       06640000
SHFRI    MVO   0(16,PTI),0(0,PTI)                                       06660000
EXPDN    EQU   LDMCC                                                    06680000
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*MZV001-TSS 06690001
MPAXC    MP    OPAC(0,WR),0(0,ADC)                                      06700000
MPBXC    MP    OPBC(0,WR),0(0,ADC)                                      06720000
MPBXD    MP    OPBD(0,WR),0(0,ADD)                                      06740000
MPAXD    MP    OPAD(0,WR),0(0,ADD)                                      06760000
*        ----------------------------------------------------MZV001-TSS 06770001
MPCXC    EQU   MPAXC                                                    06780000
MPDXD    EQU   MPAXD                                                    06800000
ACCDD    AP    OPCC(0,WR),OPDD(0,WR)                                    06820000
ABCAD    AP    OPBC(0,WR),OPAD(0,WR)                                    06840000
ABDAC    AP    OPBD(0,WR),OPAC(0,WR)                                    06860000
SACBD    SP    OPAC(0,WR),OPBD(0,WR)                                    06880000
SBCAD    SP    OPBC(0,WR),OPAD(0,WR)                                    06900000
STORE    ZAP   0(0,TGT),OPAC(0,WR)                                      06920000
COMP9    CP    XNINS(8),0(0,PTD)                                        06940000
ZEROT    XC    16(0,PTX),16(PTX)                                        06960000
         SPACE 3                                                        06980000
*                  CONSTANTS.                                           07000000
         SPACE                                                          07020000
H007     EQU   ZVSVN+2                                                  07040000
H017     DC    H'17'                                                    07060000
XNINS    DC    X'999999999999999C'                                      07080000
         SPACE 3                                                        07100000
         END                                                            07120000
