STR      TITLE '   IHESTR    STRUCTURE PROCESSOR                       *00100013
               OS/360 PL/I LIBRARY'                                     00200013
*   VERSION    FOURTH VERSION OF F-LEVEL PL/1 COMPILER                  00290015
*                                                                       00380015
*   STATUS     CHANGE LEVEL - 0                                         00470015
*                                                                       00560015
*   SIZE       1592 BYTES                                               00650015
*                                                                       00680019
*  THIS MODULE CONTAINS A FIX FOR APAR H226                             00710019
* R19          233300  336800  450200                           A27175  00720019
*                                                                       00740015
* THIS UPDATE FIXES APARS 38230 AND 38231                               00770042
* ### 092900,*  179300  197700,198500  243200,*    ### - SEE ID#        00800042
*                                                                       00806046
*  THIS UPDATE FIXES APAR 40143       - RELEASE SHOWN BY ID#.           00812046
*  297200,*   308900                                                    00818046
*                                                                       00824046
*   FUNCTION   IHESTRA - TO COMPUTE THE ADDRESS OF THE FIRST ELEMENT    00830015
*              OF A STRUCTURE AND THE TOTAL LENGTH OF THE STRUCTURE     00920015
*              GIVEN A COMPLETE STRUCTURE DOPE VECTOR AND DVD           01010015
*              IHESTRB - TO MAP A STRUCTURE COMPLETELY GIVEN A          01100015
*              STRUCTURE DOPE VECTOR WITH ONLY THE LENGTH AND BOUND     01190015
*              FIELDS COMPLETE AND A DVD USING THE PL/1 MAPPING         01280015
*              ALGORITHM                                                01370015
*              IHESTRC - AS FOR IHESTRB BUT USING THE COBOL MAPPING     01460015
*              ALGORITHM                                                01550015
*                                                                       01820015
*   ENTRY POINTS                                                        01910015
*              IHESTRA                                                  02000015
*                  RA = A(STRUCTURE DOPE VECTOR)                        02090015
*                  RB = A(DVD)                                          02180015
*                  RC = A(TARGET)                                       02270015
*              IHESTRB                                                  02360015
*                  LINKAGE AS FOR IHESTRA                               02450015
*              IHESTRC                                                  02540015
*                  LINKAGE AS FOR IHESTRA                               02630015
*                                                                       02900015
*   INPUT      N/A                                                      02990015
*                                                                       03080015
*   OUTPUT     N/A                                                      03170015
*                                                                       03260015
*   EXTERNAL MODULES                                                    03350015
*              IHESAD - GET LIBRARY VDA                                 03440015
*              IHESAF - FREE LIBRARY VDA                                03530015
*                                                                       03620015
*   EXITS      NORMAL                                                   03710015
*               RETURN TO CALLER VIA LINK REGISTER                      03800015
*              ERROR                                                    03890015
*               BRANCH TO THE ENTRY POINT IHEERRC OF THE EXECUTION      03980015
*               ERROR PACKAGE IF STRUCTURE LENGTH GE 16**6 BYTES OR IF  04070015
*               VIRTUAL ORIGIN OF AN ARRAY GE 16**6 OR LE -16**6        04160015
*                                                                       04250015
*   TABLES/WORK-AREA                                                    04340015
*              WORK-AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS).        04430015
*                                                                       04520015
*   ATTRIBUTES  READ-ONLY AND REENTRANT.                                04610015
*                                                                       04700015
*   PRIVATE MACROS                                                      04790015
*              IHELIB,IHEPRV,IHESDR                                     04880015
*                                                                       04970015
*   ASSEMBLY REQUIREMENTS                                               05060015
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   05150015
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        05240015
*                                                                       05330015
*   NOTES      SEE OS/360 PL/I LIBRARY PLM FOR LIBRARY CONVENTIONS AND  05420015
*              STANDARDS.                                               05510015
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON        05600015
*              A PARTICULAR INTERNAL REPRESENTATION OF THE              05690015
*              EXTERNAL CHARACTER SET.                                  05780015
 EJECT                                                                  05870015
IHESTR   CSECT                                                          05960015
 SPACE 2                                                                06050015
         IHELIB                                                         06140015
*              PRIVATE REGISTER ASSIGNMENT                              06230015
 SPACE                                                                  06320015
DV1      EQU   LR                  DOPE VECTOR POINTER                  06410015
SC3      EQU   LR                  SCRATCH REGISTER                     06500015
DM1      EQU   BR                  CURRENT STRUCTURE DIMENSIONALITY     06590015
DIM      EQU   R0                  CONTAINING STRUCTURE DIMENSIONALITY  06680015
NNN      EQU   RA                                                       06770015
STK      EQU   RA                  STACK POINTER                        06860015
DVD      EQU   RB                  POINTER TO DVD                       06950015
TAR      EQU   RC                  POINTER TO TARGET                    07040015
EVN      EQU   RD                  SCRATCH REGISTER                     07130015
SC1      EQU   RD                        ''                             07220015
ODD      EQU   RE                        ''                             07310015
SC2      EQU   RE                        ''                             07400015
SCR      EQU   RF                        ''                             07490015
LNK      EQU   RF                  LINK REG. FOR INTERNAL SUBROUTINES   07580015
ACC      EQU   RG                  LENGTH ACCUMULATOR                   07670015
ADD      EQU   RG                                                       07760015
LTH      EQU   RG                                                       07850015
CRF      EQU   RH                  REF. TO CONTAINING STRUCTURE         07940015
PAR      EQU   RH                                                       08030015
SRF      EQU   RI                  SCAN REFERENCE                       08120015
BAS      EQU   RJ                  BASE REGISTER                        08210015
DOV      EQU   WR                  POINTER TO DOPE VECTOR               08300015
WSP      EQU   WR                                                       08390015
 SPACE                                                                  08480015
*              LEVEL 1 WORKSPACE MAP                                    08570015
 SPACE                                                                  08660015
IHEZLW1  DSECT                                                          08750015
         DS    CL72                                                     08840015
