STP1     TITLE     'STRING PSEUDO-VARIABLE'                             00100001
*                                                                       00200001
*   VERSION        FIFTH VERSION OF F-LEVEL PL/1 COMPILER               00300001
*                                                                       00400001
*   STATUS         CHANGE LEVEL - 0                                     00500001
*        APAR 32312 FIXED AT CLEAR OFFSET 344000           CB           00550000
*                                                                       00600001
*   SIZE           1424 BYTES                                           00700001
*                                                                       00800001
*   FUNCTION       ASSIGNS A BIT OR CHARACTER STRING TO THE ELEMENTS    00900001
*                  OF A SCALAR,ARRAY OR STRUCTURE VARIABLE.             01000001
*                       (STRING PSEUDO-VARIABLE).                       01100001
*                                                                       01200001
*   ENTRY POINT    IHESTPA                                              01300001
*                     RA=A(DOPE VECTOR)                                 01400001
*                     RB=A(DOPE VECTOR DESCRIPTOR).                     01500001
*                     RC=A(STRING DOPE VECTOR).                         01600001
*                                                                       01700001
*   INPUT          N/A                                                  01800001
*                                                                       01900001
*   OUTPUT         N/A                                                  02000001
*                                                                       02100001
*   EXTERNAL MODULES                                                    02200001
*                  IHEBSK,IHEBSM,IHEJXI.                                02300001
*                                                                       02400001
*   EXITS          NORMAL                                               02500001
*                   RETURN TO CALLER VIA LINK REGISTER.                 02600001
*                                                                       02700001
*   TABLES/WORK-AREA                                                    02800001
*                  WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS).    02900001
*                                                                       03000001
*   ATTRIBUTES     READ ONLY AND REENTRANT.                             03100001
*                                                                       03200001
*   PRIVATE MACROS                                                      03300001
*                  IHELIB,IHESDR.                                       03400001
*                                                                       03500001
*   ASSEMBLY REQUIREMENTS                                               03600001
*                  MUST BE ASSEMBLED BY AN ASSEMBLER WITH               03700001
*                  PSEUDO-REGISTER SUPPORT.                             03800001
*                  E.G.  O/S 360 F-ASSEMBLER.                           03900001
*                                                                       04000001
*   NOTES          SEE OS/360 PL/1 LIBRARY PLM FOR LIBRARY CONVENTIONS  04100001
*                  AND STANDARDS.                                       04200001
*                  THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON    04300001
*                  A PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL 04400001
*                  CHARACTER SET.                                       04500001
         EJECT                                                          04600001
IHESTP   CSECT                                                          04700001
         SPACE 2                                                        04800001
         IHELIB                                                         04900001
         EJECT                                                          05000001
IHEZLW4  DSECT                                                          05100001
         DS    CL72                                                     05200001
BSWIT    DS    C                                                        05300001
VSWIT    DS    C                                                        05400001
DOPT     DS    D                                                        05500001
DOPTS    DS    D                                                        05600001
SAVE     DS    D                                                        05700001
FIRST    DS    F                                                        05800001
LAST     DS    F                                                        05900001
REGST    DS    3F                                                       06000001
LENST    DS    F                                                        06100001
STOR     DS    H                                                        06200001
STDIM    DS    F                                                        06300001
         SPACE 4                                                        06400001
*  SYMBOL                   USE                                         06500001
* ********                 *****                                        06600001
*                                                                       06700001
* BSWIT       BIT FORMAT INDICATOR                                      06800001
* DOPT        AREA IN WHICH SDV FOR BIT FORMAT ELEMENTS IS CREATED      06900001
*               FOR USE IN ASSIGNMENT OF GIVEN STRING                   07000001
* DOPTS       AREA FOR PRESERVING SDV OF GIVEN STRING                   07100001
* FIRST       HOLDS ADDRESS OF FIRST VDA SLOT                           07200001
* LAST        HOLDS ADDRESS OF LAST  VDA SLOT                           07300001
* REGST       STORE FOR REGISTERS RA,RB AND RC                          07400001
* SAVE        AREA FOR SDV OF GIVEN STRING                              07500001
* STOR        AREA USED IN ROUTINE TO ACCUMULATE NO ELEMENTS IN ARRAY   07600001
* VSWIT       VARYING STRING INDICATOR                                  07700001
         EJECT                                                          07800001
*   REGISTER SYMBOL ASSIGNMENTS                                         07900001
*                                                                       08000001
SDV      EQU   RC                                                       08100001
WORK1    EQU   RD                                                       08200001
VDA      EQU   RD                                                       08300001
DOV      EQU   RE                                                       08400001
DVD      EQU   RF                                                       08500001
WORK     EQU   RG                                                       08600001
DIMST    EQU   RH                                                       08700001
LENGTH   EQU   RH                                                       08800001
COUNT    EQU   RI                                                       08900001
ADDR     EQU   RI                                                       09000001
DIM      EQU   RJ                                                       09100001
BASE     EQU   WR                                                       09200001
         SPACE 4                                                        09300001
