OPQ      TITLE 'IHEOPQ    OPEN  PHASE IV                               /00100017
               OS/360  PL/1  LIBRARY    '                               00200017
*   VERSION    THIRD VERSION OF F_LEVEL PL/1 COMPILER                   00300017
*                                                                       00320020
*        APAR 31710 FIXED AT OFFSET 212600                 CB           00340020
* APAR 40104 FIXED AT 212600/494600            - CB.                    00343046
*                FOR RELEASE SHOWN BY ID#.                              00346046
*        APAR 35226 FIXED AT CLEAR OFFSET 241000           CB REL 21.   00350042
*                                                                       00360020
*   FUNCTION   FINAL PHASE OF OPENING PROCESS - PHASE IV                00400017
*              THIS MODULE PERFORMS THE FOLLOWING FUNCTIONS.            00500017
*                                                                       00600017
*              1) LOADS ALL THE RECORD I/O MODULES REQUIRED AND SETS    00700017
*                 UP THE ADDRESSING SCHEME IN THE FCB.                  00800017
*                                                                       00900017
*              2) FORMS ENTRY IN FILE CHAINING SCHEME.                  01000017
*                                                                       01100017
*              3) DETERMINES THE ACCESS METHOD FOR CON REG SEQ          01200017
*                 ORGANISATION                                          01300017
*                                                                       01400017
*   ENTRY POINTS                                                        01500017
*              IHEOPQA - OPEN PHASE IV                                  01600017
*                  RA = A(PLIST)                                        01700017
*                  PLIST = A(LWS)                                       01800017
*                  LWS CONTAINS 1) A(OPEN PLST) SEE IHEOCL MODULE.      01900017
*                               2) A(VDA PASSED BY PHASE I OR OPEN).    02000017
*                   THE PHASE I VDA HAS THE FOLLOWING FORM              02100017
*                                                                       02200017
*                     WORD 0  = 4*N WHERE N IS NUMBER OF FILES TO OPEN  02300017
*                     WORD 1  = ACCESS/ORGANISATION (BYTE 1).* 2 WORDS  02400017
*                               A(DCLCB)                     * FOR EACH 02500017
*                     WORD 2  = MERGED FILE ATTRIBUTES.      * FILE     02600017
*                                                                       02700017
*   INPUT                                                               02800017
*              DCLCB,FCB,FILE REGISTER,OPENED FILE                      02900017
*                                                                       03000017
*   OUTPUT                                                              03100017
*              FCB,OPENED FILE                                          03200017
*                                                                       03300017
*   EXTERNAL MODULES                                                    03400017
*              LIBRARY MODULES.                                         03500017
*                                                                       03600017
*               IHESAF _ FREE VDA.                                      03700017
*                                                                       03800017
*              CONTROL SYSTEM MODULES                                   03900017
*                                                                       04000017
*               GETMAIN  'R' TYPE                                       04100017
*               LOAD                                                    04200017
*               FREEPOOL                                                04300017
*                                                                       04400017
*                                                                       04500017
*   EXITS                                                               04600017
*              RETURN TO OCL VIA LINK REGISTER                          04700017
*                                                                       04800017
*   TABLES/WORK AREA                                                    04900017
*              SEE OS/360 PL/1 LIBRARY PLM FOR DESCRIPTION OF           05000017
*              ECB,DCLCB,FILE REGISTER.SEE MODULE IHEOCL FOR TABLE      05100017
*              OF PRIVATE ADCONS.WORK-AREA IS OBTAINED FROM DYNAMIC     05200017
*              STORAGE(LWS)                                             05300017
*                                                                       05400017
*   ATTRIBUTES READ ONLY AND REENTRANTS                                 05500017
*                                                                       05600017
*   PRIVATE MACROS                                                      05700017
*                                                                       05800017
*              IHELIB,IHEZAP                                            05900017
*                                                                       06000017
*   ASSEMBLY REQUIREMENTS                                               06100017
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO_REGISTER   06200017
*              SUPPORT E.G. O/S 360 F_ASSEMBLER                         06300017
*                                                                       06400017
*                                                                       06500017
*                                                                       06600017
*                                                                       06700017
*                                                                       06800017
*                                                                       06900017
*   NOTE       SEE O/S 360 PL/1 LIBRARY PLM FOR LIBRARY MODULE          07000017
*              CONVENTIONS AND STANDARDS.                               07100017
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    07200017
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    07300017
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  07400017
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  07500017
*              CONSTANTS,BY REASSEMBLY,WILL RESULT IN A CORRECT MODULE  07600017
*              FOR THE NEW DEFINITIONS.                                 07700017
*                                                                       07800017
*                                                                       07900017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ000-TSS 07930020
*        ----------------------------------------------------OPQ000-TSS 07960020
*                                                                       08000017
*                                                                       08100017
         EJECT                                                          08200017
