OPN      TITLE    'IHEOPN    OPEN PHASE I                              /00100013
               OS/360 PL/I LIBRARY'                                     00200013
*   VERSION    THIRD  VERSION OF F-LEVEL PL/1 COMPILER                  00300013
*                                                                       00400013
*   STATUS     CHANGE LEVEL - 0                                         00500013
*                                                                       00600013
*   SIZE       768 BYTES.                                               00700013
*                                                                       00800013
*   FUNCTION   PREPARATION FOR OPENING FILES.- PHASE I.                 00900013
*               THIS MODULE IS LINKED BY THE BOOTSTRAP MODULE (IHEOCL). 01000013
*               THE MAIN FUNCTION IS TO CHECK THAT THE FILE ATTRIBUTES  01100013
*               DO NOT CONFLICT WITH THE OPEN STATEMENT OPTIONS.        01200013
*               THE TABLE BELOW INDICATES WHERE CONFLICTS CAN OCCUR.    01300013
*                                                                       01400013
*           ..........................................................  01500013
*           .        . I . O . U . R . S . D . S . B . B . U . E . P .  01600013
*           .        . N . U . P . E . T . I . E . A . U . N . X . R .  01700013
*           .        . P . T . D . C . R . R . Q . C . F . B . C . I .  01800013
*           .        . U . P . A . O . E . E . N . K . F . U . L . N .  01900013
*           .        . T . U . T . R . A . C . T . W . E . F . S . T .  02000013
*           .        .   . T . E . D . M . T . L . D . R . F . V .   .  02100013
*           ..........................................................  02200013
*           . INPUT  .   . C . C .   .   .   .   .   .   .   . C . C .  02300013
*           ..........................................................  02400013
*           . OUTPUT . C .   . C .   .   .   .   . C .   .   . C .   .  02500013
*           ..........................................................  02600013
*           . UPDATE . C . C .   .   . C .   .   . C .   .   .   . C .  02700013
*           ..........................................................  02800013
*           . RECORD .   .   .   .   . C .   .   .   .   .   .   . C .  02900013
*           ..........................................................  03000013
*           . STREAM .   .   . C . C .   . C . C . C . C . C . C .   .  03100013
*           ..........................................................  03200013
*           . DIRECT .   .   .   .   . C .   . C . C . C . C .   . C .  03300013
*           ..........................................................  03400013
*           . SEQNTL .   .   .   .   . C . C .   .   .   .   . C . C .  03500013
*           ..........................................................  03600013
*           . BACKWD .   . C . C .   . C . C .   .   .   .   . C . C .  03700013
*           ..........................................................  03800013
*           . BUFFER .   .   .   .   . C . C .   .   .   . C . C . C .  03900013
*           ..........................................................  04000013
*           . UNBUFF .   .   .   .   . C . C .   .   . C .   . C . C .  04100013
*           ..........................................................  04200013
*           . EXCLSV . C . C .   .   .   .   . C . C . C . C .   . C .  04300013
*           ..........................................................  04400013
*           . PRINT  . C .   . C . C .   . C . C . C . C . C . C .   .  04500013
*           ..........................................................  04600013
*                                                                       04700013
*               IF A CONFLICT ARISES THE HIGH ORDER BYTE OF THE FILE    04800013
*               REGISTER IS SET WITH THE APPROPRIATE ERROR CODE.        04900013
         EJECT                                                          05000013
