VCS      TITLE '   IHEVCS    COMPLEX EXTERNAL TO STRING DIRECTOR       *00400013
               O/S 360 PL/1 LIBRARY'                                    00800013
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  01200013
*                                                                       01600013
*   STATUS     CHANGE LEVEL - 0                                         02000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*VCS000-TSS 02100001
*        ----------------------------------------------------VCS000-TSS 02200001
*                                                                       02400013
*   SIZE       488 BYTES                                                02800013
*                                                                       03200013
*   FUNCTION   TO CONVERT EXTERNAL CHARACTER REPRESENTATIONS OF THE     03600013
*              REAL AND IMAGINARY PARTS OF A COMPLEX NUMBER TO CODED    04000013
*              COMPLEX WITH THE HIGHEST BASE,SCALE AND PRECISION OF     04400013
*              THE EXTERNAL DATA. IF REQUIRED IT THEN CONVERTS CODED    04800013
*              COMPLEX TO ANY STRING DATA TYPE.                         05200013
*                                                                       05600013
*   ENTRY POINTS                                                        06000013
*              IHEVCSA - COMPLEX EXTERNAL TO STRING CONVERSION          06400013
*                   RA = A(PARAMETER LIST)                              06800013
*                   PARAM.LIST                                          07200013
*                        A(START/END ADDRESSES OF REAL DATA)            07600013
*                        A(REAL DED)                                    08000013
*                        A(START/END ADDRESSES OF IMAGINARY DATA)       08400013
*                        A(IMAGINARY DED)                               08800013
*                        A(TARGET DOPE VECTOR)                          09200013
*                        A(TARGET DED)                                  09600013
*                        A(REAL FED)                                    10000013
*                        A(IMAG FED)                                    10400013
*              IHEVCSB - COMPLEX EXTERNAL TO CODED COMPLEX CONVERSION   10800013
*                   RA = A(PARAMETER LIST)                              11200013
*                   PARAMETER LIST                                      11600013
*                        A(START/END ADDRESSES OF REAL DATA)            12000013
*                        A(REAL DED)                                    12400013
*                        A(START/END ADDRESSES OF IMAGINARY DATA)       12800013
*                        A(IMAGINARY DED)                               13200013
*                        A(TARGET)                                      13600013
*                        A(TARGET DED)                                  14000013
*                        A(REAL FED)                                    14400013
*                        A(IMAGINARY FED)                               14800013
*                                                                       15200013
*   INPUT      N/A                                                      15600013
*                                                                       16000013
*   OUTPUT     N/A                                                      16400013
*                                                                       16800013
*   EXTERNAL MODUES      IHEDMA - ARITHMETIC CONVERSION DIRECTOR        17200013
*                        IHEDNB - ARITHMETIC TO BIT STRING              17600013
*                        IHEDNC - ARITHMETIC TO CHARACTER OR PICTURED   18000013
*                                 CHARACTER STRING.                     18400013
*                        IHEUPA - TO GET ADDRESS OF IMAGINARY PART OF   18800013
*                                 CODED COMPLEX DATA.                   19200013
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              19600013
*                                                                       20000013
*   TABLES/WORKAREA                                                     20400013
*              WORKAREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)          20800013
*                                                                       21200013
*   ATTRIBUTES READ ONLY AND REENTRANT                                  21600013
*                                                                       22000013
*   PRIVATE MACROS                                                      22400013
*              IHELIB,IHEPRV,IHESDR                                     22800013
*                                                                       23200013
*   ASSEMBLY REQUIREMENTS                                               23600013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   24000013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        24400013
*                                                                       24800013
*   NOTES      SEE O/S360 PL/1 LIBRARY PLM FOR DESCRIPTION OF LIBRARY   25200013
*              CONVENTIONS AND STANDARDS                                25600013
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND ON A        26000013
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL       26400013
*              CHARACTER SET.                                           26800013
         EJECT                                                          27200013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*VCS001-TSS 27400001
*  THE FOLLOWING MODULES MUST BE INCLUDED IF REQUIRED                   27600013
         PUNCH     ' LIBRARY *(IHEDNCA,IHEDNBA)                        /28000013
                                    VCS0000A'                           28400013
*        ----------------------------------------------------VCS001-TSS 28600001
         SPACE                                                          28800013
IHEVCS   CSECT                                                          29200013
         IHELIB                                                         29600013
IHEZLW3  DSECT                                                          30000013
         DS    15D                                                      30400013
PWRK     EQU   IHEZLW3+72                                               30800013
IHEVCS   CSECT                                                          31200013
         ENTRY IHEVCSA                                                  31600013
         ENTRY IHEVCSB                                                  32000013
         USING IHEZLCA,WR               SAVE PLIST POINTER              32400013
         USING IHEZLW3,DR                                               32800013
IHEVCSA  NOPR  0                                                        33200013
IHEVCSB  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          33600013
         BALR  RJ,0                                                     34000013
         USING *,RJ                                                     34400013
         TM    OFBR+3(DR),X'02'         TEST ENTRY ADDRESS              34800013
         IHESDR LW3,WR                  UPDATE SAVE AREA POINTER        35200013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  35600013
         MVI   ENTY,X'00'               SET FOR ENTRY ONE               36000013
         BZ    SAVLS                    BRANCH IF ENTRY ONE             36400013
         MVI   ENTY,X'01'               SET FOR ENTRY TWO               36800013