IHEOPQ   CSECT                                                          08300017
         IHELIB                                                         08400017
         EJECT                                                          08450001
         IHEZAP                                                         08500017
         IHEXLV                                                         08600017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ012-TSS 08650001
         DCBD  DSORG=(QS,IS,DA,MQ)                                      08700001
*        ----------------------------------------------------OPQ012-TSS 08750001
PARM     DSECT                                                          08800017
ODCL     DS    A                        A(FILE CONTROL BLOCK(DCLB))     08900017
OOCL     DS    A                        A(OPEN OPTIONS CONTROL BLOCK)   09000017
OTIT     DS    A                        A(TITLE SDV).                   09100017
OIDT     DS    A                        A(IDENT SDV).                   09200017
ODED     DS    A                        A(DED FOR STRING).              09300017
OKEY     DS    A                        A(KEYLENGTH)                    09400017
OLIN     DS    A                        A(LINESIZE)                     09500017
OEOL     DS    0BL1                     END OF LIST FLAG                09600017
OPAG     DS    A                        A(PAGE SIZE)                    09700017
IHEZLW0  DSECT                                                          09800017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ013-TSS 09850001
         DS    9D                                                       09900017
*        ----------------------------------------------------OPQ013-TSS 09950001
OCLPP    DS    A                        P.LIST PHASE II                 10000017
VDAAD    DS    A                        A(VDA) SAVE AREA                10100017
MACVDA   DS    A                        A(DAMT OPEN LIST)               10200017
PARMP    DS    A                        A(PARM LIST) SAVE AREA.         10300017
OPZPL    DS    3A                       OPZ PARAMETERS                  10400017
         SPACE 2                                                        10500017
OPEN     EQU   X'10'                    DCB OPENED                      10600017
MEOL     EQU   X'80'                                                    10700017
NL       EQU   11                                                       10800017
VERS     EQU   3                        RELEASE THREE                   10900017
VR17     EQU   5                                                        11000017
PLOF     EQU   32                       P.LIST ENTRY LENGTH             11100017
BLRC     EQU   X'10'                    BLOCKED RECORDS.                11200017
UNBS     EQU   X'10'                                                    11250001
         SPACE 2                                                        11300017
         EJECT                                                          11400017
IHEOPQ   CSECT                                                          11500017
         ENTRY IHEOPQA                                                  11600017
         USING *,RJ                                                     11700017
         USING IHEZADC,RI                                               11800017
         USING IHADCB,RE                                                11900017
         USING IHEZAPE,RC                                               12000017
         USING IHEZDCL,RD                                               12100017
         USING IHEZLW0,WR                                               12200017
         USING PARM,RG                                                  12300017
IHEOPQA  STM   LR,WR,OFLR(DR)         . SAVE CALLER'S REGISTERS.        12400017
         LR    RJ,BR                    SET UP ADDRESSABILITTY          12500017
         L     RI,0(RA)                 GET A(PAR.POINTER PASSED TO P1) 12600017
         L     RG,0(RI)                 GET A(OPEN P.LIST).             12700017
         L     RI,4(RI)                 GET A(ADCON LIST).              12800017
         LH    WR,IQLW0                 GET LWS OFFSET                  12900017
         L     WR,0(WR,PR)              GET A(LWS LEVEL 0 ).            13000017
         ST    DR,OFDR(WR)              SET UP SSA POINTERS.            13100017
         LR    DR,WR                     *                              13200017
         L     RF,8(RA)                 GET A(DAMT OPEN LIST).          13300017
         LA    RF,4(RF)                  *                              13400017
OQFFB    EQU   *                                                        13500017
         BAL   LR,OQERB                 GO TO REPLACE ERROR BYTE        13600017
         L     RC,0(RC,PR)              GET A(FCB)                      13700017
         LA    RC,0(RC)                 LOOSE TOP BYTE                  13800017
         LTR   RC,RC                 +  FCB EXIST.                      13900017
         BZ    OQBPL                    NO                              14000017
         L     RE,TDCB                  YES.GET A(DCB).                 14100017
         CLC   TDCB+1(3),1(RF)       +  DCB'S CHECK OUT                 14200017
         BE    OQFNB                    YES                             14300017
OQBPL    EQU   *                                                        14400017
         LA    RG,PLOF(RG)              BUMP P.LIST POINTER             14500017
         B     OQFFB                                                    14600017
OQFNB    EQU   *                                                        14700017
         TM    DCBOFLGS,OPEN         +  FILE OPEN.                      14800017
         BO    OQFNC                    YES                             14900017
         CLI   TFAC,TMQT             +  IS IT QTAM DCB                  14930001
         BE    OQFND                 *  YES, GO TO FREE THE AREA GOT    14960001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ029-TSS 14980020
         L     RB,DCBBUFCB              BUFFERS GOTTEN.                 15000017
         LA    RB,0(RB)                  *                              15100017
         BCT   RB,OQFRP                  *                              15200017
         B     OQDSF                                                    15300017