*  REGISTER                 USE                                         09400001
* **********               *****                                        09500001
*                                                                       09600001
*   BASE      BASE REGISTER                                             09700001
*   COUNT     ACCUMULATES NO. OF ELEMENTS IN THE VARIABLE               09800001
*   DIM       DIMENSIONS OF ELEMENT                                     09900001
*   DIMST     AS DIM,TO ENABLE COMPUTATION OF NO. OF ELEMENTS IN        10000001
*               AN ARRAY WITHOUT DESTROYING CONTENTS OF REG. DIM        10100001
*   DOV       ADDRESS OF STRUCTURE DOPE VECTOR                          10200001
*   DVD       ADDRESS OF DOPE VECTOR DESCRIPTION                        10300001
*   SDV       ADDRESS OF STRING DOPE VECTOR FOR GIVEN STRING            10400001
*   VDA       ADDRESS OF A VDA SLOT                                     10500001
         SPACE 3                                                        10600001
*        THE FOLLOWING ARE ALSO USED AS GENERAL WORK REGISTERS          10700001
*                                                                       10800001
*   ADDR     (1) CONVERSION OF ADDRESS FORMAT (BIT - BYTE)              10900001
*            (2) INCREMENTATION OF GIVEN BIT STRING POINTER             11000001
*   LENGTH   (1) HOLD LENGTH OF ELEMENT TEMPORARILY                     11100001
*            (2) LENGTH OF GIVEN STRING REMAINING AFTER EVERY ASSGNMT.  11200001
*            (3) ADDRESS OF FIELD TO BE SET TO BLANK IF GIVEN STRING IS 11300001
*                  EXHAUSTED                                            11400001
*   WORK  )   GENERAL WORK                                              11500001
*   WORK1 )     REGISTERS                                               11600001
         EJECT                                                          11700001
IHESTP   CSECT                                                          11800001
         ENTRY IHESTPA                                                  11900001
         USING IHEZLW4,DR            *                                  12000001
IHESTPA  STM   LR,WR,OFLR(DR)        *   THE FIRST 18 WORDS OF LIBRARY  12100001
         BALR  BASE,0                * WORKSPACE LEVEL 4 ARE USED AS A  12200001
         USING *,BASE                * SAVE AREA.                       12300001
         IHESDR LW4,RJ               *   REGISTER WR (BASE) IS SET UP   12400001
*                                    * AS A BASE REGISTER AND THE       12500001
*                                    * ADDRESS OF LW4 IS STORED IN      12600001
*                                    * REGISTER DR                      12700001
         SPACE 2                                                        12800001
*                                                                       12900001
*   REGISTER RA CONTAINS ADDRESS OF FIRST STRUCTURE DOPE VECTOR (DOV)   13000001
*   REGISTER RB CONTAINS ADDRESS OF FIRST DOPE VECTOR DESCRIPTION (DVD) 13100001
*   REGISTER RC CONTAINS ADDRESS OF THE STRING DOPE VECTOR (SDV)        13200001
*                                                                       13300001
         SPACE 2                                                        13400001
         STM   RA,RC,REGST               RA,RB,RC ARE STORED IN REGST.  13500001
         LR    DOV,RA                    DOV AND DVD ARE LOADED         13600001
         LR    DVD,RB                  FROM RA AND RB RESPECTIVELY      13700001
         SR    RJ,RJ                                                    13800001
         LR    COUNT,RJ                  COUNT IS SET TO ZERO           13900001
         B     TESTB                     GO TO BASE ELEMENT TEST        14000001
LOOP1    LA    DVD,4(DVD)                POINT AT NEXT DVD.             14100001
TESTB    TM    0(DVD),X'80'              IS IT FOR A BASE ELEMENT?      14200001
         BZ    LOOP1                      NO: GOT LOOP1                 14300001
         SR    DIM,DIM                   YES: SET REGISTER RJ (DIM) TO  14400001
         IC    DIM,1(DVD)              ZERO,LOAD WITH THE MODULUS OF    14500001
         LPR   DIM,DIM                 THE DIMENSIONS. IF DIM IS NOT    14600001
         BNZ   ARRAY                   ZERO THEN GO TO ARRAY            14700001
         EJECT                                                          14800001
*   ROUTINE FOR SCALAR BASE ELEMENT                                     14900001
*                                                                       15000001
         LA    COUNT,1(COUNT)        *                                  15100001
         LA    DOV,4(DOV)            *   ADD ONE TO COUNT AND BUMP DOV  15200001
         TM    3(DVD),X'FF'          * BY 4 IF BASE ELEMENT IS NOT A    15300001
         BNZ   TEOS                  * STRING AND 8 IF IT IS.           15400001
         LA    DOV,4(DOV)            *   GO TO TEOS (TEST FOR END OF    15500001
         B     TEOS                  * STRUCTURE)                       15600001
*                                                                       15700001
*   ROUTINE FOR ARRAY BASE ELEMENT                                      15800001
*                                                                       15900001
ARRAY    LR    DIMST,DIM             *   LOAD REGISTER RH (DIMST) WITH  16000001
         LA    R0,1                  *                                  16100001
