VSA      TITLE '   IHEVSA    BIT STRING TO BIT STRING                  *00700013
               O/S 360 PL/1 LIBRARY'                                    01400013
*   STATUS     CHANGE LEVEL - 0                                         02100013
*   SIZE       312 BYTES                                                02800013
*   FUNCTION   TO ASSIGN A FIXED OR VARYING BIT STRING TO A FIXED OR    03500013
*              VARYING BIT STRING                                       04200013
*                                                                       04900013
*   ENTRY POINTS                                                        05600013
*              IHEVSAA                                                  06300013
*                  RA = A(SOURCE SDV)                                   07000013
*                  RB = A(SOURCE DED)                                   07700013
*                  RC = A(TARGET SDV)                                   08400013
*                  RD = A(TARGET DED)                                   09100013
*                                                                       09800013
*   INPUT      N/A                                                      10500013
*                                                                       11200013
*   OUTPUT     N/A                                                      11900013
*                                                                       12600013
*   EXTERNAL MODULES                                                    13300013
*              N/A                                                      14000013
*                                                                       14700013
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              15400013
*                                                                       16100013
*   TABLES/WORK AREA                                                    16800013
*              WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)         17500013
*                                                                       18200013
*   ATTRIBUTES READ ONLY AND REENTRANT                                  18900013
*                                                                       19600013
*   NOTES      SEE OS/360 PL/1 LIBRARY PLM FOR DESCRIPTION OF LIBRARY   20300013
*              CONVENTIONS AND STANDARDS                                21000013
*              THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A      21700013
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL       22400013
*              CHARACTER REPRESENTATION.                                23100013
IHEVSA   CSECT                                                          23800013
         IHELIB                                                         24500013
IHEZLW0  DSECT                                                          25200013
         DS    15D                                                      25900013
WORK     EQU   IHEZLW0                                                  26600013
IHEVSA   CSECT                                                          27300013
         ENTRY IHEVSAA                                                  28000013
         USING *,BR                                                     28700013
         USING IHEZLCA,WR                                               29400013
         USING IHEZLW0,DR                                               30100013
IHEVSAA  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          30800013
         IHESDR LW0,WR                  UPDATE SAVE AREA POINTER        31500013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  32200013
         LH    RB,6(RA)                 GET SOURCE CURRENT LENGTH (S)   32900013
         LH    R0,4(RC)                 GET TARGET MAX LENGTH (T)       33600013
         MVI   WSWC,ZERO                                                34300013
         CR    RB,R0                    COMPARE LENGTHS                 35000013
         BH    SETSL                    BRANCH SOURCE TOO LONG          35700013
         BE    SETCL                    BRANCH IF EQUAL                 36400013
         LR    RE,R0                    CALCULATE                       37100013
         SR    RE,RB                    DIFFERENCE IN LENGTHS           37800013
         STH   RE,PWORK                 SAVE FILL AMOUNT                38500013
TESVR    TM    0(RD),VARY               VARIABLE TARGET STRING          39200013
         BO    SETCL                    YES,BRANCH                      39900013
         OI    WSWC,FILL                SET FILL SWITCH                 40600013
GETSA    L     RE,0(RA)                 GET SOURCE ADDRESS              41300013
         LR    RD,RE                    CALCULATE                       42000013
         SRDL  RD,2                     SOURCE WORD                     42700013
         SLL   RD,2                     ADDRESS AND                     43400013
         SRL   RE,27                    OFFSET                          44100013
         L     RI,0(RC)                 GET TARGET ADDRESS              44800013
         LR    RH,RI                    CALCULATE                       45500013
         SRDL  RH,2                     TARGET WORD                     46200013
         SLL   RH,2                     ADDRESS AND                     46900013
         SRL   RI,27                    OFFSET                          47600013
GETDW    LM    RF,RG,0(RD)              GET DOUBLE WORD FROM SOURCE     48300013
         SLDL  RF,0(RE)                 LEFT ADJUST SOURCE BITS         49000013
         LA    RA,64                    SET NUMBER OF                   49700013
         SR    RA,RE                    BITS LOADED (N)                 50400013
TESTN    CR    RB,RA                    COMPARE S WITH N                51100013
         BH    DECRS                    BRANCH S>N                      51800013
         LR    RA,RB                    SET N EQUAL SOURCE LENGTH       52500013