OQFRP    EQU   *                                                        15400017
         LR    RA,RE                                                    15500017
         FREEPOOL (1)                $$ FREE BUFFER POOL.               15600017
*        ----------------------------------------------------OPQ029-TSS 15650020
         B     OQDSF                                                    15700017
OQFND    EQU   *                                                        15707001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ024-TSS 15710020
         LH    BR,DCBSOWA               SIZE OF THE WORK AREA           15714001
         LA    BR,12(BR)                INCLUDE SIZE OF TERMID SLOT     15721001
         A     BR,SBPL                  ADD. SUBPOOL NUMBER             15728001
         LR    R0,BR                    LENGTH IN PARM REG              15735001
         L     RA,DCBTRMAD              A(BUFFER) IN PARM REG           15742001
         LA    RA,0(RA)                 LOOSE TOP BYTE                  15749001
         C     RA,FWONE                + DOES AREA EXIST                15756001
         BNH   OQDSF                   NO , THEN NO FREE                15763001
*                                                                       15770001
         FREEMAIN  R,LV=(0),A=(1)    $$ FREE THE CORE GOT IN OPP        15777001
*                                                                       15784001
         B     OQDSF                    GO CHECK MORE FILES             15791001
*        ----------------------------------------------------OPQ024-TSS 15795020
OQFNC    EQU   *                                                        15800017
         TM    TFTY,TMRC+TMST        +  IS IT STREAM FILE.              15900017
         BNZ   OQTK0                                                    16000017
         OI    TFHT,TMCC             /  SET RECENTLY OPENED FLAG.       16100017
OQTK0    EQU   *                                                        16200017
         LR    RB,PR                                                    16300017
         SH    RB,X08X                  GET A(PRVVDA).                  16400017
         TM    1(RB),X'80'              TASKING?                        16500017
         BZ    OQNOT                    NO.                             16600017
         OI    TFFP,TMTE                SET TASKING BIT IN FCB.         16700017
         TM    TFFP,TMEX                EXCLUSIVE?                      16800017
         BZ    OQNOT                    NO.                             16900017
         SR    RB,RB                                                    17000017
         IC    RB,DCBKEYLE              GET KEYLENGTH.                  17100017
         CLI   TFOG,TMIX             +  INDEXED..                       17200017
         BNE   OQTK1                    NO. THEREFORE REGIONAL.         17300017
         TM    DCBRECFM,BLRC         +  BLOCKED INDEXED?                17400017
         BO    OQTK3                    YES.                            17500017
         LA    RB,XEN1-XBEG(RB)                                         17600017
         B     OQTK2                                                    17700017
OQTK3    EQU   *                                                        17800017
         SR    RB,RB                    IGNORE KEYLENGTH.               17900017
OQTK1    EQU   *                                                        18000017
         LA    RB,XEN2-XBEG(RB)                                         18100017
OQTK2    EQU   *                                                        18200017
         A     RB,SBPL                  SUBPOOL 1.                      18300017
         ST    RB,TXLZ                  STORE LENGTH OF EXCLUSIVE BLOCK 18400017
OQNOT    EQU   *                                                        18500017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ017-TSS 18530001
*        ----------------------------------------------------OPQ017-TSS 18560001
         SR    RB,RB                                                    18600017
         IC    RB,TFAC               +  WHICH ACCESS METHOD.            18700017
         B     *+4(RB)                  SCATTER BRANCH.                 18800017
         B     OQLQS                    QSAM                            18900017
         B     OQLBI                    BDAM                            19000017
         B     OQLQI                    QISAM                           19100017
         B     OQLBI                    BISAM                           19200017
         B     OQLBS                    BSAM                            19300017
         B     OQLBL                    BSAM LOAD MODE                  19310001
*        B     OQLQT                    QTAM                            19320001
         SPACE 2                                                        19330001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ020-TSS 19335020
         LOAD  EP=IHEITPA            $$ LOAD QTAM TRANSMITTER           19340001
*        ----------------------------------------------------OPQ020-TSS 19345020
*                                                                       19350001
         B     OQLQ2                    GO TO SET UP EODAD AND SYNAD    19360001
         SPACE 2                                                        19370001
OQLBL    EQU   *                                                        19380001
         SPACE                                                          19400017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ001-TSS 19450020
         LOAD  EP=IHEITCA            $$ GET BSAM (BDAM LOAD) XMITTER.   19500017
*        ----------------------------------------------------OPQ001-TSS 19550020
         XC    DCBEODAD+1(3),DCBEODAD+1 ZERO A(EODAD).                  19600017
         LR    RB,R0                                                    19700017
         LA    BR,2(RB)                 A(ITCA).                        19800017
         AH    RB,0(RB)                 A(SYNAD ENTRY).                 19900017
         B     OQOS3                                                    20000017
OQLBS    EQU   *                                                        20100017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ002-TSS 20150020
         LOAD  EP=IHEITBA            $$ GET BSAM TRANSMITTER.           20200017