*               IF THE FILE BEING OPENED IS DIRECT/OUTPUT REGIONAL      05100013
*               THEN THIS MODULE LINKS A SPECIAL MODULE (IHEOPZ)        05200013
*               TO INITIALISE THE PRIME AREA OF THE ALLOCATION.         05300013
*               PREPARATION IS MADE TO PASS TO PHASE II OF THE OPEN     05400013
*               PROCESS THE ATTRIBUTES FOR EACH FILE. THIS IS           05500013
*               ACHIEVED BY PASSING A VDA WITH THE ATTRIBUTES FOR       05600013
*               EACH FILE. EACH FILE HAS AN ENTRY FOR THE ACCESS TYPE,  05700013
*               A(DCLCB) AND THE FILE ATTRIBUTES.                       05800013
*               IF AFTER PROCESSING IS COMPLETE NO FILES ARE FREE FROM  05900013
*               ERROR, THEN THIS MODULE RETURNS TO THE CALLER IN THE    06000013
*               STANDARD WAY. HOWEVER IF THIS IS NOT THE CASE THEN      06100013
*               PHASE II IS GIVEN CONTROL BY THE EXECUTION OF THE       06200013
*               'XCTL' MACRO.                                           06300013
*                                                                       06400013
*   ENTRY POINTS                                                        06500013
*              IHEOPNA -INITIAL PHASE.                                  06600013
*                  RA = A(PLIST)                                        06700013
*                  PLIST = A(OPENPLST)                                  06800013
*                          A(PRIVATE ADCONS)                            06900013
*                  OPENPLST SEE SECTION 'ENTRY POINTS' OF PREFACE TO    07000013
*                  IHEOCL MODULE.                                       07100013
*                                                                       07200013
*   INPUT                                                               07300013
*              DCLCB,FILE REGISTER  (POSSIBLY FCB).                     07400013
*                                                                       07500013
*   OUTPUT                                                              07600013
*              UPDATED FILE REGISTER (ONLY IF FILE IN ERROR).           07700013
*                                                                       07800013
*   EXTERNAL MODULES                                                    07900013
*              LIBRARY MODULES0                                         08000013
*               IHESAD - GET VDA.                                       08100013
*               IHESAF - FREE VDA.                                      08200013
*               IHEOPO - OPEN PHASE II.                                 08300013
*              CONTROL SYSTEM MODULES0                                  08400013
*               XCTL  -  TRANSFER CONTROL.                              08500013
*                                                                       08600013
*   EXITS                                                               08700013
*              NORMAL                                                   08800013
*               N/A.                                                    08900013
*              ERROR                                                    09000013
*               IF ALL FILES WHICH ARE TO BE OPENED ARE FOUND TO HAVE   09100013
*               CONFLICTS THEN A NORMAL RETURN IS MADE BY CALLER'S      09200013
*               LINK REGISTER.                                          09300013
         EJECT                                                          09400013
*   TABLES/WORK AREA                                                    09500013
*              SEE OS/360 PL/I LIBRARY PLM FOR DESCRIPTION OF           09600013
*              FCB,DCLCB,FILE REGISTER.SEE MODULE IHEOCL FOR TABLE      09700013
*              OF PRIVATE ADCONS. WORK-AREA IS OBTAINED FROM DYNAMIC    09800013
*              STORAGE (LWS).                                           09900013
*                                                                       10000013
*   ATTRIBUTES  READ ONLY AND REENTRANT                                 10100013
*                                                                       10200013
*   PRIVATE MACROS                                                      10300013
*              IHELIB,IHEZAP                                            10400013
*                                                                       10500013
*   ASSEMBLY REQUIREMENTS                                               10600013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   10700013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        10800013
*                                                                       10900013
*   NOTES                                                               11000013
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    11100013
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    11200013
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  11300013
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  11400013
*              CONSTANTS, BY REASSEMBLY, WILL RESULT IN A CORRECT       11500013
*              MODULE FOR THE NEW DEFINITIONS.                          11600013
        EJECT                                                           11700013
IHEOPN   CSECT                                                          11800013
         IHELIB                                                         11900013
         IHEZAP                                                         12000013
PARM     DSECT                                                          12100013
ODCL     DS    A                        A(FILE CONTROL BLOCK(DCLB)).    12200013
OOCL     DS    A                        A(OPEN OPTIONS CONTROL BLOCK).  12300013
OTIT     DS    A                        A(TITLE SDV).                   12400013
OIDT     DS    A                        A(IDENT SDV).                   12500013
ODED     DS    A                        A(DED FOR STRING).              12600013
OKEY     DS    A                        A(KEYLENGTH)                    12700013
OLIN     DS    A                        A(LINE SIZE)                    12800013
OEOL     DS    0BL1                     END OF LIST FLAG.               12900013
OPAG     DS    A                        A(PAGE SIZE)                    13000013
         SPACE                                                          13100013
OPCB     DSECT                                                          13200013
OPCB1    DS    BL1                      OPEN OPTIONS.                   13300013
OPCB2    DS    BL1                      OPEN OPTIONS.                   13400013
OPCB3    DS    BL1                      OPEN OPTIONS.                   13500013
OPCB4    DS    BL1                      OPEN OPTIONS.                   13600013
         SPACE                                                          13700013
IHEZLW0  DSECT                                                          13800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPN003-TSS 13850001
         DS    9D                                                       13900013
*        ----------------------------------------------------OPN003-TSS 13950001
OCLPP    DS    A                        P.LIST FOR PHASE 2              14000013
VDAAD    DS    A                        A(VDA) SAVE AREA                14100013
         DS    A                                                        14200013
PARMP    DS    A                        A(PARM LIST) SAVE AREA          14300013
OPZPL    DS    3A                       IHEOPZ PARAMETERS.              14400013
         SPACE                                                          14500013
