VPC      TITLE '   IHEVPC    PACKED DECIMAL INTERMEDIATE TO E FORMAT   *00500013
               O/S 360 PL/1 LIBRARY'                                    01000013
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  01500013
*                                                                       02000013
*   STATUS     CHANGE LEVEL - 0                                         02500013
         SPACE 1                                                        02600000
* R20   560000,*  565000                                         A28505 02700000
*                                                                       03000013
*   SIZE       416 BYTES                                                03500013
*                                                                       04000013
*   FUNCTION   TO CONVERT A SEVENTEEN DIGIT NUMBER TO A CHARACTER       04500013
*              STRING OF E-FORMAT                                       05000013
*                                                                       05500013
*   ENTRY POINT                                                         06000013
*              IHEVPCA                                                  06500013
*                                                                       07000013
*   INPUT      WINT - SEVENTEEN DIGIT (NINE BYTE) PACKED DECIMAL NUMBER 07500013
*              WSCF - BINARY WORD CONTAINING SCALE FACTOR OF WINT       08000013
*              WFDT - A(FED)                                            08500013
*              WRCD - A(TARGET FIELD),A(TARGET DED)                     09000013
*                                                                       09500013
*   OUTPUT     N/A                                                      10000013
*                                                                       10500013
*   EXTERNAL MODULES                                                    11000013
*              N/A                                                      11500013
*                                                                       12000013
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              12500013
*              ERROR1 - CALL IHEERRB TO RAISE SIZE ERROR IF SOURCE TOO  13000013
*                       LARGE TO BE EXPRESSED WITH GIVEN FIELD WIDTH    13500013
*              ERROR2 - CALL IHEERRC TO RAISE ERROR IF FED IS INVALID   14000013
*                                                                       14500013
*                                                                       15000013
*   TABLES/WORK AREA                                                    15500013
*              WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)         16000013
*                                                                       16500013
*   ATTRIBUTES READ ONLY AND REENTRANT                                  17000013
*                                                                       17500013
*   PRIVATE MACROS                                                      18000013
*              IHELIB,IHEPRV                                            18500013
*                                                                       19000013
*   ASSEMBLY REQUIREMENTS                                               19500013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   20000013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        20500013
*                                                                       21000013
*   NOTES      SEE OS/360 PL/1 LIBRARY PLM FOR DESCRIPTION OF LIBRARY   21500013
*              CONVENTIONS AND STANDARDS                                22000013
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    22500013
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    23000013
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  23500013
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  24000013
*              CONSTANTS,BY REASSEMBLY,WILL RESULT IN A CORRECT MODULE  24500013
*              FOR THE NEW DEFINITIONS.                                 25000013
IHEVPC   CSECT                                                          25500013
         IHELIB                                                         26000013
IHEZLW0  DSECT                                                          26500013
         DS    15D                                                      27000013
WORK     EQU   IHEZLW0                                                  27500013
IHEVPC   CSECT                                                          28000013
         ENTRY IHEVPCA                                                  28500013
         USING *,BR                                                     29000013
         USING IHEZLCA,WR                                               29500013
         USING IHEZLW0,DR                                               30000013
IHEVPCA  IHEPRV ,WR                     GET COMMUNICATION AREA          30500013
         MVI   WSWC,ZERO                RESET SWITCHES.                 31000013
         MVI   PWRK,DSCH                STORE AND                       31500013
         MVC   PWRK+1(16),PWRK          PROPAGATE DIGIT SELECT CHAR.    32000013
         LA    1,PWRK+17                SET SIGNICFICANCE START ADDRESS 32500013
         MVI   0(1),C'0'                STORE AND                       33000013
         MVC   1(16,1),0(1)             PROPAGATE ZERO                  33500013
         EDMK  PWRK(17),WINT            EDIT SOURCE.                    34000013
         BNL   TZERO                    BRANCH NOT NEGATIVE             34500013
         OI    WSWC,SSWT                SET SIGN SWITCH                 35000013
TZERO    BNE   GETFD                    BRANCH NOT ZERO                 35500013
         OI    WSWC,ZSWT                SET ZERO SWITCH                 36000013