*        ----------------------------------------------------OPQ002-TSS 20250020
         LR    RA,R0                                                    20300017
         AH    R0,0(RA)                                                 20400017
         LR    RB,R0                    A(SYNAD ENTRY).                 20500017
         LA    BR,4(RA)                 A(ITBA).                        20600017
         AH    RA,2(RA)                 A(EODAD ENTRY).                 20700017
         B     OQOS1                                                    20800017
         SPACE                                                          20900017
OQLQS    EQU   *                                                        21000017
         TM    TFRC,TMAS             +  PRINT FILE.                     21100017
         BZ    OQQSM                    NO                              21200017
         L     RB,TTAB            40104 GET A(IHETABS) FROM FCB.        21270046
         N     RB,TABMSK          40104 CLEAR FLAG BYTE AND ALIGN ON    21340046
*                                 40104 DW.BNDY.FOR ABSOLUTE ADDRESS    21410046
         BZ    OQDSE                    YES                             21500017
         OI    TFLF,TMTB             /  SET TAB TABLE EXISTS FLAG.      21600017
         B     OQDSE                 *  MUST BE STREAM I/O              21700017
OQQSM    EQU   *                                                        21800017
         TM    TFTY,TMRC             +  RECORD I/O.                     21900017
         BZ    OQSTR                    NO.                             22000017
         TM    DCBRECFM,SPAN         +  SPANNED                         22100017
         BNO   OQNSP                 *  SPANNED                         22200017
         TM    TFLA,TMOP             +  O/P                             22300017
         BZ    OQISP                                                    22400017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ003-TSS 22450020
         LOAD  EP=IHEITLA             SPANNED RECORDS OUTPUT          22500017
*        ----------------------------------------------------OPQ003-TSS 22550020
         B     OQLQ2                                                    22600017
OQISP    EQU   *                                                        22700017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ004-TSS 22750020
         LOAD  EP=IHEITKA             SPANNED RECORDS INPUT           22800017
*        ----------------------------------------------------OPQ004-TSS 22850020
         B     OQLQ2                                                    22900017
OQNSP    EQU   *                                                        23000017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ005-TSS 23050020
         LOAD  EP=IHEITGA            $$ LOAD QSAM (RECORD I/O MODULE).  23100017
*        ----------------------------------------------------OPQ005-TSS 23150020
         B     OQLQ2                                                    23200017
         SPACE                                                          23300017
OQSTR    EQU   *                                                        23400017
         TM    TFMD,TMIN                INPUT?                          23500017
         BZ    OQDSE                    NO.                             23600017
         MVC   TMAX(2),DCBLRECL         SET TMAX TO RECORD LENGTH.      23700017
         B     OQDSE                                                    23800017
         SPACE                                                          23900017
OQLBI    EQU   *                                                        24000017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ025-TSS 24030020
*        ----------------------------------------------------OPQ025-TSS 24060020
         L     R0,TBBZ                  GET LENGTH OF BUBL.             24100017
         LTR   R0,R0                    WAS TBBZ ZERO?        A35226    24110042
         BNZ   OQLB2                    NO. FILE WAS O.K.     A35226    24120042
         LH    R0,X08X                  YES. IHEOPP FOUND ERROR35226    24130042
         ST    R0,TBBZ                  USE DEFAULT BUBL SIZE A35226    24140042
OQLB2    EQU   *                        GET CORE FOR BUBL     A35226    24150042
         GETMAIN R,LV=(0)            $$ GET FIRST BUBL.                 24200017
         ST    RA,TLAB                  A(BUBL) IN TLAB.                24300017
         XC    0(8,RA),0(RA)            ZERO CHAIN FORWARD AND BACK.    24400017
         SPACE                                                          24500017
         SR    BR,BR                    ZERO BR AS NO IOCB ROUTINE      24600017
         NI    TFFP,255-TMBU-TMHB       UNSET BUF. AND HID. BUF. FLAGS  24700017
         CLI   TFAC,TMBI             + BISAM                            24800017
         BNE   OQLBD                 *  NO, BDAM                        24900017
         SPACE                                                          25000017
         TM    TFFP,TMTE                TASKING?                        25100017
         BZ    OQITE                    NO.                             25200017
         TM    TFRC,TMVB             +  V FORMAT INDEXED                25230001
         BO    OQITO                 *  YES. LOAD V BISAM XMITTER.      25260001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ006-TSS 25280020
         LOAD  EP=IHEITHA               LOAD BISAM TASKING TRANSMITTER  25300017
*        ----------------------------------------------------OPQ006-TSS 25350020
         B     OQITH                                                    25400017
OQITO    EQU   *                                                        25420001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ021-TSS 25430020
         LOAD  EP=IHEITOA               LOAD V TASKING TRANSMITTER.     25440001
*        ----------------------------------------------------OPQ021-TSS 25450020
         B     OQITH                                                    25460001
