OCL      TITLE    'IHEOCL    OPEN/CLOSE BOOTSTRAP                      /00100017
               OS/360 PL/I LIBRARY'                                     00200017
*   VERSION    FOURTH VERSION OF F-LEVEL PL/1 COMPILER                  00300017
*                                                                       00400017
*   STATUS     CHANGE LEVEL - 0                                         00500017
*                                                                       00520020
*        APAR 34383 FIXED AT CLEAR OFFSET 412000                        00540020
*                                                                       00560020
*        APAR 36989 FIXED AT CLEAR OFFSET 287000                        00568020
*                                                                       00576020
*        APAR 38165 FIXED AT CLEAR OFFSET 500700                        00584020
*                                                                       00592020
*                                                                       00600017
*   SIZE       1600 BYTES                                               00700017
*                                                                       00800017
*   FUNCTION   BOOTSTRAP                                                00900017
*               THIS MODULE LINKS EITHER TO IHEOPN (OPEN)               01000017
*              OR IHECLT (CLOSE), WHICH RESIDE IN THE LINK LIBRARY      01100017
*              ERROR ANALYSIS (OPEN ONLY)                               01200017
*               UPON RETURN FROM IHEOPN (AND ANY OTHER OPEN MODULE)     01300017
*               THE STATUS OF THE FILES BEING OPENED IS CHECKED. THE    01400017
*               FILE REGISTER CONTAINS ERROR-CODES, IF ANY, AND THE     01500017
*               ADDRESS OF ITS RELEVANT FCB, THESE ERROR-CODES          01600017
*               INDICATING THE FOLLOWING --                             01700017
*                   1) NO DD CARD PRESENT,                              01800017
*                   2) ACCESS TYPE NOT SUPPORTED,                       01900017
*                   3) OPEN FOUND CONFLICTING ATTRIBUTES,               02000017
*                   4) NO BLOCKSIZE SPECIFIED.                          02100017
*                   5) TRANSMIT ERROR OCCURRED WHILE FORMATING INITIAL  02200017
*                   ALLOCATION.                                         02300017
*               IF ONE OF THE ABOVE ERROR CODES IS FOUND THE FILE       02400017
*               IS 'CLOSED' IF IT IS FOUND TO BE OPEN BEFORE THE        02500017
*               ERROR CONDITION 'UNDEFINEDFILE' IS RAISED.              02600017
*               BIT '0' OF THE FILE REGISTER IS SET TO '1' IF ANY       02700017
*               ERROR IS FOUND.THE ERROR CONDITION                      02800017
*               'UNDEFINEDFILE'IS NOT RAISED IF THE CALL TO THIS        02900017
*               MODULE WAS MADE BY IHEPRT.                              03000017
*               THE CURRENT-FILE (IHEQCFL) IS STACKED AND UNSTACKED     03100017
*               AT THE PROGRAM EXTREMITIES.                             03200017
*                                                                       03300017
*              THIS MODULE IS ALSO CALLED AT THE END OF A TASK TO CLEAR 03400017
*              ALL OUTSTANDING EVENTS AND EXCLUSIVE BLOCKS FOR THE TASK 03500017
*              AND TO CLOSE ALL FILES OPENED IN THE TASK BY CALLING     03600017
*              IHECLTB                                                  03700017
*                                                                       03800017
*   ENTRY POINTS                                                        03900017
*              IHEOCLA - EXPLICIT OPEN CALL                             04000017
*                  RA = A(PLIST)                                        04100017
*                  PLIST = A(DCLCB)          *                          04200017
*                          A(OCB)/0          ** THESE PARMETERS         04300017
*                          A(TITLE SDV)/0    *  ARE SPECIFIED FOR       04400017
*                          A(IDENT SDV)/0    *  EACH FILE TO BE OPENED. 04500017
*                          A(IDENT DED)/0    *  THE NORMAL END OF PARM. 04600017
*                          A(KEYLENGTH)/0    *  LIST BIT IS SET IN THE  04700017
*                          A(LINESIZE)/0     ** LAST WORD OF THE LIST.  04800017
*                          A(PAGESIZE)/0     *                          04900017
*                                                                       05000017
*              IHEOCLB - CLOSE CALL                                     05100017
*                  RA = A(PLIST)                                        05200017
*                  PLIST = A(DCLCB)          *(CF. IHEOCLA COMMENTS)    05300017
*                          A(IDENT SDV)/0    *                          05400017
*                          A(IDENT DED)/0    *                          05500017
*                                                                       05600017
*              IHEOCLC - IMPLICIT OPEN CALL                             05700017
*                  RA = A(OCB)                                          05800017
*                  RB = A(DCLCB)                                        05900017
*                                                                       06000017
*              IHEOCLD - END OF TASK CALL                               06100017
*                  RA = A(PRV OF TASK ENDING)                           06200017
*                  PR = A(PRV OF TASK EXECUTING)                        06300017
         EJECT                                                          06400017