MJSW     DS    C                   MAJOR STRUCTURE SWITCH               08930015
SLVL     DS    C                   CURRENT LEVEL                        09020015
CLVL     DS    C                   LEVEL OF CONTAINING STRUCTURE        09110015
BTSW     DS    C                   BIT STRING SWITCH                    09200015
AINC     DS    H                   ALIGNMENT INCREMENT                  09380015
MXBD     DS    H                   MAXIMUM ALIGNMENT                    09470015
OFST     DS    H                   BIT OFFSET TO START OF STRUCTURE     09560015
*                                   FROM MAXIMUM ALIGNMENT BOUNDARY     09650015
BOND     DS    H                   CURRENT ALIGNMENT                    09740015
NDIM     DS    H                   TOTAL ELEMENT DIMENSIONALITY         09830015
BNDS     DS    2H                  SLOTS FOR ARRAY BOUNDS               09920015
HBND     EQU   BNDS                UPPER BOUND OF ARRAY                 10010015
LBND     EQU   BNDS+2              LOWER BOUND                          10100015
ADVD     DS    F                   SLOT FOR ADDRESS OF DVD              10190015
         ORG   *-4                                                      10280015
ADDL     DS    F                   ADDRESS OF LAST ELEMENT              10370015
         ORG   *-8                                                      10460015
PDVD     DS    F                   DVD TO BE SET UP IF ONLY             10550015
         DS    F                    ONE ELEMENT IN STRUCTURE            10640015
LREF     DS    F                   LAST REFERENCE                       10730015
LNTH     DS    F                   ELEMENT LENGTH                       10820015
SACC     DS    F                   SLOT FOR SAVING ACCUMULATOR          10910015
 EJECT                                                                  11090015
IHESTR   CSECT                                                          11180015
 SPACE                                                                  11270015
         ENTRY IHESTRA,IHESTRB,IHESTRC                                  11370015
         USING IHEZLW1,DR                                               11470015
IHESTRA  NOPR  0                                                        11570015
IHESTRB  NOP   0                                                        11670015
IHESTRC  STM   LR,WR,OFLR(DR)                                           11770015
         BALR  BAS,0                                                    11870015
         USING *,BAS                                                    11970015
         TM    OFBR+3(DR),6        TEST ENTRY POINT                     12070015
         IHESDR LW1,WSP                                                 12170015
         LR    DOV,RA                                                   12270015
         BZ    RDDVD               BRANCH IF IHESTRA ENTRY              12370015
         BM    STDVD               BRANCH IF IHESTRB ENTRY              12470015
         LCR   TAR,TAR             SET TAR TO SHOW IHESTRC ENTRY        12570015
 SPACE                                                                  13700015
*              MAP THE STRUCTURE COMPLETELY GIVEN PARTIAL DOPE VECTOR   13790015
 SPACE                                                                  13880015
STDVD    ST    DVD,ADVD            SAVE ADDRESS OF DVD                  13970015
         LA    R0,776              SET VDA SIZE                         14060015
          IHEPRV VDA,BR                                                 14150015
         BALR  LR,BR                                                    14240015
         LA    STK,8(STK)                                               14330015
         XC    0(8,STK),0(STK)     ZERO FIRST 2 WORDS OF STACK          14420015
         ST    DOV,8(STK)          STACK DOPE VECTOR POINTER            14510015
         MVI   MJSW,OFF            SET SWITCH FOR MAJOR STRUCTURE OFF   14600015
         MVI   CLVL,1              SET CURRENT LEVEL TO 1               14690015
         TM    0(DVD),X'40'        TEST FOR STRUCTURE WITH 1 ELEMENT    14780015
         BNO   LDCRF               BRANCH IF NOT SO                     14870015
         MVC   PDVD,DUMY           SET UP DVD                           14960015
         MVC   PDVD+4(4),0(DVD)     IN WORKSPACE                        15050015
         LA    DVD,PDVD            AND POINT DVD REGISTER AT IT         15140015
LDCRF    LR    CRF,DVD             CRF TO MAJOR STRUCTURE               15230015
BPSTK    LA    STK,12(STK)         BUMP STACK POINTER                   15320015
         SR    ACC,ACC             CLEAR ACCUMULATOR                    15410015
         STH   ACC,BOND            SET BOUND AND MAXIMUM                15500015
         STH   ACC,MXBD             BOUND TO 0                          15590015
         STH   ACC,OFST            CLEAR OFFSET                         15680015
         SR    DIM,DIM                                                  15770015
         IC    DIM,1(DVD)          DIMENSIONALITY FROM DVD TO DIM       15860015
         N     DIM,MASK            CLEAR AREA BIT                       15900015
BPDVD    LA    DVD,4(DVD)          BUMP POINTER TO NEXT WORD OF DVD     15950015
         MVC   SLVL,0(DVD)         LEVEL FROM DVD                       16040015
         NI    SLVL,B'00111111'     TO SLVL                             16130015
         CLC   SLVL,CLVL           BRANCH IF SLVL LT CLVL (I.E. END     16220015
         BL    SETSW                OF MINOR STRUCTURE)                 16310015
TSTEL    TM    0(DVD),X'80'        TEST WHETHER BASE ELEMENT            16400015
         BO    BASEL               BRANCH IF YES                        16490015
         LTR   TAR,TAR                                                  16497015
         BP    NCOBL               BRANCH IF NOT COBOL                  16504015
         SR    DM1,DM1                                                  16511015
         IC    DM1,1(DVD)          DIMENSIONALITY OF MINOR STRUCTURE    16518015
         N     DM1,MASK              TO DM1                             16525015
         CR    DIM,DM1                                                  16532015
         BNE   NCOBL               BRANCH IF STRUCTURE HAS DIMENSIONS   16539015
         MVC   CLVL,SLVL             ELSE, SET CLVL AND CRF             16546015
         LR    CRF,DVD               AND GO TO EXAMINE NEXT STRUCTURE   16553015
         B     BPDVD                 MEMBER                             16560015
