UPB      TITLE '   IHEUPB    ZERO REAL OR IMAGINARY PART - PICTURE     *00700013
               O/S 360 PL/1 LIBRARY'                                    01400013
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  02100013
*                                                                       02800013
*   STATUS     CHANGE LEVEL - 0                                         03500013
*                                                                       04200013
*   SIZE       232 BYTES                                                04900013
*                                                                       05600013
*   FUNCTION   ZEROES THE REAL OR IMAGINARY PART OF A COMPLEX NUMERIC   06300013
*              FIELD AND MOVES A POINTER FROM THE REAL PART TO THE      07000013
*              IMAGINARY PART                                           07700013
*                                                                       08400013
*   ENTRY POINTS                                                        09100013
*              IHEUPBA - ZERO REAL PART AND MOVE POINTER                09800013
*                  RA = A(REAL PART OF DATA)                            10500013
*                  RB = A(DED)                                          11200013
*              IHEUPBB - MOVE POINTER AND ZERO IMAGINARY PART OR MOVE   11900013
*                        POINTER ONLY IF SWITCH IS SET                  12600013
*                                                                       13300013
*   INPUT      WSWA-X'04' UPDATE ONLY SWITCH                            14000013
*                                                                       14700013
*   OUTPUT     WRCD FIRST WORD - ADDRESS OF IMAGINARY PART              15400013
*                                                                       16100013
*   EXTERNAL MODULES                                                    16800013
*              IHEDMAA - ARITHMETIC CONVERSION DIRECTOR                 17500013
*                                                                       18200013
*   EXIT       NORMAL - RETURN TO CALLER VIA LINK REGISTER              18900013
*                                                                       19600013
*   TABLES/WORKAREA                                                     20300013
*              WORKAREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)          21000013
*                                                                       21700013
*   ATTRIBUTES READ ONLY AND REENTRANT                                  22400013
*                                                                       23100013
*   PRIVATE MACROS                                                      23800013
*              IHELIB,IHEPRV,IHESDR                                     24500013
*                                                                       25200013
*   ASSEMBLY REQUIREMENTS                                               25900013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   26600013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        27300013
*                                                                       28000013
*   NOTES      SEE OS/360 PL/1 LIBRARY PLM FOR LIBRARY MODULE           28700013
*              CONVENTIONS AND STANDARDS.                               29400013
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND             30100013
*              UPON A PARTICULAR INTERNAL REPRESENTATION OF             30800013
*              THE EXTERNAL CHARACTER SET.                              31500013
IHEUPB   CSECT                                                          32200013
         IHELIB                                                         32900013
IHEZLW1  DSECT                                                          33600013
         DS    15D                                                      34300013
WORK     EQU   IHEZLW1                                                  35000013
IHEUPB   CSECT                                                          35700013
         ENTRY IHEUPBA                                                  36400013
         ENTRY IHEUPBB                                                  37100013
         USING *,RJ                                                     37800013
         USING IHEZLCA,WR                                               38500013
         USING IHEZLW1,DR                                               39200013
*                                       ZERO REAL PART.                 39900013
IHEUPBA  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          40600013
         IHESDR LW1,WR                                                  41300013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  42000013
         LR    RJ,BR                    TRANSFER BASE REGISTER          42700013
         SR    RG,RG                    RESET SWITCH                    43400013
JOINA    LR    RC,RA                    SET TARGET                      44100013
         LR    RD,RB                    PARAMETERS                      44800013
         TM    0(RB),INTR               TEST DATA TYPE                  45500013
         BZ    RESET                    BRANCH IF F OR E EXTERNAL FORM  46200013
         TM    0(RB),BASE               TEST BASE OF DATUM              46900013
         BZ    DECAL                    BRANCH IF DECIMAL               47600013
         LA    RA,BZRO                  LOAD BINARY SOURCE AND          48300013
         LA    RB,BDED                  DED ADDRESSES.                  49000013
