SRC      TITLE    'IHESRC    ON BUILT IN FUNCTIONS AND PVS             *00500013
               OS/360 PL/1 LIBRARY'                                     01000013
*   VERSION    THIRD VERSION OF F-LEVEL PL/1 COMPILER                   01500013
*                                                                       02000013
*   STATUS     CHANGE LEVEL - 1                                         02500013
*   R19    THIS MODULE HAS BEEN LARGELY REWRITTEN, AND NO LONGER        02530019
*          DEPENDS ON WOFD & WOCH IN LCA ALWAYS BEING SET TO NULL       02560019
*          & BLANK RESPECTIVELY WHEN THE FUNCTIONS OR PV.S ARE          02590019
*          USED OUT-OF-CONTEXT OR AFTER A SIGNAL STATEMENT.             02620019
*              APAR # 25901                                             02650019
*          BEHAVIOUR IS SUMMARISED IN THE FOLLOWING TABLE:-             02680019
*                I/O CONV  DP CONV  SIG CONV  OUT-OF-CONTEXT            02710019
*  ONSOURCE BIF   AS SET    AS SET   *NULL       *NULL                  02740019
*  ONSOURCE PV    AS SET    AS SET   *NO-OP       ERROR                 02770019
*  ONCHAR   BIF   AS SET    AS SET   *BLANK      *BLANK                 02800019
*  ONCHAR   PV    AS SET    AS SET   *NO-OP       ERROR                 02830019
*      CASES MARKED * WERE INCORRECTLY IMPLEMENTED BEFORE THIS CHANGE.  02860019
* R19  754000(DATAFIELD)  782000(ONFILE)                          H391  02930019
*                                                                       03000013
*   SIZE                                                                03500013
*                                                                       04000013
*   FUNCTION                                                            04500013
*              (A) ONSOURCE PV - SETS THE ARGUMENT SDV TO REFER TO      05000013
*                  ERRONEOUS CHARACTER STRING. IF USED OUT OF CONTEXT   05500013
*                  THEN ERROR IS RAISED. IF USED IN A CONVERSION        06000013
*                  ON UNIT WHEN SIGNALED THEN NO OPERATION              06500013
*              (B) ONCHAR BIF - ASSIGNS ERRONEOUS CHARACTER TO TARGET   07000013
*                  CHARACTER. IF USED OUT OF CONTEXT BLANK IS RETURNED  07500013
*              (C) DATAFIELD BIF - SETS THE ARGUMENT SDV TO REFER TO    08000013
*                  THE ERRONEOUS DATA FIELD. IF USED OUT OF CONTEXT     08500013
*                  A NULL STRING IS RETURNED                            09000013
*              (D) ONCHAR PV - SETS THE ARGUMENT SDV TO REFER TO THE    09500013
*                  ERRONEOUS CHARACTER. IF USED OUT OF CONTEXT THEN     10000013
*                  ERROR IS RAISED. IF USED IN A CONVERSION ON UNIT     10500013
*                  WHEN SIGNALED THEN NO OPERATION                      11000013
*              (E) ONFILE BIF - SETS THE ARGUMENT SDV TO THE CURRENT    11500013
*                  FILE NAME, UNLESS THERE IS NO CURRENT FILE IN WHICH  12000013
*                  CASE A NULL STRING IS RETURNED                       12500013
*              (F) ONSOURCE BIF - SETS THE ARGUMENT SDV TO REFER TO     13000013
*                  THE ERRONEOUS CHARACTER STRING. IF USED OUT OF       13500013
*                  CONTEXT A NULL STRING IS RETURNED                    14000013
*                                                                       14500013
*   ENTRY POINTS                                                        15000013
*              IHESRCA - ONSOURCE PV                                    15500013
*                  RA= A(PARM)                                          16000013
*               WHERE PARM = A(ARGUMENT SDV)                            16500013
*              IHESRCB - ONCHAR BIF                                     17000013
*                  RA - A(TARGET SDV)                                   17500013
*              IHESRCC - DATAFIELD                                      18000013
*                  CF ONSOURCE PV                                       18500013
*              IHESRCD - ONCHAR PV                                      19000013
*                  CF ONSOURCE PV                                       19500013
*              IHESRCE - ONFILE                                         20000013
*                  CF ONSOURCE PV                                       20500013
*              IHESRCF - ONSOURCE BIF                                   21000013
*                  CF ONSOURCE PV                                       21500013
*                                                                       22000013
*   INPUT                                                               22500013
*              COMMUNICATIONS AREA - REFERENCED BY PSEUDO-REG(IHEQLCA). 23000013
*                                                                       23500013
*   OUTPUT                                                              24000013
*              UPDATED ARGUMENT SDV.                                    24500013
*                                                                       25000013
*   EXTERNAL MODULES                                                    25500013
*              N/A                                                      26000013
*                                                                       26500013
*   EXITS                                                               27000013
*              RETURN TO CALLER VIA LINK REGISTER.                      27500013
*                                                                       28000013
*   TABLES/WORK AREA                                                    28500013
*              LW0 SAVE AREA                                            29000013
*              SEE OS/360 PL/I LIBRARY PLM FOR DESCRIPTION OF           29500013
*              LIBRARY COMMUNICATIONS AREA.                             30000013
*                                                                       30500013
*   ATTRIBUTES  READ ONLY AND REENTRANT                                 31000013
*                                                                       31500013
*   PRIVATE MACROS                                                      32000013
*              IHELIB,IHEPRV,IHESDR,IHEZAP                              32500013
*                                                                       33000013
*   ASSEMBLY REQUIREMENTS                                               33500013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   34000013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        34500013
*                                                                       35000013
*   NOTES                                                               35500013
*           THE OPERATION OF THIS MODULE DEPENDS ON AN INTERNAL         36000019
*           REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS       36500019
*           EQUIVALENT TO THE ONE AT ASSEMBLY TIME.                     37000019
        EJECT                                                           37500013