OQITE    EQU   *                                                        25500017
         TM    TFRC,TMVB             +  V FORMAT INDEXED...             25510001
         BZ    OQITK                 *  NO. F FORMAT.                   25520001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ022-TSS 25525020
         LOAD  EP=IHEITMA             GETV BISAM TRANSMITTER.         25530001
*        ----------------------------------------------------OPQ022-TSS 25535020
         B     OQITH                 *                                  25540001
OQITK    EQU   *                                                        25550001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ007-TSS 25570020
         LOAD  EP=IHEITEA            $$ LOAD BISAM TRANSMITTER          25600017
*        ----------------------------------------------------OPQ007-TSS 25650020
OQITH    EQU   *                                                        25700017
         LR    BR,R0                    A(BISAM TRANSMITTER)            25800017
         B     OQOS2                                                    25900017
         SPACE                                                          26000017
OQLBD    EQU   *                                                        26100017
         TM    TFFP,TMTE                TASKING?                        26200017
         BZ    OQITF                    NO.                             26300017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ008-TSS 26350020
         LOAD  EP=IHEITJA               LOAD BDAM TASKING TRANSMITTER   26400017
*        ----------------------------------------------------OPQ008-TSS 26450020
         B     OQITJ                                                    26500017
OQITF    EQU   *                                                        26600017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ009-TSS 26650020
         LOAD  EP=IHEITFA            $$ LOAD BDAM TRANSMITTER           26700017
*        ----------------------------------------------------OPQ009-TSS 26750020
OQITJ    EQU   *                                                        26800017
         LR    RB,R0                    A(TRANSMITTER)                  26900017
         LA    BR,2(RB)                 A(ENTRY POINT OF TRANSMITTER)   27000017
         AH    RB,0(RB)                 A(SYNAD)                        27100017
         B     OQOS3                                                    27200017
OQLQI    EQU   *                                                        27300017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ028-TSS 27350020
         NC    DCBRKP(2),DCBRKP      + RKP = 0 ?                        27400017
         BNZ   OQLQJ                    NO.                             27500017
         TM    DCBRECFM,BLRC         +  BLOCKED?                        27600017
         BO    OQLQJ                    YES.                            27700017
         TM    TFMD,TMOP             +  OUTPUT?                         27800017
         BZ    OQLQJ                    NO.                             27900017
         TM    DCBKEYLE,X'07'           KEYLENGTH MULTIPLE OF 8?        28000017
         BZ    OQLQJ                    YES.                            28100017
         OI    TFFP,TMHQ             /  SET BIT FOR ITD.                28200017
*        ----------------------------------------------------OPQ028-TSS 28250020
OQLQJ    EQU   *                                                        28300017
         TM    TFRC,TMVB             +  V FORMAT INDEXED...             28310001
         BZ    OQLQ1                 *  NO. F FORMAT.                   28320001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ023-TSS 28325020
         LOAD  EP=IHEITNA             GET V QISAM TRANSMITTER.        28330001
*        ----------------------------------------------------OPQ023-TSS 28335020
         B     OQLQ2                 *                                  28340001
OQLQ1    EQU   *                                                        28350001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ010-TSS 28370020
         LOAD  EP=IHEITDA            $$ GET QISAM TRANSMITTER.          28400017
*        ----------------------------------------------------OPQ010-TSS 28450020
OQLQ2    EQU   *                                                        28500017
         LR    RA,R0                    SAVE A(IHEITDA).                28600017
         LA    BR,4(RA)                 A(TRANSMITTER)                  28700017
         AH    R0,0(RA)                                                 28800017
         LR    RB,R0                    A(SYNAD ENTRY).                 28900017
         AH    RA,2(RA)                 A(EODAD ENTRY).                 29000017
OQOS1    EQU   *                                                        29100017
         IC    LR,DCBEODAD                                              29200017
         ST    RA,DCBEODAD              A(EODAD EXIT ) IN FCB.          29300017
         STC   LR,DCBEODAD                                              29400017
OQOS3    EQU   *                                                        29500017
         IC    LR,DCBSYNAD                                              29600017
         ST    RB,DCBSYNAD              A(SYNAD EXIT ) IN FCB.          29700017
         STC   LR,DCBSYNAD                                              29800017
OQOS2    EQU   *                                                        29900017
         IC    LR,TACM                                                  30000017
         CLI   IFOPE,VR17            TEST IF R17 LINK-EDIT OR LATER     30100017
         BL    OQOS2A                IF SO GET OFFSET OF NEW ENTRY      30200017
         AH    BR,0(BR)            FROM HALFWORD IN TRANSMITTER         30300017
         B     OQOS2B                                                   30400017
OQOS2A   LA    BR,2(BR)              BUMP BR OVER OFFSET OF NEW ENTRY   30500017
OQOS2B   EQU   *                                                        30600017
         ST    BR,TACM                  A(TRANSMITTER) IN FCB.          30700017
         STC   LR,TACM                                                  30800017