NCOBL    EQU   *                                                        16567015
         MVC   CLVL,SLVL                                                16580015
         LR    CRF,DVD             LOAD CONTAINING STRUCTURE REFERENCE  16670015
         ST    ACC,0(STK)          STACK ACCUMULATOR                    16760015
         MVC   4(2,STK),OFST             OFFSET                         16850015
         STC   DIM,6(STK)                DIMENSIONALITY                 16940015
         MVC   7(1,STK),MXBD+1           MAXIMUM BOUND                  17030015
         ST    DOV,8(STK)          STACK DOPE VECTOR POINTER            17120015
         B     BPSTK               RETURN FOR NEXT ELEMENT              17210015
 SPACE                                                                  17300015
*              PROCESS BASE ELEMENT                                     17390015
 SPACE                                                                  17480015
*        THE BIT LENGTH OF THE ELEMENT IS SET IN LNTH AND THE           17570015
*        BOUNDARY ON WHICH IT MUST BE ALLOCATED IS SET IN BOND          17660015
 SPACE                                                                  17750015
BASEL    SR    DM1,DM1                                                  17840015
         ST    DM1,LNTH            SET LNTH TO ZERO                     17930015
         STH   DM1,AINC                SET ALIGNMENT INCREMENT TO ZERO  17970042
         IC    DM1,1(DVD)          DIMENSIONALITY OF ELEMENT TO DM1     18020015
         N     DM1,MASK            CLEAR AREA BIT                       18060015
         STH   DM1,NDIM             AND NDIM                            18110015
         MVC   BOND+1(1),2(DVD)    BOUND TO BOND                        18200015
         NI    BOND+1,B'00111111'                                       18290015
         MVC   LNTH+3(1),3(DVD)    LENGTH OF ELEMENT FROM DVD TO LNTH   18380015
         TM    1(DVD),X'40'        IS IT EVENT                          18390015
         BNO   TSTRG               NO                                   18400015
         MVI   LNTH+3,0            YES,                                 18410015
         MVI   LNTH+2,1              SET LENGTH TO 256                  18420015
TSTRG    EQU   *                                                        18430015
         TM    3(DVD),X'FF'        TEST FOR STRING                      18470015
         BNZ   BTOFF               BRANCH IF NOT STRING                 18560015
         LR    SCR,DM1             IF FIXED-LENGTH STRING, OBTAIN       18650015
         SLL   SCR,3                LENGTH FROM LAST WORD OF SADV       18740015
         AR    SCR,DOV                                                  18830015
         MVC   LNTH+2(2),4(SCR)                                         18920015
         MVI   BTSW,ON             SET BIT STRING SWITCH ON             19010015
         TM    2(DVD),X'80'        TEST FOR ALIGNED BIT STRING          19100015
         BO    BYTAL               BRANCH IF SO                         19190015
         CLI   BOND+1,0            TEST FOR BIT STRING                  19280015
         BE    TSTDM               BRANCH IF SO                         19370015
         L     SCR,LNTH            IF CHAR STRING, CONVERT              19460015
         SLL   SCR,3                LENGTH TO BIT LENGTH                19550015
         TM    1(DVD),X'80'        TEST FOR AREA VARIABLE               19640015
         BZ    NOARA               BRANCH IF NOT                        19730015
         LA    SC1,63(SCR)             PAD LENGTH OF ELEMENT UP TO      19750042
         SRL   SC1,6                   NEXT 8 BYTE BOUNDARY.            19770042
         SLL   SC1,6                                                    19790042
         SR    SC1,SCR                                                  19810042
         STH   SC1,AINC                STORE AMOUNT OF PADDING.         19830042
         LA    SCR,128(SC1,SCR)        CALCULATE LENGTH OF ELEMENT +    19850042
*                                      PADDING + 16 CONTROL BYTES.      19870042
NOARA    ST    SCR,LNTH                                                 19910015
BTOFF    MVI   BTSW,OFF                                                 20000015
         B     TSTDM                                                    20360015
BYTAL    L     SCR,LNTH                                                 20450015
         LA    SCR,7(SCR)                                               20540015
         ST    SCR,LNTH            IF ALIGNED BIT STRING                20630015
         NI    LNTH+3,X'F8'         ALIGN LNTH TO BYTE BOUNDARY         20720015
TSTDM    LTR   DM1,DM1                                                  20810015
         BZ    ALIGN               BRANCH IF ELEMENT UNDIMENSIONED      20900015
 SPACE                                                                  20990015
*              CALCULATE BASE ELEMENT MULTIPLIERS                       21080015
 SPACE                                                                  21170015
         SR    SCR,SCR                                                  21260015
         ST    SCR,0(DOV)          CLEAR VIRTUAL ORIGIN SLOT            21350015
CMPDM    CR    DIM,DM1             BRANCH IF UNINHERITED DIMENSIONALITY 21440015
         BE    ALIGN                IS 0                                21530015
         L     SCR,LNTH                                                 21620015
         CLI   BTSW,ON                                                  21710015
         BE    NODIV               BRANCH IF BIT MULTIPLIER             21800015
         SRL   SCR,3                OTHERWISE CONVERT TO BYTE           21890015