GETFD    L     RB,WFDT                  GET ADDRESS OF TARGET FED       36500013
         LH    RC,0(RB)                 GET FIELD  WIDTH (W)            37000013
         SR    RD,RD                                                    37500013
         IC    RD,2(RB)                 GET NO.OF DECIMAL PLACES (D)    38000013
         SR    RE,RE                                                    38500013
         IC    RE,3(RB)                 GET NO.OF SIGNIFICANT DIGITS(S) 39000013
         LTR   RE,RE                    IS S ZERO                       39500013
         BZ    ERROD                    YES - GO TO ERROR CALL          40000013
         CH    RE,KH16               +  S > 16 ..                       40100016
         BH    ERROD                   YES - GO TO ERROR CALL      H136 40300017
         CR    RD,RE                    COMPARE D WITH S                40500013
         BH    ERROD                    BRANCH IF D GREATER THAN S      41000013
         TM    WSWB,2                   E-FORMAT..                      41030015
          BZ   NORND                    NO.                             41060015
         LA    LR,0(RE,1)               GET L.S. DIGIT + 1.             41090015
         CLI   0(LR),C'5'               ROUNDING NEEDED..               41120015
         BL    NORND                    NO.                             41150015
         BCTR  LR,0                     L.S. DIGIT.                     41180015
RLOOP    CLI   0(LR),DSCH               BLANK POSITION                  41210015
         BE    RNDBL                    YES.                            41240015
         TR    0(1,LR),TRAB-C'0'        ROUND.                          41270015
         CLI   0(LR),C'0'               CARRY NEEDED..                  41300015
         BNE   NORND                    NO.                             41330015
         BCT   LR,RLOOP                 ROUND.                          41360015
RNDBL    MVI   0(LR),C'1'               REPLACE BLANK BY '1'.           41390015
         BCTR  1,0                                                      41420015
NORND    EQU   *                                                        41450015
         LA    RF,PWRK+17(RD)           RX=HLIMIT+D-SCF-LLIMIT-S        41500013
         S     RF,WSCF                                                  42000013
         SR    RF,1                                                     42500013
         SR    RF,RE                                                    43000013
         TM    WSWC,ZSWT                TEST SOURCE ZERO SWITCH         43500013
         BZ    LOADB                    BRANCH NOT SET                  44000013
         SR    RF,RF                    ZERO DIGIT POINTER              44500013
LOADB    L     RG,WRCD                  GET BUFFER ADDRESS.             45000013
         MVI   0(RG),C' '               BLANK FIRST CHARACTER           45500013
         LR    RJ,RG                    SAVE FIELD ADDRES               46000013
         LR    RH,RC                    GET WIDTH OF FIELD              46500013
BLOOP    BCT   RH,ZYXWV                 HAVE WE DONE                    47000013
         B     BLNKT                    YES - DO NOT BLANK              47500013
ZYXWV    SH    RH,K255                  IS W ABSURDLY LARGE             48000013
         BNH   BLOUT                    NOT ANY MORE                    48500013
         MVC   1(256,RG),0(RG)          BLOT OUT 256 BYTES              49000013
         LA    RG,256(RG)               STEP OVER DEBRIS                49500013
         B     BLOOP                    AGAIN AND AGAIN                 50000013
BLOUT    LA    RH,254(RH)               WHATS LEFT THEN                 50500013
         EX    RH,MVBUF                 CLEAR IT OUT                    51000013
BLNKT    LR    RG,RJ                    RESTORE FIELD ADDRESS           51500013
         LTR   RD,RD                    IS D 0                          52000013
         BNZ   TESTW                    NO SKIP THIS                    52500013
         LA    RG,1(RG)                 NO POINT SO START FURTHER RIGHT 53000013
TESTW    SR    RC,RE                    CALCULATE PRECEDING BLANKS      53500013
         SH    RC,K005                                                  54000013
         BP    INSBL                    IF (W-S-5) GT 0  BRANCH         54500013
         BM    ERROR                    IF (W-S-5) LT 0  BRANCH         55000013
         TM    WSWC,SSWT                TEST SIGN SWITCH                55500013
         BO    TESTW1                  BRANCH IF SOURCE NEGATIVE A28505 56000000
         B     STINT                                                    56500013
TESTW1   LTR   RD,RD                   IS D 0. IF NOT THEN       A28505 56600000
         BNZ   ERROD                   W IS TOO SMALL            A28505 56700000
INSBL    BCTR  RC,0                     ALLOW FOR SIGN                  57000013
         AR    RG,RC                    FIND POSITION OF SIGN           57500013
         TM    WSWC,SSWT                TEST SIGN SWITCH                58000013
         BZ    BUMPP                    BRANCH IF POSITIVE              58500013
         MVI   0(RG),C'-'               STASH MINUS SIGN                59000013