DECRS    SR    RB,RA                    DECREMENT SOURCE LENGTH BY N    53200013
LOOP1    LR    RJ,RF                    COPY FIRST WORD                 53900013
         SRL   RJ,0(RI)                 ALIGN FOR TARGET                54600013
         L     LR,0(RH)                 GET WORD FROM TARGET            55300013
         LCR   RC,RI                    COMPLEMENT OFFSET               56000013
         SRL   LR,32(RC)                ZERO UNWANTED                   56700013
         SLL   LR,32(RC)                TARGET BITS                     57400013
         OR    RJ,LR                    COMBINE SOURCE/TARGET BITS      58100013
         AR    RI,RA                    CALCULATE OFFSET PLUS SOURCE    58800013
         CH    RI,K032                  TEST AGAINST WORD LENGTH        59500013
         BH    SLOOP                    LONGER THAN WORD                60200013
         BL    COMPO                    LESS THAN WORD                  60900013
         ST    RJ,0(RH)                 EQUAL.STORE WORD IN TARGET      61600013
         LA    RH,4(RH)                 UPDATE TARGET WORD ADDRESS      62300013
         SR    RI,RI                    ZERO OFFSET                     63000013
         B     TESTS                                                    63700013
COMPO    LCR   RI,RI                    COMPLEMENT ACTUAL LENGTH        64400013
         SRL   RJ,32(RI)                ZERO BITS                       65100013
         SLL   RJ,32(RI)                BEYOND DATUM                    65800013
         L     LR,0(RH)                 GET WORD FROM TARGET            66500013
         LCR   RI,RI                    GET OFFSET                      67200013
         SLL   LR,0(RI)                 ZERO TARGET WORD                67900013
         SRL   LR,0(RI)                 DATUM BITS                      68600013
         OR    RJ,LR                    COMBINE SOURCE/TARGET BITS      69300013
         ST    RJ,0(RH)                 STORE WORD IN TARGET            70000013
TESTS    LTR   RB,RB                    TEST LENGTH OF SOURCE           70700013
         BZ    FILLT                    BRANCH IF ZERO                  71400013
         TM    WSWC,PADD                TEST PAD SWITCH                 72100013
         BZ    BUMPS                    BRANCH NOT SET                  72800013
FILOP    SR    RF,RF                    GET DOUBLE WORD                 73500013
         LR    RG,RF                    ALL ZEROS                       74200013
         LA    RA,64                    SET N EQUAL SIXTY FOUR          74900013
         B     TESTN                    GO TO FILL WITH ZEROS           75600013
BUMPS    LA    RD,8(RD)                 BUMP SOURCE ADDRESS BY TWO WORD 76300013
         SR    RE,RE                    ZERO SOURCE OFFSET              77000013
         B     GETDW                    LOOP                            77700013
FILLT    TM    WSWC,FILL                TEST FILL SWITCH                78400013
         BZ    ENDRT                    BRANCH NOT SET                  79100013
         LH    RB,PWORK                 SET S EQUAL FILL AMOUNT         79800013
         MVI   WSWC,ZERO                RESET FILL SWITCH               80500013
         OI    WSWC,PADD                SET PAD SWITCH                  81200013
         B     FILOP                    GO TO INITIALISE FILL           81900013
SETCL    STH   RB,6(RC)                 SET TARGET CURRENT LENGTH       82600013
         B     GETSA                                                    83300013
SETSL    LR    RB,R0                    SET SOURCE EQUAL TARGET MAX     84000013
         TM    0(RD),VARY               TEST FOR VARYING TARGET         84700013
         BO    SETCL                                                    85400013
         B     GETSA                                                    86100013
SLOOP    ST    RJ,0(RH)                 STORE FIRST WORD IN TARGET      86800013
         LA    RH,4(RH)                 BUMP TARGET WORD ADDRESS        87500013
         SLDL  RF,32(RC)                RE-ALIGN SOURCE BITS            88200013
         LA    LR,32(RC)                DECREMENT NUMBER OF             88900013
         SR    RA,LR                    BITS TO BE STORED               89600013
         SR    RI,RI                    ZERO OFFSET                     90300013
         B     LOOP1                    LOOP                            91000013
ENDRT    L     DR,OFDR(DR)              RESET SAVE AREA POINTER         91700013
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       92400013
         BR    LR                       EXIT                            93100013
K032     DC    H'32'                                                    93800013
ZERO     EQU   X'00'                                                    94500013
VARY     EQU   X'10'                                                    95200013
FILL     EQU   X'01'                                                    95900013
PADD     EQU   X'02'                                                    96600013
PWORK    EQU   WORK+72                                                  97300013
       END                                                              98000013