LOOP2    LA    WORK,0(DIM,DIMST)     * DIMENSIONS.                      16200001
         AR    WORK,WORK             *   MULTIPLY DIMENSIONS BY 8 (TO   16300001
         AR    WORK,WORK             * POINT AT UPPER BOUND).           16400001
         LH    WORK1,0(WORK,DOV)     *   CALCULATE NUMBER OF ELEMENTS   16500001
         SH    WORK1,2(WORK,DOV)     * (UPPER BOUND-LOWER BOUND+1).     16600001
         LA    WORK1,1(WORK1)        *   ADD NO. OF ELEMENTS TO COUNT   16700001
         STH   WORK1,STOR            *                                  16800001
         MH    R0,STOR               * REDUCE DIMST BY ONE              16900001
         BCT   DIMST,LOOP2           * IF NOT ZERO GO TO LOOP2          17000001
         AR    COUNT,R0              *                                  17100001
         SLL   DIM,3                 *   MULTIPLY DIMENSIONS BY 8 AND   17200001
         LA    DOV,4(DIM,DOV)        * BUMP DOV TO POINT AT NEXT        17300001
         TM    3(DVD),X'FF'          * STRUCTURE DOPE VECTOR            17400001
         BNZ   TEOS                  *   IF NOT STRING DOV=DOV+DIM+4    17500001
         LA    DOV,4(DOV)            *   IF STRING     DOV=DOV+DIM+8    17600001
TEOS     TM    0(DVD),X'40'          *   TEST FOR END OF STRUCTURE      17700001
         BZ    LOOP1                 * IF NOT GO TO LOOP1               17800001
         EJECT                                                          17900001
*   ROUTINE TO GET VARIABLE DATA AREA (VDA) ADDRESS                     18000001
*                                                                       18100001
         SLL   COUNT,3               *   CALCULATE LENGTH OF VDA BY     18200001
         LA    COUNT,8(COUNT)        * MULTIPLYING COUNT BY8 AND        18300001
         LR    R0,COUNT              * ADDING 8 (FOR CONTROL BYTES).AND 18400001
         IHEPRV VDA,BR               * PUT THIS PARAMETER IN R0. GO TO  18500001
         BALR  LR,BR                 * IHESA AND GET VDA ADDRESS        18600001
         SPACE 2                                                        18700001
*                                                                       18800001
*   ADDRESS OF VARIABLE DATA AREA IS PASSED BACK IN REGISTER RA.        18900001
*                                                                       19000001
         SPACE 2                                                        19100001
         LR    VDA,RA                *   LOAD VDA ADDRESS FROM RA       19200001
         LM    RA,RC,REGST           *   RELOAD RA,RB AND RC(SDV)       19300001
         LR    DOV,RA                *   RELOAD DOV AND DVD FROM RA     19400001
         LR    DVD,RB                * AND RB                           19500001
         MVC   SAVE,0(RC)            *                                  19600001
         LA    SDV,SAVE              *                                  19700001
         MVI   BSWIT,0               *   SET BIT SWITCH TO ZERO         19800001
         LA    VDA,8(VDA)            *   PASS OVER 8 CONTROL BYTES OF   19900001
         ST    VDA,FIRST             * VDA AND STORE FIRST SLOT ADDRESS 20000001
         B     TESTB1                *                                  20100001
LOOP3    LA    DVD,4(DVD)            *   POINT AT NEXT DVD              20200001
TESTB1   TM    0(DVD),X'80'          *   IS IT FOR A BASE ELEMENT?      20300001
         BZ    LOOP3                 *   NO: GO TO LOOP3                20400001
         TM    2(DVD),X'80'          *  YES: IF BASE ELEMENT IS BIT     20500001
         BO    SETSW                 * STRING OR BINARY NUMBER,SET ON   20600001
         TM    2(DVD),X'07'          * BIT SWITCH AND GO TO TESTD       20700001
         BO    TESTD                 * OTHERWISE GO TO TESTD            20800001
SETSW    MVI   BSWIT,1               *                                  20900001
TESTD    SR    DIM,DIM               *   LOAD MODULUS OF DIMENSIONS IN  21000001
         IC    DIM,1(DVD)            * DIM,IF DIM IS ZERO GO TO         21100001
         LPR   DIM,DIM               * SCALAR ROUTINE                   21200001
         BZ    SCALAR                *                                  21300001
         EJECT                                                          21400001
*   ROUTINE FOR ARRAY BASE ELEMENT                                      21500001
*                                                                       21600001
         XC    STDIM(3),STDIM        * CLEAR FIRST THREE BYTES          21700001
         MVC   STDIM+3(1),1(DVD)     *    SET UP PARAMETERS FOR IHEJXI  21800001
         LA    RB,STDIM              * RA= A(ARRAY DOPE VECTOR)         21900001
*                                    * RB= A(DIMENSIONS)                22000001
         LR    RA,DOV                *                                  22100001
         TM    2(DVD),X'40'          *   IF ARRAY IS OF VARYING STRING  22200001
         BO    VARSTA                * FORMAT GO TO VARSTA.             22300001
         CLI   BSWIT,1               *   IF IT IS OF BIT FORMAT GO TO   22400001
         BE    BITA                  * BITA                             22500001
*                                                                       22600001
* ROUTINE FOR NON VARYING STRING,NON BIT FORMAT ARRAY                   22700001
*                                                                       22800001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*STP999-TSS 22850000
         L     BR,JXIY               *   BRANCH AND LINK TO IHEJXIY     22900001
*        ----------------------------------------------------STP999-TSS 22950000
         BALR  LR,BR                 * ON RETURN RA CONTAINS ADDRESS OF 23000001
         ST    RA,0(VDA)             * FIRST ELEMENT.STORE THIS ADDRESS 23100001
         TM    3(DVD),X'FF'          * IN FIRST 4 BYTES OF NEXT VDA     23200001
         BNZ   NUMA                  * SLOT. GET LENGTH OF ELEMENT FROM 23300001