NODIV    LR    SC1,DM1             COMPUTE OFFSET OF SLOT FOR           21980015
         SLL   SC1,2                MULTIPLIER IN ADV                   22070015
         ST    SCR,0(SC1,DOV)      STORE MULTIPLIER                     22160015
         LH    SCR,NDIM                                                 22250015
         SLL   SCR,2               NDIM*4                               22340015
         AR    SCR,SC1             DIM1*4 + NDIM*4                      22430015
         L     ODD,LNTH                                                 22520015
         MH    ODD,2(SCR,DOV)      ODD=LNTH*LBOUND                      22610015
         L     EVN,0(DOV)                                               22700015
         SR    EVN,ODD             VO = VO - LNTH*LBND                  22790015
         LPR   ODD,EVN                                                  22880015
         C     ODD,XMAX            ERROR IF VO TOO SMALL                22970015
         BH    ERR01                OR TOO LARGE                        23060015
         ST    EVN,0(DOV)                                               23150015
         LH    SC1,0(SCR,DOV)      LOAD UPPER BOUND                     23240015
         SH    SC1,HM01                                                 23300020
         SH    SC1,2(SCR,DOV)          (UPPER BND-LOWER BND)+1          23360020
         BM    ERR03                   ILLEGAL IF NEGATIVE              23420020
         L     ODD,LNTH            LNTH = LNTH*(UBOUND-LBOUND+1)        23510015
         MR    EVN,SC1                                                  23600015
         LTR   EVN,EVN                                                  23690015
         BNZ   ERR02                                                    23780015
         C     ODD,XMAX            ERROR IF LENGTH TOO LARGE            23870015
         BH    ERR02                                                    23960015
         ST    ODD,LNTH                                                 24050015
         BCTR  DM1,0               DIM1 = DIM1-1                        24140015
         B     CMPDM               RETURN FOR NEXT MULTIPLIER           24230015
ALIGN    L     SCR,LNTH                SUBTRACT ALIGNMENT INCREMENT     24260042
         SH    SCR,AINC                FROM LENGTH OF ELEMENT.          24290042
         ST    SCR,LNTH                                                 24320042
         LH    SCR,BOND                                                 24350042
         LCR   SC1,SCR                                                  24410015
         BCTR  SC1,0               SET MASK                             24500015
         LTR   TAR,TAR             TEST ENTRY                           24590015
         BM    COBL1               BRANCH IF C ENTRY                    24680015
         LCR   SC2,ACC                                                  24770015
         AR    ACC,SCR             ACC+BOUND-1                          24860015
         NR    ACC,SC1             MASK OUT LAST BITS TO ALIGN          24950015
         AR    SC2,ACC             ALIGNMENT INCREMENT                  25040015
         LH    SCR,MXBD                                                 25130015
         LCR   SCR,SCR                                                  25220015
         BCTR  SCR,0                                                    25310015
         NR    SCR,SC2             CALCULATE AMOUNT BY WHICH PAD CAN    25400015
         AH    SCR,OFST             BE REDUCED, AND ADD THIS TO OFFSET  25490015
         STH   SCR,OFST                                                 25580015
         LR    SC2,ACC             CALCULATE ACTUAL LENGTH OF           25670015
         SR    SC2,SCR              PACKED STRUCTURE                    25760015
         B     ANYDM                                                    25850015
COBL1    AR    ACC,SCR             ACC+BOUND-1                          25940015
         NR    ACC,SC1             MASK OUT LAST BITS TO ALIGN          26030015
         LR    SC2,ACC             SET SC2 = LENGTH OF PACKED STRUCTURE 26120015
ANYDM    CLC   NDIM,H000                                                26210015
         BE    STRVO               BRANCH IF NO DIMENSIONS              26300015
         A     SC2,0(DOV)          ADD VIRTUAL ORIGIN SUM               26390015
STRVO    ST    SC2,0(DOV)          SET OFFSET                           26480015
         A     ACC,LNTH            ADD LENGTH OF ELEMENT TO ACC         26570015
         ST    DVD,LREF            SET LREF TO ELEMENT                  26660015
         LR    SRF,DVD             SET UP REGISTERS AND BRANCH TO       26750015
         LR    DV1,DOV              SUBROUTINE TO BUMP DOV PAST         26840015
         BAL   LNK,BPDOV            ENTRY IN STRUCTURE DOPE VECTOR      26930015
         LR    DOV,DV1              FOR ELEMENT                         27020015
         CLC   BOND,MXBD                                                27110015
         BNH   BDLOW               SET MXBD IF BOND GT MXBD             27200015
         MVC   MXBD,BOND                                                27290015
BDLOW    TM    0(DVD),B'01000000'  TEST FOR END OF STRUCTURE            27380015
         BO    ENDST               BRANCH IF END                        27470015
         MVC   CLVL,SLVL           CLVL = SLVL                          27560015
         B     BPDVD               RETURN TO EXAMINE NEXT STRUCTURE     27650015
*                                   MEMBER                              27740015
 SPACE                                                                  27830015
ENDST    MVI   SLVL,1              IF END OF STRUCTURE SET SLVL TO 1    27920015
SETSW    CLC   2(2,CRF),HM01       TEST IF CONTAINING STRUCTURE MAJOR   28010015
         BE    MAJST               YES                                  28020015
         LTR   TAR,TAR                                                  28030015
         BP    NOMAJ               BRANCH IF NOT COBOL                  28040015
         IC    DM1,1(CRF)          DIMENSIONALITY OF CONTAINING         28050015
         N     DM1,MASK              STRUCTURE TO DM1                   28060015
         LH    SCR,2(CRF)          FIND NEXT CONTAINING STRUCTURE       28070015
         A     SCR,ADVD                                                 28080015
         IC    DIM,1(SCR)          PUT ITS DIMENSIONALITY IN DIM        28090015
         N     DIM,MASK                                                 28100015
         CR    DIM,DM1             IS CONTAINING STRUCTURE DIMENSIONED  28110015
         BNE   NOMAJ                 YES                                28120015
         MVC   CLVL,0(CRF)         LEVEL TO CLVL                        28130015
         NI    CLVL,B'00111111'                                         28140015
         B     NOREP               NO, GO TO NEXT CONTAINING STRUCTURE  28150015
MAJST    MVI   MJSW,ON             IF MAJOR STRUCTURE, SET MJSW ON      28160015
 SPACE                                                                  28280015
*              ALIGN STRUCTURE MULTIPLIERS                              28370015
 SPACE                                                                  28460015
*        IF THE MINOR STRUCTURE HAS DIMENSIONS OF ITS OWN, THE LENGTH   28550015
*        SO FAR CALCULATED IS PADDED TO A MULTIPLE OF THE MAXIMUM       28640015
*        ALIGNMENT BOUNDARY APPEARING IN IT. THIS PAD IS STORED SO THAT 28730015
*        IT CAN BE SUBTRACTED AFTER THE MULTIPLIERS HAVE BEEN           28820015
*        CALCULATED                                                     28910015
 SPACE                                                                  29000015