PARLIST  DSECT                                                          14600013
CTYP     DS    0BL1                     ORGANISATION FOR PHASE 2.       14700013
CDCL     DS    A                        A(DCLCB)                        14800013
COM1     DS    BL1                      COMBINED OPTIONS FROM OPEN-DEC. 14900013
COM2     DS    BL1                      COMBINED OPTIONS FROM OPEN-DEC. 15000013
COM3     DS    BL1                      COMBINED OPTIONS FROM OPEN-DEC. 15100013
COM4     DS    BL1                      COMBINED OPTIONS FROM OPEN-DEC. 15200013
         EJECT                                                          15300013
DATA     EQU   X'10'                    DATA I/O.                       15400013
RECD     EQU   X'20'                    RECORD I/O                      15500013
DRSQ     EQU   X'30'                    DIR/SEQ SPECIFIED               15600013
SEQL     EQU   X'10'                    SEQUENTIAL ACCESS               15700013
DIRT     EQU   X'20'                    DIRECT ACCESS.                  15800013
RGIN     EQU   X'07'                    REGIONAL OR INDEXED SPECIFIED.  15900013
INDX     EQU   X'06'                    INDEXED SPEC.                   16000013
TROP     EQU   X'05'                    TP                              16050001
BUFS     EQU   X'20'                    BUFFERS SPECIFIED.              16100013
BUUN     EQU   X'30'                    BUFF OR UNBUFF SPECIFIED.       16200013
INPT     EQU   X'01'                    INPUT SPECIFIED.                16300013
OUTT     EQU   X'02'                    OUTPUT SPECIFIED.               16400013
UPDT     EQU   X'04'                    UPDATE SPECIFIED                16500013
BCKD     EQU   X'08'                    BACKWARDS SPECIFIED.            16600013
EXCL     EQU   X'40'                    EXCLUSIVE SPECIFIED.            16700013
DELT     EQU   X'04'                    DELETING SPECIFIED.             16800013
KEYD     EQU   X'80'                    KEYED SPECIFIED.                16900013
TRAN     EQU   X'08'                    TRANSIENT FILE                  16950001
ASAS     EQU   X'04'                    ASA CONTROL CHAR.               17000013
MEOL     EQU   X'80'                    END OF LIST.                    17100013
SCP2     EQU   X'00'                    SEQ/CON.                        17200013
SRP2     EQU   X'04'                    SEQ/REG.                        17300013
SIP2     EQU   X'08'                    SEQ/IND.                        17400013
DRP2     EQU   X'0C'                    DIR/REG.                        17500013
DIP2     EQU   X'10'                    DIR/IND.                        17600013
STP2     EQU   X'14'                    SEQ/TP  TYPE BYTE               17650001
VERS     EQU   3                        RELEASE THREE                   17700013
PLOF     EQU   32                       P.LIST ENTRY LENGTH             17800013
AECN     EQU   X'06'                    ATTR. ENV CONFLICTS             17900013
ATCN     EQU   X'01'                    ATTRIBUTE CONFLICTS             18000013
FTNS     EQU   X'02'                    NOT SUPPORTED FLAG              18100013
         EJECT                                                          18200013
*        ENTRY POINTS TO THIS MODULE ARE,                               18300013
         SPACE                                                          18400013
*        ENTRY IHEOPNA.                                                 18500013
         SPACE                                                          18600013
IHEOPN   CSECT                                                          18700013
         ENTRY IHEOPNA                                                  18800013
         SPACE                                                          18900013
         USING *,RJ                                                     19000013
         USING IHEZADC,RI                                               19100013
         USING OPCB,RB                                                  19200013
         USING IHEZDCL,RD                                               19300013
         USING IHEZLW0,WR                                               19400013
         USING PARM,RG                                                  19500013
         USING PARLIST,RF                                               19600013
         SPACE 3                                                        19700013
IHEOPNA  EQU   *                                                        19800013
         STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          19900013
         LR    RJ,BR                    SET UP BASE REGISTER            20000013
         L     RI,4(RA)                 GET A(ADCON LIST)               20100013
         LH    WR,IQLW0                 OFFSET OF LIBWS SLOT IN PRV.    20200013
         L     WR,0(WR,PR)                                              20300013
OPFLG    L     RG,0(RA)                 SET UP PARM LIST                20400013
         ST    DR,OFDR(WR)                                              20500013
         LR    DR,WR                    SET POINTER TO OPEN SAVE AREA   20600013
         ST    RG,PARMP                 SAVE PARM.LIST POINTER          20700013
         ST    RA,OCLPP                 SAVE POINTER                    20800013
         SPACE 2                                                        20900013
         LA    RA,1                                                     21000013
OPTES    EQU   *                                                        21100013
         TM    OEOL,MEOL             +  END OF LIST YET.                21200013
         BO    OPNFS                    YES,NO OF FILES TO OPEN FOUND.  21300013
         LA    RG,PLOF(RG)              NO,BUMP PARM LIST POINTER       21400013
         LA    RA,1(RA)                 BUMP NO OF FILES COUNT.         21500013
         B     OPTES                                                    21600013