*   INPUT                                                               06500017
*              CURRENT-FILE PSEUDO-REGISTER,DCLCB.                      06600017
*                                                                       06700017
*   OUTPUT                                                              06800017
*              CURRENT FILE PSEUDO-REGISTER,FCB,FILE REGISTER           06900017
*                                                                       07000017
*   EXTERNAL MODULES                                                    07100017
*               LIBRARY MODULES0                                        07200017
*               IHEOPN - OPEN PHASE I.                                  07300017
*               IHECLS - CLOSE.                                         07400017
*               IHEERR - EXEP 'B' ENTRY.                                07500017
*               IHESAF/IHETSA - FREE VDA                                07600017
*               CONTROL SYSTEM MODULES0                                 07700017
*               LINK                                                    07800017
*               FREEMAIN.                                               07900017
*               DEQ                                                     08000017
*               ENQ                                                     08100017
*                                                                       08200017
*   EXITS                                                               08300017
*              NORMAL                                                   08400017
*               RETURN TO CALLER VIA LINK REGISTER.                     08500017
*              ERROR                                                    08600017
*               RAISE 'UNDEFINEDFILE'ERROR CONDITION, IF THE USER HAS   08700017
*               AN ON UNIT FOR THIS CONDITION AND RETURNS TO THIS       08800017
*               MODULE THEN PROCESSING WILL CONTINUE WITH THE NEXT      08900017
*               FILE IN THE OPEN STACK. IF THE ERROR CONDITION IS       09000017
*               RAISED BECAUSE NO ON UNIT EXISTS THEN THE FILE          09100017
*               REGISTERS OF REMAINING FILES MAY HAVE ERROR CODES       09200017
*               LEFT UNPROCESSED IN THE FIRST BYTE.                     09300017
*                                                                       09400017
*   TABLES/WORK AREA                                                    09500017
*              SEE O/S 360 LIBRARY PLM FOR DECRIPTION OF                09600017
*              FCB,DCLCB,FILE REGISTER AND CURRENT FILE.                09700017
*              WORK-AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS).        09800017
*              A TABLE EXISTS (ADCON) IN THIS MODULE WHICH              09900017
*              CONTAINS ALL THE ADCONS REQUIRED BY THE OPEN AND CLOSE   10000017
*              MODULES AND IT'S ADDRESS IS PASSED IN THE CALLING        10100017
*              SEQUENCE TO THESE MODULES.                               10200017
*              THIS A(ADCON) LIST IS STORED IN THE FCB BY THE OPEN      10300017
*              MODULES AND IS USED BY 'LOADED' TRANSMIT MODULES.        10400017
*                                                                       10500017
*   ATTRIBUTES  READ ONLY AND REENTRANT                                 10600017
*                                                                       10700017
*   PRIVATE MACROS                                                      10800017
*              IHELIB,IHEPRV,IHESDR,IHEZAP                              10900017
*                                                                       11000017
*   ASSEMBLY REQUIREMENTS                                               11100017
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   11200017
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        11300017
*                                                                       11400017
*   NOTES                                                               11500017
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    11600017
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    11700017
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  11800017
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  11900017
*              CONSTANTS, BY REASSEMBLY, WILL RESULT IN A CORRECT       12000017
*              MODULE FOR THE NEW DEFINITIONS.                          12100017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL000-TSS 12130020
*        ----------------------------------------------------OCL000-TSS 12160020
        EJECT                                                           12200017
IHEOCL   CSECT                                                          12300017
         IHELIB                                                         12400017
         IHEZAP                                                         12500017
         IHEXLV                                                         12600017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL011-TSS 12630001
IHEQEVT  DXD   2A                                                       12700017
IHEQSPR  DXD   A                                                        12800017
*        ----------------------------------------------------OCL011-TSS 12820020
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL010-TSS 12850001
         DCBD  DSORG=(QS,IS,DA)                                         12900017
*        ----------------------------------------------------OCL010-TSS 12950001
         EJECT                                                          13000017
*        ENTRY POINTS TO THIS MODULE ARE,                               13100017
         SPACE 2                                                        13200017
         ENTRY IHEOCLA,IHEOCLB,IHEOCLC,IHEOCLD                          13300017
         SPACE 2                                                        13400017
PARM     DSECT                                                          13500017
ODCL     DS    A                        A(FILE CONTROL BLOCK(DCLB)).    13600017
OOCL     DS    A                        A(OPEN OPTIONS CONTROL BLOCK).  13700017
OTIT     DS    A                        A(TITLE SDV).                   13800017
OIDT     DS    A                        A(IDENT SDV).                   13900017
ODED     DS    A                        A(DED FOR STRING).              14000017
OKEY     DS    A                        A(KEYLENGTH)                    14100017
OLIN     DS    A                        A(LINE SIZE)                    14200017
OEOL     DS    0BL1                     END OF LIST FLAG.               14300017
OPAG     DS    A                        A(PAGE SIZE)                    14400017
         SPACE                                                          14500017
IHEZLW2  DSECT                                                          14600017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL012-TSS 14650001
         DS    9D                       SSA GROUP 1.                    14700017
*        ----------------------------------------------------OCL012-TSS 14750001
OCPL     DS    A                        OPEN/CLOSE P.LIST POINTER.      14800017
OCAD     DS    A                        ADCONS POINTER.                 14900017
DEP1     DS    4D                       PLIST FOR IMPLICIT OPEN.        15000017
BRBR     DS    C                                                        15100017
DEQF     DS    A                                                        15200017
DEQA     DS    2A                                                       15300017
ITCPL    DS    5A                                                       15400017
RARA     EQU   DEP1                                                     15500017
RBRB     EQU   DEP1+4                                                   15600017
         SPACE 3                                                        15700017