SAVLS    LR    RE,RA                    SAVE PLIST POINTER              37200013
         LM    RA,RD,0(RA)              GET SOURCE PARAMETERS           37600013
         MVC   DED1(1),0(RB)            COPY REAL DED                   38000013
         OC    DED1(1),0(RD)            OR IN IMAG DED                  38400013
         OI    DED1,CDCX                SET CODED COMPLEX               38800013
         NI    DED1,X'BF'               ZERO UNWANTED BIT               39200013
         MVC   DED2(1),DED1             SET                             39600013
         NI    DED2,X'06'               INDEX FOR MAX PRECISION (N)     40000013
         MVI   PSWT,ZERO                ZERO SWITCH                     40400013
         SR    RF,RF                    ZERO                            40800013
         LR    RG,RF                    PRECISION                       41200013
         LR    RH,RF                    AND                             41600013
         LR    RI,RF                    SCALE AND                       42000013
         LR    LR,RF                    SWITCH REGISTERS                42400013
         IC    RF,1(RB)                 LOAD PRECISION AND              42800013
         IC    RG,2(RB)                 SCALE FACTOR                    43200013
         SH    RG,K128                  OF REAL PART                    43600013
         IC    RH,1(RD)                 LOAD PRECISION AND              44000013
         IC    RI,2(RD)                 SCALE FACTOR                    44400013
         SH    RI,K128                  OF IMAG PART                    44800013
         TM    0(RB),BINY               TEST BASE OF REAL PART          45200013
         BO    TESTBI                   BRANCH IF BINARY                45600013
         TM    0(RD),BINY               TEST BASE OF IMAG PART          46000013
         BZ    COMPR                    BRANCH IF DECIMAL               46400013
         B     CONPQ                    GO CONVERT PRECISION            46800013
TESTBI   TM    0(RD),BINY               TEST BASE OF IMAG PART          47200013
         BO    COMPR                    BRANCH IF BINARY                47600013
         STM   RF,RG,TEMP               SAVE PRECISIONS                 48000013
         LR    RF,RH                    EXCHANGE                        48400013
         LR    RG,RI                    REAL AND IMAG                   48800013
         LM    RH,RI,TEMP               PARAMETERS                      49200013
CONPQ    MH    RF,K332                  CALCULATE BINARY                49600013
         SRL   RF,8                     EQUIVALENT OF                   50000013
         LA    RF,1(RF)                 DECIMAL PRECISION               50400013
         TM    DED1,FLOT                TEST SCALE OF INTERMEDIATE      50800013
         BO    TESTN                    BRANCH IF FLOAT                 51200013
         LA    RF,1(RF)                 BUMP PRECISION                  51600013
         SR    BR,BR                    INITIALISE SIGN SWITCH          52000013
         LTR   RG,RG                    TEST SIGN OF SCALE FACTOR       52400013
         BNL   CONVQ                    BRANCH NOT MINUS                52800013
         BALR  BR,0                     SET SIGN SWITCH FOR MINUS       53200013
         LPR   RG,RG                    SET SCALE FACTOR POSITIVE       53600013
CONVQ    MH    RG,K332                  CALCULATE BINARY                54000013
         SRL   RG,8                     EQUIVALENT OF                   54400013
         LA    RG,1(RG)                 SCALE FACTOR                    54800013
         LTR   BR,BR                    TEST SIGN OF SCALE FACTOR       55200013
         BZ    TESTN                    BRANCH IF POSITIVE              55600013
         LCR   RG,RG                    SET NEGATIVE                    56000013
TESTN    CH    RG,K127                  COMPARE SCALE FACTOR WITH MAX   56400013
         BNH   TESTM                    BRANCH IF LOW OR EQUAL          56800013
         LH    RG,K127                  SET SCALE FACTOR TO MAX VALUE   57200013
         B     COMPR                    GO COMPARE PRECISIONS           57600013
TESTM    CH    RG,M128                  COMPARE SCALE FACTOR WITH MIN   58000013
         BH    COMPR                    BRANCH IF HIGH                  58400013
         LH    RG,M128                  SET SCALE FACTOR MINIMUM VALUE  58800013
COMPR    SR    RF,RG                    P1-PQ.                          59200013
         SR    RH,RI                    P2-Q2.                          59600013
*  COMPUTE MAX(P1-Q1,P2-Q2).                                            60000013
         CR    RF,RH                                                    60400013
         BH    TAKRF                                                    60800013
         LR    RF,RH                                                    61200013
*   COMPUTE MAX(Q1,Q2).                                                 61600013
TAKRF    CR    RG,RI                                                    62000013
         BH    TAKRG                                                    62400013
         LR    RG,RI                                                    62800013