IHESRC   CSECT                                                          38000013
         IHELIB                                                         38500013
         IHEZAP                                                         39000013
SDVD     DSECT                                                          39500019
*                              ** STRING DOPE VECTOR DSECT **           40000019
ASTRING  DS    A               STRING ADDRESS.                          40500019
MAXLEN   DS    H               MAXIMUM LENGTH.                          41000019
CURLEN   DS    H               CURRENT LENGTH.                          41500019
         EJECT                                                          42000019
IHESRC   CSECT                                                          42500019
OSPV     EQU   1               ONSOURCE PV.                             43000019
OSBF     EQU   2               ONSOURCE BIF.                            43500019
OCPV     EQU   3               ONCHAR PV.                               44000019
OCBF     EQU   4               ONCHAR BIF.                              44500019
OFBF     EQU   5               ONFILE BIF.                              45000019
DFBF     EQU   6               DATAFIELD BIF.                           45500019
         ENTRY IHESRCA,IHESRCB,IHESRCC,IHESRCD,IHESRCE,IHESRCF          46000019
         USING IHEZDCL,RG                                               46500019
         USING IHEZLCA,RJ                                               47000019
         USING SDVD,RA                                                  47500019
IHESRCA  NOPR  OSPV            ONSOURCE PV ENTRY.                       48000019
IHESRCB  NOPR  OCBF            ONCHAR BIF ENTRY.                        48500019
IHESRCC  NOPR  DFBF            DATAFIELD BIF ENTRY                      49000019
IHESRCD  NOPR  OCPV            ONCHAR PV ENTRY.                         49500019
IHESRCE  NOPR  OFBF            ONFILE BIF ENTRY.                        50000019
IHESRCF  NOPR  OSBF            ONSOURCE BIF ENTRY.                      50500019
         SPACE                                                          51000019
SRC00    EQU   *                                                        53500013
         STM   LR,WR,OFLR(DR)           SAVE CALLER'S REGISTERS.        54000013
         LR    RD,DR                                                    54500013
         BALR  WR,0                     ESTABLISH ADDRESSIBILITY.       55000013
         USING *,WR                                                     55500013
         IHESDR LW0,RI                  SET UP NEW SAVE AREA.           56000013
         IHEPRV LCA,RE                  GET A(LCA).                     56500013
         LR    RJ,RE                                                    57000013
         SH    RJ,H008                  GET A(PRIOR LCA).               57500013
         L     RJ,0(RJ)                                                 58000013
         LTR   RJ,RJ                   IS IT ZERO                       58500013
         BNZ   OK1                                                      59000013
         LR    RJ,RE                   SET RJ AT CURRENT LCA            59500013