OQDSE    EQU   *                                                        30900017
*              FCB NOW HAS EXTRA 8 BYTES ON FRONT. USE 1ST 4 TO CONTAIN 31000017
*        MASK FOR VALIDATING STATEMENTS. EACH VALID COMBINATION OF      31100017
*        STATEMENT TYPE AND OPTIONS IS REPRESENTED BY 1 BIT. THE MASK   31200017
*        IS SET UP BY 'AND'ING TOGETHER MASKS FOR ALL OF THE FILE'S     31300017
*        ATTRIBUTES ZEROING THE BIT FOR EACH INVALID STATEMENT.         31400017
         SPACE                                                          31500017
         CLI   IFOPE,VR17            TEST FOR RELEASE 17 OR LATER       31600017
         BL    OQM80                 BRANCH IF EARLIER(EXTRA 8 BYTES    31700017
*                                    NOT PRESENT)                       31800017
         SH    RC,X08X                                                  31900017
         XC    0(8,RC),0(RC)         CLEAR EXTRA 8 BYTES                32000017
         LA    RC,8(RC)                                                 32100017
         TM    TFTY,TMRC             TEST FOR RECORD I/O                32200017
         BZ    OQM80                 IF STREAM LEAVE EXTRA BYTES 0      32300017
         L     R0,M8                 SET REG 0 TO 'FFFFFFF8'            32400017
*              FIRST TEST FOR INPUT, OUTPUT, OR UPDATE                  32500017
         TM    TFMD,TMIN                                                32600017
         BZ    OQM10                    NOT INPUT                       32700017
         SPACE                                                          32800017
         N     R0,INMSK                 'AND' WITH INPUT MASK           32900017
         B     OQM20                                                    33000017
         SPACE                                                          33100017
OQM10    TM    TFMD,TMOP                                                33200017
         BZ    OQM15                    NOT OUTPUT                      33300017
         SPACE                                                          33400017
         N     R0,OUTMSK                'AND' WITH OUTPUT MASK          33500017
         B     OQM20                                                    33600017
         SPACE                                                          33700017
OQM15    N     R0,UPDMSK                'AND' WITH UPDATE MASK          33800017
         TM    DCLD,X'04'            TEST FOR NOWRITE                   33900017
         BNZ   OQM17                 YES                                34000017
         TM    TFFP,TMDR             DIRECT                             34100017
         BNZ   OQM18                 YES                                34200017
OQM17    N     R0,NWRTFL             ZERO WRITE BITS                    34300017
OQM18    EQU   *                                                        34400017
         SPACE 2                                                        34500017
*              NOW TEST FOR TYPE OF ACCESS METHOD                       34600017
OQM20    XR    BR,BR                                                    34700017
         IC    BR,TFAC                                                  34800017
         B     OQM22(BR)                                                34900017
OQM22    B     OQM30                   QSAM                             35000017
         B     OQM40                   BDAM                             35100017
         B     OQM50                   QISAM                            35200017
         B     OQM50                   BISAM                            35300017
         B     OQM60                   BSAM                             35400017
         B     OQM60                   BSAM LOAD                        35500017
*        B     OQM30                    QTAM                            35550001
         SPACE                                                          35600017
*   QSAM/QTAM MEANS SEQUENSIAL BUFFERED                                 35700001
OQM30    N     R0,BUFMSK               'AND' WITH BUFFERED MASK         35800017
         B     OQM62                   JOIN BSAM ROUTINE                35900017
*              BISAM AND QISAM NEED A BIT OF SPECIAL TREATMENT. IF THE  36000017
*        FILE IS BLOCKED WITH RKP=0 THE DELETE STATEMENT IS INVALID     36100017
OQM50    EQU   *                                                        36120001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ026-TSS 36130020
         TM    TFRC,TMVB             +  V FORMAT INDEXED...             36140001
         BZ    OQM31                 *  NO.                             36160001
         CLC   DCBRKP,X04X           +  RKP = 4...                      36180001
         BNE   OQM52                 *  NO.                             36200001
         B     OQM32                 * YES.                             36220001
OQM31    EQU   *                                                        36240001
         TM    DCBRECFM,BLRC         +  BLOCKED RECORDS...              36260001
         BZ    OQM52                   NO                               36300017
         NC    DCBRKP(2),DCBRKP        RKP=0                            36400017
         BNZ   OQM52                   NO                               36500017
OQM32    EQU   *                                                        36550001
         SPACE                                                          36600017
         N     R0,DELMSK               CLEAR DELETE BITS                36700017
*        ----------------------------------------------------OPQ026-TSS 36750020
         SPACE                                                          36800017
OQM52    B     OQM52(BR)               SEPARATE BISAM AND QISAM         36900017
         BC    0,OQM52                                                  37000017
         B     OQM42                   QISAM                            37100017
         SPACE                                                          37200017
*              THIS IS FOR BDAM AND (AFTER SPECIAL TEST) FOR BISAM.     37300017
*        DIRECT UNBUFFERED KEYED ARE IMPLIED                            37400017
OQM40    N     R0,DIRMSK                                                37500017
NOTBUFFR EQU   *                                                        37550001
         N     R0,UNBMSK                                                37600017
         B     OQM45                   JOIN BDAM ROUTINE                37700017
         SPACE 2                                                        37800017