OPNFS    EQU   *                                                        21700013
         LR    RB,RA                    SAVE N.                         21800013
         SLL   RA,3                     8*N                             21900013
         LA    R0,12(RA)                8N+12.                          22000013
         L     BR,ISADF                 GET A(GET VDA MODULE).          22100013
         BALR  LR,BR                 $$ GET VDA                         22200013
         SLL   RB,2                     4*N.                            22300013
         ST    RB,8(RA)                 SAVE 4*N IN VDA (FOR PHASE 2).  22400013
         LA    RF,4(RA)                                                 22500013
         LA    RA,8(RA)                 SET A(VDA) IN WORKSPACE.        22600013
         ST    RA,VDAAD                 SAVE A(VDA)                     22700013
         L     RG,PARMP                 GET A(PARM LIST) POINTER.       22800013
         EJECT                                                          22900013
OPLP1    EQU   *                                                        23000013
         LA    RF,8(RF)                 BUMP DAMT P.LIST POINTER        23100013
         SR    RD,RD                                                    23200013
         ST    RD,0(RF)                                                 23300013
OPLP2    EQU   *                                                        23400013
         L     RD,ODCL                  A(DEC BLOCK).                   23500013
         L     RB,OOCL                  A(OPEN OPTIONS BLOCK).          23600013
         LTR   RB,RB                 +  OCB SPECIFIED.                  23700013
         BP    OPOCS                    YES.                            23800013
         LA    RB,OOCL                                                  23900013
OPOCS    EQU   *                                                        24000013
         LH    RH,DPRO                  GET P.R.OFFSET.                 24100013
         ALR   RH,PR                    A(P.R.).                        24200013
         NC    1(3,RH),1(RH)         +  FILE OPEN.                      24300013
         BZ    OPGEM                    NO.                             24400013
OPSER    EQU   *                                                        24500013
         TM    OEOL,MEOL             +  YES,ANY MORE FILES.             24600013
         BO    OPTAO                    NO,GO TEST IF ANY LEFT TO OPEN. 24700013
         LA    RG,PLOF(RG)              BUMP P.LIST POINTER             24800013
         B     OPLP2                                                    24900013
OPTAO    EQU   *                                                        25000013
         SH    RF,X08X                                                  25100013
         CL    RF,VDAAD              +  ANY FILES LEFT TO BE OPENED     25200013
         BNH   OPEND                    NO.                             25300013
         B     OPEP1                    YES.                            25400013
OPGEM    EQU   *                                                        25500013
         MVI   0(RH),0                  ZERO HIGH ORDER BYTE OF F.REG.  25600013
         LH    RC,DCLA                  MOVE DCL ATTRIBUTES INTO        25700013
         STH   RC,COM1                   COMBINED ATTRIBUTE AREA.       25800013
         LH    RC,DCLB                    *                             25900013
         STH   RC,COM3                    *                             26000013
         OC    COM1(4),OPCB1            GET LOGICAL SUM OF ATTRIBUTES.  26100013
         EJECT                                                          26200013
*   CHECK ATTRIBUTES ON OPEN STATEMENT WITH THOSE ON THE DCL STATEMENT. 26300013
         SPACE                                                          26400013
         L     RC,COM1                  GET ATTRIBUTES.                 26500013
         LR    RE,RC                    SAVE ATTRIBUTES.                26600013
         SPACE                                                          26700013
*   (0)  CHECK FOR CONFLICTS WITH 'TRANSIENT' RECORD I/O                26709001
         SPACE                                                          26718001
         TM    COM3,TRAN                TRANSIENT SPECIFIED             26727001
         BNO   OPNTN                 *  NO,                             26736001
         OI    COM1,RECD             /  DEFAULT RECORD                  26745001
         N     RC,TRANCON            +  ANY CONFLICT WITH TRANSIENT     26754001
         BM    OPER0                 ** YES,  ERROR                     26763001
         B     OPNPF                 *  NO, GO CHECK FOR OTHERS         26772001
OPNTN    EQU   *                                                        26781001
         SPACE                                                          26790001
*    (1)  CHECK FOR CONFLICTS WITH'DATA STREAM I/O'.                    26800013
         SPACE                                                          26900013
         TM    COM1,DATA             +  DATA STREAM SPECIFIED.          27000013
         BZ    OPNDS                    NO.                             27100013
         N     RC,DATACON            +  ANY CONFLICTS WITH DATA STREAM. 27200013
         BM    OPER1                 ** YES-ERROR.                      27300013
OPNDS    EQU   *                        NO.                             27400013
         SPACE                                                          27500013