ERR0     EQU   X'C804'                  NO DD CARD.                     15800017
ERR1     EQU   X'0010'                  IMPLECIT OPEN ERROR             15900017
ERR2     EQU   X'C802'                  FILE TYPE NOT SUPPORTED.        16000017
ERR3     EQU   X'C803'                  NO BLOCKSIZE SPECIFIED.         16100017
ERR4     EQU   X'C805'                  ERROR INITIALISING REGIONAL DS. 16200017
ERR5     EQU   X'0013'                  CLOSE FILE  IN WRONG TASK.      16300017
PWR      EQU   WR                                                       16400017
MEOL     EQU   X'80'                    END OF LIST FLAG.               16500017
SYSP     EQU   X'40'                    PRINT  INITIATED FILE.          16600017
OPEN     EQU   X'10'                    FILE OPENED CORRECTLY.          16700017
MCFL     EQU   X'01'                    CURRENT FILE ACTIVE FLAG.       16800017
OFCF     EQU   72                       OFFSET OF CURRENT FILE.         16900017
VERS     EQU   3                                                        17000017
PLOF     EQU   32                                                       17100017
VR17     EQU   5                       RELEASE 17 CODE          36989   17150020
         EJECT                                                          17200017
IHEOCL   CSECT                                                          17300017
         SPACE                                                          17400017
         USING *,BR                                                     17500017
         USING IHEZLCA,RI                                               17600017
         USING IHEZLW2,PWR                                              17700017
         USING IHEZADC,RE                                       36989   17800020
         USING IHADCB,BR                                                17900017
         USING IHEZDCL,RD                                               18000017
         USING IHEZAPE,RC                                               18100017
         USING PARM,RF                                                  18200017
         SPACE                                                          18300017
IHEOCLA  EQU   *                        OPEN BOOTSTRAP.                 18400017
         NOPR  PWR                                                      18500017
         SPACE                                                          18600017
IHEOCLB  EQU   *                        CLOSE BOOTSTRAP.                18700017
         SPACE                                                          18800017
         NOPR  0                                                        18900017
IHEOCLC  EQU   *                                                        19000017
         NOPR  0                                                        19100017
         SPACE                                                          19200017
IHEOCLD  EQU   *                        IMPLICIT CLOSE                  19300017
         SPACE                                                          19400017
         STM   LR,PWR,OFLR(DR)       .  SAVE CALLERS REGISTERS.         19500017
         BALR  RJ,0                                                     19600017
         SPACE 2                                                        19700017
         USING *,RJ                                                     19800017
         SPACE 2                                                        19900017
         IHEPRV LCA,RI,OP=L             GET A(LCA) AND HOLD IN RI       20000017
         SPACE                                                          20100017
         IHEPRV LW2,PWR,OP=L            GET A(LIBWS) - CLOSE.           20200017
         STC   BR,BRBR                  SAVE ENTRY POINT.               20300017
         LR    RG,DR                    SAVE OLD DR.                    20400017
         ST    DR,4(PWR)                SET UP SAVE AREA.               20500017
         LR    DR,PWR                                                   20600017
         IHEPRV ADC,RC                  GET A(ADCON LIST).              20700017
         ST    RC,OCAD                  STORE IT.                       20800017
OCL01    EQU   *                                                        20900017
         TM    BRBR,X'04'               IMPLICIT OPEN OR CLOSE?         21000017
         BO    OCIMP                    YES.                            21100017
OCLIJ    EQU   *                                                        21200017
         LR    RF,RA                    SAVE OPEN P.LIST.               21300017
         IHEPRV CFL,RD,OP=LA            STACK CURRENT FILE.             21400017
         MVC   OFCF+1(7,RG),1(RD)                                       21500017
         OI    OFCF+4(RG),MCFL       /  SET P.R< ACTIVE.                21600017
         ST    RA,OCPL                  SAVE A(OPEN/CLOSE P.LIST).      21700017
         LA    RA,OCPL                  POINT TO SUB P.LIST.            21800017
         TM    BRBR,X'02'               CLOSE TO BE LINKED?             21900017
         BO    OCCLS                    YES.                            22000017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL001-TSS 22050001
         LINK  EP=IHEOPNA,MF=(E,(1)) $$ NO,GET OPEN PASS IT CONTROL.    22100017
*        ----------------------------------------------------OCL001-TSS 22150001
         EJECT                                                          22200017
*    CHECK ALL FILES IN OPEN STACK - BUT DONT RAISE 'UNDEFINEDFILE'YET. 22300017
         SPACE                                                          22400017
         LR    RG,RF                    SAVE P.LIST POINTER.            22500017
OCLPA    EQU   *                                                        22600017
         L     RD,ODCL                  GET A(DCLCB).                   22700017
         LH    RE,DPRO                  GET P.R.OFFSET OF FIL REG.      22800017
         L     RC,0(RE,PR)              GET A(FCB).                     22900017
         LA    RC,0(RC)                  *                              23000017
         ALR   RE,PR                    GET A(F.R).                     23100017
         LTR   RC,RC                 +  A(FCB) SET.                     23200017
         BZ    OCBMP                    NO-ERROR HAS ARISEN.            23300017
         L     BR,TDCB                  GET A(DCB).                     23400017
         XC    DCBEXLST+1(3),DCBEXLST+1 ZERO EXIT LIST.                 23500017
         TM    DCBOFLGS,OPEN         +  FILE OPENED CORRECTLY.          23600017
         BZ    OCFRE                    NO.                             23700017
         TM    0(RE),X'FF'           +  YES,ERROR FLAG SET.             23800017
         BNZ   OPCLS                                                    23900017
         TM    TFTY,TMRC+TMST        +  STREAM..                        24000017
         BNZ   OCBPM                                                    24100017
         TM    TFHT,TMCC             +  FILE RECENTLY OPENED?           24200017
         MVI   TFHT,0                   CLEAR HISTORY BYTE.             24300017
         BZ    OCBPM                    NO.                             24400017
         LR    RA,RC                    ADDRESS OF FCB.                 24500017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL999-TSS 24550020
         L     BR,VIOFA                                                 24600017