NOMAJ    SH    STK,H012            STK=STK-12                           29090015
         IC    DM1,1(CRF)          DIMENSIONALITY OF CONT. STR. TO DM1  29180015
         N     DM1,MASK            CLEAR AREA BIT                       29220015
         LTR   DM1,DM1                                                  29270015
         BZ    UNSTK               BRANCH IF ZERO                       29360015
         IC    DIM,6(STK)          STACKED DIMENSIONALITY TO DIM        29450015
         CR    DIM,DM1                                                  29540015
         BE    UNSTK               BRANCH IF DIM=DM1                    29630015
         LH    SCR,MXBD                                                 29810015
         LCR   SC1,SCR                                                  29900015
         BCTR  SC1,0               SET MASK                             29990015
         SH    ACC,OFST                                                 30080015
         LCR   SC2,ACC             NEGATE ELEMENT LENGTH                30170015
         AR    ACC,SCR             ACC+BOUND-1                          30260015
         NR    ACC,SC1             ALIGN                                30350015
         AR    SC2,ACC             CALCULATE ALIGNMENT                  30440015
         STH   SC2,AINC             INCREMENT                           30530015
         LR    SRF,CRF             POINT SRF AT CONTAINING STRUCTURE    30620015
 SPACE                                                                  30710015
*              CALCULATE MINOR STRUCTURE MULTIPLIERS                    30800015
 SPACE                                                                  30890015
LDDV1    L     DV1,8(STK)              LOAD DV1 FROM STACK.             30930046
BRFND    BAL   LNK,FNDEL           FIND BASE ELEMENT                    30980015
         MVC   NDIM+1(1),1(SRF)    SET DIMENSIONALITY IN NDIM           31070015
         NI    NDIM+1,X'3F'        CLEAR AREA AND EVENT BITS            31110015
         LH    SC1,NDIM                                                 31160015
         SLL   SC1,2               NDIM*4                               31250015
         LR    SCR,DM1                                                  31340015
         SLL   SCR,2               DM1*4                                31430015
         LR    SC2,SC1                                                  31520015
         AR    SC2,SCR             NDIM*4 + DM1*4                       31610015
         AR    SC2,DV1             POINT SC2 AT SLOT IN ADV             31700015
         MVC   BNDS(4),0(SC2)       TO LOAD UPPER AND LOWER BOUNDS      31790015
         LH    ODD,LBND                                                 31880015
         MR    EVN,ACC             LNTH = ACC*LBND                      31970015
         ST    ODD,LNTH                                                 32060015
         LR    SC2,ACC                                                  32150015
         TM    2(SRF),B'00111111'                                       32240015
         BZ    BITML               BRANCH IF BIT MULTIPLIER             32330015
         TM    2(SRF),X'80'                                             32420015
         BO    BITML               BRANCH IF BIT MULTIPLIER             32510015
         SRL   SC2,3                                                    32600015
BITML    ST    SC2,0(SCR,DV1)                                           32690015
         L     SCR,0(DV1)                                               32780015
         S     SCR,LNTH            SET VO = VO - ACC*LBND               32870015
         LPR   SC2,SCR                                                  32960015
         C     SC2,XMAX            ERROR IF VO TOO SMALL                33050015
         BH    ERR01                OR TOO LARGE                        33140015
         ST    SCR,0(DV1)                                               33230015
         BAL   LNK,BPDOV           BUMP DV1 PAST DOPE VECTOR ENTRY      33320015
         C     SRF,LREF            TEST END OF MINOR STRUCTURE          33410015
         BNE   BRFND               RETURN IF NOT                        33500015
         LH    SCR,HBND                                                 33590015
         SH    SCR,HM01                                                 33650020
         SH    SCR,LBND                                                 33710020
         BM    ERR03                                                    33770020
         MR    ACC-1,SCR           ACC=ACC*(HBND-LBND+1)                33860015
         LTR   ACC-1,ACC-1                                              33950015
         BNZ   ERR02                                                    34040015
         C     ACC,XMAX            ERROR IF LENGTH TOO LARGE            34130015
         BH    ERR02                                                    34220015
         BCTR  DM1,0                                                    34310015
         CR    DIM,DM1                                                  34400015
         BNE   LDSRF                                                    34490015
         AH    ACC,OFST            ADD OFFSET                           34580015
         SH    ACC,AINC            SUBTRACT ALIGNMENT INCREMENT         34670015
         B     UNSTK               BRANCH OUT OF LOOP                   34760015
LDSRF    LR    SRF,CRF                                                  34850015
         B     LDDV1                                                    34940015
 SPACE                                                                  35030015
*              ALIGN ADJACENT STRUCTURE                                 35120015
 SPACE                                                                  35210015
*        THE INFORMATION AT THE TOP OF THE STACK IS UNSTACKED AND THE   35300015
*        AMOUNT OF PADDING WHICH MUST BE PLACED BETWEEN THE PRECEDING   35390015
*        AND PRESENT STRUCTURES CALCULATED SO THAT THEY ARE BOTH        35480015
*        ALIGNED ON THE CORRECT BOUNDARIES                              35570015
 SPACE                                                                  35660015
UNSTK    MVC   BOND+1(1),7(STK)    UNSTACK BOUND                        35750015
         ST    ACC,SACC            SAVE ACCUMULATOR                     35840015
         CLI   MJSW,ON                                                  35930015
         BNE   ACCST               BRANCH IF NOT MAJOR STRUCTURE        36020015
         LH    ACC,OFST            IF MAJOR STRUCTURE SET ACC = BIT     36110015
         N     ACC,F007             OFFSET OF START OF STRUCTURE FROM   36200015
*                                   NEAREST BYTE BOUNDARY FOR ADDING    36290015
*                                   TO ALL FINAL OFFSETS                36380015
         B     STCLV                                                    36470015