TAKRG    AR    RF,RG                    MAX(P1-Q1,P2-Q2)+MAX(Q1,Q2).    63200013
         LA    RF,1(RF)                        ''       +1.             63600013
         IC    LR,DED2                  SET INDEX FOR BASE.             64000013
         CH    RF,BIGN(LR)              TEST IF EXP IS GREATER THAN N   64400013
         BNH   TAKIT                    NO PRESCISION FOUND.            64800013
         LH    RF,BIGN(LR)              YES USE N AS PRESICION.         65200013
TAKIT    STC   RF,DED1+1                SET PRESICION.                  65600013
         AH    RG,K128                                                  66000013
         STC   RG,DED1+2                SET SCALE.                      66400013
LODAD    LA    RD,DED1                  SET INTERMEDIATE DED POINTER    66800013
         LA    RC,INTR                  SET INTERMEDIATE FIELD POINTER  67200013
TESTB    TM    0(RB),BINY               TEST BASE OF SOURCE             67600013
         BZ    DECML                    BRANCH IF DECIMAL               68000013
         ST    RA,WCNP                  SET SOURCE POINTER              68400013
CLDMA    L     BR,DMAA                  CALL ARITHMETIC                 68800013
         BALR  LR,BR                    CONVERSION DIRECTOR             69200013
         TM    PSWT,IMAG                TEST IMAG PART SWITCH           69600013
         BO    CALAS                    BRANCH IF SET                   70000013
         LR    RA,RC                    SET PARAMETERS                  70400013
         LR    RB,RD                    FOR CALL                        70800013
         OI    WSWA,UPDO                SET UPDATE ONLY SWITCH          71200013
         L     BR,UPAB                  CALL ROUTINE TO GET             71600013
         BALR  LR,BR                    ADDR OF IMAGINARY PART          72000013
         L     RC,WRCD                  LOAD ADDRESS OF TARGET IMAG PRT 72400013
         LM    RA,RB,8(RE)              LOAD IMAG SOURCE PARAMETERS     72800013
         OI    PSWT,IMAG                SET IMAG PART SWITCH            73200013
         B     TESTB                    LOOP                            73600013
DECML    LM    RH,RI,24(RE)             LOAD FED POINTERS               74000013
         L     RA,0(RA)                 SET FIELD POINTER               74400013
         ST    RH,WFED                  SET FED POINTER                 74800013
         TM    PSWT,IMAG                TEST IMAG PART SWITCH           75200013
         BZ    CLDMA                    BRANCH NOT SET                  75600013
         ST    RI,WFED                  SET IMAG FED POINTER            76000013
         B     CLDMA                    GO CALL CONVERSION              76400013
CALAS    LR    RB,RD                    SET SOURCE PARAMETERS TO POINT  76800013
         LA    RA,INTR                  TO CODED COMPLEX INTERMEDIATE   77200013
         LM    RC,RD,16(RE)             LOAD TARGET STRING PARAMETERS   77600013
         CLI   ENTY,X'01'               TEST ENTRY POINT USED           78000013
         BNE   TSTRG                    BRANCH IF ENTRY ONE             78400013
         MVC   0(16,RC),INTR            COPY CODED COMPLEX AND          78800013
         MVC   16(3,RC),0(RB)           DED INTO RESULT                 79200013
         B     ENDRT                    GO TO EXIT                      79600013
TSTRG    TM    0(RD),CHAR               TEST TARGET STRING TYPE         80000013
         L     BR,DNCA                  SET FOR CHARACTER               80400013
         BO    CALLS                    BRANCH IF CHARACTER             80800013
         L     BR,DNBA                  SET FOR BIT                     81200013
CALLS    BALR  LR,BR                    CALL ARITH TO STRING CONVERSION 81600013
ENDRT    L     DR,OFDR(DR)              RESET SAVE AREA POINTER         82000013
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       82400013
         BR    LR                       RETURN                          82800013
BIGN     DC    H'15'                    DECIMAL FIXED MAX PRECISION (N) 83200013
         DC    H'16'                            FLOAT                   83600013
         DC    H'31'                    BINARY  FIXED                   84000013
         DC    H'53'                            FLOAT                   84400013
K332     DC    X'0352'                                                  84800013
K128     DC    H'128'                                                   85200013
K127     DC    H'127'                                                   85600013
M128     DC    H'-128'                                                  86000013
DMAA     DC    V(IHEDMAA)                                               86400013
UPAB     DC    V(IHEUPAB)                                               86800013
DNCA     DC    V(IHEDNCA)                                               87200013
DNBA     DC    V(IHEDNBA)                                               87600013
CDCX     EQU   X'09'                                                    88000013
BINY     EQU   X'04'                                                    88400013
IMAG     EQU   X'01'                                                    88800013
CHAR     EQU   X'04'                                                    89200013
ZERO     EQU   X'00'                                                    89600013
FLOT     EQU   X'02'                                                    90000013
UPDO     EQU   X'04'                                                    90400013
DED1     EQU   PWRK                                                     90800013
DED2     EQU   DED1+3                                                   91200013
PSWT     EQU   DED2+1                                                   91600013
ENTY     EQU   PSWT+1                                                   92000013
INTR     EQU   DED1+8                                                   92400013
TEMP     EQU   INTR                                                     92800013
         END                                                            93200013