*        ----------------------------------------------------OCL999-TSS 24650020
         BALR  LR,BR                    GET A RECORD.                   24700017
         TM    TFMD,TMAS             +  PRINT FILE?                     24800017
         BZ    OCBPM                                                    24900017
         CLC   DPRO(2),IQSPR         +  SYSPRINT..                      25000017
         BNE   OCLNS                    NO                              25100017
         OI    TFFP,TMPT                SET TO SAY SYSPRINT             25200017
OCLNS    EQU   *                                                        25300017
         L     RA,TCBA                  ADDRESS ASA                     25400017
         BCTR  RA,0                     BYTE.                           25500017
         MVC   0(1,RA),MEJT             SET EJECT CHARACTER.            25600017
         LA    RA,1                                                     25700017
         STH   RA,TLNN                  SET LINE NUMBER = 1.            25800017
         NI    TFLX,255-TMEP            CLEAR ENDPAGE FLAG.             25900017
         B     OCBPM                                                    26000017
*    FILE MUST BE CLOSED AS PSEODO DEFAULT WAS APPLIED AT 'DCBEXIT'.    26100017
         SPACE                                                          26200017
OPCLS    EQU   *                                                        26300017
         LA    R0,20                                                    26400017
         NI    TFHT,255-TMCC         /  RESET RECENTLY OPENED FLAG.     26500017
         IHEPRV VDA,BR                                                  26600017
         BALR  LR,BR                 $$ GET VDA FOR CLOSE P.LIST.       26700017
         LA    RA,8(RA)                                                 26800017
         ST    RD,0(RA)                 SET UP P.LIST FOR CLOSE.        26900017
         SR    BR,BR                     *                              27000017
         ST    BR,4(RA)                  *                              27100017
         ST    BR,8(RA)                  *                              27200017
         OI    8(RA),MEOL            /   * SET END OF LIST.             27300017
         ST    RA,OCPL                   *                              27400017
         LA    RA,OCPL                   *                              27500017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL002-TSS 27550001
         LINK  EP=IHECLTA,MF=(E,(1))    LINK CLOSE.                     27600017
*        ----------------------------------------------------OCL002-TSS 27650001
         IHEPRV FVD,BR                                                  27700017
         BALR  LR,BR                 $$  *                              27800017
         B     OCBMP                                                    27900017
         SPACE                                                          28000017
*    CORE WAS GOTTEN BY OPEN FOR AN ERROR FILE - FREE IT.               28100017
         SPACE                                                          28200017
OCFRE    EQU   *                                                        28300017
         XC    1(3,RE),1(RE)            ZERO FCB IN F.R.                28400017
         LH    R0,TLEN                  NO,FREE CORE GOTTEN FOR FCB.    28500017
         A     R0,SUBPL                     *                           28600017
         LR    RA,RC                        *                           28700017
         L     RE,OCAD                 ADDRESS ADCON LIST       36989   28710020
         CLI   IFOPE,VR17              TEST IF R17 OR LATER     36989   28720020
         BL    OCL16                   BRANCH IF NOT            36989   28730020
         SH    RA,HAIT                 POINT RA AT FCB PREFIX   36989   28740020
         AH    R0,HAIT                 ADJUST THE LENGTH        36989   28750020
OCL16    EQU   *                                                36989   28760020
         FREEMAIN R,LV=(0),A=(1)     $$     *                           28800017
OCBMP    EQU   *                                                        28900017
OCBPM    EQU   *                                                        29000017
         TM    OEOL,MEOL             +  END OF LIST YET.                29100017
         BO    OCLPB                                                    29200017
         LA    RF,PLOF(RF)              BUMP P.LIST POINTER             29300017
         B     OCLPA                                                    29400017
         SPACE                                                          29500017
*    CHECK ALL FILES FOR ERROR AND RAISE 'UNDF' ERROR IF NECESSARY.     29600017
         SPACE                                                          29700017
OCLPB    EQU   *                                                        29800017
         LR    RF,RG                    GET P.LIST POINTER.             29900017
OCLP1    EQU   *                                                        30000017
         L     RD,ODCL                  GET A(DCLCB).                   30100017
         LH    RE,DPRO                  GET FILE REG OFFSET.            30200017
         L     RC,0(RE,PR)              GET A(FCB).                     30300017
         LA    RC,0(RC)                                                 30400017
         ALR   RE,PR                    A(FILE REGISTER).               30500017
         LTR   RC,RC                 +  FILE REGISTER SET.              30600017
         BNZ   OCLP2                    YES.                            30700017
         LH    RG,UNDEF                 TOP BYTE OF ERROR CODE          30800017
         IC    RG,0(RE)                 INSERT LOWER BYTE OF ERROR CODE 30900017
         LR    RA,RG                    ERROR CODE FOR ERROR SLOT       31000017
         LA    RG,128(RG)               SET CANNOT BE OPENED FLAG       31100017
         STC   RG,0(RE)                 REPLACE ERROR CODE IN F.R.      31200017
         L     RB,OOCL                  GET A(OCB).                     31300017
         LTR   RB,RB                 +  OCB EXIST FOR THIS FILE.        31400017
         BZ    OCERB                    NO.                             31500017
         TM    0(RB),SYSP            +  PRINT CALL TO OPEN.             31600017
         BO    OCLPX                    YES DONT RAISE ERROR COND       31700017