ACCST    L     ACC,0(STK)          STACKED ACCUMULATOR TO ACC           36560015
         LH    SCR,MXBD                                                 36650015
         LCR   SC1,SCR                                                  36740015
         BCTR  SC1,0                                                    36830015
         LTR   TAR,TAR             TEST ENTRY                           36920015
         BM    COBL2               BRANCH IF C ENTRY                    37010015
         LR    SC2,SCR             CALCULATE AMOUNT BY WHICH ACC        37100015
         NR    SC2,ACC              INTRUDES INTO BOUND FIELD           37190015
         LCR   SC2,SC2                                                  37280015
         AH    SC2,OFST                                                 37370015
         BNM   ALACC                                                    37460015
         SR    SC2,SC1                                                  37550015
         AR    ACC,SCR             ADD BOUND TO ACC                     37640015
ALACC    NR    ACC,SC1             ALIGN ACC                            37730015
         AH    ACC,OFST                                                 37820015
         LH    SC1,BOND            CALCULATE NUMBER OF UNITS OF BOUND   37910015
         LCR   SC1,SC1              REQUIRED TO ALIGN                   38000015
         BCTR  SC1,0                ACC TO                              38090015
         NR    SC2,SC1              MAX BOUND                           38180015
         AH    SC2,4(STK)                                               38270015
         SR    ACC,SC2                                                  38360015
         B     STCLV                                                    38450015
COBL2    AR    ACC,SCR             ADD BOUND TO ACC                     38540015
         NR    ACC,SC1             ALIGN ACC                            38630015
STCLV    MVC   CLVL,0(CRF)         LEVEL TO CLVL                        38720015
         NI    CLVL,B'00111111'                                         38810015
 SPACE                                                                  38900015
*              ADD ADJACENT STRUCTURE OFFSET                            38990015
 SPACE                                                                  39080015
*        THE OFFSET FROM THE START OF THE PRECEDING MINOR STRUCTURE TO  39170015
*        THE START OF THE PRESENT MINOR STRUCTURE IS ADDED INTO EACH    39260015
*        PARTIAL OFFSET SUM OF EACH BASE ELEMENT OF THE PRESENT MINOR   39350015
*        STRUCTURE. FOR THE MAJOR STRUCTURE, THE FINAL COMPLETE OFFSET  39440015
*        IS CONVERTED TO BYTE AND BIT OFFSET FORM                       39530015
 SPACE                                                                  39620015
         LR    SRF,CRF             SRF TO CONTAINING STRUCTURE          39710015
         L     DV1,8(STK)          RESTORE DV1                          39800015
OFCLC    BAL   LNK,FNDEL           FIND BASE ELEMENT                    39890015
         MVC   NDIM+1(1),1(SRF)    DIMENSIONALITY TO NDIM               39980015
         NI    NDIM+1,X'3F'        CLEAR AREA AND EVENT BITS            40020015
         L     SC1,0(DV1)                                               40070015
         AR    SC1,ACC             ADD ACC                              40160015
         ST    SC1,0(DV1)          SET OFFSET                           40250015
         CLI   MJSW,OFF                                                 40340015
         BE    BPAGN               BRANCH IF NOT MAJOR STRUCTURE        40430015
         LR    SC2,SC1             IF MAJOR STRUCTURE                   40520015
         SRL   SC1,3                CONVERT FINAL COMPLETE OFFSET       40610015
         SLL   SC2,5                INTO A BYTE LENGTH AND              40700015
         ST    SC1,0(DV1)           BIT OFFSET                          40790015
         STC   SC2,0(DV1)                                               40880015
BPAGN    BAL   LNK,BPDOV           BUMP DV1 TO NEXT DV ENTRY            40970015
         C     SRF,LREF                                                 41060015
         BNE   OFCLC               LOOP IF MORE ELEMENTS                41150015
         TM    MJSW,ON             BRANCH TO TERMINATION                41240015
         BO    SDONE                IF MAJSW ON                         41330015
         A     ACC,SACC                                                 41420015
         LTR   TAR,TAR             TEST ENTRY                           41510015
         BM    STCRF               BRANCH IF C ENTRY                    41600015
         SH    ACC,OFST            SUBTRACT OFFSET (WHICH IS            41690015
         AR    ACC,SC2              INCLUDED IN SACC)                   41780015
         STH   SC2,OFST            SET OFFSET                           41870015
STCRF    CLC   MXBD+1(1),7(STK)                                         41960015
         BNL   NOREP               REPLACE MXBD BY STACKED              42050015
         MVC   MXBD+1(1),7(STK)     BOUND IF LATTER GREATER             42140015
NOREP    LH    CRF,2(CRF)          SET CRF TO NEXT                      42230015
         A     CRF,ADVD              CONTAINING STRUCTURE               42320015
         CLC   SLVL,CLVL                                                42410015
         BNE   SETSW                IF SLVL NOT= CLVL                   42500015
         B     TSTEL               OTHERWISE TEST NEXT ELEMENT          42590015
 SPACE                                                                  42680015
SDONE    L     ACC,SACC                                                 42770015
         A     ACC,F007            COMPUTE LENGTH OF STRUCTURE(+OFFSET) 42860015
         SRL   ACC,3                IN BYTES                            42950015
         LH    SCR,OFST                                                 43040015
         SRL   SCR,3               COMPUTE OFFSET IN BYTES              43130015
         SR    ACC,SCR             COMPUTE LENGTH OF STRUCTURE IN BYTES 43220015
         LPR   TAR,TAR             MAKE TAR POSITIVE IN CASE C ENTRY    43310015
         ST    ACC,4(TAR)          STORE STRUCTURE LENGTH               43400015
         STC   SCR,4(TAR)           AND OFFSET IN TARGET                43490015
         SR    ACC,ACC             SET ADDRESS OF START OF STRUCTURE    43580015
         ST    ACC,0(TAR)           TO ZERO                             43670015
          IHEPRV FVD,BR                                                 43760015
         BALR  LR,BR               FREE STACK VDA                       43850015
         B     RSTOR                AND BRANCH TO RETURN                43940015
 SPACE                                                                  44030015