*              QISAM MEANS BUFFERED SEQUENTIAL KEYED                    37900017
OQM42    EQU   *                                                        37950001
         N     R0,SEQMSK                SET SEQUENTIAL                  38000001
         N     R0,BUFMSK                USE BUFFERED MASK.              38020001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ027-TSS 38030020
         TM    TFFP,TMBU                TEST FOR UNBUFFERED             38050001
         BO    NOTBUFFR                 YES. GO TO SET UNBUF-POSS ERR   38100001
*        ----------------------------------------------------OPQ027-TSS 38150020
         SPACE                                                          38200017
*              BISAM ROUTINES JOINS IN HERE                             38300017
OQM45    N     R0,KEYMSK               'AND' KEYED MASK                 38400017
         SPACE                                                          38500017
         TM    TFFP,TMEX               TEST FOR EXCLUSIVE               38600017
         BNZ   OQM70                 YES. END OF ROUTINE                38700017
         B     OQM68                 NO. GO TO 'AND' UNEXCLUSIVE MASK   38800017
         SPACE 2                                                        38900017
*              THIS IS FOR BSAM. IT IMPLIES SEQUENTIAL                  39000017
OQM60    TM    TFFP,TMBU               FOR REGIONAL SEQUENTIAL FILE MAY 39100017
         BZ    OQM30                 BE BUFFERED. BRANCH IF SO          39200017
         SPACE                                                          39300017
         N     R0,UNBMSK               'AND' UNBUFFERED MASK            39400017
         SPACE                                                          39500017
OQM62    N     R0,SEQMSK               'AND' SEQUENTIAL MASK            39600017
         CLI   TFLD,TMIX                 TEST FOR REGIONAL              39700017
         BNH   OQM63                    NO                              39800017
*   READ KEY NOT ALLOWED FOR REGIONAL SEQUENTIAL OR TRANSIENT           39900001
         N     R0,RKMSK                                                 40000017
OQM63    EQU   *                                                        40100017
         SPACE                                                          40200017
         TM    TFMD,TMBK               TEST FOR BACKWARDS               40300017
         BZ    OQM64                   NO                               40400017
         SPACE                                                          40500017
         N     R0,BKWMSK             AND WITH BACKWARD MASK             40600017
         SPACE                                                          40700017
OQM64    TM    TFFP,TMKD               TEST FOR KEYED                   40800017
         BZ    OQM66                   NO                               40900017
         SPACE                                                          41000017
         N     R0,KEYMSK               'AND' KEYED MASK                 41100017
         B     OQM67                                                    41200017
         SPACE                                                          41300017
OQM66    N     R0,NOKMSK               'AND UNKEYED MASK                41400017
         SPACE                                                          41500017
*              FOR REGIONAL AND CONSECUTIVE SEQUENTIAL FILES NO DELETE  41600017
*        IS ALLOWED                                                     41700017
OQM67    N     R0,DELMSK                                                41800017
         SPACE 2                                                        41900017
         SPACE                                                          42000017
OQM68    N     R0,NXCMSK             'AND' WITH UNEXCLUSIVE MASK        42100017
OQM70    SH    RC,X08X                                                  42200017
         ST    R0,0(RC)                                                 42300017
         LA    RC,8(RC)                                                 42400017
*              END OF ROUTINE                                           42500017
         SPACE 4                                                        42600017
OQM80    EQU   *                                                        42700017
         L     LR,IFOPE                                                 42800017
         LTR   LR,LR                 +  1ST RELEASE OCL.                42900017
         BZ    OQDSF                    IF 1 ST RELEASE OCL             43000017
         LH    LR,IQFOP                 GET A(FCB ANCHOR).              43100017
         LA    LR,0(LR,PR)               *                              43200017
         L     BR,0(LR)                 FIX UP CHAIN.                   43300017
         ST    RC,0(LR)                  *                              43400017
         IC    R0,TFLE                  SAVE HISTORY FLAG.              43500017
         ST    BR,TFOP                   *                              43600017
         STC   R0,TFLE                  RESTORE HISTORY FLAG.           43700017
OQDSF    EQU   *                                                        43800017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ014-TSS 43850001
         TM    0(RF),MEOL            +  END OF LIST YET.                43900017
*        ----------------------------------------------------OPQ014-TSS 43950001
         BO    OQFVD                    YES                             44000017
         LA    RG,PLOF(RG)              BUMP P.LIST POINTER             44100017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ015-TSS 44150001
         LA    RF,4(RF)                  *                              44200017
*        ----------------------------------------------------OPQ015-TSS 44250001
         B     OQFFB                                                    44300017