OCERB    EQU   *                        NO,RAISE ERROR CONDITION.       31800017
         IHEPRV ERR,RA,OP=STH           PUT ERROR CODE IN ERROR SLOT.   31900017
         IHEPRV CFL,RD,OP=ST         /  SET CURRENT FILE.               32000017
         ST    RD,WFIL                  SET WFIL IN CASE OF ONFILE      32100017
         LR    RA,RD                    SET UP P.LIST FOR EXEP.         32200017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL998-TSS 32250020
         L     BR,VERRB                                                 32300017
*        ----------------------------------------------------OCL998-TSS 32350020
         BALR  LR,BR                 ** RAISE'UNDEFINED FILE'ERROR.     32400017
         B     OCLPX                                                    32500017
OCLP2    EQU   *                                                        32600017
         NI    TFHE,255-TMOC         /  RESET OPEN-CLOSE FLAG.          32700017
OCLPX    EQU   *                                                        32800017
         TM    OEOL,MEOL             +  END OF LIST.                    32900017
         BO    OCLNK                    YES.                            33000017
         LA    RF,PLOF(RF)              NO,BUMP P.LIST POINTER          33100017
         B     OCLP1                                                    33200017
         EJECT                                                          33300017
OCCLS    EQU   *                                                        33400017
         L     RD,ODCL                  A(DCLCB).                       33500017
         LH    RE,DPRO                  GET A(FCB).                     33600017
         L     RC,0(RE,PR)               *                              33700017
         LA    RC,0(RC)                  *                              33800017
         LTR   RC,RC                 +  FILE OPEN.                      33900017
         BZ    OCL04                    NO.                             34000017
         IHEPRV FOP,BR                  GET A(FIRST OPEN FILE FCB).     34100017
         OI    TFHT,TMCC             /  SET PREVENT CLOSE FAG.          34200017
OCL05    EQU   *                                                        34300017
         LA    BR,0(BR)                 REMOVE TOP BYTE.                34400017
         LTR   BR,BR                 +  END OF CHAIN?                   34500017
         BZ    OCL04                                                    34600017
         CR    RC,BR                 +  WAS FILE OPENED IN TASK.        34700017
         L     BR,TFOP-TBEG(BR)         GET NEXT FILE.                  34800017
         BNE   OCL05                    LOOP IF FILE NOT FOUND.         34900017
         NI    TFHT,255-TMCC         /  RESET PREVENT CLOSE FLAG.       35000017
OCL02    EQU   *                                                        35100017
         BAL   RH,OCLRS                 CALL PROCESS SUBROUTINE.        35200017
OCL04    EQU   *                                                        35300017
         TM    8(RF),MEOL            +  END OF LIST YET.                35400017
         BO    OCL03                    YES.                            35500017
         LA    RF,12(RF)                NO, BUMP P.LIST POINTER.        35600017
         B     OCCLS                                                    35700017
OCL03    EQU   *                                                        35800017
         LA    RA,OCPL                  GET A(P.LIST).                  35900017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL003-TSS 35950001
         LINK  EP=IHECLTA,MF=(E,(1))    GET CLOSE AND PASS IT CONTROL.  36000017
*        ----------------------------------------------------OCL003-TSS 36050001
         L     RF,OCPL                  GET A(CLOSE P.LIST).            36100017
OCWTA    EQU   *                                                        36200017
         L     RD,ODCL                  GET A(DCLCB).                   36300017
         LH    RE,DPRO                  GET A(FCB).                     36400017
         L     RC,0(RE,PR)               *                              36500017
         LA    RC,0(RC)                  *                              36600017
         LTR   RC,RC                 +  FILE OPEN..                     36700017
         BZ    OCWTB                                                    36800017
         NI    TFHT,255-TMCL-TMCC    /  RESET CLOSE FLAGS.              36900017
OCWTB    EQU   *                                                        37000017
         TM    8(RF),MEOL            +  END OF LIST..                   37100017
         BO    OCLNK                    YES.                            37200017
         LA    RF,12(RF)                NO. BUMP P.LIST POINTER.        37300017
         B     OCWTA                                                    37400017
OCLNK    EQU   *                                                        37500017
         L     BR,OFDR(DR)                                              37600017
         IHEPRV CFL,RB,OP=LA            UNSTACK CURRENT FILE.           37700017
         MVC   1(7,RB),OFCF+1(BR)                                       37800017
         NI    OFCF+4(BR),255-MCFL      UNSET P.R. ACTIVE FLAG.         37900017
         TM    BRBR,X'04'            +  IMPLICIT OPEN?                  38000017
         BNZ   OCIM2                    YES.                            38100017
         LR    DR,BR                                                    38200017
         LM    LR,PWR,OFLR(DR)          RESTORE CALLERS REGISTERS.      38300017
         BR    LR                    X  RETURN TO CALLER.               38400017
         EJECT                                                          38500017
