NL1      TITLE '    IHENL1    ALL/ANY, ARRAYS SIMPLE && INTERLEAVED VAR*00400001
               OS/360 PL/I LIBRARY'                                     00800001
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  01200001
*                                                                       01600001
*   STATUS     CHANGE LEVEL - 0.                                        02000001
*                                                                       02400001
*   SIZE       280 BYTES                                                02800001
*                                                                       03200001
*   FUNCTION   'ALL' & 'ANY' FOR A SIMPLE ARRAY, OR AN INTERLEAVED      03600001
*              ARRAY OF 'VARYING' LENGTH ELEMENTS.                      04000001
*              SEE OS/360 PL/I LIBRARY - COMPUTATIONAL SUBROUTINES,     04400001
*              FORM C28-6590, FOR DESCRIPTION OF METHOD.                04800001
*                                                                       05200001
*   ENTRY POINTS                                                        05600001
*              IHENL1A - 'ALL' OR 'ANY', ALIGNED ELEMENTS & TARGET.     06000001
*                  RA = A(PLIST)                                        06400001
*                  PLIST = A(SADV)                                      06800001
*                          A(NUMBER OF DIMENSIONS)                      07200001
*                          A(DED OF ARRAY)                              07600001
*                         (A(IHEBSA0) FOR 'ALL'                         08000001
*                         ( OR                                          08400001
*                         (A(IHEBSO0) FOR 'ANY'                         08800001
*                          A(SDV OF TARGET FIELD)                       09200001
*              IHENL1L - 'ALL', ELEMENTS AND TARGET WITH ANY ALIGNMENT. 09600001
*                  RA =  A(PLIST)                                       10000001
*                  PLIST = A(SADV)                                      10400001
*                          A(NUMBER OF DIMENSIONS)                      10800001
*                          A(DED OF ARRAY)                              11200001
*                          A(IHEBSF0)                                   11600001
*                          A(SDV OF TARGET FIELD).                      12000001
*              IHENL1N - 'ANY', ELEMENTS AND TARGET WITH ANY ALIGNMENT. 12400001
*                  (AS FOR IHENL1L).                                    12800001
*                                                                       13200001
*   INPUT      N/A                                                      13600001
*                                                                       14000001
*   OUTPUT     N/A                                                      14400001
*                                                                       14800001
*   EXTERNAL MODULES                                                    15200001
*              IHEBSA - 'AND'                                           15600001
*              IHEBSO - 'OR'                                            16000001
*              IHEBSF - 'BOOL'                                          16400001
*              IHEJXS - SIMPLE ARRAY INDEXER.                           16800001
*                                                                       17200001
*   EXITS      NORMAL                                                   17600001
*               RETURN TO CALLER VIA LINK REGISTER.                     18000001
*                                                                       18400001
*   TABLES/WORK-AREA                                                    18800001
*              WORK-AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS).        19200001
*                                                                       19600001
*   ATTRIBUTES  READ-ONLY AND REENTRANT.                                20000001
*                                                                       20400001
*   PRIVATE MACROS                                                      20800001
*              IHELIB,IHESDR                                            21200001
*                                                                       21600001
*   ASSEMBLY REQUIREMENTS                                               22000001
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   22400001
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        22800001
*                                                                       23200001
*   NOTES      SEE OS/360 PL/I LIBRARY PLM FOR LIBRARY CONVENTIONS AND  23600001
*              STANDARDS.                                               24000001
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON        24400001
*              A PARTICULAR INTERNAL REPRESENTATION OF THE              24800001
*              EXTERNAL CHARACTER SET.                                  25200001
         EJECT                                                          25600001
IHENL1   CSECT                                                          26000001
         SPACE 2                                                        26400001
         IHELIB                                                         26800001
*                                  PRIVATE OFFSETS.                     27200001
         SPACE                                                          27600001
OPAL     EQU   72                                                       28000001
OPSD     EQU   OPAL+16                                                  28400001
OPBR     EQU   OPSD+8                                                   28800001
         EJECT                                                          29200001
*             THE COMMENTS REFER TO THE 'BOOL' FUNCTION AS 'BF.         29600001
         SPACE 4                                                        30000001
IHENL1   CSECT                                                          30400001
         ENTRY IHENL1A                                                  30800001
         ENTRY IHENL1L                                                  31200001
         ENTRY IHENL1N                                                  31600001
         SPACE 2                                                        32000001
*                                  ************************************ 32400001
*                                  * 'ANY' FOR ELEMENTS AND TARGET    * 32800001
*                                  * WITH ANY ALIGNMENT.              * 33200001
*                                  ************************************ 33600001
         SPACE                                                          34000001
         SPACE                                                          34400001
         USING *,BR                                                     34800001
IHENL1N  STM   LR,RX,OFLR(DR)                                           35200001
         LA    RG,FBFN             SELECT 'ANY' ARGUMENT BITS FOR BF.   35600001
         BAL   BR,TC010                                                 36000001
         SPACE 2                                                        36400001
*                                  ************************************ 36800001
*                                  * 'ALL' FOR ELEMENTS AND TARGET    * 37200001
*                                  * WITH ANY ALIGNMENT.              * 37600001
*                                  ************************************ 38000001
         SPACE                                                          38400001
         USING *,BR                                                     38800001
IHENL1L  STM   LR,RX,OFLR(DR)      SAVE CALLER'S REGS.                  39200001
         LA    RG,FBFL             SELECT 'ALL' ARGUMENT BITS FOR BF.   39600001
TC010    LA    RI,TC080            SET SWITCH TO INDICATE ANY-ALIGNMENT 40000001
         BAL   BR,TC020                                                 40400001
         SPACE 2                                                        40800001
*                                  ************************************ 41200001
*                                  * BOTH 'ALL' & 'ANY' FOR ALIGNED   * 41600001
*                                  * ELEMENTS AND TARGET.             * 42000001
*                                  ************************************ 42400001
         SPACE                                                          42800001
         USING *,BR                                                     43200001
IHENL1A  STM   LR,RX,OFLR(DR)      SAVE CALLER'S REGS.                  43600001
         LA    RI,TC090            SET SWITCH TO INDICATE ALIGNED CASE. 44000001
TC020    IHESDR LW1,RH                                                  44400001
         SPACE                                                          44800001
         ST    RG,OPAL+8(DR)       STORE ADDR OF BF BITS IN BF ARG LIST 45200001
         LM    RA,RE,0(RA)         LOAD IHENL1'S ARGUMENTS INTO REGS.   45600001
         LR    RF,RA               MOVE A(SADV) TO REG THAT IS SAVED.   46000001
         ST    RE,OPAL+12(DR)      STORE TARGET SDV ADDR IN LIST OF     46400001
*                                    ARGUMENTS  FOR BF (OR AND/OR).     46800001
         ST    RD,OPBR(DR)         SAVE ADDR OF BF (OR OR OR AND).      47200001
         TM    0(RC),X'10'         TEST DED - QUERY CONSTANT OR VARYING 47600001
         BC    1,TC030             BRANCH TO TC030 IF VARYING.          48000001
         SPACE 5                                                        48400001
*                                  HERE TO INITIALISE FOR CONSTANT      48800001
*                                    LENGTH STRINGS.                    49200001
         SPACE                                                          49600001
         L     BR,VXSI             BRANCH TO SIMPLE INDEXING ROUTINE TO 50000001
         BALR  LR,BR                 GET BIT ADDRS OF 1ST & LAST        50400001
*                                    ELEMENTS OF THE ARRAY (IN R0 & RA) 50800001
         USING *,LR                                                     51200001
         L     RB,0(RB)            LOAD NO. OF DIMENSIONS (N).          51600001
         SLL   RB,3                RB = 8*N.                            52000001
         LH    RH,6(RF,RB)         LOAD LENGTH OF ELEMENT.              52400001
         STH   RH,OPSD+4(DR)       STORE IN SDV FOR ARRAY ELEMENTS.     52800001
         STH   RH,OPSD+6(DR)                                            53200001
         LTR   RH,RH               IS LENGTH ZERO.                      53600001
         BNZ   TC025               BRANCH IF NOT.                       54000001
         ST    RH,4(RE)            SET TARGET SDV LENGTH FIELDS TO ZERO 54400001
         B     TC110               BRANCH TO EXIT.                      54800001
TC025    SRL   RB,1                RB = 4*N.                            55200001
         L     RH,0(RF,RB)         LOAD EFFECTIVE LENGTH OF AN ELEMENT. 55600001
         LR    RF,R0               SET UP 1ST WORD OF SDV (OFFSET-BYTE  56000001
         LR    RG,RF                 FORM).                             56400001
         SRDL  RF,3                                                     56800001
         ST    RG,OPSD(DR)           STORING DONE HERE.                 57200001
         LA    RB,OPSD(DR)         NOW PUT THE ADDRESS OF THE SDV INTO  57600001
         LR    RC,RB                 THE LIST OF ARGUMENTS.             58000001
         STM   RB,RC,OPAL(DR)        FOR FIRST CALL TO BF (AND/OR) SET  58400001
*                                    BOTH SOURCE FIELDS AS THE FIRST    58800001
*                                    ELEMENT OF THE ARRAY.              59200001
         LA    RJ,TC070            SET SWITCH TO INDICATE CONSTANT      59600001
         BC    15,TC040              LENGTH STRINGS.                    60000001
         EJECT                                                          60400001
*                                  HERE TO INITIALISE FOR VARYING       60800001
*                                    LENGTH STRINGS.                    61200001
         DROP  LR                                                       61600001
         USING IHENL1A,BR                                               62000001
TC030    L     BR,VXSY             BRANCH TO SIMPLE INDEXING ROUTINE TO 62400001
         BALR  LR,BR                 GET BYTE ADDRS OF 1ST AND LAST     62800001
*                                    ELEMENTS OF THE ARRAY (IN R0 & RA) 63200001
         USING *,LR                                                     63600001
         LR    BR,R0                                                    64000001
         STM   BR,R0,OPAL(DR)      PUT ADDR OF SOURCE SDV IN LIST OF    64400001
*                                    ARGUMENTS  FOR BF (AND/OR).        64800001
         LR    RB,R0               LOAD 2ND ARG REG FOR CALLS TO AND/OR 65200001
         LA    RH,8                SET INCREMENT REG = 8.               65600001
         LA    RJ,TC060            SET SWITCH TO INDICATE VARYING       66000001
*                                    LENGTH STRINGS.                    66400001
TC040    BALR  LR,0                                                     66800001
         USING *,LR                                                     67200001
         LR    RG,RI               COPY ALIGNMENT SWITCH.               67600001
         LR    RX,R0               LOAD INDEX REG WITH A(1ST ELEMENT).  68000001
         LR    RI,RA               LOAD COMP REG WITH A(LAST ELEMENT).  68400001
         LA    RF,TC050            SET SWITCH TO INDICATE THAT FIRST    68800001
*                                    SOURCE MUST BE SET TO BE THE       69200001
*                                    TARGET FIELD.                      69600001
         LR    RC,RE               LOAD 3RD ARG REG FOR CALLS TO AND/OR 70000001
         LA    RE,TC100            SET BRANCH REG FOR THE FIRST BCR     70400001
*                                    INSTRUCTION AFTER TC080.           70800001
         BR    RG                  TEST SWITCH, ANY ALIGNMENT - GO TO   71200001
*                                    TC080, ALIGNED - GO TO TC090.      71600001
         SPACE 5                                                        72000001
*                                  CHANGE 1ST ARGUMENT  FOR BF (AND/OR) 72400001
TC050    MVC   OPAL(4,DR),OPAL+12(DR) TO BE THE TARGET FIELD.           72800001
         LR    RF,RJ               RESET SWITCH TO BYPASS THIS PART ON  73200001
*                                    SUBSEQUENT ITERATIONS OF THE LOOP. 73600001
         BCR   15,RJ               QUERY VARYING OR CONSTANT LENGTH     74000001
*                                    STRINGS (GO TO TC060 OR TC070).    74400001
         SPACE                                                          74800001
         DROP  LR                                                       75200001
TC060    ST    RX,OPAL+4(DR)       VARYING. PUT ADDR OF SDV OF NEXT     75600001
         LR    RB,RX                 ELEMENT INTO LIST OF ARGUMENTS.    76000001
         BR    RG                  TEST SWITCH, ANY ALIGNMENT - GO TO   76400001
*                                    TC080, ALIGNED - GO TO TC090.      76800001
         SPACE                                                          77200001
*                                  CONSTANT. PUT ADDR OF NEXT ELEMENT   77600001
TC070    LR    R0,RX                 INTO SDV, (OFFSET-BYTE FORM).      78000001
         LR    RA,RX                                                    78400001
         SRDL  R0,3                                                     78800001
         ST    RA,OPSD(DR)                                              79200001
         BR    RG                  TEST SWITCH, ANY ALIGNMENT - GO TO   79600001
*                                    TC080, ALIGNED - GO TO TC090.      80000001
         SPACE 2                                                        80400001
*                                  HERE IF ANY-ALIGMENT CASE.           80800001
TC080    LA    RA,OPAL(DR)         SET RA = ADDR OF ARG LIST FOR BF.    81200001
         BCR   15,RE               BRANCH TO TC100.                     81600001
         SPACE                                                          82000001
*                                  HERE IF ALIGNED CASE.                82400001
TC090    L     RA,OPAL(DR)         LOAD 1ST ARGUMENT FOR AND/OR.        82800001
TC100    L     BR,OPBR(DR)         LOAD BRANCH REGISTER.                83200001
         BALR  LR,BR               BRANCH TO 'AND' OR 'OR' OR 'BOOL'.   83600001
         BXLE  RX,RH,0(RF)         INCREMENT AND TEST INDEX REGISTER.   84000001
*                                    (ORIGINALLY SET TO ADDR OF FIRST   84400001
*                                     ELEMENT OF THE ARRAY).            84800001
*                                    (RF = RJ, AFTER 1ST TIME           85200001
*                                        = VARYING OR CONSTANT SWITCH   85600001
*                                        = TC060 OR TC070)              86000001
         SPACE 5                                                        86400001
TC110    L     DR,OFDR(DR)         END. RESET SAVE AREA POINTER.        86800001
         LM    LR,RX,OFLR(DR)      RESTORE CALLER'S REGS.               87200001
         MVI   OFLR(DR),X'FF'      STOP TRACE.                          87600001
         BCR   15,LR               RETURN.                              88000001
         SPACE 5                                                        88400001
VXSI     DC    V(IHEJXSI)                                               88800001
VXSY     DC    V(IHEJXSY)                                               89200001
FBFL     DC    F'1'                                                     89600001
FBFN     DC    F'7'                                                     90000001
         SPACE 5                                                        90400001
         END                                                            90800001
