NL2      TITLE '    IHENL2    ALL/ANY, INTERLEAVED ARRAY, FIXED LENGTH *00020000
               OS/360 PL/I LIBRARY'                                     00040000
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  00060000
*                                                                       00080000
*   STATUS     CHANGE LEVEL - 0.                                        00100000
*                                                                       00120000
*   SIZE       192 BYTES                                                00140000
*                                                                       00160000
*   FUNCTION   'ALL' & 'ANY' FOR AN INTERLEAVED ARRAY OF FIXED LENGTH   00180000
*              ELEMENTS.                                                00200000
*              SEE OS/360 PL/I LIBRARY - COMPUTATIONAL SUBROUTINES,     00220000
*              FORM C28-6590, FOR DESCRIPTION OF METHOD.                00240000
*                                                                       00260000
*   ENTRY POINTS                                                        00280000
*              IHENL2A - 'ALL' OR 'ANY', ALIGNED ELEMENTS & TARGET.     00300000
*                  RA = A(PLIST)                                        00320000
*                  PLIST = A(SADV)                                      00340000
*                          A(NUMBER OF DIMENSIONS)                      00360000
*                          A(DED OF ARRAY) - NOT USED                   00380000
*                         (A(IHEBSA0) FOR 'ALL'                         00400000
*                         ( OR                                          00420000
*                         (A(IHEBSO0) FOR 'ANY'                         00440000
*                          A(SDV OF TARGET FIELD)                       00460000
*              IHENL2L - 'ALL', ELEMENTS AND TARGET WITH ANY ALIGNMENT. 00480000
*                  RA = A(PLIST)                                        00500000
*                  PLIST = A(SADV)                                      00520000
*                          A(NUMBER OF DIMENSIONS)                      00540000
*                          A(DED OF ARRAY) - NOT USED                   00560000
*                          A(IHEBSF0)                                   00580000
*                          A(SDV OF TARGET FIELD)                       00600000
*              IHENL2N - 'ANY', ELEMENTS AND TARGET WITH ANY ALIGNMENT. 00620000
*                  (AS FOR IHENL2L)                                     00640000
*                                                                       00660000
*   INPUT      N/A                                                      00680000
*                                                                       00700000
*   OUTPUT     N/A                                                      00720000
*                                                                       00740000
*   EXTERNAL MODULES                                                    00760000
*              IHEBSA - 'AND'                                           00780000
*              IHEBSO - 'OR'                                            00800000
*              IHEBSF - 'BOOL'                                          00820000
*              IHEJXI - INTERLEAVED ARRAY INDEXER.                      00840000
*                                                                       00860000
*   EXITS      NORMAL                                                   00880000
*               RETURN TO CALLER VIA LINK REGISTER.                     00900000
*                                                                       00920000
*   TABLES/WORK-AREA                                                    00940000
*              WORK-AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS).        00960000
*                                                                       00980000
*   ATTRIBUTES  READ-ONLY AND REENTRANT.                                01000000
*                                                                       01020000
*   PRIVATE MACROS                                                      01040000
*              IHELIB,IHESDR                                            01060000
*                                                                       01080000
*   ASSEMBLY REQUIREMENTS                                               01100000
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   01120000
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        01140000
*                                                                       01160000
*   NOTES      SEE OS/360 PL/I LIBRARY PLM FOR LIBRARY CONVENTIONS AND  01180000
*              STANDARDS.                                               01200000
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON        01220000
*              A PARTICULAR INTERNAL REPRESENTATION OF THE              01240000
*              EXTERNAL CHARACTER SET.                                  01260000
         EJECT                                                          01280000
IHENL2   CSECT                                                          01300000
         SPACE 2                                                        01320000
         IHELIB                                                         01340000
*                                  PRIVATE OFFSETS.                     01360000
         SPACE                                                          01380000
OPAL     EQU   72                                                       01400000
OPSD     EQU   OPAL+16                                                  01420000
OPBR     EQU   OPSD+8                                                   01440000
         EJECT                                                          01460000
*             THE COMMENTS REFER TO THE 'BOOL' FUNCTION AS 'BF'.        01480000
         SPACE 4                                                        01500000
IHENL2   CSECT                                                          01520000
         ENTRY IHENL2A                                                  01540000
         ENTRY IHENL2L                                                  01560000
         ENTRY IHENL2N                                                  01580000
*                                  ************************************ 01600000
*                                  * 'ANY', FOR ELEMENTS AND TARGET   * 01620000
*                                  * WITH ANY ALIGNMENT.              * 01640000
*                                  ************************************ 01660000
         SPACE                                                          01680000
         USING *,BR                                                     01700000
IHENL2N  STM   LR,RX,OFLR(DR)                                           01720000
         LA    RB,FBFN             SELECT 'ANY' ARGUMENT BITS FOR BF.   01740000
         BAL   BR,TC010                                                 01760000
         SPACE 2                                                        01780000
*                                  ************************************ 01800000
*                                  * 'ALL', FOR ELEMENTS AND TARGET   * 01820000
*                                  * WITH ANY ALIGNMENT.              * 01840000
*                                  ************************************ 01860000
         SPACE                                                          01880000
         USING *,BR                                                     01900000
IHENL2L  STM   LR,RX,OFLR(DR)      SAVE CALLER'S REGS.                  01920000
         LA    RB,FBFL             SELECT 'ALL' ARGUMENT BITS FOR BF.   01940000
TC010    LA    RG,TC060            SET SWITCH TO INDICATE ANY ALIGNMENT 01960000
         BAL   BR,TC020                                                 01980000
         SPACE 2                                                        02000000
*                                  ************************************ 02020000
*                                  * BOTH 'ALL' & 'ANY' FOR BYTE-     * 02040000
*                                  * ALIGNED ELEMENTS AND TARGET.     * 02060000
*                                  ************************************ 02080000
         SPACE                                                          02100000
         USING *,BR                                                     02120000
IHENL2A  STM   LR,RX,OFLR(DR)      SAVE CALLER'S REGS.                  02140000
         LA    RG,TC070            SET SWITCH TO INDICATE ALIGNED CASE. 02160000
         SPACE                                                          02180000
TC020    IHESDR LW2,RH                                                  02200000
         SPACE                                                          02220000
         ST    RB,OPAL+8(DR)       STORE ADDR OF BF BITS IN BF ARG LIST 02240000
         LM    RA,RE,0(RA)         LOAD IHENL2'S ARGUMENTS INTO REGS.   02260000
         LR    RH,RA               MOVE A(SADV) TO REG THAT IS SAVED.   02280000
         ST    RE,OPAL+12(DR)      PUT ADDR OF TARGET SDV IN LIST OF    02300000
*                                    ARGUMENTS  FOR BF (OR AND/OR).     02320000
         ST    RD,OPBR(DR)         SAVE ADDR OF BF (OR OR OR AND).      02340000
         L     BR,VXII                                                  02360000
         BALR  LR,BR               BRANCH TO INITIALISE INDEXER.        02380000
         USING *,LR                                                     02400000
         L     RB,0(RB)            LOAD NO. OF DIMENSIONS.              02420000
         SLL   RB,3                PICK UP LENGTH OF ELEMENT FROM SADV  02440000
         LH    RF,6(RH,RB)           AND STORE IN SDV.                  02460000
         STH   RF,OPSD+6(DR)         (LENGTH AT A(SADV)+8N+6).          02480000
         LA    RB,OPSD(DR)         FOR FIRST CALL TO BF (AND/OR) THE    02500000
         LR    RC,RB                 TWO SOURCE SDVS ARE THE SAME.      02520000
         STM   RB,RC,OPAL(DR)                                           02540000
         LR    RC,RE               LOAD 3RD ARG REG FOR CALLS TO AND/OR 02560000
         LA    RF,TC100            SET SWITCH TO INDICATE THAT FIRST    02580000
*                                    SOURCE MUST BE CHANGED TO BE THE   02600000
*                                    TARGET FIELD.                      02620000
         BALR RJ,0                 SET BASE REG FOR REMAINDER OF PROG.  02640000
         USING *,RJ                                                     02660000
         SPACE 5                                                        02680000
TC040    LR    RI,RA               CONVERT BIT ADDRESS IN RA TO OFFSET- 02700000
         LR    RH,RA                 BYTE FORM,                         02720000
         SRDL  RH,3                                                     02740000
         ST    RI,OPSD(DR)           AND STORE IN SDV.                  02760000
         BR    RG                  TEST SWITCH, ANY ALIGNMENT - GO TO   02780000
*                                    TC060, ALIGNED - GO TO TC070.      02800000
         SPACE 2                                                        02820000
*                                  ANY-ALIGNMENT CASE.                  02840000
TC060    LA    RA,OPAL(DR)         SET POINTER TO ARGUMENT LIST (FOR BF 02860000
         BC    15,TC080                                                 02880000
         SPACE                                                          02900000
*                                  ALIGNED CASE.                        02920000
TC070    L     RA,OPAL(DR)         LOAD 1ST ARG REG FOR CALL TO AND /OR 02940000
TC080    L     BR,OPBR(DR)         LOAD BRANCH REGISTER.                02960000
         BALR  LR,BR               BRANCH TO 'AND', 'OR' OR 'BF'.       02980000
         BCR   15,RF               ON FIRST PASS THROUGH HERE BRANCH TO 03000000
*                                    CHANGE FIRST SOURCE TO TARGET.     03020000
*                                    (IE. FIRST TIME BRANCH TO TC100,   03040000
*                                    SUBSEQUENTLY TO TC110).            03060000
         SPACE 2                                                        03080000
*                                  CHANGE FIRST ARGUMENT  FOR BF (AND/  03100000
TC100    MVC   OPAL(4,DR),OPAL+12(DR) OR) TO POINT TO THE TARGET FIELD. 03120000
         LA    RF,TC110            SET SWITCH TO BYPASS THIS PART ON    03140000
*                                    SUBSEQUENT ITERATIONS OF THE LOOP. 03160000
         SPACE                                                          03180000
TC110    L     BR,VXIA                                                  03200000
         BALR  LR,BR                 ADDRESS OF NEXT ELEMENT OF ARRAY.  03220000
         LTR   BR,BR               HAS LAST ADDR ALREADY BEEN USED.     03240000
         BC    8,TC040             BRANCH IF NOT.                       03260000
         SPACE 5                                                        03280000
TC120    L     DR,OFDR(DR)         END. RESET SAVE AREA POINTER.        03300000
         LM    LR,RJ,OFLR(DR)      RESTORE CALLER'S REGS.               03320000
         MVI   OFLR(DR),X'FF'      STOP TRACE.                          03340000
         BCR   15,LR               RETURN.                              03360000
         SPACE 5                                                        03380000
VXII     DC    V(IHEJXII)                                               03400000
VXIA     DC    V(IHEJXIA)                                               03420000
FBFL     DC    F'1'                                                     03440000
FBFN     DC    F'7'                                                     03460000
         SPACE 5                                                        03480000
         END                                                            03500000
