VSD      TITLE '   IHEVSD    CHARACTER STRING TO BIT STRING            *00500013
               O/S 360 PL/1 LIBRARY'                                    01000013
*   VERSION    SECOND VERSION OF F-LEVEL PL/1 COMPILER                  01500013
*                                                                       02000013
*   STATUS     CHANGE LEVEL - 0                                         02500013
*                                                                       03000013
*   SIZE       416 BYTES                                                03500013
*                                                                       04000013
*   FUNCTION   TO CONVERT A FIXED OR VARYING CHARACTER STRING TO A      04500013
*              FIXED OR VARYING BIT STRING                              05000013
*                                                                       05500013
*   ENTRY POINTS                                                        06000013
*              IHEVSDA - INITIALISE ON SOURCE INFORMATION               06500013
*                        AND THEN CONVERT                               07000013
*                  RA = A(SOURCE SDV)                                   07500013
*                  RB = A(SOURCE DED)                                   08000013
*                  RC = A(TARGET SDV)                                   08500013
*                  RD = A(TARGET DED)                                   09000013
*              IHEVSDB - CONVERSION ONLY,ARGUMENTS AS FOR IHEVSDA       09500013
*                                                                       10000013
*   INPUT      N/A                                                      10500013
*                                                                       11000013
*   OUTPUT     N/A                                                      11500013
*                                                                       12000013
*   EXTERNAL MODULES                                                    12500013
*              N/A                                                      13000013
*                                                                       13500013
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              14000013
*              ERROR  - CALLS IHEERRB TO RAISE CONVERSION ERROR         14500013
*   TABLES/WORK AREA                                                    15000013
*              WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)         15500013
*                                                                       16000013
*   ATTRIBUTES READ ONLY AND REENTRANT                                  16500013
*                                                                       17000013
*   PRIVATE MACROS                                                      17500013
*              IHELIB,IHEPRV,IHESDR                                     18000013
*                                                                       18500013
*   ASSEMBLY REQUIREMENTS                                               19000013
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   19500013
*              SUPPORT E.G. O/S 360 F-ASSEMBLER.                        20000013
*                                                                       20500013
*   NOTES      SEE OS/360 PL1 LIBRARY PLM FOR DESCRIPTION OF LIBRARY    21000013
*              CONVENTIONS AND STANDARDS                                21500013
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    22000013
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    22500013
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  23000013
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  23500013
*              CONSTANTS,BY REASSEMBLY,WILL RESULT IN A CORRECT MODULE  24000013
*              FOR THE NEW DEFINITIONS.                                 24500013
IHEVSD   CSECT                                                          25000013
         IHELIB                                                         25500013
IHEZLW0  DSECT                                                          26000013
         DS    15D                                                      26500013
WORK     EQU   IHEZLW0                                                  27000013
IHEVSD   CSECT                                                          27500013
         ENTRY IHEVSDA                                                  28000013
         ENTRY IHEVSDB                                                  28500013
         USING IHEZLCA,WR                                               29000013
         USING IHEZLW0,DR                                               29500013
IHEVSDA  NOPR  0                                                        30000013
IHEVSDB  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          30500013
         BALR  RE,0                     SET UP ADDRESSABILITY           31000013
         USING *,RE                                                     31500013
         TM    OFBR+3(DR),X'02'         TEST ENTRY POINT                32000013
         IHESDR LW0,WR                  UPDATE SAVE AREA POINTER        32500013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  33000013
         BO    SADSV                    BRANCH IF SECOND ENTRY POINT    33500013
         LA    LR,RETRY                 STORE RETRY ENTRY POINT AND     34000013
         STM   DR,LR,WCNV               SAVE AREA ADDRESS IN LCA        34500013
         MVC   WOFD(8),0(RA)            SAVE ON SOURCE INFORMATION      35000013