OCIMP    EQU   *                                                        38600017
         TM    BRBR,X'02'               IMPLICIT CLOSE?                 38700017
         BO    OCICL                                                    38800017
         MVC   DEP1(IOEPL),IOEP1        PLACE P.LIST IN LWS.            38900017
         ST    RB,DEP1                  A(DCLCB) IN PLIST.              39000017
         ST    RA,DEP1+4                A(OCB) IN PLIST.                39100017
         USING IHEZDCL,RB                                               39200017
         CLI   1(RA),0                  TEST IF INPUT FROM IOG.         39300017
         BNE   IOENU                    NO.                             39400017
         LR    RD,RB                    MOVE A(DCLCB).                  39500017
         TM    DCLA+1,OUTP              IS IT OUTPUT?                   39600017
         BO    IOER3                    YES RAISE UNDEFINED FILE.       39700017
IOENU    EQU   *                                                        39800017
         LA    RA,DEP1                  A(OPEN PARAMETER LIST)          39900017
         B     OCLIJ                                                    40000017
         SPACE                                                          40100017
OCIM2    L     RD,0(RE)                 CONTENTS OF FILE REGISTER.      40200017
         LA    RD,0(RD)                 LOSE TOP BYTE.                  40300017
         LTR   RD,RD                    TEST IF ZERO                    40400017
         BZ    IOER2                    NO                              40500017
IOER1    EQU   *                                                        40600017
         USING IHEZLCA,RI                                               40700017
         IHEPRV LCA,RI,OP=L                                             40800017
         L     DR,OFDR(DR)              RESTORE CALLERS REGISTERS       40900017
         LM    LR,WR,OFLR(DR)                                           41000017
         BR    LR                       RETURN.                         41100017
IOER3    EQU   *                                                        41200017
         LH    RD,DPRO            34383 GET P.R.OFFSET                  41230020
         ALR   RD,PR              34383 ADDRESS P.R.FOR FILE            41260020
         MVI   0(RD),ATCN               ERROR CODE FOR ATTR. CONFLICT   41300017
         MVC   WFIL(4),DEP1             SET ONFILE SLOT.                41400017
         LH    RA,ERRB                  ERROR CODE (UNDEFINED FILE)     41500017
         IHEPRV ERR,RA,OP=STH           PUT ERROR CODE IN ERROR SLOT    41600017
         LR    RA,RB                    A(DCLCB)                        41700017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL997-TSS 41750020
         L     BR,VERRB                 A(ERROR MODULE)                 41800017
*        ----------------------------------------------------OCL997-TSS 41850020
         BALR  LR,BR                    RAISE *UNDEFINED * FILE ERROR   41900017
IOER2    EQU   *                                                        42000017
         MVC   WFIL(4),DEP1             SET ONFILE SLOT.                42100017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL996-TSS 42150020
         L     BR,VERRC                 A(ERROR MODULE)                 42200017
*        ----------------------------------------------------OCL996-TSS 42250020
         BALR  RA,BR                    GO TO ERROR (NO RETURN)         42300017
         DC    AL2(ERR1)                ERROR CODE                      42400017
*  SKELETON PLIST FOR BRANCH TO OCLA                                    42500017
         SPACE                                                          42600017
IOEP1    DC    A(*-*)                                                   42700017
         DC    A(*-*)                                                   42800017
         DC    5A(0)                                                    42900017
         DC    X'80'                                                    43000017
         DC    AL3(0)                                                   43100017
IOEPL    EQU   *-IOEP1                                                  43200017
ERRB     DC    X'C801'                                                  43300017
         EJECT                                                          43400017
*   IMPLICIT CLOSE                                                      43500017
         SPACE                                                          43600017
OCICL    EQU   *                                                        43700017
         LR    RI,RA                    SAVE CURRENT P.R.V. ADDRESS.    43800017
OMF00    EQU   *                                                        43900017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL007-TSS 43950001
         L     RB,0(RI)                 GET                             44000017
         ORG   *-2                      FILES-OPEN                      44100017
         DC    QL2(IHEQFOP)             CHAIN POINTER.                  44200017
*        ----------------------------------------------------OCL007-TSS 44250001
         LR    RD,RB                    SAVE POINTER.                   44300017
         SR    RC,RC                    ZERO FILE COUNT.                44400017
OMF01    EQU   *                                                        44500017
         LTR   RB,RB                 +  END QFOP CHAIN?                 44600017
         BZ    OMF02                    YES.                            44700017
         LA    RC,4(RC)                 COUNT ONE FILE.                 44800017
         L     RB,TFOP-TBEG(RB)         STEP DOWN QFOP CHAIN.           44900017
         LA    RB,0(RB)                 REMOVE TOP BYTE.                45000017
         B     OMF01                                                    45100017
OMF02    EQU   *                                                        45200017
         LTR   RC,RC                 +  ANY FILES?                      45300017
         BZ    OMF05                    NO.                             45400017
         LA    R0,16(RC)                SIZE OF VDA.                    45500017
         IHEPRV VDA,BR                                                  45600017
         BALR  LR,BR                 $$ GET A VDA FOR CLTB CALL.        45700017
         ST    RC,8(RA)                 STORE FILE COUNT * 4.           45800017
         MVC   12(4,RA),OCAD            MOVE A (ADCON LIST).            45900017
         LA    RC,8(RA)                 POINT AT CLTB CALL SEQ.         46000017