OQFVD    EQU   *                                                        44400017
         L     BR,ISAFD                 LOAD A(FREE VDA MODULE)         44500017
         BALR  LR,BR                 {{ FREE SECOND VDA                 44600017
OQEND    EQU   *                                                        44700017
         TM    OEOL,MEOL             +  TEST IF END OF LIST             44800017
         BO    OQFVA                    YES                             44900017
         LA    RG,PLOF(RG)              BUMP P.LIST POINTER             45000017
         BAL   LR,OQERB                 REPLACE ERROR BYTE              45100017
         B     OQEND                                                    45200017
OQFVA    EQU   *                                                        45300017
         L     BR,ISAFD                 A(FREE VDA MODULE)              45400017
         BALR  LR,BR                 {{ FREE FIRST VDA                  45500017
         L     DR,OFDR(DR)              RESTORE SAVE AREA POINTER       45600017
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       45700017
         BR    LR                    X  RETURN                          45800017
         EJECT                                                          45900017
OQERB    EQU   *                                                        46000017
         L     RD,0(RG)                 GET A(DCLCB)                    46100017
         LH    RC,DPRO                  GET FILE REG OFFSET             46200017
         LA    RA,0(RC,PR)              A( FILE REGISTER)               46300017
         TM    0(RA),X'FF'           +  ANY ERRORS                      46400017
         BM    OQERC                 *  YES                             46500017
         L     RE,0(RA)                 A(FCB)                          46600017
         L     RE,0(RE)                 A(DCB)                          46700017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ016-TSS 46750001
         TM    48(RE),OPEN           +  IS FILE PROPERLY OPENED         46800017
*        ----------------------------------------------------OPQ016-TSS 46850001
         BCR   1,LR                  *  YES                             46900017
         MVI   0(RA),X'04'           *  NO,  MUST BE NO DD CARD         47000017
OQERC    EQU   *                                                        47100017
         CLI   IFOPE,VERS               IS IT VERSION THREE             47200017
         BCR   NL,LR                    BRANCH IF VERSION THREE OR OVER 47300017
         XR    RA,RA                    CLEAR RA                        47400017
         IC    RA,0(RC,PR)              GET ERROR BYTE                  47500017
         IC    RA,CONTAB(RA)            FIND REPLACEMENT                47600017
         STC   RA,0(RC,PR)              STORE NEW ERROR BYTE            47700017
         BR    LR                       RETURN                          47800017
SPAN     EQU   X'48'                    SPANNED BITS IN DCB.            47900017
         EJECT                                                          48000017
CONTAB   DC    X'00'                                                    48100017
C801     DC    X'02'                    ATTRIBUTE CONFLICT              48200017
C802     DC    X'04'                    FILE TYPE NOT SUPPORTED         48300017
C803     DC    X'06'                    BLOCKSIZE NOT SPECIFIED         48400017
         DC    X'00'                    NO DD CARD                      48500017
C805     DC    X'08'                    TRANSMIT IN OPZ                 48600017
C806     DC    X'02'                    ATTR. AND ENV. CONFLICT         48700017
C807     DC    X'02'                    ENV. AND/OR DD CONFLICT         48800017
C808     DC    X'02'                    KEY LENGTH NOT SPECIFIED        48900017
C809     DC    X'02'                    ERROR IN BLOCKSIZE OR LRECL     49000017
C80A     DC    X'02'                   LINESIZE GT. MAX. LENGTH         49100017
C80B     DC    X'02'                    LRECL TOO SMALL FOR EMB. KEY    49200017
MXLN     DC    H'32767'                                                 49300017
X04X     DC    H'4'                                                     49350001
X08X     DC    H'8'                                                     49400017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ018-TSS 49430001
*        ----------------------------------------------------OPQ018-TSS 49460001
M8       DC    F'-8'                                                    49500017
FWONE    DC    F'1'                                                     49550001
TABMSK   DC    X'00FFFFF8'                                              49570046
DELMSK   DC    X'FFFFFF0F'                                              49600017
INMSK    DC    X'FFF80007'                                              49700017
OUTMSK   DC    X'00078307'                                              49800017
UPDMSK   DC    X'FFFAFCFF'                                              49900017
SEQMSK   DC    X'FDEFEBA7'                                              50000017
DIRMSK   DC    X'0632945F'                                              50100017
BUFMSK   DC    X'FD066387'                                              50200017
UNBMSK   DC    X'1FFFBCFF'                                              50300017
BKWMSK   DC    X'91880007'                                              50400017
NXCMSK   DC X'FDEFFFF7'              UNEXCLUSIVE MASK                   50500017
KEYMSK   DC    X'FFFAFDFF'                                              50600017
NOKMSK   DC    X'918D6AA7'                                              50700017
NWRTFL   DC    X'FFF87FFF'                                              50800017
RKMSK    DC    X'D9CFFFFF'                                              50900017
         DS    0A                                                       51000017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*OPQ011-TSS 51050001
SBPL     DC    X'01000000'                                              51100017
*        ----------------------------------------------------OPQ011-TSS 51150001
         END   IHEOPQA                                                  51200017