OK1      L     RA,0(RA)                 GET A( ARGUMENT SDV ).          60000013
         SR    RC,RC                                                    60200019
         IC    RC,1(0,BR)      PICK UP ENTRY POINT NUMBER.              60400019
         SLL   RC,2            MULTIPLY BY 4 FOR USE AS INDEX.          60600019
         B     *(RC)                                                    60800019
         B     ONSRCPV                                                  61000019
         B     ONSRCBIF                                                 61200019
         B     ONCHRPV                                                  61400019
         B     ONCHRBIF                                                 61600019
         B     ONFILBIF                                                 61800019
         B     DAFLDBIF                                                 62000019
         SPACE                                                          62200019
*                       E R R O R     E X I T                           62400019
PVERROR  L     BR,VERRC        RAISE ERROR FOR USE OF PSEUDO-           62600019
         BALR  RA,BR           VARIABLES OUT OF CONTEXT.                62800019
         DC    X'0408'         ERROR CODE FOR IHEERRC                   63000019
*                       ** SUBROUTINE TO CHECK ENVIRONMENT **           63200019
*             RET 1.    LR+0   NOT IN CONVERSION ON-UNIT.               63400019
*             RET 2.    LR+4   CONVERSION SIGNALLED.                    63600019
*             RET 3.    LR+8   CONVERSION RAISED NORMALLY.              63800019
ENVIRONS CR    RE,RJ           IS THERE A PRIOR LWS?                    64000019
         BCR   8,LR            NO, RET 1.                               64200019
         CLI   WONC,X'C0'      I/O CONVERSION?                          64400019
         BE    8(0,LR)         YES, RET 3.                              64600019
         CLI   WONC,X'40'      CONVERSION?                              64800019
         BCR   7,LR            NO, RET 1.                               65000019
         CLI   WONC+1,X'00'    CONVERSION - IS IT SIGNALLED?            65200019
         BE    4(0,LR)         YES, RET 2.                              65400019
         B     8(0,LR)         NO, RET 3.                               65600019
*                       ** END OF MINI SUBROUTINE ***                   65800019
         SPACE                                                          66000019
*                       ONSOURCE BIF                                    66200019
ONSRCBIF BAL   LR,ENVIRONS                                              66400019
ONSRCBF1 B     ONSRCSIG        AS WHEN SIGNALLED.                       66600019
ONSRCBF2 B     ONSRCSIG        AS WHEN SIGNALLED.                       66800019
ONSRCBF3 B     ONSRCPV4        AS PV, BUT SWITCH NOT SET.               67000019
*                       ** ONSOURCE PV                                  67200019
ONSRCPV  BAL   LR,ENVIRONS                                              67400019
ONSRCPV1 B     PVERROR         NOT IN ON-UNIT, SO RAISE ERROR.          67600019
ONSRCPV2 B     ONSRCSIG        IN SIGNALLED CONVERSION ON-UNIT.         67800019
ONSRCPV3 OI    WONC+2,X'80'    NORMAL USE.  SHOW PV USED.               68000019
ONSRCPV4 MVC   ASTRING+1(7),WOFD+1 MOVE ONSOURCE DV TO PARAMETER.       68200019
         B     COMMON1                                                  68400019
*                ONSOURCE WHEN SIGNALLED, AND BIF OUT OF CONTEXT.       68600019
ONSRCSIG XC    ASTRING,ASTRING     SET DV TO NULL.                      68800019
         B     COMMON3                                                  69000019
         SPACE                                                          69200019
*                       ** ONCHAR   BIF                                 69400019
ONCHRBIF BAL   LR,ENVIRONS                                              69600019
ONCHRBF1 B     ONCHRBF4        AS WHEN SIGNALLED.                       69800019
ONCHRBF2 B     ONCHRBF4        AS WHEN SIGNALLED.                       70000019
ONCHRBF3 L     RA,ASTRING      RA POINTS TO TARGET DATA.                70200019
         L     RB,WOCH         RB POINTS TO ONCHAR DATA BYTE.           70400019
         MVC   0(1,RA),0(RB)   MOVE DATA TO TARGET.                     70600019
         B     COMMON4                                                  70800019