OMF03    EQU   *                                                        46100017
         ST    RD,16(RA)                STORE AN FCB ADDRESS.           46200017
         LA    RA,4(RA)                                                 46300017
         L     RD,TFOP-TBEG(RD)         STEP DOWN QFOP CHAIN.           46400017
         LA    RD,0(RD)                 REMOVE TOP OF BYTE.             46500017
         LTR   RD,RD                    END OF CHAIN.                   46600017
         BNZ   OMF03                                                    46700017
OMF04    EQU   *                                                        46800017
         LR    RA,RC                    RESTORE CLTB CALL SEQ.          46900017
         LA    RC,4(RC)                 STEP OVER ADCON POINTER.        47000017
         A     RC,0(RA)                 POINT AT LAST FCB ADDRESS.      47100017
         MVI   0(RC),X'80'              MARK LAST FCB ADDRESS.          47200017
         LA    RB,4(RA)                 RB = A(FIRST FCB-4) .           47300017
         ST    RA,RARA                                                  47400017
OMF06    EQU   *                                                        47500017
         LA    RB,4(RB)                 POINT AT NEXT FCB ADDRESS.      47600017
         ST    RB,RBRB                                                  47700017
         L     RC,0(RB)                 GET FCB ADDRESS.                47800017
         OI    TFHE,TMOC             /  SET OPEN-CLOSE FLAG.            47900017
         BAL   RH,OCLRS                 CALL PROCESS SUBROUTINE.        48000017
         L     RB,RBRB                                                  48100017
         TM    0(RB),X'80'              LAST FCB ADDRESS?               48200017
         BZ    OMF06                    NO.                             48300017
         L     RA,RARA                                                  48400017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL004-TSS 48450001
         LINK  EP=IHECLTB,MF=(E,(1))    CLOSE FILES.                    48500017
*        ----------------------------------------------------OCL004-TSS 48550001
         IHEPRV FVD,BR                                                  48600017
         BALR  LR,BR                                                    48700017
OMF05    EQU   *                                                        48800017
         L     DR,OFDR(DR)                                              48900017
         LM    LR,WR,OFLR(DR)                                           49000017
         BR    LR                      RETURN TO CALLERR.               49100017
         SPACE                                                          49200017
         EJECT                                                          49300017
OCLRS    EQU   *                                                        49400017
         OI    TFHT,TMCL             /  SET CLOSE IN PRGRESS FLAG?      49500017
         TM    TFTY,TMDS+TMRC+TMST   +  STREAM I/O?                     49600017
         BM    OCLR1                    NO.                             49700017
         TM    TFLA,TMOP+TMUN        +  YES. UNDEFINED OUTPUT RECORDS?  49800017
         BC    12,OCLR1                 NO.                             49900017
         LR    RA,RD                                                    50000017
         TM    BRBR,X'04'            +  IMPLICIT CLOSE?                 50100017
         BZ    OCLR2                    NO.                             50200017
         OI    TFER,TMNX             /  SET FLAG TO PREVENT ERROR.      50300017
         L     RA,TDCL                  GET A(DCLCB).                   50400017
         LA    RA,0(RA)                 REMOVE TOP BYTE.                50500017
OCLR2    EQU   *                                                        50600017
         L     BR,OCAD                 GET ADDR OF ADCONS LIST   38165  50640020
         LH    BR,IQLCA-ISADF(BR)      P.R.OFFSET OF LCA PTR     38165  50680020
         L     BR,0(BR,PR)             GET A(LCA)                38156  50720020
         ST    RA,WFIL-WBR1(BR)        SET WFIL IN CASE OFONFILE 38156  50760020
         LR    RA,RC                    MOVE A(FCB).                    50800017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL995-TSS 50850020
         L     BR,VIOFA                                                 50900017
*        ----------------------------------------------------OCL995-TSS 50950020
         BALR  LR,BR                    FLUSH RECORD.                   51000017
OCLR1    EQU   *                                                        51100017
         L     BR,TDCB               LOAD ADD.  DCB                     51200017
         TM    TFHT,TMLT             +  WAS LAST OP. A LOCATE           51300017
         BZ    CL040                    NO                              51400017
         TM    DCBRECFM,SPAN         +  SPANNED RECORDS                 51500017
         BO    CLSP3                 *  YES                             51600017
         CLI   TFAC,TMQT             +  IS IT QTAM                      51630001
         BE    CLSP3                 *  YES,                            51660001
         CLI   TFAC,TMQI             +  QISAM                           51700017
         BNE   CL040                     NO                             51800017
         LH    RD,DCBRKP                GET R.K.P.                      51900017
         LTR   RD,RD                 +  IS IT 0?                        52000017
         BZ    CL040                    YES .                           52100017
         TM    TFRC,TMVB             +  V FORMAT INDEXED...             52110001
         BZ    OCLR3                 *  NO.                             52120001
         CH    RD,X04X               +  YES, RKP = 4...                 52130001
         BE    CL040                 *  YES.                            52140001