*    (2)  CHECK FOR CONFLICTS WITH'PRINT'FILES.                         27600013
         SPACE                                                          27700013
         TM    COM4,ASAS             +  PRINT FILE SPECIFIED.           27800013
         BZ    OPNPF                    NO.                             27900013
         LR    RC,RE                    YES.                            28000013
         N     RC,PRINTCON           +  ANY CONFLICTS WITH PRINT FILE.  28100013
         BM    OPER2                 ** YES - ERROR.                    28200013
         OI    COM1,DATA             /  DATA STREAM DEFAULT             28250001
OPNPF    EQU   *                        NO.                             28300013
         SPACE                                                          28400013
*    (3)  CHECK FOR'SEQUENTIAL'CONFLICTS.                               28500013
         SPACE                                                          28600013
         TM    COM2,SEQL             +  SEQUENTIAL SPECIFIED.           28700013
         BZ    OPNSQ                    NO.                             28800013
         LR    RC,RE                    YES.                            28900013
         N     RC,SEQTCON            +  ANY CONFLICTS WITH SEQUENTIAL.  29000013
         BM    OPER3                 ** YES - ERROR.                    29100013
OPNSQ    EQU   *                        NO.                             29200013
         SPACE                                                          29300013
*    (4)  CHECK FOR'DIRECT'CONFLICTS.                                   29400013
         SPACE                                                          29500013
         TM    COM2,DIRT             +  DIRECT SPECIFIED.               29600013
         BZ    OPNDR                    NO.                             29700013
         OI    COM3,KEYD             /  SET KEYED ATTRIBUTE  (DEFAULT). 29800013
         LR    RC,RE                    YES.                            29900013
         N     RC,DIRTCON            +  ANY CONFLICTS WITH DIRECT.      30000013
         BM    OPER4                 ** YES - ERROR.                    30100013
OPNDR    EQU   *                        NO.                             30200013
         SPACE                                                          30300013
*    (5)  CHECK FOR 'INPUT' CONFLICTS.                                  30400013
         SPACE                                                          30500013
         TM    COM2,INPT             +  INPUT SPECIFIED.                30600013
         BZ    OPNIP                    NO.                             30700013
         LR    RC,RE                    YES.                            30800013
         N     RC,INPUTCON           +  ANY CONFLICTS WITH INPUT.       30900013
         BM    OPER5                 ** YES - ERROR.                    31000013
OPNIP    EQU   *                        NO.                             31100013
         EJECT                                                          31200013
*    (6)  CHECK FOR 'OUTPUT' CONFLICTS.                                 31300013
         SPACE                                                          31400013
         TM    COM2,OUTT             +  OUTPUT SPECIFIED.               31500013
         BZ    OPNOP                    NO.                             31600013
         LR    RC,RE                    YES.                            31700013
         N     RC,OUTPTCON           +  ANY CONFLICTS WITH OUTPUT.      31800013
         BM    OPER6                 ** YES - ERROR.                    31900013
OPNOP    EQU   *                        NO.                             32000013
         SPACE                                                          32100013
*    (7)  CHECK FOR 'UPDATE' CONFLICTS.                                 32200013
         SPACE                                                          32300013
         TM    COM2,UPDT             +  UPDATE SPECIFIED.               32400013
         BZ    OPNUP                    NO.                             32500013
         LR    RC,RE                    YES.                            32600013
         N     RC,UPDATCON           +  ANY CONFLICTS WITH UPDATE.      32700013
         BM    OPER7                 ** YES - ERROR.                    32800013
OPNUP    EQU   *                                                        32900013
         SPACE                                                          33000013
*    (8)  CHECK FOR 'BACKWARDS' CONFLICTS.                              33100013
         SPACE                                                          33200013
         TM    COM2,BCKD             +  BACKWARDS SPECIFIED.            33300013
         BZ    OPNBK                    NO.                             33400013
         LR    RC,RE                    YES.                            33500013
         N     RC,BACKCON            +  ANY CONFLICTS WITH BACKWARDS.   33600013
         BM    OPER8                 ** YES - ERROR.                    33700013
OPNBK    EQU   *                                                        33800013
         SPACE                                                          33900013
*    (9)  CHECK FOR 'BUFFERRED' CONFLICTS.                              34000013
         SPACE                                                          34100013
         TM    COM3,BUFS             +  BUFFERS SPECIFIED.              34200013
         BZ    OPNBF                    NO.                             34300013
         LR    RC,RE                    YES.                            34400013
         N     RC,BUFFCON            +  ANY CONFLICTS WITH BUFFERS.     34500013
         BM    OPER9                 ** YES - ERROR.                    34600013
OPNBF    EQU   *                        NO.                             34700013
         EJECT                                                          34800013
