VSC      TITLE '   IHEVSC    CHARACTER STRING TO CHARCTER STRING       *01000013
               O/S 360 PL/1 LIBRARY'                                    02000013
*   STATUS     CHANGE LEVEL - 0                                         03000013
*   SIZE       160 BYTES                                                04000013
*   FUNCTION   TO ASSIGN A FIXED OR VARYING CHARACTER STRING TO A       05000013
*              FIXED OR VARYING CHARACTER STRING                        06000013
*                                                                       07000013
*   ENTRY POINTS                                                        08000013
*              IHEVSCA                                                  09000013
*                  RA = A(SOURCE SDV)                                   10000013
*                  RB = A(SOURCE DED)                                   11000013
*                  RC = A(TARGET SDV)                                   12000013
*                  RD = A(TARGET DED)                                   13000013
*                                                                       14000013
*   INPUT      N/A                                                      15000013
*                                                                       16000013
*   OUTPUT     N/A                                                      17000013
*                                                                       18000013
*   EXTERNAL MODULES                                                    19000013
*              N/A                                                      20000013
*                                                                       21000013
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              22000013
*                                                                       23000013
*   TABLES/WORK AREA                                                    24000013
*              WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)         25000013
*                                                                       26000013
*   ATTRIBUTES READ ONLY AND REENTRANT                                  27000013
*                                                                       28000013
*   NOTES      SEE OS/360 PL/1 LIBRARY PLM FOR DESCRIPTION OF LIBRARY   29000013
*              CONVENTIONS AND STANDARDS                                30000013
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    31000013
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    32000013
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  33000013
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  34000013
*              CONSTANTS,BY REASSEMBLY,WILL RESULT IN A CORRECT MODULE  35000013
*              FOR THE NEW DEFINITIONS.                                 36000013
IHEVSC   CSECT                                                          37000013
         IHELIB                                                         38000013
IHEZLW0  DSECT                                                          39000013
         DS    15D                                                      40000013
WORK     EQU   IHEZLW0                                                  41000013
IHEVSC   CSECT                                                          42000013
         ENTRY IHEVSCA                                                  43000013
         USING *,BR                                                     44000013
         USING IHEZLCA,WR                                               45000013
         USING IHEZLW0,DR                                               46000013
IHEVSCA  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          47000013
         IHESDR LW0,WR                  UPDATE SAVE AREA POINTER        48000013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  49000013
         MVI   WSWC,ZERO                RESET FILL SWITCH               50000013
         L     RJ,0(RA)                 GET SOURCE ADDRESS              51000013
         L     RI,0(RC)                 GET TARGET ADDRESS              52000013
         LH    RF,6(RA)                 GET SOURCE CURRENT LENGTH       53000013
         LH    RG,4(RC)                 GET TARGET MAX LENGTH           54000013
         CR    RF,RG                    COMPARE LENGTHS.                55000013
         BNH   TESVR                    BRANCH IF SOURCE NOT LONGER     56000013
         LR    RF,RG                    SET SOURCE = TARGET MAX LENGTH  57000013
TESVR    TM    0(RD),VARY               VARYING TARGET STRING           58000013
         BO    SETCL                    YES,BRANCH                      59000013
         LR    RH,RG                    CALCULATE FILL AMOUNT           60000013
         SR    RH,RF                    FOR FIXED LENGTH TARGET         61000013
         MVI   WSWC,FILL                SET FILL SWITCH                 62000013
TESTS    SH    RF,K256                  COMPARE SOURCE WITH 256         63000013
         BP    MV256                    BRANCH IF GREATER               64000013
         AH    RF,K255                  RESET SOURCE LENGTH             65000013
         BM    ENDRT                    ZERO SOURCE REMOVED HERE        66000013
         EX    RF,MVCIN                 MOVE SOURCE TO TARGET           67000013
         LA    RI,1(RI,RF)              BUMP TARGET ADDRESS             68000013
ENDRT    TM    WSWC,FILL                TEST FILL SWITCH                69000013
         BZ    PRVOP                    BRANCH IF NOT SET               70000013
         LTR   RH,RH                                                    71000013
         BZ    PRVOP                    BRANCH IF NO FILL NEEDED        72000013
MOVE0    MVI   0(RI),C' '               PAD TARGET WITH BLANK           73000013
         NI    WSWC,255-FILL            RESET FILL SWITCH               74000013
         BCT   RH,CLEAR                 TEST FOR FILL LENGTH OF ONE     75000013
PRVOP    L     DR,OFDR(DR)              RESET SAVE AREA POINTER         76000013
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       77000013
         BR    LR                       EXIT                            78000013
CLEAR    LR    RJ,RI                    SET FIRST BLANK AS SOURCE       79000013
         LA    RI,1(RI)                 SET NEXT BYTE AS TARGET         80000013
         LR    RF,RH                    SET UP LENGTH                   81000013
         B     TESTS                    GO TO MOVE A CHARACTER FIELD    82000013
MV256    LH    RE,K255                  SET LENGTH OF MOVE              83000013
         EX    RE,MVCIN                 MOVE SOURCE TO TARGET           84000013
         LA    RJ,256(RJ)               BUMP SOURCE AND TARGET          85000013
         LA    RI,256(RI)               STRING ADDRESSES.               86000013
         B     TESTS                    LOOP                            87000013
SETCL    STH   RF,6(RC)                 SET CURRENT LENGTH OF TARGET.   88000013
         B     TESTS                                                    89000013
MVCIN    MVC   0(0,RI),0(RJ)            EXECUTED MOVE CHARACTER.        90000013
K256     DC    H'256'                                                   91000013
K255     DC    H'255'                                                   92000013
ZERO     EQU   X'00'                                                    93000013
VARY     EQU   X'10'                                                    94000013
FILL     EQU   X'01'                                                    95000013
       END                                                              96000013