ERR01    IHEPRV FVD,BR                                                  44120015
         BALR  LR,BR               FREE STACK VDA                       44210015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*STR999-TSS 44250020
         L     BR,VXEP             ERROR EXIT FOR VO OUTSIDE            44300015
*        ----------------------------------------------------STR999-TSS 44340020
         BALR  RA,BR                RANGE (-16**6, 16**6)               44390015
         DC    X'0302'             ERROR CODE                           44480015
 SPACE                                                                  44570015
ERR02    IHEPRV FVD,BR                                                  44660015
         BALR  LR,BR               FREE STACK VDA                       44750015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*STR998-TSS 44790020
         L     BR,VXEP             ERROR EXIT FOR STRUCTURE LENGTH      44840015
*        ----------------------------------------------------STR998-TSS 44880020
         BALR  RA,BR                GE 16**6                            44930015
         DC    X'0301'             ERROR CODE                           45020015
         SPACE 1                                                        45030019
ERR03    IHEPRV FVD,BR                                                  45040019
         BALR  LR,BR                   FREE STACK VDA            A27175 45050019
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*STR996-TSS 45055020
         L     BR,VXEP                 ERROR EXIT FOR UPPER      A27175 45060019
*        ----------------------------------------------------STR996-TSS 45065020
         BALR  RA,BR              BOUND GREATER THAN LOWER BOUND A27175 45070019
         DC    X'0303'                 ERROR CODE                A27175 45080019
 SPACE                                                                  45110015
*              CALCULATE STRUCTURE LENGTH FROM COMPLETE                 45200015
*              STRUCTURE DOPE VECTOR                                    45290015
 SPACE                                                                  45380015
RDDVD    SH    DVD,H004                                                 45470015
         LR    SRF,DVD                                                  45560015
         BAL   LNK,FNDEL           BRANCH TO FIND BASE ELEMENT          45650015
         SR    DM1,DM1             SET DIMENSIONALITY OF FIRST BASE     45740015
         IC    DM1,1(SRF)           ELEMENT IN DM1                      45830015
         N     DM1,MASK            CLEAR AREA BIT                       45870015
         LA    PAR,2               SET UP PARAMETERS FOR BRANCH TO      45920015
         LR    ADD,TAR              SUBROUTINE TO OBTAIN ADDRESS OF     46100015
         BAL   LNK,ETYPE            FIRST ELEMENT IN FIRST WORD OF      46190015
*                                   TARGET                              46280015
         SR    DM1,DM1             DIMENSIONALITY OF BASE               46370015
         IC    DM1,1(SRF)           ELEMENT TO DM1                      46460015
         N     DM1,MASK            CLEAR AREA BIT                       46500015
         TM    0(SRF),X'40'        TEST FOR END OF STRUCTURE AND        46550015
         BO    STEND               BRANCH IF SO                         46640015
         SLL   DM1,3               BUMP DOV PAST ENTRY IN STRUCTURE     46730015
         LA    DOV,4(DOV,DM1)       DOPE VECTOR FOR THAT ELEMENT        46820015
         TM    3(SRF),X'FF'        TEST FOR STRING AND IF STRING        46910015
         BNZ   FNDEL                BUMP DOV BY A FURTHER 4             47000015
         LA    DOV,4(DOV)           BEFORE BRANCHING TO FIND NEXT       47090015
         B     FNDEL                BASE ELEMENT                        47180015
 SPACE                                                                  47270015
STEND    SR    PAR,PAR             SET UP PARAMETERS FOR BRANCH TO      47360015
         LA    ADD,ADDL             SUBROUTINE TO OBTAIN ADDRESS OF     47450015
         BAL   LNK,ETYPE            LAST ELEMENT IN ADDL                47540015
 SPACE                                                                  47630015
         SR    LTH,LTH                                                  47720015
         IC    LTH,3(SRF)          OBTAIN LENGTH OF LAST ELEMENT (BITS) 47810015
         TM    1(SRF),X'40'        TEST EVENT                           47820015
         BNO   NEVNT               NO                                   47830015
         LA    LTH,256             YES, SET LENGTH 256                  47840015
NEVNT    EQU   *                                                        47850015
         LTR   LTH,LTH              IN LTH OR 0 IF LAST ELEMENT STRING  47900015
         BNZ   NOSTR                                                    47990015
         AR    NNN,NNN             NNN = 8*DIM                          48080015
         LA    SC2,4(NNN,DOV)                                           48170015
         LH    LTH,0(SC2)          SET LENGTH FROM SADV                 48260015
         CLI   BTSW,ON                                                  48350015
         BE    NOSTR               BRANCH IF BIT STRING. IF CHAR THEN   48440015
         SLL   LTH,3                CONVERT BYTE LENGTH TO BITS         48530015
         TM    1(SRF),X'80'        TEST FOR AREA VARIABLE               48620015
         BNO   NOSTR               BRANCH IF NOT                        48710015
         LA    LTH,128(LTH)        IF AREA, ADD 16 BYTES TO LENGTH      48800015
NOSTR    L     SC3,0(TAR)          OBTAIN BYTE ADDRESS OF START         48890015
         LA    SC3,0(SC3)           OF STRUCTURE                        48980015
         SR    EVN,EVN                                                  49070015
         L     ODD,ADDL            OBTAIN BYTE ADDRESS OF LAST ELEMENT  49160015
         SLDL  EVN,3                OF STRUCTURE IN ODD AND BIT OFFSET  49250015
         SRL   ODD,3                IN EVN                              49340015
         LA    LTH,7(LTH,EVN)      SET LTH = CEIL((BIT OFFSET OF LAST   49430015
         SRL   LTH,3                ELEMENT + BIT LENGTH OF ELEMENT)/8) 49520015
         SR    LTH,SC3             FINAL LENGTH =                       49610015
         AR    LTH,ODD               BYTE ADDRESS OF LAST ELEMENT       49700015