*   (11)  CHECK FOR 'KEYED' CONFLICTS.                                  34900013
         SPACE                                                          35000013
         TM    COM3,KEYD             +  KEYED SPECIFIED.                35100013
         BZ    OPNKD                    NO.                             35200013
         TM    COM1,RGIN             +  YES, ORGANISATION SPECIFIED.    35300013
         BZ    OPERB                 ** NO - ERROR.                     35400013
         OI    COM1,RECD             /  YES - SET RECORD I/O (DEFAULT). 35500013
OPNKD    EQU   *                                                        35600013
         SPACE                                                          35700013
*    (12) CHECK FOR 'EXCLUSIVE' CONFLICTS.                              35800013
         SPACE                                                          35900013
         TM    COM3,EXCL             +  EXCLUSIVE SPECIFIED.            36000013
         BZ    OPNEX                    NO.                             36100013
         LR    RC,RE                    YES.                            36200013
         N     RC,EXCLCON            +  ANY CONFLICT WITH EXCLUSIVE..   36300015
         BM    OPERC                 ** YES - ERROR.                    36400013
         OI    COM2,UPDT             /  NO, SET UPDATE BIT (DEFAULT).   36500013
OPNEX    EQU   *                                                        36600013
         SPACE                                                          36700013
         TM    COM2,DRSQ             +  DIRECT/SEQUENTIAL SPECIFIED.    36800013
         BZ    OPDEF                    NO, DEFAULT NEEDED.             36900013
         OI    COM1,RECD             /  SET RECORD I/O FLAG (DEFAULT).  37000013
         TM    COM2,SEQL             +  YES,SEQUENTIAL SPECIFIED.       37100013
         BO    OPSEQ                    YES.                            37200013
         B     OPDIR                    NO.                             37300013
         EJECT                                                          37400013
*    APPLY DEFAULTS TO ATTRIBUTES.                                      37500013
         SPACE                                                          37600013
OPDEF    EQU   *                                                        37700013
         TM    COM1,DATA             +  DATA STREAM I/O SPECIFIED.      37800013
         BO    OPSQ1                    YES - DEFAULT SEQUENTIAL.       37900013
         TM    COM2,BCKD             +  NO,BACKWARDS SPECIFIED.         38000013
         BO    OPSRI                    YES - RECORD I/O,SEQ (DEFAULT). 38100013
         TM    COM3,EXCL             +  NO,EXCLUSIVE SPECIFIED.         38200013
         BZ    OPNDA                    NO.                             38300013
         OI    COM1,RECD             /  SET RECORD I/O BIT.(DEFAULT).   38400013
         B     OPDIR                                                    38500013
OPNDA    EQU   *                                                        38600013
         TM    COM1,RECD             +  RECORD I/O.                     38700013
         BO    OPSQ1                    YES.                            38800013
         TM    COM4,ASAS             +  NO,PRINT FILE.                  38900013
         BO    OPSDI                    YES,DATA STREAM (DEFAULT).      39000013
         TM    COM2,UPDT             +  NO,UPDATE MODE SPECIFIED.       39100013
         BO    OPSRI                    YES,RECORD I/O (DEFAULT).       39200013
         TM    COM3,BUUN             +  NO,BUFFERING NOT SPECIFIED.     39300013
         BZ    OPSDI                    YES,DATA STREAM(DEFAULT).       39400013
OPSRI    EQU   *                        NO                              39500013
         OI    COM1,RECD             /  SET RECORD I/O (DEFAULT).       39600013
         B     OPSQ1                                                    39700013
OPSDI    EQU   *                                                        39800013
         OI    COM1,DATA             /  SET DATA STREAM I/O (DEFAULT).  39900013
         B     OPSQ1                                                    40000013
         SPACE                                                          40100013
*    DETERMINE ACCESS/ORGANISATION METHOD.                              40200013
         SPACE                                                          40300013
OPSEQ    EQU   *                        SEQUENTIAL SPECIFIED.           40400013
OPSQ1    EQU   *                                                        40500013
         TM    COM3,BUUN             +  BUFFERING SPECIFIED             40600013
         BM    OPORG                    YES.                            40700013
         OI    COM3,BUFS             /  NO,SET BUFFERS REQ. (DEFAULT).  40800013
OPORG    EQU   *                                                        40900013
         TM    COM1,RGIN             +  ORGANISATION SPECIFIED.         41000013
         BZ    OPSCN                    NO - CON/SEQ.                   41100013
         TM    COM1,DATA             +  IS IT STREAM I/O                41200013
         BO    OPERB                 ** ERROR,  ORGANISATION INVALID    41300013
         TM    COM1,INDX             +  INDEXED SPECIFIED.              41400013
         BZ    OPSIN                    YES.                            41500013
         B     OPSRG                    NO.                             41600013