CALLR    L     BR,DMAA                  LOAD BRANCH ADDRESS             49700013
         BALR  LR,BR                    CALL ARITH CONVERSION DIRECTOR  50400013
         LR    RA,RC                    RESET                           51100013
         LR    RB,RD                    REGISTERS                       51800013
         LA    RJ,IHEUPBB               BUMP BASE ADDRESS               52500013
         LTR   RG,RG                    TEST SWITCH                     53200013
         BNZ   ENDRT-IHEUPBB(RJ)        BRANCH IF SET                   53900013
         B     JOINB-IHEUPBB(RJ)                                        54600013
RESET    LA    RG,1                     SET SWITCH                      55300013
DECAL    LA    RA,DZRO                  LOAD DECIMAL SOURCE AND         56000013
         LA    RB,DDED                  ADDRESSES.                      56700013
         B     CALLR                                                    57400013
BZRO     DC    E'0'                                                     58100013
BDED     DC    X'8E1500'                                                58800013
DZRO     DC    PL1'+0'                  PACKED DECIMAL ZERO             59500013
DDED     DC    X'880180'                PACKED DECIMAL (1,0) DED        60200013
*                                                                       60900013
         USING IHEUPBB,RJ                                               61600013
IHEUPBB  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          62300013
         LR    RJ,BR                    TRANSFER BASE REGISTER          63000013
         IHESDR LW1,WR                                                  63700013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  64400013
         TM    WSWA,UPDO                TEST UPDATE ONLY SWITCH         65100013
         BO    ZWSWC                    BRANCH IF SET                   65800013
         LA    RG,1                     SET SWITCH                      66500013
JOINB    SR    RF,RF                                                    67200013
         IC    RF,3(RB)                 GET FIELD WIDTH                 67900013
         TM    0(RB),BASE               TEST BASE                       68600013
         BZ    DECML                    BRANCH IF DECIMAL               69300013
         L     BR,0(RA)                 GET FIELD ADDRESS FROM DOPE VEC 70000013
         LR    LR,BR                    GET BIT                         70700013
         SLDL  LR,3                     ADDRESS                         71400013
         AR    LR,RF                    ADD ON FIELD WIDTH              72100013
         LR    BR,LR                    GET NEW                         72800013
         SRDL  LR,3                     BYTE ADDRESS AND OFFSET         73500013
         ST    BR,PWORK                 MAKE NEW DOPE VECTOR            74200013
         LA    RA,PWORK                 SET POINTER TO NEW DV.          74900013
         B     TESTW                                                    75600013
DECML    AR    RA,RF                    BUMP FIELD ADDRESS              76300013
TESTW    LTR   RG,RG                    TEST SWITCH                     77000013
         BZ    ENDRT                    BRANCH IF NOT SET               77700013
         L     RJ,UPBA                  RESET BASE REGISTER             78400013
         B     JOINA-IHEUPBA(RJ)        GO TO ZERO FIELD                79100013
ZWSWC    SR    RG,RG                    RESET SWITCH                    79800013
         NI    WSWA,NUPD                RESET UPDATE ONLY SWITCH        80500013
         B     JOINB                                                    81200013
*                                                                       81900013
ENDRT    ST    RA,WRCD                  SAVE UPDATED ADDRESS IN LCA.    82600013
         L     DR,OFDR(DR)              RESET SAVE AREA POINTER         83300013
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       84000013
         BR    LR                       EXIT                            84700013
DMAA     DC    V(IHEDMAA)                                               85400013
UPBA     DC    V(IHEUPBA)                                               86100013
INTR     EQU   X'80'                                                    86800013
ZERO     EQU   X'00'                                                    87500013
BASE     EQU   X'04'                                                    88200013
UPDO     EQU   X'04'                                                    88900013
K001     EQU   X'01'                                                    89600013
NUPD     EQU   X'FB'                                                    90300013
PWORK    EQU   WORK+72                                                  91000013
         END                                                            91700013