NONUMB   SLL   DIM,3                 * DVD IF NUMERIC AND DOV IF NOT    23400001
         SR    LENGTH,LENGTH         *                                  23500001
         LH    LENGTH,4(DIM,DOV)     * AND STORE IN NEXT 4 BYTES OF VDA 23600001
         LA    DOV,8(DIM,DOV)        * SLOT.                            23700001
         B     STOR1                 *   BUMP DOV BY (8XDIM)+4 AND IF   23800001
NUMA     SR    LENGTH,LENGTH         * ELEMENT IS NOT NUMERIC BY        23900001
         IC    LENGTH,3(DVD)         * ANOTHER 4. SET FLAG (BIT 32 OF   24000001
         SRL   LENGTH,3              * VDA) TO 0.                       24100001
         SLL   DIM,3                 *       GO TO BUMP1                24200001
         LA    DOV,4(DIM,DOV)        *     (BUMP VDA POINTER)           24300001
STOR1    ST    LENGTH,4(VDA)         *                                  24400001
         NI    4(VDA),X'7F'          * SET OFF VARYING STRING FLAG      24500001
         B     BUMP1                 *                                  24600001
*                                                                       24700001
* ROUTINE FOR NON-VARYING STRING,BIT FORMAT ARRAY                       24800001
*                                                                       24900001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*STP998-TSS 24950000
BITA     L     BR,JXII               *                                  25000001
*        ----------------------------------------------------STP998-TSS 25050000
         BALR  LR,BR                 *                                  25100001
         ST    RA,0(VDA)             *                                  25200001
         TM    3(DVD),X'FF'          *                                  25300001
         BZ    NONUMB                *   AS FOR ROUTINE FOR NON VARYING 25400001
NUMB     SR    LENGTH,LENGTH         * NON BIT FORMAT EXCEPT BRANCH     25500001
         IC    LENGTH,3(DVD)         * TO JXII                          25600001
         SLL   DIM,3                 * ALL ADDRESSES WILL BE IN         25700001
         LA    DOV,4(DIM,DOV)        * BIT FORMAT.                      25800001
         B     STOR1                 *                                  25900001
BUMP1    LA    VDA,8(VDA)            *   POINT AT NEXT VDA              26000001
*                                                                       26100001
*   ROUTINE TO GET ADDRESS OF NEXT ELEMENT OF AN ARRAY                  26200001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*STP997-TSS 26250000
         L     BR,JXIA               *   BRANCH AND LINK TO IHEJXIA     26300001
*        ----------------------------------------------------STP997-TSS 26350000
         BALR  LR,BR                 * IF ON RETURN BR=4 THEN GO TO     26400001
         CL    BR,FOUR               * TEOS1(TEST FOR END OF STUCTURE)  26500001
         BE    TEOS1                 * OTHERWISE STORE ADDRESS(FROM RA) 26600001
         ST    RA,0(VDA)             * AND LENGTH IN VDA. SET FLAG TO 0 26700001
         ST    LENGTH,4(VDA)         *                                  26800001
         NI    4(VDA),X'7F'          *                                  26900001
         B     BUMP1                 *   GO TO BUMP1                    27000001
TEOS1    TM    0(DVD),X'40'          *   ON END OF STRUCTURE CONDITION  27100001
         BO    SORT                  * GO TO SORT                       27200001
LOOP4    LA    DVD,4(DVD)            *                                  27300001
         TM    0(DVD),X'80'          *   SEARCH DVDS FOR BASE ELEMENT   27400001
         BO    TESTD                 * AND GO TO TESTD                  27500001
         B     LOOP4                 *                                  27600001
*                                                                       27700001
*   ROUTINE FOR VARYING STRING ARRAY                                    27800001
*                                                                       27900001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*STP996-TSS 27950000
VARSTA   L     BR,JXIY               *   BRANCH AND LINK TO JXIY        28000001
*        ----------------------------------------------------STP996-TSS 28050000
         BALR  LR,BR                 *   ON RETURN RA CONTAINS ADDRESS  28100001
         CLI   BSWIT,1               * OF SDV. GET ADDRESS OF ELEMENT   28200001
         BE    BITVA1                * FROM SDV AND CONVERT TO BIT      28300001
         MVC   0(4,VDA),0(RA)        * FORMAT IF BIT STRING. STORE THIS 28400001
         B     STSDV                 * ADDRESS IN FIRST 4 BYTES OF VDA  28500001
BITVA1   SR    WORK,WORK             * SLOT.                            28600001
         IC    WORK,0(RA)            *                                  28700001
         SRL   WORK,5                *    STORE ADDRESS OF SDV IN NEXT  28800001
         L     ADDR,0(RA)            * 4 BYTES OF VDA SLOT AND SET FLAG 28900001
         SLL   ADDR,3                * IN BIT 32 TO 1.                  29000001
         AR    ADDR,WORK             *                                  29100001
         ST    ADDR,0(VDA)           *                                  29200001
STSDV    ST    RA,4(VDA)             *                                  29300001
         OI    4(VDA),X'80'          *                                  29400001