*                       ONCHAR BIF WHEN SIGNALLED OR OUT OF CONTEXT.    71000019
ONCHRBF4 L     RA,ASTRING      RA POINTS TO TARGET DATA.                71200019
         MVI   0(RA),C' '      RETURN A BLANK.                          71400019
         B     COMMON4                                                  71600019
*                    ** ONCHAR   PV                                     71800019
ONCHRPV  BAL   LR,ENVIRONS                                              72000019
ONCHRPV1 B     PVERROR         NOT IN ON-UNIT, SO RAISE ERROR.          72200019
ONCHRPV2 B     ONCHRPV4        IN SIGNALLED CONVERSION ON-UNIT.         72400019
ONCHRPV3 OI    WONC+2,X'80'    NORMAL USE.   SHOW PV USED.              72600019
         L     RB,WOCH         PICK UP ONCHAR ADDRESS.                  72800019
         LA    RE,4(0,RB)                                               73000019
         CR    RE,RJ                                                    73200019
         BNE   RETWOCH                                                  73400019
         LA    RB,1(0,RE)                                               73600019
RETWOCH  ST    RB,ASTRING                                               73800019
         LA    RB,1            LENGTH=1.                                74000019
         STH   RB,CURLEN                                                74200019
         B     COMMON2                                                  74400019
*                       ONCHAR PV IS NO-OP WHEN SIGNALLED.              74600019
ONCHRPV4 LR    RB,RA                                                    74800019
         B     RETWOCH                                                  75000019
*                       **  DATAFIELD BIF.                              75200019
DAFLDBIF EQU   *                                                        75400019
         CR    RE,RJ              IS THERE A PRIOR LWS?           H391  75800019
         BE    ONSRCSIG           NO - RETURN NULL STRING.        H391  76200019
         CLI   WONC,X'88'         IS IT "NAME" CONDITION?.        H391  76600019
         BNE   ONSRCSIG           NO - RETURN NULL STRING.        H391  77000019
SRC30    MVC   0(8,RA),WODF             MOVE ERROR SDV TO ARGUMENT SDV. 77500013
         B     COMMON1                                                  78000013
*                       **  ONFILE BIF                                  78100019
ONFILBIF EQU   *                                                        78200019
         CR    RE,RJ              IS THERE A PRIOR LWS?           H391  78260019
         BE    ONSRCSIG           NO - RETURN NULL STRING.        H391  78320019
         TM    WONC,X'80'         IS IT AN I/O CONDITION?         H391  78380019
         BZ    ONSRCSIG           NO - RETURN NULL STRING.        H391  78440019
SRC40    L     RG,WFIL                  GET A(DCLCB).                   78500013
         ST    PR,0(RA)                 SET SDV ARGUMENT IF NULL.       79000013
         ST    RG,4(RA)                                                 79500013
         LTR   RG,RG                 +  CURRENT FILE SET.               80000013
         BZ    COMMON2                                                  80500013
         LA    RC,DFIL                  A(FILENAME).                    81000013
         ST    RC,0(RA)                 SET IN ARGUMENT SDV.            81500013
         SR    RC,RC                                                    82000013
         IC    RC,DFLN                  L(FILENAME-1).                  82500013
         LA    RC,1(RC)                                                 83000013
         STH   RC,6(RA)                 SET IN CURRENT LENGTH.          83500013
COMMON1  TM    6(RA),X'FF'           +  STRING GT 255.                  85000013
         BZ    COMMON2                 NO                               85500013
         OI    7(RA),X'FF'                                              86000013
COMMON2  MVI   6(RA),0                  TRUNCATE CURRENT LENGTH.        86500013
         MVC   4(2,RA),6(RA)            SET MAX LENGTH= CURRENT LENGTH. 87000013
COMMON3  NC    1(3,RA),1(RA)         +  ARGUMENT SDV SET ZERO.          87500013
         BNZ   COMMON4                 NO                               88000013
         XC    4(4,RA),4(RA)            ZERO LENGTH FIELDS.             88500013
         ST    PR,0(RA)                                                 89000013
COMMON4  LR    DR,RD                    RESTORE CALLER'S SSA.           89500013
         LM    LR,WR,OFLR(DR)           RESTORE CALLER'S REGISTERS.     90000013
         BR    LR                                                       90500013
VERRC    DC    V(IHEERRC)                                               91000013
H008     DC    H'8'                                                     91500013
         END                                                            92000013
