UPA      TITLE '   IHEUPA    ZERO REAL OR IMAGINARY PART - CAD         *00800013
               O/S 360 PL/1 LIBRARY'                                    01600013
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  02400013
*                                                                       03200013
*   STATUS     CHANGE LEVEL - 0                                         04000013
*                                                                       04800013
*   SIZE       192 BYTES                                                05600013
*                                                                       06400013
*   FUNCTION   ZEROES THE REAL OR IMAGINARY PART OF COMPLEX ARITHMETIC  07200013
*              DATA AND MOVES A POINTER FROM THE REAL PART TO THE       08000013
*              IMAGINARY PART                                           08800013
*                                                                       09600013
*   ENTRY POINTS                                                        10400013
*              IHEUPAA - ZERO REAL PART AND MOVE POINTER                11200013
*                  RA = A(REAL PART OF DATA)                            12000013
*                  RB = A(DED)                                          12800013
*              IHEUPAB - MOVE POINTER AND ZERO IMAGINARY PART OR MOVE   13600013
*                        POINTER ONLY IF SWITCH IS SET                  14400013
*                                                                       15200013
*   INPUT      WSWA-X'04' UPDATE ONLY SWITCH                            16000013
*                                                                       16800013
*   OUTPUT     WRCD FIRST WORD - ADDRESS OF IMAGINARY PART              17600013
*                                                                       18400013
*   EXTERNAL MODULES                                                    19200013
*              N/A                                                      20000013
*                                                                       20800013
*   EXIT       NORMAL - RETURN TO CALLER VIA LINK REGISTER              21600013
*                                                                       22400013
*   TABLES/WORKAREA - WORKAREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)   23200013
*                                                                       24000013
*   ATTRIBUTES READ ONLY AND REENTRANT                                  24800013
*                                                                       25600013
*   PRIVATE MACROS                                                      26400013
*              IHELIB,IHEPRV                                            27200013
*                                                                       28000013
*   ASSEMBLY REQUIREMENTS                                               28800013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   29600013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        30400013
*                                                                       31200013
*   NOTES      SEE OS/360 PL/1 LIBRARY PLM FOR LIBRARY MODULE           32000013
*              CONVENTIONS AND STANDARDS.                               32800013
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND             33600013
*              UPON A PARTICULAR INTERNAL REPRESENTATION OF             34400013
*              THE EXTERNAL CHARACTER SET.                              35200013
IHEUPA   CSECT                                                          36000013
         IHELIB                                                         36800013
IHEUPA   CSECT                                                          37600013
         ENTRY IHEUPAA                                                  38400013
         ENTRY IHEUPAB                                                  39200013
         USING *,BR                                                     40000013
         USING IHEZLCA,WR                                               40800013
*                                       ZERO REAL PART.                 41600013
IHEUPAA  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          42400013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  43200013
         MVI   WSWC,ZERO                RESET SWITCH                    44000013
JOINA    SR    RF,RF                                                    44800013
         TM    0(RB),BASE               TEST FOR DECIMAL                45600013
         BZ    DECAL                    BRANCH SOURCE DECIMAL           46400013
         TM    0(RB),HWRD         TEST DED FOR HALFWORD/LONG FLOAT      46800001
         BZ    NOTLA              BRANCH NO                             47200001
         TM    0(RB),X'02'        TEST LONG FLOAT                       47600001
         BZ    HALFA              NO BRANCH (I.E. HALFWORD)             48000001
         ST    RF,0(RA)           ZERO FOUR BYTES                       48400001
         ST    RF,4(RA)           ZERO SECOND WORD OF LONG FLOAT        48800001
         B     NOTLA1                                                   49200001
HALFA    STH   RF,0(RA)           ZERO TWO BYTES                        49600001
         B     NOTLA1                                                   50000001
NOTLA    ST    RF,0(RA)           ZERO FOUR BYTES                       50400001
NOTLA1   LA    BR,IHEUPAB         BUMP BASE ADDRESS                     50800001
         CLI   WSWC,ZERO                TEST SWITCH                     51200013
         BNE   ENDRT-IHEUPAB(BR)        BRANCH IF SET                   52000013
         B     JOINB-IHEUPAB(BR)                                        52800013
DECAL    IC    RF,1(RB)                 GET PRECISION                   53600013
         SRL   RF,1                     GET NO OF BYTES                 54400013
         SLL   RF,4                     SET TARGET LENGTH               55200013
         EX    RF,ZAPIN                 ZERO DECIMAL TARGET.            56000013
         B     NOTLA1                                                   56800001
ZAPIN    ZAP   0(0,RA),PDZO(1)          ZERO DECIMAL FIXED FIELD        57600013
PDZO     DC    PL1'+0'                                                  58400013
*                                                                       59200013
*                                       ZERO IMAGINARY PART             60000013
         USING IHEUPAB,BR                                               60800013
IHEUPAB  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          61600013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  62400013
         TM    WSWA,UPDO                TEST UPDATE ONLY SWITCH         63200013
         BO    ZWSWC                    BRANCH IF ON                    64000013
         MVI   WSWC,K001                SET SWITCH                      64800013
JOINB    TM    0(RB),BASE               TEST BASE OF SOURCE             65600013
         BZ    DECML                    BRANCH IF DECIMAL               66400013
         TM    0(RB),HWRD         TEST DED FOR HALFWORD/LONG FLOAT      66800001
         BZ    NOTLB              BRANCH NO                             67200001
         TM    0(RB),X'02'        TEST LONG FLOAT                       67600001
         BZ    HALFB              BRANCH NO (I.E. HALFWORD)             68000001
         LA    RA,8(RA)           BUMP TARGET POINTER BY 8              68400001
         B     NOTLB1                                                   68800001
HALFB    LA    RA,2(RA)           BUMP TARGET POINTER BY 2              69200001
         B     NOTLB1                                                   69600001
NOTLB    LA    RA,4(RA)           BUMP TARGET POINTER BY 4              70000001
NOTLB1   CLI   WSWC,K001          TEST SWITCH                           70400001
         BNE   ENDRT                    BRANCH IF NOT SET               71200013
         L     BR,UPAA                  LOAD BASE ADDRESS               72000013
         B     JOINA-IHEUPAA(BR)        GO TO ZERO FIELD.               72800013
ZWSWC    MVI   WSWC,ZERO                RESET SWITCH                    73600013
         NI    WSWA,NUPD                RESET UPDATE ONLY SWITCH        74400013
         B     JOINB                                                    75200013
DECML    SR    RF,RF                    GET                             76000013
         IC    RF,1(RB)                 PRECISION                       76800013
         SRL   RF,1                                                     77600013
         LA    RA,1(RA,RF)              INCREASE TARGET POINTER         78400013
         B     NOTLB1                                                   79200001
*                                                                       80000013
ENDRT    ST    RA,WRCD                  SAVE UPDATED ADDRESS            80800013
         LM    LR,WR,OFLR(DR)                                           81600013
         BR    LR                                                       82400013
UPAA     DC    A(IHEUPAA)                                               83200013
ZERO     EQU   X'00'                                                    84000013
BASE     EQU   X'06'                                                    84800013
LFLT     EQU   X'12'                                                    85600013
UPDO     EQU   X'04'                                                    86400013
K001     EQU   X'01'                                                    87200013
NUPD     EQU   X'FB'                                                    88000013
HWRD     EQU   X'10'                                                    88400001
       END                                                              88800013