BUMPP    LA    RG,1(RG)                 BUMP BUFFER POINTER             59500013
STINT    BCTR  RE,0                                                     60000013
         LR    RJ,RG                    SAVE ADDRESS OF FIRST DIGIT     60500013
         SR    RE,RD                                                    61000013
         BM    STPNT                                                    61500013
         EX    RE,MVCSB                 STASH INTEGER PART              62000013
         LA    RG,1(RG,RE)              BUMP BUFFER POINTER             62500013
         LA    RA,1(RA,RE)                                              63000013
STPNT    LTR   RD,RD                    TEST FOR ZERO D                 63500013
         BNH   STEXP                    SKIP THE FRACTION               64000013
         MVI   0(RG),C'.'               STASH POINT                     64500013
         LA    RG,1(RG)                 BUMP BUFFER POINTER             65000013
         BCTR  RD,0                                                     65500013
         EX    RD,MVCSB                 STASH FRACTIONAL PART           66000013
         LA    RG,1(RG,RD)              BUMP BUFFER POINTER             66500013
STEXP    MVI   0(RG),C'E'               STASH EXPONENT MARKER           67000013
         MVI   1(RG),C'+'               SET EXPONENT SIGN POSITIVE      67500013
         LTR   RF,RF                                                    68000013
         BC    10,TESTE                                                 68500013
         MVI   1(RG),C'-'               SET EXPONENT SIGN NEGATIVE      69000013
TESTE    LPR   RF,RF                                                    69500013
         CH    RF,K099                  TEST FOR EXPONENT OVERFLOW      70000013
         BH    ERROR                                                    70500013
         CVD   RF,PWRK                  CONVERT EXPONENT TO DECIMAL     71000013
         UNPK  PWRK(3),PWRK+6(2)        UNPACK                          71500013
         MVZ   PWRK+2,PWRK+1            CORRECT ZONE ON JUNIOR DIGIT    72000013
         MVC   2(2,RG),PWRK+1           STASH EXPONENT                  72500013
         TM    WSWC,ZSWT                WAS THE SOURCE ZERO             73000013
         BZ    ENDRT                    NO WE HAVE FINISHED             73500013
         LTR   RE,RE                                                    74000013
         BNH   ENDRT                    ZEROS SUPPRESSED NATURALLY      74500013
SPRES    LR    RG,RJ                    RESTORE ADDRESS OF FIRST DIGIT  75000013
         MVI   0(RG),C' '               ONE DIGIT SUPPRESSED            75500013
         BCT   RE,SERPS                 MORE THAN                       76000013
         B     ENDRT                    NO                              76500013
SERPS    BCTR  RE,0                     ONE FOR THE POT                 77000013
         EX    RE,MVBUF                 SUPPRESS SOME MORE              77500013
ENDRT    L     DR,OFDR(DR)              RESET SAVE AREA POINTER         78000013
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       78500013
         BR    LR                       EXIT                            79000013
ERROR    IHEPRV ERR,RE,OP=LA            GET ADDRESS OF ERROR CODE       79500013
         OI    0(RE),SIZE               SET FOR                         80000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*VPC999-TSS 80200000
         L     BR,ERRB                  CALL EXECUTION                  80500013
SZERO    BALR  LR,BR                    ERROR PACKAGE                   81000013
         USING *,LR                                                     81500013
         L     BR,BASE                  RESTORE BASE ADDRESS            82000013
         DROP  LR                                                       82500013
         B     ENDRT                    CONTINUE IF RETURN              83000013
ERROD    L     BR,ERRC                  RAISE ERROR CONDITION           83500013
*        ----------------------------------------------------VPC999-TSS 83700000
         BALR  RA,BR                    CALL ERROR PACKAGE              84000013
EROR     DC    X'0400'                                                  84500013
MVBUF    MVC   1(0,RG),0(RG)                                            85000013
MVCSB    MVC   0(0,RG),0(RA)                                            85500013
K255     DC    H'255'                                                   86000013
K005     DC    H'5'                                                     86500013
K099     DC    H'99'                                                    87000013
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*VPC998-TSS 87200000
ERRC     DC    V(IHEERRC)                                               87500013
ERRB     DC    V(IHEERRB)                                               88000013
BASE     DC    V(IHEVPCA)                                               88500013
*        ----------------------------------------------------VPC998-TSS 88600000
TRAB     DC    C'1234567890'                                            88700015
KH16     DC    H'16'                                                    88800016
ZERO     EQU   X'00'                                                    89000013
DSCH     EQU   X'20'                                                    89500013
SSWT     EQU   X'01'                                                    90000013
ZSWT     EQU   X'02'                                                    90500013
SIZE     EQU   X'20'                                                    91000013
PWRK     EQU   WORK+72                                                  91500013
         END                                                            92000013
