VCA      TITLE '   IHEVCA    DATA ANALYSIS ROUTINE                     *00700013
               O/S 360 PL/1 LIBRARY'                                    01400013
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  02100013
*                                                                       02800013
*   STATUS     CHANGE LEVEL - 0                                         03500013
*                                                                       04200013
*   SIZE       272 BYTES                                                04900013
*                                                                       05600013
*   FUNCTION   TO CREATE A DED (FLAG BYTE,P-BYTE,Q-BYTE) TO DESCRIBE    06300013
*              THE BASE,SCALE,MODE AND PRECISION OF A CHARACTER         07000013
*              REPRESENTATION OF AN ARITHMETIC VALUE                    07700013
*                                                                       08400013
*   ENTRY POINT                                                         09100013
*              IHEVCAA                                                  09800013
*                  RA = A(DED)                                          10500013
*                                                                       11200013
*   INPUT      WCNP = A(START/END ADDRESS PAIR GIVING CHARACTER STRING) 11900013
*                                                                       12600013
*   OUTPUT     N/A                                                      13300013
*                                                                       14000013
*   EXTERNAL MODULES                                                    14700013
*              N/A                                                      15400013
*                                                                       16100013
*   EXIT       NORMAL - RETURN TO CALLER VIA LINK REGISTER              16800013
*                                                                       17500013
*   TABLES/WORKAREA                                                     18200013
*              WORKAREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)          18900013
*                                                                       19600013
*   ATTRIBUTES READ ONLY AND REENTRANT                                  20300013
*                                                                       21000013
*   PRIVATE MACROS                                                      21700013
*              IHELIB,IHEPRV,IHESDR                                     22400013
*                                                                       23100013
*   ASSEMBLY REQUIREMENTS                                               23800013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   24500013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        25200013
*                                                                       25900013
*   NOTES      SEE OS/360 PL1 LIBRARY PLM FOR DESCRIPTION OF LIBRARY    26600013
*              CONVENTIONS AND STANDARDS                                27300013
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    28000013
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    28700013
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  29400013
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  30100013
*              CONSTANTS,BY REASSEMBLY,WILL RESULT IN A CORRECT MODULE  30800013
*              FOR THE NEW DEFINITIONS.                                 31500013
IHEVCA   CSECT                                                          32200013
         IHELIB                                                         32900013
IHEZLW0  DSECT                                                          33600013
         DS    15D                                                      34300013
WORK     EQU   IHEZLW0                                                  35000013
IHEVCA   CSECT                                                          35700013
         ENTRY IHEVCAA                                                  36400013
         USING *,BR                                                     37100013
         USING IHEZLCA,WR                                               37800013
         USING IHEZLW0,DR                                               38500013
IHEVCAA  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          39200013
         IHESDR LW0,WR                  GET WORKSPACE ADDRESS           39900013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  40600013
         SR    RF,RF                    ZERO DIGIT COUNT                41300013
         STH   RF,CODE                  ZERO RETURN CODE                42000013
         LR    RE,RF                    ZERO INTEGER COUNT              42700013
         LR    RH,RF                    RESET                           43400013
         LR    RI,RF                    SWITCHES                        44100013
         MVI   0(RA),X'C8'              SET DED FOR CONSTANT            44800013
         L     RB,WCNP                  GET CONSTANT                    45500013
         L     RC,0(RB)                 START ADDRESS                   46200013
TESTC    CLI   0(RC),C'0'               TEST CHARACTER                  46900013
         BL    TESTP                    BRANCH IF NOT DIGIT             47600013
         CLI   0(RC),C'9'               TEST CHARACTER                  48300013
         BH    TESTP                    BRANCH IF NOT DIGIT             49000013
         BCTR  RI,0                     SET SIGN SWITCH                 49700013
         LA    RF,1(RF)                 COUNT DIGIT                     50400013
SKIPP    C     RC,4(RB)                 COMPARE SCAN AND END ADDRESS    51100013
         LA    RC,1(RC)                 BUMP SCAN ADDRESS               51800013
         BL    TESTC                   LOOP IF NOT EQUAL          H412  52100019
         BE    ENDRT                                              H412  52400019
         LA    RF,0                    NULL CHARACTER STRING      H412  52700019