*                                                                       29500001
*   ROUTINE TO GET ADDRESS OF NEXT ELEMENT                              29600001
*                                                                       29700001
BUMP2    LA    VDA,8(VDA)            *   POINT AT NEXT VDA SLOT         29800001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*STP995-TSS 29850000
         L     BR,JXIA               *                                  29900001
*        ----------------------------------------------------STP995-TSS 29950000
         BALR  LR,BR                 *   BRANCH AND LINK TO IHEJXIA.    30000001
        CL     BR,FOUR               *   IF ON RETURN BR=4 (END OF      30100001
        BE     BUMP3                 * ARRAY) GO TO BUMP3 (BUMP DOV)    30200001
         ST    RA,4(VDA)             *           RA CONTAINS ADDRESS OF 30300001
         OI    4(VDA),X'80'          * SDV.STORE THIS IN VDA SLOT AND   30400001
         CLI   BSWIT,1               * SET FLAG TO 1.                   30500001
         BE    BITVA2                *   GET ADDRESS OF ELEMENT FROM    30600001
         MVC   0(4,VDA),0(RA)        * SDV AND CONVERT TO BIT ADDRESS   30700001
         B     BUMP2                 * IF ELEMENT IS BIT STRING.        30800001
BITVA2   SR    WORK,WORK             *   STORE THIS ADDRESS IN FIRST    30900001
         IC    WORK,0(RA)            * 4 BYTES OF VDA SLOT              31000001
         SRL   WORK,5                *                                  31100001
         L     ADDR,0(RA)            *    GO TO BUMP2 (POINT AT NEXT    31200001
         SLL   ADDR,3                *  VDA SLOT)                       31300001
         AR    ADDR,WORK             *                                  31400001
         ST    ADDR,0(VDA)           *                                  31500001
         B     BUMP2                 *                                  31600001
BUMP3    SLL   DIM,3                 *    POINT AT NEXT DOV AND GO TO   31700001
         LA    DOV,8(DIM,DOV)        * TEOS1  TEST FOR END OF STRUCTURE 31800001
         B     TEOS1                 *                                  31900001
*                                                                       32000001
*   ROUTINE FOR SCALAR BASE ELEMENT.                                    32100001
*                                                                       32200001
SCALAR   CLI   BSWIT,1               *   IF ELEMENT IS BIT FORMAT GO TO 32300001
         BE    BITSC                 * BITSC                            32400001
         MVC   0(4,VDA),0(DOV)       *   PUT ADDRESS OF ELEMENT IN VDA  32500001
         TM    2(DVD),X'40'          * SLOT.                            32600001
         BO    VARSC                 *   IF ELEMENT IS VARYING STRING   32700001
*                                                                       32800001
*   ROUTINE FOR NON-VARYING STRING,CHARACTER FORMAT                     32900001
*                                                                       33000001
         TM    3(DVD),X'FF'          * GO TO VARSC,IF NUMERIC           33100001
*                                    * GO TO NUMSC                      33200001
         BNZ   NUMSC                 *   STORE LENGTH OF ELEMENT IN     33300001
STBLEN   MVC   6(2,VDA),4(DOV)       * VDA,SET FLAG TO ZERO AND BUMP    33400001
         NI    4(VDA),X'00'          * DOV BY 8 IF ELEMENT IS STRING    33500001
         NI    5(VDA),X'00'          *    AND 4 IF IT IS NUMERIC        33600001
BUMP4    LA    DOV,8(DOV)            *                                  33700001
         B     BUMP6                 *                                  33800001
NUMSC    SR    LENGTH,LENGTH         *                                  33900001
         IC    LENGTH,3(DVD)         *                                  34000001
         SRL   LENGTH,3              *                                  34100001
BUMP5    ST    LENGTH,4(VDA)         *                                  34200001
         NI    4(VDA),X'7F'          *                                  34300001
         LA    DOV,4(DOV)            *  GO TO BUMP6           32312     34400000
         B     BUMP6                 *  (BUMP VDA POINTER)              34500001
BITSC    SR    WORK,WORK             *                                  34600001
         IC    WORK,0(DOV)           *                                  34700001
         SRL   WORK,5                *   CONVERT THE ADDRESS IN THE SDV 34800001
         L     ADDR,0(DOV)           * TO A BIT ADDRESS                 34900001
         SLL   ADDR,3                * AND STORE IT IN THE VDA SLOT.    35000001
         AR    ADDR,WORK             *                                  35100001
         ST    ADDR,0(VDA)           *                                  35200001
         TM    2(DVD),X'40'          *                                  35300001
         BO    VARSC                 *                                  35400001
*                                                                       35500001
*   ROUTINE FOR NON-VARYING STRING BIT FORMAT                           35600001
*                                                                       35700001
         TM    3(DVD),X'FF'          *   IF ELEMENT IS BIT STRING GO TO 35800001
         BZ    STBLEN                * STBLEN (STORE LENGTH),IF NUMERIC 35900001
         SR    LENGTH,LENGTH         * GET LENGTH FROM DVD AND GO TO    36000001
         IC    LENGTH,3(DVD)         * BUMP5 (STORE LENGTH)             36100001
         B     BUMP5                 *                                  36200001