OPDIR    EQU   *                        DIRECT SPECIFIED.               41700013
         TM    COM1,RGIN             +  ORGANISATION SPECIFIED.         41800013
         BZ    OPERB                    NO - ERROR.                     41900013
         TM    COM1,INDX             +  YES, INDEXED SPECIFIED.         42000013
         BZ    OPDIN                    YES.                            42100013
         EJECT                                                          42200013
OPDRG    EQU   *                                                        42300013
         MVI   CTYP,DRP2             /  SET DIR/REG FOR PHASE 2.        42400013
         TM    COM2,OUTT             +  OUTPUT SPECIFIED.               42500013
         BZ    OPSDL                    NO.                             42600013
         NI    COM2,255-OUTT                                            42700013
         OI    COM2,UPDT             /  SET UPDATE FLAG.                42800013
         LR    RB,RF                    SET UP PARAMETERS FOR OPZ.      42900013
         LR    RC,RG                     *                              43000013
         STM   RB,RD,OPZPL              YES, SAVE OPZ PARAMETERS.       43100013
         LA    RA,OPZPL                 A(PLIST FOR OPZ).               43200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPN001-TSS 43250001
         LINK  EP=IHEOPZA,MF=(E,(1)) $$ LINK IN IHEOPZA TO INITIALISE.  43300013
*        ----------------------------------------------------OPN001-TSS 43350001
         LH    RA,DPRO                  GET A(PRV SLOT).                43400013
         ALR   RA,PR                     *                              43500013
         TM    0(RA),X'FF'           +  ANY ERRORS FOUND IN OPZ.        43600013
         BM    OPERZ                    YES.                            43700013
         B     OPSDL                                                    43800013
OPDIN    EQU   *                                                        43900013
         TM    COM2,OUTT             +  OUTPUT SPECIFIED.               44000013
         BO    OPERB                 ** YES, CANT HAVE DIR/IND/OUTPUT.  44100013
         MVI   CTYP,DIP2             /  SET DIR/IND FOR PHASE 2.        44200013
         B     OPSDL                                                    44300013
OPSRG    EQU   *                                                        44400013
         MVI   CTYP,SRP2             /  SET SEQ/REG FOR PHASE 2.        44500013
OPSIR    EQU   *                                                        44550015
         TM    COM2,OUTT             +  IS IT OUTPUT                    44600013
         BZ    OPSC1                 *  NO,                             44700013
         TM    COM3,KEYD             +  IS IT KEYED                     44800013
         BZ    OPERB                 ** NO,ERROR (OUTPUT MUST BE KEYED) 44900013
         B     OPSC1                                                    45000013
OPSIN    EQU   *                                                        45100013
         MVI   CTYP,SIP2             /  SET SEQ/IND FOR PHASE 2.        45200013
         B     OPSIR                                                    45300015
OPSCN    EQU   *                                                        45400013
         MVI   CTYP,SCP2             /  SET SEQ/CON FOR PHASE 2.        45500013
         TM    COM3,TRAN             +  IS IT TRANSIENT                 45530001
         BO    OPERB                 ** YES, ERROR                      45560001
OPSC1    EQU   *                                                        45600013
         TM    COM1,TROP             +  IS IT TP                        45610001
         BNO   OPSDL                 *  NO,                             45620001
         TM    COM3,TRAN             +  IS IT TRANSIENT                 45630001
         BNO   OPERB                 ** NO, ERROR ( ATTR. ENV. CONFT )  45640001
         MVI   CTYP,STP2             /  SET SEQ/TP FOR PHASE 2          45650001
OPSDL    EQU   *                                                        45700013
         IC    RE,CTYP                                                  45800013
         ST    RD,CDCL                  SAVE A(DCLCB).                  45900013
         STC   RE,CTYP                                                  46000013
         TM    OEOL,MEOL             +  LAST ENTRY IN P.LIST.           46100013
         BO    OPEP1                    YES.                            46200013
         LA    RG,PLOF(RG)              NO, BUMP P.LIST                 46300013
         B     OPLP1                                                    46400013
OPEP1    EQU   *                                                        46500013
         LA    RA,OCLPP                 GET A(PHASE II PLIST).          46600013
         L     DR,OFDR(DR)              RESTORE CALLER'S SSA POINTER.   46700013
         L     LR,OFLR(DR)              RESTORE LINK REG.               46800013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPN002-TSS 46850001
         XCTL  (2,11),EP=IHEOPOA,MF=(E,(1))  $$ TRANSFER TO PHASE 2.    46900013
*        ----------------------------------------------------OPN002-TSS 46950001
         SPACE 3                                                        47000013
OPEND    EQU   *                                                        47100013
         CLI   IFOPE,VERS               TEST IF THIRD VERSION           47200013
         BNL   OPERM                    YES                             47300013
         L     RG,PARMP                 GET A(PARM LIST) POINTER        47400013