SADSV    MVC   PWORK+4(4),0(RA)         SAVE STRING ADDRESS             35500013
         MVI   WSWC,0                   RESET SWITCHES                  36000013
         L     RH,0(RC)                 GET TARGET ADDRESS              36500013
         LR    RI,RH                    GET BIT                         37000013
         SLDL  RH,3                     ADDRESS                         37500013
         ST    RH,PWORK+8               SAVE IN WORKSPACE               38000013
         LH    R0,6(RA)                 GET SOURCE CURRENT LENGTH       38500013
         LH    LR,4(RC)                 GET TARGET MAX LENGTH           39000013
         CR    R0,LR                    COMPARE LENGTHS                 39500013
         BNH   TESVR                    BRANCH SOURCE NOT LONGER        40000013
         LR    R0,LR                    SET SOURCE EQUAL TO TARGET MAX  40500013
TESVR    TM    0(RD),VARY               TARGET FIXED OR VARYING         41000013
         BO    SETCL                    BRANCH IF VARYING               41500013
         CR    R0,LR                    COMPARE LENGTHS                 42000013
         BE    TESTS                    BRANCH IF EQUAL                 42500013
         LR    RH,LR                    CALCULATE DIFFERENCE BETWEEN    43000013
         SR    RH,R0                    SOURCE AND TARGET LENGTHS       43500013
         ST    RH,PWORK                 STORE IN WORKSPACE              44000013
         OI    WSWC,FILL                SET FILL SWITCH                 44500013
TESTS    CH    R0,K064                  COMPARE LENGTH WITH SIXTY FOUR  45000013
         BH    SET64                    BRANCH IF SOURCE LONGER THAN 64 45500013
         LR    RD,R0                    SET COUNT EQUAL SOURCE LENGTH   46000013
GETCC    SR    RF,RF                    ZERO                            46500013
         LR    RG,RF                    ACCUMULATORS                    47000013
         SR    R0,RD                    DECREMENT SOURCE LENGTH BY CNT. 47500013
         LCR   RH,RD                    SAVE COUNT                      48000013
         L     RA,PWORK+4               LOAD SOURCE ADDRESS             48500013
         LTR   RD,RD                    TEST FOR SOURCE LENGTH OF ZERO  49000013
         BZ    STORA                    SKIP CHARACTER READING          49500013
GETCB    SLDL  RF,1                     GET ZERO                        50000013
         TM    WSWC,PADD                TEST PAD SWITCH                 50500013
         BO    DECMT                    BRANCH IF SET                   51000013
         CLI   0(RA),C'0'               SOURCE CHARACTER ZERO           51500013
         BE    COUNT                    YES,BRANCH                      52000013
         CLI   0(RA),C'1'               SOURCE CHARACTER ONE            52500013
         BNE   ERCON                    NO,BRANCH                       53000013
         O     RG,K001                  CHANGE ZERO TO ONE              53500013
COUNT    LA    RA,1(RA)                 BUMP SOURCE ADDRESS             54000013
DECMT    BCT   RD,GETCB                 LOOP UNTIL REQUIRED BITS STORED 54500013
STORA    ST    RA,PWORK+4               SAVE UPDATED SOURCE ADDRESS     55000013
         SLDL  RF,64(RH)                LEFT ADJUST COLLECTED BITS      55500013
         LCR   RD,RH                    RESTORE COUNT                   56000013
         L     RH,PWORK+8               LOAD TARGET BIT ADDRESS         56500013
         LR    RI,RH                    UPDATE TARGET.                  56800019
         AR    RI,RD                   BIT ADDRESS                      57100019
         ST    RI,PWORK+8               SAVE UPDATED TARGET ADDRESS     57500013
         SRDL  RH,5                     GET TARGET                      58000013
         SLL   RH,2                     WORK ADDRESS                    58500013
         SRL   RI,27                    AND OFFSET                      59000013