*                                                                       36300001
*   ROUTINE FOR VARYING STRING SCALAR BASE ELEMENT.                     36400001
*                                                                       36500001
VARSC    ST    DOV,4(VDA)            *   STORE ADDRESS OF SDV IN VDA    36600001
         OI    4(VDA),X'80'          * SLOT,SET FLAG TO 1,AND GO TO     36700001
         B     BUMP4                 * BUMP4 (BUMP DOV)                 36800001
BUMP6    LA    VDA,8(VDA)            * BUMP VDA POINTER                 36900001
         B     TEOS1                 *                                  37000001
         EJECT                                                          37100001
*   SORT ROUTINE                                                        37200001
*                                                                       37300001
SORT     S     VDA,EIGHT             *                                  37400001
         ST    VDA,LAST              *   LOAD COUNT WITH ADDRESS OF     37500001
         L     COUNT,FIRST           * FIRST VDA SLOT                   37600001
        B     LASTTEST            GO TO TEST IF LAST ELEMENT            37650001
INCW1    LA    WORK,8(COUNT)         *   LOAD WORK WITH COUNT+8         37700001
COMP     CLC   0(4,WORK),0(COUNT)    *                                  37800001
         BNL   INCW2                 *   IF ADDRESS IN VDA SLOT POINTED 37900001
         XC    0(8,COUNT),0(WORK)    * AT BY WORK < THAT BY COUNT       38000001
         XC    0(8,WORK),0(COUNT)    *   INTERCHANGE THE VDA SLOTS      38100001
         XC    0(8,COUNT),0(WORK)    *                                  38200001
INCW2    LA    WORK,8(WORK)          *   POINT WORK AT NEXT VDA SLOT,IF 38300001
         CL    WORK,LAST             * WORK IS NOT > LAST VDA SLOT GO   38400001
         BNH   COMP                  * TO COMP.                         38500001
         LA    COUNT,8(COUNT)        *   IF IT IS INCREASE COUNT BY 8   38600001
LASTTEST EQU  *                                                         38650001
         CL    COUNT,LAST            * WHEN COUNT =LAST VDA SLOT        38700001
         BNE   INCW1                 * SORT IS FINISHED                 38800001
         EJECT                                                          38900001
         L     VDA,FIRST             *   POINT AT FIRST VDA SLOT        39000001
         TM    BSWIT,1               * IF IT IS BIT FORMAT GO TO BIT    39100001
         BO    BIT                   *                                  39200001
         L     ADDR,0(SDV)           *   LOAD RI(ADDR) WITH ADDRESS OF  39300001
         LH    LENGTH,6(SDV)         * SDV FOR GIVEN STRING             39400001
         ST    LENGTH,LENST          *                                  39500001
         LR    SDV,ADDR              *                                  39600001
TESTV    TM    4(VDA),X'80'          * IF IT IS VARYING STRING GO TO    39700001
         BO    VARY                  * VARY                             39800001
*                                                                       39900001
*   ROUTINE FOR NON VARYING STRING,CHARACTER FORMAT                     40000001
*                                                                       40100001
         C     LENGTH,4(VDA)         *   IF THE STRING IS TOO SHORT FOR 40200001
         BL    LESS                  * ELEMENT GO TO LESS,IF IT IS      40300001
         BE    EQU                   * EQUAL GO TO EQU                  40400001
         LA    RJ,ENUF               *   ELSE LOAD ADDRESS OF ROUTINE   40500001
         L     RB,0(VDA)             * ENUF,ADDRESS AND LENGTH OF       40600001
         L     RA,4(VDA)             * ELEMENT IN RJ,RB AND RA          40700001
         B     MOVE                  *   GO TO MOVE                     40800001
LESS     LA    RJ,FEW                *   LOAD ADDRESS OF FEW ROUTINE IN 40900001
         L     RB,0(VDA)             * RJ,ADDRESS OF ELEMENT AND LENGTH 41000001
         LR    RA,LENGTH             * OF STRING LEFT INTO RJ,RB AND RA 41100001
         B     MOVE                  *                                  41200001
EQU      LA    RJ,EOST               *   LOAD ADDRESS OF EOST (END OF   41300001
         L     RB,0(VDA)             * STRING)ROUTINE,ADDRESS AND       41400001
         L     RA,4(VDA)             * LENGTH OF ELEMENT INTO RJ,RB,RA. 41500001
MOVE     C     RA,K256               *   IF LENGTH IS OVER 256 BYTES    41600001
         BNH   MOVER                 * LONG MOVE 256 BYTES,AT A TIME,   41700001
         MVC   0(256,RB),0(SDV)      * FROM STRING TO STORAGE. WHEN     41800001
         LA    RB,256(RB)            * LENGTH IS LESS THAN 256 BYTES    41900001
         LA    SDV,256(SDV)          * MOVE THIS LENGTH OF THE STRING   42000001
         S     LENGTH,K256           *                                  42100001
         S     RA,K256               * INTO STORAGE AND BRANCH TO       42200001
         B     MOVE                  * ROUTINE VIA REGISTER RJ          42300001
MOVER    BCTR  RA,0                  *                                  42400001
         LTR   RA,RA                                                    42500001
         BL    TESTL                                                    42600001
         EX    RA,MOVA               *                                  42700001
         BR    RJ                    *                                  42800001