ENDRT    LTR   RH,RH                    TEST SWITCH                     53200013
         BZ    STSCF                    BRANCH NOT SET                  53900013
         LR    RF,RG                    GET SCALE FACTOR                54600013
STSCF    LA    RG,0(RE,RF)              CALCULATE PRECISION             55300013
         TM    CODE+1,X'04'             TEST RETURN CODE                56000013
         BO    ADDEX                    BRANCH IF POINT FOUND           56700013
         LR    RG,RF                    SET PRECISION                   57400013
         SR    RF,RF                    SET SCALE FACTOR                58100013
ADDEX    AH    RF,K128                  ADD EXCESS TO SCALE FACTOR      58800013
         STC   RF,2(RA)                 STORE SCALE FACTOR AND          59500013
         STC   RG,1(RA)                 PRECISION IN DED                60200013
         TM    0(RA),FLOT               TEST SCALE OF CONSTANT          60900013
         BZ    LCODE                    BRANCH IF FIXED                 61600013
         TM    0(RA),BINY               TEST BASE OF CONSTANT           62300013
         BO    TST21                    BRANCH IF BINARY                63000013
         CLI   1(RA),X'06'              TEST PRECISION                  63700013
         BNH   LCODE                    BRANCH LESS THAN OR = TO 6      64400013
SLONG    OI    0(RA),LONG               SET DED FOR LONG                65100013
LCODE    LH    BR,CODE                  SET RETURN CODE                 65800013
         L     DR,OFDR(DR)              RESET SAVE AREA POINTER         66500013
         L     LR,OFLR(DR)              RESTORE RETURN ADDRESS          67200013
         LM    R0,WR,OFR0(DR)           RESTORE CALLERS REGISTERS       67900013
         BR    LR                       EXIT                            68600013
TST21    CLI   1(RA),X'15'              TEST PRECISION                  69300013
         BNH   LCODE                    BRANCH LESS THAN OR = TO 21     70000013
         B     SLONG                                                    70700013
TESTP    CLI   0(RC),C'+'               TEST CHARACTER                  71400013
         BE    SETSN                    BRANCH IF PLUS SIGN             72100013
         CLI   0(RC),C'-'                                               72800013
         BE    SETSN                    BRANCH IF MINUS SIGN            73500013
         CLI   0(RC),C'.'                                               74200013
         BE    SETSF                    BRANCH IF PERIOD                74900013
         CLI   0(RC),C'E'                                               75600013
         BE    SETDF                    BRANCH IF E                     76300013
         CLI   0(RC),C'B'                                               77000013
         BE    SETDB                    BRANCH IF B                     77700013
         CLI   0(RC),C'I'                                               78400013
         BNE   SKIPP                    BRANCH NOT I                    79100013
         OI    0(RA),CPLX               SET DED FOR COMPLEX             79800013
         B     SKIPP                    LOOP                            80500013
SETSN    LTR   RI,RI                    TEST SIGN SWITCH                81200013
         BCTR  RI,0                     SET SIGN SWITCH                 81900013
         BZ    SKIPP                    BRANCH NOT SET                  82600013
SETDF    LR    RG,RF                    SAVE SCALE FACTOR               83300013
         OI    0(RA),FLOT               SET DED FOR FLOATING POINT      84000013
         BCT   RH,SKIPP                 SET SWITCH AND LOOP             84700013
SETDB    OI    0(RA),BINY               SET BASE BINARY                 85400013
         B     SKIPP                    LOOP                            86100013
SETSF    LR    RE,RF                    SAVE LENGTH OF INTEGRAL PART    86800013
         OI    CODE+1,4                 SET RETURN CODE FOR POINT       87500013
         SR    RF,RF                    ZERO DIGIT COUNT                88200013
         B     SKIPP                    LOOP                            88900013
K128     DC    H'128'                                                   89600013
CPLX     EQU   X'01'                                                    90300013
FLOT     EQU   X'02'                                                    91000013
BINY     EQU   X'04'                                                    91700013
CODE     EQU   WORK+72                                                  92400013
LONG     EQU   X'10'                                                    93100013
         END                                                            93800013