OPERL    EQU   *                                                        47500013
         L     RD,ODCL                  A(DEC BLOCK).                   47600013
         LH    RH,DPRO                  GET P.R. OFFSET                 47700013
         ALR   RH,PR                    A(P.R)                          47800013
         NC    1(3,RH),1(RH)            FILE OPEN                       47900013
         BNZ   OPERK                    YES                             48000013
         XR    RA,RA                                                    48100013
         IC    RA,0(RH)                 GET ERROR BYTE                  48200013
         IC    RA,CONTAB(RA)            FIND REPLACEMENT                48300013
         STC   RA,0(RH)                 STORE NEW ERROR BYTE            48400013
OPERK    EQU   *                                                        48500013
         TM    OEOL,MEOL                YES,ANY MORE FILES              48600013
         BO    OPERM                    NO,                             48700013
         LA    RG,PLOF(RG)              BUMP P.LIST POINTER             48800013
         B     OPERL                                                    48900013
OPERM    EQU   *                                                        49000013
         L     BR,ISAFD                 GET A(FREE VDA MOD.).           49100013
         BALR  LR,BR                 $$ GO TO FREE VDA.                 49200013
         L     DR,OFDR(DR)              RESTORE CALLER'S SSA POINTER.   49300013
         LM    LR,WR,OFLR(DR)           RESTORE CALLER'S REGISTERS.     49400013
         BR    LR                    X  RETURN.                         49500013
         EJECT                                                          49600013
OPERB    EQU   *                                                        49700013
         OI    0(RH),AECN             / ERROR CODE ENV ATTR CONFLICT    49800013
         B     OPERZ                                                    49900013
OPER0    EQU   *                                                        49950001
OPER1    EQU   *                                                        50000013
OPER2    EQU   *                                                        50100013
OPER3    EQU   *                                                        50200013
OPER4    EQU   *                                                        50300013
OPER5    EQU   *                                                        50400013
OPER6    EQU   *                                                        50500013
OPER7    EQU   *                                                        50600013
OPER8    EQU   *                                                        50700013
OPER9    EQU   *                                                        50800013
OPERA    EQU   *                                                        50900013
OPERC    EQU   *                                                        51000013
         OI    0(RH),ATCN             / ERROR CODE FOR ATTR CONFLICT    51100013
OPERZ    EQU   *                                                        51200013
         XC    CDCL,CDCL             +  ZERO ENTRY FOR PHASE II P.LIST. 51300013
         B     OPSER                                                    51400013
         EJECT                                                          51500013
CONTAB   DC    X'00'                                                    51600013
C801     DC    X'02'                    ATTRIBUTE CONFLICT              51700013
C802     DC    X'04'                    FILE TYPE NOT SUPPORTED         51800013
C803     DC    X'06'                    BLOCKSIZE NOT SPECIFIED         51900013
         DC    X'00'                    NO DD CARD                      52000013
C805     DC    X'08'                    TRANSMIT IN OPZ                 52100013
C806     DC    X'02'                    ATTR. AND ENV. CONFLICT         52200013
C807     DC    X'02'                    ENV. AND/OR DD CONFLICT         52300013
C808     DC    X'02'                    KEY LENGTH NOT SPECIFIED        52400013
C809     DC    X'02'                    ERROR IN BLOCKSIZE OR LRECL     52500013
C80A     DC    X'02'                   LINESIZE GT. MAX. LENGTH         52600013
C80B     DC    X'02'                    LRECL TOO SMALL FOR EMB. KEY    52700013
         SPACE 2                                                        52800013
         SPACE 3                                                        52900013
X08X     DC    H'8'                                                     53000013
         CNOP  0,4                                                      53100013
DATACON  DC    XL4'273CF808'            DATA CONFLICT                   53190001
PRINTCON DC    XL4'273DF808'            PRINT CONFLICT                  53280001
SEQTCON  DC    XL4'10204000'            SEQUENTIAL CONFLICT             53370001
DIRTCON  DC    XL4'1018380C'            DIRECT CONFLICT                 53460001
INPUTCON DC    XL4'00064000'            INPUT CONFLICT                  53550001
OUTPTCON DC    XL4'000D4000'            OUTPUT CONFLICT                 53640001
UPDATCON DC    XL4'100B080C'            UPDATE CONFLICT                 53730001
BACKCON  DC    XL4'1726C80C'            BACKWARDS CONFLICT              53820001
BUFFCON  DC    XL4'10205000'            BUFFERED CONFLICT               53910001
EXCLCON  DC    XL4'101B380C'            EXCLUSIVE CONFLICT              54000001
TRANCON  DC    XL4'102C50F8'            TRANSIENT CONFLICT              54090001
         SPACE                                                          54200013
         END   IHEOPNA                                                  54300013