LOOP1    LR    RJ,RF                    COPY FIRST 32 BITS TO BE STORED 59500013
         SRL   RJ,0(RI)                 ALIGN BITS                      60000013
         L     LR,0(RH)                 GET WORD FROM TARGET            60500013
         LCR   RB,RI                    COMPLEMENT OFFSET               61000013
         SRL   LR,32(RB)                ZERO UNWANTED                   61500013
         SLL   LR,32(RB)                TARGET BITS.                    62000013
         OR    RJ,LR                    COMBINE RESULT AND TARGET BITS  62500013
         AR    RI,RD                    CALCULATE OFFSET & RESULT LNGTH 63000013
         CH    RI,K032                  EQUAL TO WORK LENGTH            63500013
         BE    STASH                    YES,BRANCH                      64000013
         BH    SLOOP                    BRANCH IF GREATER THAN WORK LEN 64500013
         LCR   RI,RI                    COMPLEMENT ACTUAL LENGTH        65000013
         SRL   RJ,32(RI)                ZERO BITS                       65500013
         SLL   RJ,32(RI)                BEYOND DATUM                    66000013
         L     LR,0(RH)                 GET TARGET WORD                 66500013
         LCR   RI,RI                    GET OFFSET                      67000013
         SLL   LR,0(RI)                 ZERO UNWANTED BIT               67500013
         SRL   LR,0(RI)                 IN TARGET WORD                  68000013
         OR    RJ,LR                    COMBINE RESULT WITH TARGET BITS 68500013
STASH    ST    RJ,0(RH)                 STORE WORD IN TARGET STRING.    69000013
         LTR   R0,R0                    TEST SOURCE LENGTH              69500013
         BNZ   TESTS                    BRANCH IF NOT ZERO              70000013
         TM    WSWC,PADD                TEST PAD SWITCH                 70500013
         BO    ENDRT                    BRANCH IF SET                   71000013
         TM    WSWC,FILL                TEST FILL SWITCH                71500013
         BZ    ENDRT                    BRANCH NOT SET                  72000013
         L     R0,PWORK                 SET LENGTH EQUAL TO FILL AMOUNT 72500013
         OI    WSWC,PADD                SET PAD SWITCH                  73000013
         B     TESTS                    LOOP                            73500013
SLOOP    ST    RJ,0(RH)                 STORE WORD IN TARGET STRING     74000013
         LA    RH,4(RH)                 BUMP WORD ADDRESS               74500013
         SLDL  RF,32(RB)                REALI N RESULT                  75000013
         LA    LR,32(RB)                DECREMENT                       75500013
         SR    RD,LR                    DATUM LENGTH                    76000013
         SR    RI,RI                    ZERO OFFSET                     76500013
         B     LOOP1                    LOOP                            77000013
RETRY    L     LR,OFDR(DR)              RESTORE ORIGINAL                77500013
         LM    RA,RD,OFRA(LR)           PARAMETERS AND                  78000013
         B     SADSV                    TRY AGAIN                       78500013
ENDRT    L     DR,OFDR(DR)              RESET SAVE AREA POINTER         79000013
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS PARAMETERS      79500013
         BR    LR                       EXIT                            80000013
SET64    LA    RD,64                    SET COUNT EQUAL SIXTY FOUR      80500013
         B     GETCC                    GO TO SCAN SOURCE               81000013
SETCL    STH   R0,6(RC)                 SET CURRENT LENGTH OF TARGET    81500013
         B     TESTS                                                    82000013
ERCON    ST    RA,WOCH                  SAVE ERROR ADDRESS              82500013
         IHEPRV ERR,RA,OP=LA            GET ADDRESS OF ERROR CODE       83000013
         OI    0(RA),CONV               SET FOR CONVERSION ERROR        83500013
         OI    1(RA),CHBT               SET UP CHAR TO BIT TYPE SOURCE  84000013
         L     BR,ERRB                  CALL EXECUTION                  84500013
         BALR  LR,BR                    ERROR PACKAGE                   85000013
         L     RA,WOCH                  RESTORE SCAN ADDRESS            85500013
         B     COUNT                    CONTINUE                        86000013
ERRB     DC    V(IHEERRB)                                               86500013
K001     DC    F'1'                                                     87000013
K032     DC    H'032'                                                   87500013
K064     DC    H'064'                                                   88000013
ZERO     EQU   X'00'                                                    88500013
CHBT     EQU   X'05'                                                    89000013
VARY     EQU   X'10'                                                    89500013
FILL     EQU   X'01'                                                    90000013
PADD     EQU   X'02'                                                    90500013
IOBT     EQU   X'80'                                                    91000013
SIZE     EQU   X'20'                                                    91500013
CONV     EQU   X'40'                                                    92000013
PWORK    EQU   WORK+72                                                  92500013
         END                                                            93000013