MOVA     MVC   0(0,RB),0(SDV)        *                                  42900001
ENUF     LA    RA,1(RA)              *                                  43000001
         AR    SDV,RA                *   POINT SDV AT NEXT BYTE OF      43100001
         SR    LENGTH,RA             * STRING AND REDUCE LENGTH BY      43200001
         ST    LENGTH,LENST             SAVE REMAINING LENGTH.          43250001
TESTL    C     VDA,LAST              * AMOUNT JUST MOVED.               43300001
         BNL   FINISH                *   IF LAST VDA HAS BEEN DEALT     43400001
         LA    VDA,8(VDA)            * WITH GO TO FINISH,ELSE POINT AT  43500001
         B     TESTV                 * NEXT VDA AND GO TO TESTV         43600001
FEW      L     WORK,4(VDA)           *                                  43700001
FEWA     L     LENGTH,LENST          *                                  43800001
         SR    WORK,LENGTH           *                                  43900001
         A     LENGTH,0(VDA)         *   LENGTH POINTS AT FIRST BYTE TO 44000001
BLANK    MVI   0(LENGTH),X'40'       * BE SET TO BLANK                  44100001
BZERO    LR    RB,LENGTH             *                                  44200001
         LR    RA,WORK               *                                  44300001
MAXA     C     RA,K256               *   IF LENGTH IS MORE THAN 256     44400001
         BNH   MOVERA                * MOVE 256 BLANKS AT A TIME        44500001
         MVC   1(256,RB),0(RB)       *                                  44600001
         LA    RB,256(RB)            *   WHEN LENGTH IS LESS THAN 256   44700001
         S     RA,K256               * MOVE NUMBER OF BLANKS REQUIRED   44800001
         S     LENGTH,K256           *                                  44900001
         B     MAXA                  * INTO STORAGE.                    45000001
MOVERA   BCTR  RA,0                  *                                  45100001
         BCTR  RA,0                  *                                  45200001
         LTR   RA,RA                 *                                  45300001
         BL    EOST                  *                                  45400001
         EX    RA,MOVEA              *                                  45500001
EOST     C     VDA,LAST              *   WHEN LAST VDA HAS BEEN DEALT   45600001
         BNL   FINISH                * WITH,GO TO FINISH ROUTINE        45700001
         LA    VDA,8(VDA)            *   OTHERWISE POINT AT NEXT VDA    45800001
         TM    4(VDA),X'80'          * IF IT IS FOR VARYING STRING GO   45900001
         BO    SETL                  * TO SETL                          46000001
         TM    BSWIT,1               *   IF ELEMENT IS NOT OF BIT       46100001
         BZ    CHAR                  * FORMAT GO TO CHAR, ELSE CONVERT  46200001
         L     LENGTH,0(VDA)         * ADDRESS TO BYTES AND LOAD INTO   46300001
         SRL   LENGTH,3              * RH                               46400001
         L     WORK,4(VDA)           *   CONVERT LENGTH OF ELEMENT TO   46500001
         SRL   WORK,3                * BYTES,ADD 2 AND GO TO BZERO      46600001
         LA    WORK,2(WORK)          *                                  46700001
         MVI   0(LENGTH),X'00'       * SET BYTE TO ZERO                 46800001
         B     BZERO                 *                                  46900001
CHAR     L     LENGTH,0(VDA)         *   IF ELEMENT IS CHARACTER LOAD   47000001
         L     WORK,4(VDA)           * ADDRESS AND LENGTH IN RH AND RG  47100001
         B     BLANK                 *   GO TO BLANK                    47200001
MOVEA    MVC   1(0,RB),0(RB)         *                                  47300001
*                                                                       47400001
*   ROUTINE FOR VARYING STRING FORMAT ELEMENTS                          47500001
*                                                                       47600001
VARY     NI    4(VDA),X'7F'          *                                  47700001
         L     RB,0(VDA)             *   LOAD ADDRESS OF ELEMENT        47800001
         L     ADDR,4(VDA)           *                                  47900001
         CH    LENGTH,4(ADDR)        *    IF STRING IS TO SHORT GO TO   48000001
         BL    LOW                   * LOW,IF EQUAL TO SAME             48100001
         BE    SAME                  *                                  48200001
         LA    RJ,ENUF               *   ELSE LOAD ADDRESS OF ROUTINE   48300001
         LH    RA,4(ADDR)            * ENUF AND LENGTH OF ELEMENT IN RJ 48360001
         STH   RA,6(ADDR)            *                                  48420001
         B     MOVE                  * AND RA,GO TO MOVE                48500001
LOW      LA    RJ,EOST               *   LOAD ADDRESS OF ROUTINE FEWV   48600001
         LR    RA,LENGTH             * AND LENGTH OF STRING IN RJ,RA    48700001
         STH   RA,6(ADDR)            *                                  48750001
         B     MOVE                  *   GO TO MOVE.                    48800001
SAME     LA    RJ,EOST               *   LOAD ADDRESS OF ROUTINE EOST   48900001
         LR    RA,LENGTH             * AND LENGTH OF STRING IN RJ,RA    49000001
         STH   RA,6(ADDR)            *                                  49050001
         B     MOVE                  *   GO TO MOVE.                    49100001
FEWV     LH    WORK,6(ADDR)          *   LOAD CURRENT LENGTH INTO WORK  49200001
         B     FEWA                  *   GO TO FEWA                     49300001
