VSF      TITLE '   IHEVSF    BIT STRING TO PICTURE CHARACTER STRING    *00800013
               O/S 360 PL/1 LIBRARY'                                    01600013
*   STATUS     CHANGE LEVEL - 0                                         02400013
*   SIZE       264 BYTES                                                03200013
*   FUNCTION   TO CONVERT A FIXED OR VARYING BIT STRING TO A            04000013
*              PICTURED CHARACTER STRING                                04800013
*                                                                       05600013
*   ENTRY POINTS                                                        06400013
*              IHEVSFA                                                  07200013
*                  RA = A(SOURCE SDV)                                   08000013
*                  RB = A(SOURCE DED)                                   08800013
*                  RC = A(TARGET SDV)                                   09600013
*                  RD = A(TARGET DED)                                   10400013
*                                                                       11200013
*   INPUT      N/A                                                      12000013
*                                                                       12800013
*   OUTPUT     N/A                                                      13600013
*                                                                       14400013
*   EXTERNAL MODULES                                                    15200013
*              N/A                                                      16000013
*                                                                       16800013
*   EXITS      NORMAL - RETURN TO CALLER VIA LINK REGISTER              17600013
*              ERROR  - CALLS IHEERRC IF PICTURE DISALLOWS DATA         18400013
*   TABLES/WORK AREA                                                    19200013
*              WORK AREA IS OBTAINED FROM DYNAMIC STORAGE (LWS)         20000013
*                                                                       20800013
*   ATTRIBUTES READ ONLY AND REENTRANT                                  21600013
*   NOTES      SEE OS/360 PL1 LIBRARY PLM FOR DESCRIPTION OF LIBRARY    22400013
*              CONVENTIONS AND STANDARDS                                23200013
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    24000013
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    24800013
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  25600013
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  26400013
*              CONSTANTS,BY REASSEMBLY,WILL RESULT IN A CORRECT MODULE  27200013
*              FOR THE NEW DEFINITIONS.                                 28000013
IHEVSF   CSECT                                                          28800013
         IHELIB                                                         29600013
IHEZLW0  DSECT                                                          30400013
         DS    15D                                                      31200013
WORK     EQU   IHEZLW0                                                  32000013
IHEVSF   CSECT                                                          32800013
         ENTRY IHEVSFA                                                  33600013
         USING *,BR                                                     34400013
         USING IHEZLCA,WR                                               35200013
         USING IHEZLW0,DR                                               36000013
IHEVSFA  STM   LR,WR,OFLR(DR)           SAVE CALLERS REGISTERS          36800013
         IHESDR LW0,WR                  UPDATE SAVE AREA POINTER        37600013
         IHEPRV ,WR                     GET COMMUNICATION AREA ADDRESS  38400013
         MVI   WSWC,0                                                   39200013
         L     RG,0(RA)                 GET SOURCE ADDRESS.             40000013
         L     RH,0(RC)                 GET TARGET ADDRESS.             40800013
         LH    RE,6(RA)                 GET CURRENT LENGTH OF SOURCE    41600013
         LH    RF,4(RC)                 GET MPX LENGTH OF TARGET        42400013
         CR    RE,RF                    COMPARE LENGTHS.                43200013
         BH    INT00                    BRANCH IF SOURCE TOO LONG       44000013
         LR    RI,RE                    SET SOURCE LENGTH FOR MOVE.     44800013
         BE    MOVE0                    BRANCH IF EQUAL                 45600013
         OI    WSWC,PADD                SET PADD SWITCH                 46400013
         B     MOVE0                                                    47200013
ENDRT    L     DR,OFDR(DR)              RESET SAVE AREA POINTER         48000013
         LM    LR,WR,OFLR(DR)           RESTORE CALLERS REGISTERS       48800013
         BR    LR                       EXIT                            49600013
INT00    LR    RI,RF                    SET SOURCE EQUAL TARGET MAX     50400013
MOVE0    SR    RF,RE                    SET UP FILL LENGTH              51200013
         LTR   RI,RI                    TEST SOURCE LENGTH              52000013
         BZ    SWT00                    BRANCH IF NULL                  52800013
         LA    RE,3(RD)                 GET ADDRESS OF PICTURE          53600013
         SR    RB,RB                    TURN BIT OFFSET INTO MASK       54400013
         LR    RC,RG                    COPY SOURCE ADDRESS             55200013
         SLDL  RB,3                     GET BIT OFFSET                  56000013
         LA    RJ,128                   SET MASK                        56800013
         SRL   RJ,0(RB)                 ANITIALISE MASK                 57600013
LOOP1    CLI   0(RE),C'A'               TEST FOR VALID PICTURE.         58400013
         BE    ERCAL                    BRANCH IF INVALID PICTURE       59200013
MZERO    MVI   0(RH),C'0'               SET TARGET CHARACTER ZERO       60000013
         EX    RJ,TMSK                  TEST SOURCE BIT                 60800013
         BZ    NOTON                    BRANCH IF ZERO                  61600013
         MVI   0(RH),C'1'               SET TARGET TO ONE.              62400013
NOTON    LA    RE,1(RE)                 UPDATE PICTURE POINTER          63200013
         LA    RH,1(RH)                 UPDATE TARGET POINTER.          64000013
         SRA   RJ,1                     MOVE MASK.                      64800013
         BNZ   BRCNT                    BRANCH TILL END OF BYTE         65600013
         LA    RJ,128                   RESET MASK                      66400013
         LA    RG,1(RG)                 UPDATE SOURCE POINTER.          67200013
BRCNT    BCT   RI,LOOP1                 BRANCH TILL SOURCE CONVERTED    68000013
SWT00    TM    WSWC,PADD                TEST FILL SWITCH                68800013
         BZ    ENDRT                    BRANCH NOT SET                  69600013
SH000    MVI   0(RH),C' '               SET FIRST BLANK                 70400013
         BCT   RF,MORE1                 REDUCE AND TEST PAD COUNT       71200013
         B     ENDRT                   ONLY ONE FILL CHARACTER NEEDED   72000013
MORE1    CH    RF,K256                  COMPARE FILL LENGTH WITH 256    72800013
         BNH   DOFIL                    BRANCH LESS OR EQUAL 256        73600013
         LA    RA,255                   MOVE 256 BLANKS                 74400013
         EX    RA,MVCH                  INTO TARGET                     75200013
         SH    RF,K256                  DECREMENT FILL AMOUNT           76000013
         LA    RH,256(RH)               BUMP TARGET ADDRESS             76800013
         B     MORE1                    LOOP                            77600013
DOFIL    BCTR  RF,0                     GET LENGTH OF REMAINDER         78400013
         EX    RF,MVCH                  MOVE REMAINING BLANKS TO TARGET 79200013
         B     ENDRT                    GO TO END OF JUB ROUTINE        80000013
TMSK     TM    0(RG),0                  EXECUTED TEST SOURCE BIT        80800013
MVCH     MVC   1(0,RH),0(RH)            EXECUTED BLANK TARGET           81600013
ERCAL    L     BR,ERRC                  CALL EXECUTION                  82400013
         BALR  RA,BR                    ERROR PACKAGE                   83200013
         DC    X'0406'                                                  84000013
ERRC     DC    V(IHEERRC)                                               84800013
K001     DC    H'1'                                                     85600013
K256     DC    H'256'                                                   86400013
PADD     EQU   X'01'                                                    87200013
ZERO     EQU   X'00'                                                    88000013
CONV     EQU   X'40'                                                    88800013
         END                                                            89600013