*                                  - BYTE ADDRESS OF FIRST ELEMENT      49790015
*                                  + NUMBER OF BYTES OCCUPIED BY LAST   49880015
*                                    ELEMENT AND ITS BIT OFFSET         49970015
         ST    LTH,4(TAR)          LENGTH TO 2ND WORD OF TARGET         50060015
RSTOR    L     DR,OFDR(DR)                                              50150015
         LM    LR,WR,OFLR(DR)                                           50240015
         BR    LR                  RETURN TO CALLER                     50330015
 SPACE                                                                  50420015
*        SUBROUTINE TO TEST DATA TYPE AND RETURN ITS ADDRESS IN BYTE    50510015
*        AND BIT OFFSET FORM. IN THE CASE OF AN ARRAY, EITHER THE       50600015
*        ADDRESS OF THE FIRST ELEMENT (IF PAR = 2) OR THE LAST ELEMENT  50690015
*        (IF PAR = 0) IS RETURNED.                                      50780015
 SPACE                                                                  50870015
ETYPE    LR    DV1,DOV                                                  50960015
         MVI   BTSW,OFF            SET BIT STRING SWITCH OFF            51050015
         TM    2(SRF),X'80'        TEST FOR ALIGNED BIT STRING          51140015
         BO    BITST                                                    51230015
         TM    2(SRF),B'00111111'  TEST FOR PACKED BIT STRING           51320015
         BZ    BITST                                                    51410015
         L     EVN,0(DOV)          LOAD ADDRESS OF ELEMENT (IF ARRAY,   51500015
*                                   ADDRESS OF VIRTUAL ORIGIN)          51590015
DMTST    LA    NNN,0(DM1,DM1)                                           51680015
         LTR   DM1,DM1                                                  51770015
         BZ    NODIM               BRANCH IF UNDIMENSIONED              51860015
         AR    NNN,NNN             PAR = PAR+4*DM2                      51950015
         AR    PAR,NNN                                                  52040015
MLOOP    L     SC2,4(DV1)                                               52130015
         MH    SC2,4(PAR,DV1)      SC2 = M(I)*U(I) OR M(I)*L(I)         52220015
         AR    EVN,SC2             ADD TO ADDRESS SUM                   52310015
         LA    DV1,4(DV1)                                               52400015
         BCT   DM1,MLOOP           LOOP UNTIL ALL DIMENSIONS            52490015
*                                   ACCOUNTED FOR                       52580015
         BAL   PAR,CNVRT           CONVERT TO BYTE ADDRESS IF NECESSARY 52670015
         TM    2(SRF),X'40'        TEST FOR VARYING STRING              52760015
         BZ    NOVAR               IF VARYING STRING, EVN POINTS TO SDV 52850015
         L     EVN,0(EVN)           OF ELEMENT SO LOAD ADDRESS INTO EVN 52940015
NOVAR    ST    EVN,0(ADD)          STORE ADDRESS OF ELEMENT             53030015
         BR    LNK                 RETURN                               53120015
 SPACE                                                                  53210015
BITST    L     ODD,0(DOV)                                               53300015
         LR    EVN,ODD             IF BIT STRING, COMPUTE BIT ADDRESS   53390015
         SLDL  EVN,3                IN EVN                              53480015
         MVI   BTSW,ON             SET BIT SWITCH ON                    53570015
         B     DMTST                                                    53660015
 SPACE                                                                  53750015
NODIM    LA    PAR,NOVAR           SET RETURN FROM CNVRT TO NOVAR       53840015
 SPACE                                                                  53930015
CNVRT    CLI   BTSW,OFF            SUBROUTINE TO TEST WHETHER ADDRESS   54020015
         BCR   8,PAR                IN EVN IS IN BITS OR BYTES AND      54110015
         SR    ODD,ODD              IF THE FORMER TO CONVERT TO BYTE    54200015
         SRDL  EVN,3                AND BIT OFFSET FORM                 54290015
         OR    EVN,ODD                                                  54380015
         BR    PAR                                                      54470015
 SPACE                                                                  54560015
*              SUBROUTINE TO UPDATE SRF UNTIL IT POINTS TO              54650015
*              A BASE ELEMENT                                           54740015
 SPACE                                                                  54830015
FNDEL    LA    SRF,4(SRF)          UPDATE SRF                           54920015
         TM    0(SRF),X'80'         UNTIL BASE ELEMENT                  55010015
         BZ    FNDEL                FOUND                               55100015
         BR    LNK                                                      55190015
 SPACE                                                                  55280015
*              SUBROUTINE TO BUMP DOPE VECTOR POINTER TO NEXT ENTRY     55370015
 SPACE                                                                  55460015
BPDOV    LH    SC1,NDIM                                                 55550015
         SLL   SC1,3                                                    55640015
         LA    DV1,4(DV1,SC1)      BUMP DV1 PAST ENTRY                  55730015
         TM    3(SRF),X'FF'                                             55820015
         BCR   7,LNK                                                    55910015
         LA    DV1,4(DV1)          IF STRING BUMP ANOTHER 4             56000015
         BR    LNK                                                      56090015
 SPACE                                                                  56180015
*              CONSTANTS                                                56270015
 SPACE                                                                  56360015
ON       EQU   X'FF'                                                    56450015
OFF      EQU   X'00'                                                    56540015
H012     EQU   BPSTK+2                                                  56630015
H004     EQU   FNDEL+2                                                  56720015
DUMY     DS    0F                  * THESE MUST                         56810015
H000     DC    H'0'                * BE KEPT                            56900015
HM01     DC    H'-1'               * TOGETHER                           56990015
F007     DC    F'7'                                                     57080015
XMAX     DC    X'07FFFFF8'         8*(16**6-1)                          57170015
MASK     DC    X'0000003F'                                              57210015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*STR997-TSS 57230020
VXEP     DC    V(IHEERRC)                                               57260015
*        ----------------------------------------------------STR997-TSS 58260020
 SPACE 4                                                                59600013
         END                                                            59700013
