VSB      TITLE '   IHEVSB    BIT STRING TO CHARACTER STRING            *00900013
               O/S 360 PL/1 LIBRARY'                                    01800013
*   STATUS     CHANGE LEVEL - 0                                         02700013
*        THIS MODULE CONTAINS A FIX FOR APAR 12132                      03100015
*   SIZE       192 BYTES                                                03600013
*   FUNCTION   TO CONVERT A FIXED OR VARYING BIT STRING TO A FIXED OR   04500013
*              VARYING CHARACTER STRING                                 05400013
*                                                                       06300013
*   ENTRY POINTS                                                        07200013
*              IHEVSBA                                                  08100013
*                  RA = A(SOURCE SDV)                                   09000013
*                  RB = A(SOURCE DED)                                   09900013
*                  RC = A(TARGET SDV)                                   10800013
*                  RD = A(TARGET DED)                                   11700013
*                                                                       12600013
*   INPUT      N/A                                                      13500013
*                                                                       14400013
*   OUTPUT     N/A                                                      15300013
*                                                                       16200013
*   EXTERNAL MODULES                                                    17100013
*              N/A                                                      18000013
*                                                                       18900013
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              19800013
*                                                                       20700013
*   TABLES/WORK AREA                                                    21600013
*              WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)         22500013
*                                                                       23400013
*   ATTRIBUTES READ ONLY AND REENTRANT                                  24300013
*   NOTES      SEE OS/360 PL/1 LIBRARY PLM FOR DESCRIPTION OF LIBRARY   25200013
*              CONVENTIONS AND STANDARDS                                26100013
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    27000013
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    27900013
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  28800013
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  29700013
*              CONSTANTS,BY REASSEMBLY,WILL RESULT IN A CORRECT MODULE  30600013
*              FOR THE NEW DEFINITIONS.                                 31500013
IHEVSB   CSECT                                                          32400013
         IHELIB                                                         33300013
IHEZLW0  DSECT                                                          34200013
         DS    15D                                                      35100013
WORK     EQU   IHEZLW0                                                  36000013
IHEVSB   CSECT                                                          36900013
         ENTRY IHEVSBA                                                  37800013
         USING *,BR                                                     38700013
         USING IHEZLCA,WR                                               39600013
         USING IHEZLW0,DR                                               40500013
IHEVSBA  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          41400013
         IHESDR LW0,WR                  UPDATE SAVE AREA POINTER        42300013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  43200013
         MVI   WSWC,0                   RESET SWITCHES                  44100013
         LH    RG,6(RA)                 GET SOURCE CURRENT LENGTH       45000013
         LTR   RG,RG                 +  TEST SOURCE LENGTH.             45100015
         BNM   NOTNG                                                    45200015
         SR    RG,RG                    ZERO NEGATIVE LENGTH.           45300015
NOTNG    EQU   *                                                        45400015
         LH    RF,4(RC)                 GET TARGET MAX LENGTH           45900013
         LTR   RF,RF                 +  TEST TARGET LENGTH.             46000015
         BNM   NTNEG                                                    46100015
         SR    RF,RF                    ZERO NEGATIVE LENGTH.           46200015
NTNEG    EQU   *                                                        46300015
         L     RI,0(RC)                 GET TARGET ADDRESS.             46400015
         CR    RG,RF                    COMPARE LENGTHS                 46800013
         BH    TRGTS                    BRANCH IF SOURCE LONGER THAN TG 47700013
         LR    RJ,RG                    COPY SOURCE LENGTH              48600013
         TM    0(RD),VARY               TEST FOR VARIABLE TARGET        49500013
         BO    SETRG                    BRANCH IF VARIABLE              50400013
         MVI   SWIT,FILL                SET FILL SWITCH                 51300013
         B     CONVT                                                    52200013
ENDRT    L     DR,OFDR(DR)              RESET SAVE AREA POINTER         53100013
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       54000013
         BR    LR                       EXIT                            54900013
TRGTS    LR    RJ,RF                    GET TARGET MAX LENGTH           55800013
         TM    0(RD),VARY               VARIABLE LENGTH TARGET          56700013
         BZ    CONVT                    BRANCH IF FIXED                 57600013
SETRG    STH   RJ,6(RC)                 SET TRG CURRENT LENGTH=SOURCE   58500013
CONVT    SR    RF,RJ                    GET DIFF IN LENGTH OF SRCE/TARG 59400013
         LTR   RJ,RJ                    TEST FOR                        60300013
         BZ    SWTST                    ZERO SOURCE                     61200013
         SR    RH,RH                    GET BIT OFFSET OF               62100013
         IC    RH,0(RA)                 SOURCE STRING                   63000013
         SRL   RH,5                     RIGHT ADJUST OFFSET AMOUNT      63900013
         LA    RG,128                   SET MASK TO                     64800013
         SRL   RG,0(RH)                 TEST FIRST BIT                  65700013
         L     RH,0(RA)                 GET SOURCE BYTE ADDRESS         66600013
LOOPS    MVI   0(RI),C'0'               SET TARGET CHARACTER ZERO       68400013
         EX    RG,TMSK                  EXECUTE TM ON SOURCE BIT        69300013
         BZ    BUMPA                    BRANCH IF ZERO                  70200013
         MVI   0(RI),C'1'               SET TARGET CHARACTER ONE        71100013
BUMPA    LA    RI,1(RI)                 BUMP TARGET ADDRESS             72000013
         SRA   RG,1                     SET MASK FOR NEXT BIT           72900013
         BNZ   COUNT                    BRANCH IF MASK NOT ZERO         73800013
         LA    RG,128                   RESET MASK                      74700013
         LA    RH,1(RH)                 BUMP SOURCE BYTE ADDRESS        75600013
COUNT    BCT   RJ,LOOPS                 LOOP UNTIL SOURCE CONVERTED     76500013
SWTST    CLI   SWIT,ZERO                TEST FILL SWITCH                77400013
         BE    ENDRT                    BRANCH IF NOT SET               78300013
         MVI   SWIT,ZERO                RESET FILL SWITCH               79200013
         LTR   RF,RF                                                    80100013
         BZ    ENDRT                    BRANCH IF NO FILL NEEDED        81000013
FILLS    MVI   0(RI),C' '               PAD STRING WITH BLANKS          81900013
         LA    RI,1(RI)                 BUMP TARGET STRING ADDRESS      82800013
         BCT   RF,FILLS                 LOOP TILL END OF TARGET         83700013
         B     ENDRT                                                    84600013
TMSK     TM    0(RH),ZERO               EXECUTED TEST SOURCE BIT.       85500013
SWIT     EQU   WSWC                                                     86400013
FILL     EQU   X'01'                                                    87300013
VARY     EQU   X'10'                                                    88200013
ZERO     EQU   X'00'                                                    89100013
         END                                                            90000013