SETL     NI    4(VDA),X'7F'          *                                  49400001
         L     ADDR,4(VDA)           *   SET THE CURRENT LENGTH IN THE  49500001
         MVC   6(2,ADDR),ZERO        * ELEMENT SDV TO 0 AND GO TO END   49600001
         B     EOST                  * OF STRING ROUTINE                49700001
         EJECT                                                          49800001
*   ROUTINE FOR BIT FORMAT ELEMENT                                      49900001
*                                                                       50000001
BIT      EQU   *                     *                                  50100001
TESTVB   MVC   DOPTS,0(SDV)          *                                  50200001
         LA    RA,DOPTS              *                                  50300001
         TM    4(VDA),X'80'          *   IF ELEMENT IS VARYING STRING   50400001
         BO    BVARY                 * GO TO BVARY.                     50500001
         MVI   VSWIT,0               * SET OFF VSWIT                    50600001
         LA    RB,DOPT               *                                  50700001
         L     WORK,0(VDA)           *                                  50800001
         SRL   WORK,3                *   CREATE A STRING DOPE VECTOR    50900001
         ST    WORK,DOPT             * FOR THE ELEMENT IN THE STORAGE   51000001
         SLL   WORK,3                * AREA 'DOPT' AND LOAD ADDRESS OF  51100001
         S     WORK,0(VDA)           * THIS AREA IN RB                  51200001
         LPR   WORK,WORK             *                                  51300001
         SLL   WORK,5                *                                  51400001
         STC   WORK,0(RB)            *                                  51500001
         MVC   4(2,VDA),6(VDA)       *                                  51600001
         MVC   4(4,RB),4(VDA)        *                                  51700001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*STP994-TSS 51750000
ASSGNB   L     BR,BSKA               *   BRANCH AND LINK TO IHEBSKA     51800001
*        ----------------------------------------------------STP994-TSS 51850000
         BALR  LR,BR                 * (ASSIGNS BIT STRING)             51900001
         LH    WORK,6(SDV)           *                                  52000001
         SH    WORK,4(RB)            *   UPDATE LENGTH IN SDV,AND IF    52100001
         BNH   TESTCL                * <=0 GO TO TESTCL                 52200001
         C     VDA,LAST              *                                  52300001
         BNL   FINISH                *                                  52400001
         STH   WORK,6(SDV)           *                                  52500001
         L     WORK,0(SDV)           *                                  52600001
         SLL   WORK,3                *                                  52700001
         SR    ADDR,ADDR             *   INCREASE ADDRESS TO NEXT       52800001
         IC    ADDR,0(SDV)           * AVAILABLE BIT OF BIT STRING BY   52900001
         SRL   ADDR,5                * BUMPING ADDRESS (BYTE +OFFSET)   53000001
         AR    ADDR,WORK             * IN SDV.                          53100001
         AH    ADDR,4(RB)            *                                  53200001
        LR     WORK,ADDR             *                                  53300001
         SRL   ADDR,3                *                                  53400001
         ST    ADDR,0(SDV)           *                                  53500001
         SLL   ADDR,3                *                                  53600001
         SR    WORK,ADDR             *                                  53700001
         SLL   WORK,5                *                                  53800001
         STC   WORK,0(SDV)           *                                  53900001
         LA    VDA,8(VDA)            *                                  54000001
         B     TESTVB                *                                  54100001
TESTCL   CLC   4(2,RB),6(RB)         *                                  54200001
         BE    EOST                  * IF C.L.=M.L. OR ELEMENT IS       54300001
         TM    VSWIT,1               * VARYING STRING                   54400001
         BO    EOST                  * GO TO EOST                       54500001
         LR    RA,RB                 * ELSE BRANCH TO IHEBSMZ(PADS      54600001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*STP993-TSS 54650000
         L     BR,BSMZ               * ELEMENT WITH ZEROS)              54700001
*        ----------------------------------------------------STP993-TSS 54750000
         BALR  LR,BR                 * AND GO TO EOST                   54800001
         B     EOST                  *                                  54900001
BVARY    NI    4(VDA),X'7F'          * SET OFF FLAG BIT                 55000001
         MVI   VSWIT,1               * SET ON VSWIT                     55100001
         L     RB,4(VDA)             *                                  55200001
         B     ASSGNB                *                                  55300001
         EJECT                                                          55400001
*   CLOSE ROUTINE                                                       55500001
*                                                                       55600001
FINISH   IHEPRV FVD,BR               *                                  55700001
         BALR  LR,BR                 *                                  55900001
         L     DR,OFDR(DR)           *   RESTORE CONDITIONS.            56000001
         LM    LR,WR,OFLR(DR)        *                                  56100001
         BR    LR                    *                                  56200001
*                                                                       56300001
FOUR     DC    F'4'                                                     56400001
EIGHT    DC    F'8'                                                     56500001
K256     DC    F'256'                                                   56600001
ZERO     DC    H'0'                                                     56700001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*STP992-TSS 56750000
JXII     DC    V(IHEJXII)                                               56800001
JXIY     DC    V(IHEJXIY)                                               56900001
JXIA     DC    V(IHEJXIA)                                               57000001
BSKA     DC    V(IHEBSKA)                                               57100001
BSMZ     DC    V(IHEBSMZ)                                               57200001
*                                                                       57300001
*        ----------------------------------------------------STP992-TSS 57350000
         END                                                            57400001