OCLR3    EQU   *                        NO.                             52150001
         A     RD,TCBA                  FIND ADDRESS OF EMBEDDED KEY.   52200017
         SR    LR,LR                    GET                             52300017
         IC    LR,DCBKEYLE              KEYLENGTH.                      52400017
         BCTR  LR,0                     MINUS ONE FOR EXECUTE.          52500017
         L     RB,TPKA                  ADDRESS OF PREVIOUS KEY.        52600017
         EX    LR,CLCP1                 COMPARE                         52700017
         BNE   CLMES                    KEY ERROR                       52800017
CL040    EQU   *                                                        52900017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL014-TSS 52950020
         CLI   TFAC,TMBL                BSAM LOAD MODE?                 53000017
         BNE   CL001                    NO.                             53100017
         TM    TFHT,TMET                END OF EXTENT.                  53200017
         BO    CL001                    YES.                            53300017
CLSP3    EQU   *                                                        53400017
         TM    TFER,TMOE                TRANSMIT ERROR.                 53500017
         BO    CL001                    YES.                            53600017
         TM    BRBR,X'04'               IMPLICIT CLOSE..                53700017
         BZ    CL041                    NO.                             53800017
         OI    TFHT,TMCT             /  YES. SET FLAG.                  53900017
CL041    EQU   *                                                        54000017
         MVC   ITCPL(20),CLITC          MOVE ITC PLIST INTO WORKSPACE.  54100017
         ST    RD,ITCPL                 A(DCLCB) IN PLIST.              54200017
         LA    RB,ITCPL                 A(PLISTFOR ITC MOD.)            54300017
         L     BR,OCAD                                                  54400017
         LH    RA,IQLCA-ISADF(BR)                                       54500017
         L     RA,0(RA,PR)              GET A(LCA).                     54600017
         ST    RD,WFIL-WBR1(RA)         SET WFIL IN CASE OF ON FILE.    54700017
         LR    RA,RC                    A(FCB)                          54800017
         L     BR,TACM                  A(IHEITCA).                     54900017
         LA    LR,CL042                 RETURN ADDRESS                  55000017
         STM   LR,WR,OFLR(DR)           SAVE FOR ITC TO RESTORE         55100017
         IHESDR LW1,LR                  GET WORKSPACE FOR ITC           55200017
         BR    BR                                                       55300017
CL042    EQU   *                                                        55400017
         TM    TFHT,TMCC+TMCT        +  IMPLICIT CLOSE AND ERROR        55500017
         BO    CLMET                    KEY ERROR                       55600017
CL001    EQU   *                                                        55700017
         BR    RH                                                       55800017
         SPACE                                                          55900017
CLMES    EX    LR,CLMV1                 CORRECT KEY                     56000017
CLMET    LA    R0,180                                                   56100017
         GETMAIN R,LV=(0)               AREA FOR MESSAGE                56200017
         ST    DR,0(RA)                                                 56300017
         LR    DR,RA                                                    56400017
         LINK  EP=IHETOME               MODULE TO PUT OUT MESSAGE       56500017
         LA    R0,180                                                   56600017
         LR    RA,DR                                                    56700017
         L     DR,0(DR)                                                 56800017
         FREEMAIN R,LV=(0),A=(1)        FREE AREA                       56900017
         NI    TFHT,255-TMCC         /  ALLOW CLOSE TO OCCUR.           57000017
         B     CL001                                                    57100017
         SPACE                                                          57200017
CLITC    DC    A(0)                     ITC PLIST SKELETON.             57300017
         DC    A(CLRDV)                  *                              57400017
         DC    A(0)                      *                              57500017
         DC    A(CLKSV)                  *                              57600017
         DC    A(CLREQ)                  *                              57700017
CLREQ    DC    X'04080000'              REQUEST CODES.                  57800017
CLKSV    DC    A(CLKWD)                                                 57900017
         DC    H'8,8'                                                   58000017
CLRDV    DC    A(CLKWD)                                                 58100017
         DC    A(8)                                                     58200017
CLKWD    DC    C'99999999'                                              58300017
*        ----------------------------------------------------OCL014-TSS 58350020
CLCP1    CLC   0(0,RD),0(RB)                                            58400017
CLMV1    MVC   0(0,RD),0(RB)                                            58500017
KEYY     DC    X'A805'                                                  58600017
ATCN     EQU   X'81'                                                    58700017
OUTP     EQU   X'02'                                                    58800017
SPAN     EQU   X'48'                    SPANNED BITS IN DCB.            58900017
         DS    0H                                                       59000017
UNDEF    DC    XL2'C800'                                                59100017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL008-TSS 59150020
VIOFA    DC    V(IHEIOFA)               FLUSH BUFFER MODULE.            59200017
SUBPL    DC    X'01000000'                                              59300017
*        ----------------------------------------------------OCL008-TSS 59350001
         DS    0A                                                       59400017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL994-TSS 59450020
VERRB    DC    V(IHEERRB)               ON ERROR ENTRY.                 59500017
VERRC    DC    V(IHEERRC)                                               59600017
*        ----------------------------------------------------OCL994-TSS 59610020
MEJT     DC    C'1'                                                     59700017
XAL1     DC    X'FF000000'                                              59800017
HONE     DC    H'1'                                                     59900017
X04X     DC    H'4'                                                     59950001
HAIT     DC    H'8'                                                     60000017
HOFV     DC    AL2(BECB-BBEG)                                           60100017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OCL009-TSS 60150001
IQSPR    DC    QL2(IHEQSPR)                                             60200017
*        ----------------------------------------------------OCL009-TSS 60250001
         END                                                            60300017
