ZZC      TITLE 'IHEZZC - CONTROL ROUTINE FOR IHEDUMP OUTPUT            /00300015
               OS/360 PL/I LIBRARY'                                     00600015
*   VERSION    FOURTH VERSION OF F-LEVEL PL/1 COMPILER.                 00604015
*                                                                       00608015
*   STATUS     CHANGE LEVEL - 4                                         00612015
*                                                                       00616015
*APARS FIXED                                                            00616201
*                                                                       00616401
*        H237                                                           00616556
*   21.6       C595600                                        CAS 45960 00616656
*                                                                       00616801
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC000-TSS 00616919
*   SIZE       2872 BYTES - BUT MAY BE SCATTER LOADED -                 00617015
*               GIVING CONTROL SECTIONS OF -                            00618015
*               1328 BYTES,                                             00619015
*               520 BYTES,                                              00620015
*               896 BYTES AND                                           00621015
*               128 BYTES.                                              00622015
*                                                                       00628015
*   FUNCTION                                                            00632015
*              1. TO ORGANISE DUMP OUTPUT.                              00636015
*              2. TO OPEN FILE PL1DUMP.                                 00640015
*              3. TO OUTPUT INFORMATION ABOUT FILES.                    00644015
*              4. TO CALL IHEZZF                                        00648015
*              5. TO INVOKE SNAP MACRO.                                 00652015
*        ----------------------------------------------------ZZC000-TSS 00654019
*                                                                       00656015
*   ENTRY POINTS                                                        00660015
*              IHEZZCA                                                  00664015
*                                                                       00668015
*   INPUT                                                               00672015
*              NONE                                                     00676015
*                                                                       00680015
*   OUTPUT                                                              00684015
*              SNAP DUMP (SEE FUNCTION).                                00688015
*                                                                       00692015
*   EXTERNAL MODULES                                                    00696015
*              IHEZZFA VIA LOAD AND CALL.                               00700015
*                                                                       00704015
*   SUPERVISOR MACROS.                                                  00708015
*              ABEND                    EXTRACT                         00712015
*              CHAP                    FREEMAIN                         00716015
*              CHECK                   GETMAIN                          00720015
*              CLOSE                   LOAD                             00724015
*              DCB                     OPEN                             00728015
*              DCBD                    SNAP                             00732015
*              DELETE                  SPIE                             00736015
*              DEQ                     WRITE                            00740015
*              DEVTYPE                 WTO                              00744015
*              ENQ                                                      00748015
*                                                                       00752015
*   EXITS                                                               00756015
*              NORMAL                                                   00760015
*               RETURN                                                  00764015
*              ABNORMAL                                                 00768015
*               ABEND WITH DUMP AND STEP OPTIONS.                       00772015
*                                                                       00776015
*   TABLES/WORK AREA                                                    00780015
*              NONE                                                     00784015
*                                                                       00788015
*   ATRIBUTES  READ ONLY AND REENTRANT                                  00792015
*                                                                       00796015
*   PRIVATE MACROS                                                      00800015
*              IHELIB, IHEZAP, IHEZZZ                                   00804015
*                                                                       00808015
*   ASSEMBLY REQUIREMENTS                                               00812015
*              MUST BE ASSEMBLED BY AN ASSEMBLER WITH PSEUDO-REGISTER   00816015
*              E.G. O/S360 F-ASSEMBLER.                                 00820015
*                                                                       00824015
*   NOTES                                                               00828015
*              SEE OS/360 PL/1 LIBRARY PLM FOR DESCRIPTION OF           00832015
*              LIBRARY CONVENTIONS AND STANDARDS.                       00836015
*              THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL    00844015
*              REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS    00848015
*              EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING  00852015
*              HAS BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER''  00860015
*              CONSTANTS, BY REASSEMBLY, WILL RESULT IN A               00864015
*              CORRECT MODULE FOR THE NEW DEFINITIONS.                  00868015
         EJECT                                                          00872015
IHEZZC   CSECT                                                          00900015
         ENTRY IHEZZCA                                                  01200015
         IHELIB                                                         01500015
         IHEZAP                                                         01800015
         IHEZZZ                                                         02300015
EQDQ     EQU   OPNL+4                                                   02500016
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC001-TSS 02600019
DEVT     EQU   DIAG                                                     02800015
         DCBD  DSORG=BS                                                 03300015
*        ----------------------------------------------------ZZC001-TSS 03500019
COMP     EQU   EMCP                                                     03800015
EJCT     EQU   C'1'                                                     04300015
SPC2     EQU   C'0'                                                     04800015
BLNK     EQU   C' '                                                     05300015
UNRC     EQU   X'08'                                                    05800015
P40S     EQU   X'08'                                                    06300015
P44S     EQU   X'0A'                                                    06800015
OPEN     EQU   X'10'                                                    07300015
PRTR     EQU   0                   TEMP TEMP                            07800015
* PRV                                                                   09300015
* FLAGS                                                                 09600015
MPRV     EQU   X'29'                    MOTHER PRV/ONLY PRV(NON-TASK).  09900015
DPR1     EQU   X'2D'                    DAUGHTER TASK PRV,NO ON+SLOTS.  10200015
DPR2     EQU   X'2F'                    DAUGHTER TASK PRV, ON-SLOTS.    10500015
* OFFSETS AFTER PR'S(FROM END OF PR'S-8)                                10800015
ODSA     EQU   8                                                        10900015
OPRV     EQU   12                       POINTER TO PREVIOUS PRV-VDA.    11100015
OFTV     EQU   16                       POINTER TO TASK VARIABLE.       11400015
* TASK VARIABLE                                                         11700015
TPRV     EQU   0                        POINTER TO PRV-VDA FOR TASK.    12000015
TTCB     EQU   4                        POINTER TO OS/TCB FOR TASK.     12300015
TSYM     EQU   8                                                        12370015
TLIM     EQU   16                       LIMIT PRIORITY.                 12440015
TPRI     EQU   18                       CURRENT PRIORITY.               12510015
TFCH     EQU   X'14'                    POINTER-NEXT T.V. IN CHAIN.     12600015
TBCH     EQU   X'18'                    POINTER-PREVIOUS T.V/PRV-VDA.   12900015
* WORK FLAGS                                                            13200015
ENDT     EQU   X'01'                    END OF DUMP FLAG.               13500015
PRER     EQU   X'01'                                                    13800015
DUMP     EQU   0                        DUMP AND TERMINATE STEP.        14100015
DUMC     EQU   2                        DUMP TASK AND CONTINUE.         14400015
DUMJ     EQU   4                        DUMP STEP AND CONTINUE.         14700015
DUMT     EQU   6                        DUMP AND TERMINATE TASK.        15000015
OFCF     EQU   8                        OFFSET TO CHAIN FORWARD IN SA.  15300015
*      OFFSETS IN TCB AND RB.                                           15340015
TCBRBP   EQU   0                        POINTER TO LAST RB.             15380015
XSTAB    EQU   10                       RB FLAG CODE.                   15420015
XRBLNK   EQU   28                       POINTER TO PREVIOUS RB.         15460015
XRBREG   EQU   32                       START OF REGISTER SAVE AREA.    15500015
         EJECT                                                          15540015
IHEZZC   CSECT                                                          15600015
IHEZZCA  STM   LR,PR,OFLR(DR)           SAVE CALLER'S REGISTERS         15900015
         BALR  WR,0                                                     16200015
         USING *,WR                     ESTABLISH ADDRESSIBILITY.       16500015
         LA    R0,LWRK+12          LENGTH OF WORKSPACE                  16800016
         LR    RB,RA                                                    17100015
         LR    RC,R0                                                    17400015
         GETMAIN R,LV=(0)               GET WORKSPACE.                  17700015
         ST    DR,4(RA)                 SET CHAIN BACK.                 18000015
         ST    RC,0(RA)                 SAVE LENGTH.                    18300015
         LR    DR,RA                    SET ADDRESS OF MAIN SAVE AREA.  18600015
         USING WORK,DR                                                  18900015
         MVI   SAV2,X'FF'               SET FLAG FOR SUBROUTINE SA.     18940015
         NI    FLAG2,0                                                  18980015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC002-TSS 19000019
         SPIE  SPEXT,((1,15))           HANDLE ALL PROGRAM INTERRUPTS.  19020015
         ST    RA,SPIA                  SAVE PREVIOUS PICA.             19060015
         MVC   APBFA(12),APUTS          SET ADDRESSES OF OUTPUT RTNE    19100015
*        ----------------------------------------------------ZZC002-TSS 19120000
         NI    FLAG3,0                  CLEAR WRITE/CHECK FLAGS.        19140015
         MVC   PARM(LPRM),0(RB)         STORE PARMS.                    19500015
         LR    RB,PR                                                    22800015
         SH    RB,H008                  ADDRESS PRV VDA.                23100015
         ST    RB,SVPR                  SAVE CURRENT PRV PTR.           23400015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC003-TSS 23500019
         TM    1(RB),X'80'              TEST FOR TASKING ENV.           23700015
         BZ    MTHER                    NO.                             24000015
         MVC   EQDQ(12),QLIST      PLIST FOR ENQ/DEQ                    24050016
         ENQ   MF=(E,EQDQ)              ENSURE EXCLUSIVE USE OF PL1DUMP 24100015
         OI    FLAG2,X'08'                                              24400015
         LH    BR,LNPR             LOAD LEN OF PRV                      24600001
         LA    BR,3(BR)                                                 24900015
         N     BR,M004                                                  25200015
         STH   BR,LNPR             STORE LEN OF PRV                     25500001
         TM    ENTP,DUMC                TASK ONLY..                     25800015
         BO    MTHER                    YES, SNAP ONLY FOR THIS TASK.   26100015
BACKP    CLI   0(RB),MPRV               TEST FOR MAJOR TASK.            26400015
         BE    MTHER                    YES.                            26700015
         CLI   0(RB),DPR1               DAUGHTER TASK (NO ON)..         27300015
         BE    CNTNU                    YES                             27600015
         CLI   0(RB),DPR2               DAUGHTER TASK (ON)..            27900015
         BNE   PRVER                 ** NO, SOMETHING WRONG.            28200015
CNTNU    EQU   *                                                        28400001
         AH    RB,LNPR             ADD LEN OF PRV                       28600001
         L     RB,OPRV(RB)              ADDRESS PREVIOUS PRV VDA AND    28800015
         B     BACKP                     SEARCH FOR MAJOR TASK PRV VDA. 29100015
*        ----------------------------------------------------ZZC003-TSS 29150019
MTHER    ST    RB,PRVA                  SAVE ADDRESS PRV FOR TASK.      29200015
         NI    FLAG2,X'F7'                                              29300015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC999-TSS 29350000
         L     BR,VZZCB                 OPEN PL1DUMP FILE.              29400015
         BALR  LR,BR                                                    29700015
*        ----------------------------------------------------ZZC999-TSS 29750000
         TM    ENTP,X'F9'               ANY DRASTIC ERRORS..            29800015
         BO    EXITN                    YES - FILE COULD NOT BE OPENED. 29900015
         TM    ENTP,PRER                WAS THERE AN ERROR IN THE PRV   30000015
         BO    PRVRR                 **  FLAGS.. YES COMMENT AND ABEND. 30300015
LOADE    EQU   *                                                        30500015
         OI    FLAG2,X'08'                                              30700015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC004-TSS 30800019
         TM    1(RB),X'80'              TEST FOR TASKING.               30900015
         BZ    FILES                    NO.                             31200015
         TM    ENTP,DUMC                TASK ONLY..                     31500015
         BO    PTASK                    YES, OUTPUT FOR CURRENT TASK    31800015
NEXTC    L     RC,OFDR(RB)              ADDRESS ESA TO TASK             32100015
NXTDS    L     RC,OFCF(RC)              ADDRESS NEXT DSA DOWN.          32400015
         LTR   RC,RC                    END OF DSA CHAIN..              32700015
         BZ    PTASK                    YES, RB=PRV-VDA FOR LOWEST TASK 32800015
         TM    0(RC),X'80'              TEST IF WE ARE STILL IN A DSA.  32900015
         BZ    PTASK                    NO. MUST BE A LIB SA.           33000015
         TM    96(RC),X'80'             COULD PROC CALL WITH TASK..     33300015
         BZ    NXTDS                    NEVER - TRY NEXT DSA.           33600015
         L     RD,100(RC)               ADDR FOR LAST TASK ATTACHED.    33900015
         LTR   RD,RD                    WERE ANY ATTACHED..             34200015
         BZ    NXTDS                    NO - TRY NEXT DSA.              34500015
NXTTV    L     RC,TFCH(RD)              ADDRESS NEXT TV IN CHAIN.       34800015
         LTR   RC,RC                    WAS THIS FIRST TASK ATTACHED..  35100015
         BZ    EXITT                    YES-END OF TASKS AT THIS LEVEL. 35400015
         LR    RD,RC                    NO - GET NEXT TV                35700015
         B     NXTTV                     IN CHAIN.                      36000015
EXITT    L     RB,TPRV(RD)              GO AND SEE IF THIS TASK IS THE  36300015
         LA    RB,0(RB)                                                 36400015
         B     NEXTC                     LOWEST LEVEL IN THIS CHAIN.    36600015
PTASK    MVC   LINE+5(L'THED),THED                                      36607015
         NI    FLAG2,X'F7'                                              36614015
         MVC   OUTL(L'CAST),CAST                                        36621015
         ST    RB,PRVA                  ADDR PRV FOR TASK BEING DUMPED  36624015
         LR    RC,RB                                                    36628015
         AH    RC,LNPR             ADD LEN OF PRV                       36635001
         L     RC,OFTV(RC)              ADDRESS TASK VARIABLE.          36642015
         CLI   0(RB),MPRV                                               36649015
         BE    PTHED                                                    36656015
         MVC   LINE+14(LTSK),TASK                                       36663015
         L     RD,TSYM(RC)                                              36670015
         LTR   RD,RD                    WAS A TASK NAME GIVEN..         36677015
         BZ    ATSTM                    NO.                             36684015
         SR    RE,RE                                                    36687015
         IC    RE,0(RD)                                                 36691015
         CH    RE,H031                  VALID TASK NAME..               36693015
         BH    GARBT                    DEFINITELY NOT.                 36695015
         BCTR  RE,0                                                     36698015
         EX    RE,MVTSK                                                 36705015
         B     ATSTM                                                    36706015
         SPACE                                                          36707015
GARBT    MVI   LINE+19,C'*'                                             36708015
         MVC   LINE+20(7),LINE+19                                       36709015
ATSTM    LR    RE,RB                                                    36712015
         AH    RE,LNPR             ADD LEN OF PRV                       36719001
         L     RE,ODSA(RE)              ADDRESS ATTACHOR DSA.           36726015
         TM    0(RE),X'40'              TEST FOR STATEMENT OPTION.      36733015
         BZ    PTHED                                                    36740015
         BAL   RG,PTBUF                 YES, OUTPUT TASK IDENT.         36747015
         MVC   LINE+11(L'CALD),CALD                                     36754015
         MVC   LINE+12+L'CALD(L'LEVL),LEVL                              36761015
         LR    RE,RB                                                    36768015
         AH    RE,LNPR             ADD LEN OF PRV                       36775001
         L     RE,OFTV(RE)              ADDRESS TASK VARIABLE.          36782015
         L     RE,12(RE)                ADDRESS EVENT VARIABLE          36789015
         USING IHEZEVT,RE                                               36796015
         LH    RE,EVST+2                PICK UP STATEMENT NUMBER.       36803015
         DROP  RE                                                       36810015
         CVD   RE,DECM                                                  36817015
         ED    LINE+12+L'CALD(L'LEVL),DECM+6  OUTPUT STMT NO.           36824015
PTHED    BAL   RG,PTBUF                                                 36831015
         MVC   LINE+10(LPRI),PRIO                                       36838015
         LH    RE,TPRI(RC)                                              36845015
         CVD   RE,DECM                                                  36852015
         ED    LINE+L'PRIO+10(6),DECM+5                                 36859015
         BAL   RG,PTBUF                                                 36866015
*        ----------------------------------------------------ZZC004-TSS 36916019
FILES    OI    FLAG2,X'04'                                              36966015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC998-TSS 37016000
         L     BR,VZZCC                 OUTPUTINFO ABOUT FILES.         37066015
         BALR  LR,BR                                                    37200015
*        ----------------------------------------------------ZZC998-TSS 37250000
FLRTN    NI    FLAG2,X'FB'                                              37300015
         NI    FLAG,X'01'                                               37400015
         SR    RD,RD                                                    37800015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC005-TSS 37900019
         TM    1(RB),X'80'              TASKING..                       38100015
         BZ    LRG13                    NO.                             38400015
         LR    RC,RB                                                    38700015
         AH    RC,LNPR             ADD LEN OF PRV                       39000001
         L     RC,OFTV(RC)              ADDRESS TASK VARIABLE.          39300015
         L     RD,TTCB(RC)              ADDRESS OS/TCB FOR TASK.        39600015
         LA    RB,0(RB)                                                 39700015
         CL    RB,SVPR                  IS THIS THE CURRENT PRV..       39900015
         BNE   XTRCT                    NO, GET REG 13 VIA TASK TCB.    40200015
*        ----------------------------------------------------ZZC005-TSS 40300019
LRG13    L     RE,RG13                  GET REG 13 AS PASSED.           40500015
TST13    TM    0(RE),X'FF'                                              40600015
         BM    CALLF                    OUTPUT TRACE.                   40700015
         L     RE,OFDR(RE)                                              40800015
         B     TST13                    LOOP BACK UNTIL PL1 SAVE AREA.  40900015
XTRCT    OI    FLAG,X'10'               THIS TASK DID NOT CALL IHEDUMP. 41000015
         L     BR,TCBRBP(RD)            PICK UP ADDRESS OF LAST RB.     41100015
         TM    XSTAB(BR),X'C0'          IS THIS RB A PRB..              41200015
         BZ    XTTCB                    YES.                            41300015
NXTRB    LR    LR,BR                                                    41400015
         L     BR,XRBLNK(BR)            PICK UP PREVIOUS RB.            41500015
         TM    XSTAB(BR),X'C0'          IS THIS RB A PRB..              41600015
         BO    NXTRB                    NO.                             41700015
         L     RE,XRBREG+13*4(LR)       PICK UP RG 13 FROM SVRB.        41800015
         B     TST13                    GO TO FIND LAST PL/1 SA.        41900015
XTTCB    L     RE,48+13*4(RD)           PICK UP RG13 FROM TCB.          42000015
         B     TST13                    GO TO FIND LAST PL/1 SA.        42050015
CALLF    ST    RE,LR13                                                  42100015
         OI    FLAG2,X'02'                                              42200015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC006-TSS 42250000
         L     BR,SVAD                  OUTPUT SAVE AREA TRACE.         42300015
         BALR  LR,BR                                                    42400015
SNAPT    NI    FLAG2,X'FD'                                              42500015
         OI    FLAG3,X'40'              SET FLAG FOR FINAL WAIT.        42600015
         BAL   RG,PWATE                                                 42700015
         MVI   FLAG3,0                  CLEAR FLAGS IN CASE WE LOOP.    42800015
         L     BR,VZZCE                 OUTPUT SNAP.                    43200015
         BALR  LR,BR                                                    43500015
         TM    ENTP,X'F9'               ANY TERMINAL ERRORS..           43600015
         BNZ   EXITR                    YES.                            43700015
         TM    ENTP,DUMC                ONLY DUMPING ONE TASK..         43800015
         BO    EXITR                    YES.                            44100015
         CLI   0(RB),MPRV               WAS THAT THE MOTHER TASK..      44150015
         BE    EXITR                    YES, END OF DUMP                44200015
         MVI   OUTL,EJCT                                                44250015
         BAL   RG,PTBUF                 POSITION TO NEW PAGE            44300015
         OI    FLAG2,X'08'                                              44350015
         AH    RB,LNPR             ADD LEN OF PRV                       44450001
         L     RC,OFTV(RB)              ADDR TASK VARIABLE.             44700015
         L     RC,TBCH(RC)              ADDR PREVIOUS 'TV' IN CHAIN.    45000015
         L     R0,TBCH(RC)              PICK UP BACK CHAIN.             45300015
         LTR   R0,R0                    IF ZERO THEN 'TV' IS PART OF    45600015
         BNZ   GTPRV                      ATTACHING DSA.                45900015
         L     RC,ODSA(RB)                                              46000015
         L     RB,OPRV(RB)              ADDRESS ATTACHING PRV.          46200015
         B     NXTDS                    GO AND LOOK NEXT DSA.           47200015
GTPRV    L     RB,TPRV(RC)              PICK UP PRV FOR TASK.           49200015
         B     NEXTC                    OUTPUT FOR NEW TASK.            49300015
         EJECT                                                          49400015
*     **       END OF THE DUMP ** ** ** CLEAN UP AND RETURN.            49500015
EXITR    LA    RH,DIAG                                                  49800015
         LA    R0,129                                                   49870015
         L     R1,BUFAD                                                 49940015
         FREEMAIN R,LV=(0),A=(1)        FREE BUFFER .                   50010015
         LA    RA,OPNL                                                  50030015
         CLOSE MF=(E,(1))               CLOSE PL1DUMP.                  50050015
         DELETE EP=IHEZZFA              DELETE MODULE IHEZZF.           50070015
         L     PR,SVPR                                                  50090015
         TM    1(PR),X'80'              TASKING..                       50110015
         BZ    EXITN                    NO.                             50130015
         TM    VERS,X'01'          TEST IF VERSION 5                    50140001
         BO    CONTL               THEN RELEASE CONTROL IN DUM          50150001
         AH    PR,LNPR             ADD LEN OF PRV                       50160001
         L     PR,OFTV(PR)                                              50170015
         LH    R0,TPRI(PR)                                              50174017
         SH    R0,TLIM(PR)                                              50178017
         L     PR,12(PR)                A(EV)                           50182017
         MVI   21(PR),0                 ZERO MCF.                       50186017
         CHAP  (0)                      RESTORE PRIORITY.               50190017
         TM    28(PR),X'80'          +  TASK WAITING.                   50194017
         BNO   TSTPR                 *  NO.                             50198017
         LA    RA,28(PR)                YES.                            50202017
         POST  (1)                                                      50206017
         LA    RA,24(PR)                                                50210017
         WAIT  ECB=(1)                                                  50214017
TSTPR    TM    24(PR),X'80'          +  PRIORITY WAITING.               50218017
         BZ    CONTL                 *  NO.                             50222017
         LA    RA,24(PR)                YES.                            50226017
         POST  (1)                                                      50230017
CONTL    EQU   *                                                        50234017
         DEQ   MF=(E,EQDQ)              RELEASE CONTROL OF PL1DUMP      50250015
EXITN    L     RA,SPIA                                                  50270015
         SPIE  MF=(E,(1))               RESTORE PICA                    50290015
*        ----------------------------------------------------ZZC006-TSS 50340019
         LR    RA,DR                                                    50400015
         L     DR,OFDR(DR)                                              50700015
         L     RB,OFRA(DR)              PASS FLAGS BACK TO IHEDUM       50800015
         MVC   ENTP-PARM(1,RB),ENTP-WORK(RA)                            50900015
         L     R0,0(RA)                                                 51000015
         FREEMAIN R,LV=(0),A=(1)        FREE WORK AREA.                 51300015
         LM    LR,PR,OFLR(DR)                                           51600015
         SR    BR,BR                                                    51900015
         BR    LR                       RETURN TO IHEDUM                51910015
         EJECT                                                          51920015
*        ** ** PROGRAM INTERRUPT HANDLER ** ** **                       51930015
         SPACE 2                                                        51940015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC06A-TSS 51945019
SPEXT    L     RB,8(R1)                                                 51950015
         MVC   9(3,R1),SPRRA            ACCEPT PROGRAM INTERRUPT.       51960015
         BR    LR                                                       51970015
*        ----------------------------------------------------ZZC06A-TSS 51975019
         SPACE                                                          51980015
SPERR    TM    0(DR),X'FF'              WERE WE IN A SUBROUTINE..       51990015
         BO    SUBS                     YES.                            52000015
         TM    FLAG2,X'08'              WERE WE SCANNING THE TASK CHAIN 52010015
         BO    PRVRR                    YES,  THERE IS SUMAT WRONG.     52020015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC007-TSS 52025019
ABEND    ABEND 3333,DUMP,STEP          CATASTROPHIC ERROR.              52030015
*        ----------------------------------------------------ZZC007-TSS 52035019
         SPACE 2                                                        52040015
SUBS     L     DR,OFDR(DR)              RESTORE DR TO MAIN SAVE AREA.   52050015
         TM    FLAG2,X'01'              OUTPUTTING DUMP ID..            52060015
         BZ    TRACE                    NO.                             52070015
         LA    BR,0                     SET ID TO ZERO                  52080015
         LA    DR,SAV2                  AND GO TO OUTPUT HEADING.       52090015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC997-TSS 52095000
         L     LR,ASTRD                                                 52100015
         BR    LR                                                       52110015
*        ----------------------------------------------------ZZC997-TSS 52115000
         SPACE                                                          52120015
TRACE    TM    FLAG2,X'02'              OUTPUTTING SAVE AREA TRACE..    52130015
         BO    TRERR                    YES.                            52140015
         TM    FLAG2,X'04'              OUTPUTTING INFO ABOUT FILES..   52150015
         BO    FLERR                    YES.                            52160015
         B     ABEND                    NO, A CATASTROPHIC ERROR.       52170015
         SPACE 2                                                        52180015
TRERR    BAL   RG,PTBUF                                                 52190015
         MVC   LINE+5(L'CHAN),CHAN      ERROR IN SAVE AREA TRACE.       52200015
         BAL   RG,PTBF3                                                 52210015
         LM    LR,WR,OFLR(DR)                                           52220015
         B     SNAPT                    GO AND GIVE SNAP DUMP FOR TASK. 52230015
         SPACE 2                                                        52240015
FLERR    BAL   RG,PTBUF                                                 52250015
         MVC   LINE+5(L'FLER),FLER      FILE ADDRESSING ERROR.          52260015
         BAL   RG,PTBF3                                                 52270015
         LM    LR,WR,OFLR(DR)                                           52280015
         B     FLRTN                    GO AND TRY TO OUTPUT SA TRACE.  52290015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC008-TSS 52295019
         SPACE 4                                                        52300015
PRVER    OI    ENTP,PRER                SET FLAG TO SHOW PRV ERROR.     52310015
         B     MTHER                                                    52320015
*        ----------------------------------------------------ZZC008-TSS 52325019
         SPACE                                                          52330015
PRVRR    MVC   LINE+5(L'PRRR),PRRR      ERROR IN PRV CHAIN.             52340015
         BAL   RG,PTBF3                                                 52350015
         OI    ENTP,X'F9'                                               52352015
         OI    FLAG3,X'40'                                              52354015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC009-TSS 52355019
         BAL   RG,PWATE                                                 52356015
*        ----------------------------------------------------ZZC009-TSS 52357019
         MVI   FLAG3,0                                                  52358015
         B     EXITR                                                    52360015
         EJECT                                                          52370015
*        PREAMBLE IF OUTPUT ROUTINE IS ENTERED FROM MAIN PART.          52380015
         SPACE 2                                                        52390015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC010-TSS 52395019
PWATE    LA    BR,PWAIT                 WAIT FOR LAST WRITE TO COMPLETE 52400015
         B     PTBFE                                                    52410015
*        ----------------------------------------------------ZZC010-TSS 52415019
PTBUF    LA    BR,PTBFA                 OUTPUT LINE AS IS               52420015
         B     PTBFE                                                    52430015
PTBF3    LA    BR,PTBFC                 OUTPUT LINE WITH TRIPLE SPACE.  52440015
PTBFE    ST    DR,SAV2+OFDR                                             52450015
         LA    DR,SAV2                  UPDATE DR.                      52460015
         BALR  RF,BR                   OUTPUT LINE.                     52470015
         L     DR,OFDR(DR)              RESTORE DR.                     52480015
         BR    RG                                                       52490015
         SPACE 4                                                        52500015
*        ROUTINE TO OUTPUT A LINE OF INFORMATION.                       52510015
         SPACE 2                                                        52520015
         USING SAV2,DR                                                  52530015
PTBFC    MVC   OUTL(L'CAST),CAST        SET TO TRIPLE SPACE AND ***     52540015
         B     PTBFA                                                    52550015
PTBFB    MVI   OUTL,SPC2                SET TO DOUBLE SPACE.            52560015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC011-TSS 52565019
PTBFA    TM    FLAG3,X'80'              SPACE SET - FIRST WRITE..       52570015
         BZ    NOCHK                    YES.                            52580015
PWAIT    EQU   *                                                        52590017
         CHECK DECB                     WAIT FOR COMPLETION OF WRITE    52610015
         TM    FLAG3,X'40'              WAIT ONLY..                     52620015
         BCR   7,RF                     YES, RETURN.                    52630015
NOCHK    L     RA,BUFAD                                                 52640015
         MVC   8(L'LINE+1,RA),OUTL      MOVE LINE TO BUFFER.            52650015
WRITE    WRITE DECB,SF,DIAG,MF=E     OUTPUT BUFFER.                     52660015
         TM    FLAG3,X'40'              WAS THIS THE LAST WRITE..       52670015
         BO    PWAIT                    YES, WAIT FOR COMPLETION.       52680015
         OI    FLAG3,X'80'              SET FLAG TO SHOW BLOCK OUTPUT.  52690015
*        ----------------------------------------------------ZZC011-TSS 52695019
         MVI   OUTL,BLNK                BLANK OUT                       52700015
         MVC   LINE,OUTL                LINE AND SET TO SINGLE SPACE.   52710015
         BR    RF                                                       52720015
         EJECT                                                          52730015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC012-TSS 52735019
         USING WORK,DR                                                  52740015
MVTSK    MVC   LINE+19(*-*),1(RD)                                       52750015
QLIST    ENQ   (PRIO,PRIO,,8),MF=L                                      52760016
*        ----------------------------------------------------ZZC012-TSS 52765019
PRRR     DC    C'ERROR IN PRV/TASK CHAIN'                               52770015
CHAN     DC    C'CHAINING ERROR'                                        52780015
FLER     DC    C'FILE ADDRESSING ERROR'                                 52790015
THED     DC    C'DUMP FOR MAJOR TASK      '                             52800015
CALD     DC    C'CALLED FROM STATEMENT'                                 52810015
TASK     EQU   THED+15                                                  52820015
LTSK     EQU   10                                                       52830015
PRIO     DC    C'PRIORITY ='                                            52840015
RITY     DC    X'402020202120'                                          52850015
LPRI     EQU   L'PRIO+L'RITY                                            52860015
CAST     DC    C'- ***'                                                 52870015
ENTY     DC    C'PCJT'                                                  52880015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC013-TSS 52885019
HEAD      DC    C'* * * OS/360 PL/I * IHEDUMP ID='                      52890015
*        ----------------------------------------------------ZZC013-TSS 52895019
LEVL     DC    X'40202120'                                              52900015
LAST     DC    C' * * *'                                                52910015
LHED     EQU   L'HEAD+L'LEVL+L'LAST                                     52920015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC996-TSS 52925000
SPRRA    DC    AL3(SPERR)                                               52930015
VBLK     DC    AL2(129,0,125,0)                                         52940015
APUTS    DC    A(PTBFA,PTBFB,PTBFC)                                     52950015
ASTRD    DC    A(STRID)                                                 52960015
*        ----------------------------------------------------ZZC996-TSS 53160000
H008     DC    H'8'                                                     53400015
H031     DC    H'31'                                                    53500015
M004     DC    F'-4'                                                    53700015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC014-TSS 53800019
VZZCB    DC    V(IHEZZCB)                                               54000015
VZZCC    DC    V(IHEZZCC)                                               54300015
VZZCE    DC    V(IHEZZCE)                                               54900015
         EJECT                                                          55200015
IHEZZCB  CSECT                                                          55500015
         STM   LR,PR,OFLR(DR)                                           55800015
         BALR  WR-1,0                                                   56100015
         USING *,WR-1                                                   56400015
*        ----------------------------------------------------ZZC014-TSS 56500000
         ST    DR,SAV2+OFDR                                             56700015
         LA    DR,SAV2                                                  57000015
         USING SAV2,DR                                                  57300015
         IC    BR,ENTP                                                  57320015
         N     BR,F006                                                  57340015
         SRL   BR,1                                                     57360015
         IC    BR,ENTY(BR)                                              57380015
         STC   BR,ENTC                  SET ENTRY POINT CODE.           57400015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC015-TSS 57410019
*      FIND OUT WHAT SORT OF DEVICE IS TO BE USED                       57420015
         LA    RE,PLID                  TRY PL1DUMP.                    57440015
DVTYP    LA    R0,DEVT                                                  57460015
         DEVTYPE (5),(0)                                                57480015
         LTR   BR,BR                    WAS THERE A DD CARD..           57500015
         BZ    DDFND                    YES GO TO OPEN FILE.            57520015
         OI   ENTP,X'F9'                NO,  GIVE ABEND DUMP.           57540015
         B     NDDDD                    NO DD CARD.                     57560015
DDFND    CLI   DEVT+2,UNRC              OUTPUT TO UNIT RECORD..         57580015
         BNE   SETBL                    NO.                             57600015
         CLI   DEVT+3,P40S              1400 SERIES PRINTER..           57620015
         BE    PRNTR                    YES.                            57640015
         CLI   DEVT+3,P44S              1440 SERIES PRINTER..           57660015
         BNE   SETBL                    NO,  WHAT IS IT THEN...         57680015
PRNTR    OI    FLAG,PRTR                SET TO PRINTER.                 57700015
SETBL    MVC   DIAG(LDCB),DCB           INITIALIZE DCB.                 57720015
         LA    RC,DIAG                                                  57740015
         LA    R0,129                                                   57760015
         GETMAIN R,LV=(0)               GET CORE FOR BUFFER.            57780015
         ST    RA,BUFAD                 SAVE ADDR FOR VARIOUS REASONS   57800015
         MVC   0(8,RA),VBLK                                             57820015
         ST    RC,OPNL                  SET ADDRESS OF DCB.             57840015
         MVC   OPNL(1),OPNX             SET OPEN FLAGS.                 57860015
         LA    R1,OPNL                  ADDRESS OPEN PARAMETER LIST     57880015
         OPEN  MF=(E,(1))               OPEN FILE FOR DUMP OUTPUT.      57900015
         USING IHADCB,RC                                                57920015
         TM    DCBOFLGS,OPEN            IS FILE OPEN..                  57940015
         BZ    NOPEN                    NO TERMINATE .                  57960015
         DROP  RC                                                       57980015
*        ----------------------------------------------------ZZC015-TSS 57990019
         MVI   OUTL,BLNK                                                58000015
         MVC   LINE,OUTL                                                58020015
         MVI   OUTL,EJCT                SET PAGE EJECT FOR FIRST LINE.  58040015
         MVC   LINE+40(LHED),HEAD       SET BASIC HEADING.              58060015
         OI    FLAG2,X'01'                                              58080015
         L     BR,SNPP                  ADDRESS (SNAP ID CODE.)         58100015
         LTR   BR,BR                    ANY PASSED..                    58120015
         BZ    STRID                    NO, ASSUME ZERO.                58140015
         L     BR,0(BR)                 ADDRESS CODE.                   58160015
         L     BR,0(BR)                 PICK UP CODE.                   58180015
         LA    LR,127                   MAXIMUM ID CODE.                58200015
         CLR   BR,LR                    GTR THAN MAXIMUM ALLOWED..      58220015
         BNH   STRID                    NO.                             58240015
         LR    BR,LR                    YES, RESTRICT TO MAXIMUM.       58260015
STRID    ST    BR,SNPP               SAVE FOR LATER USE.                58280015
         NI    FLAG2,X'FE'                                              58300015
         CVD   BR,DECM                  PREPARE TO OUTPUT SNAP ID.      58320015
         ED    LINE+40+L'HEAD(4),DECM+6 SET ID CODE.                    58340015
         MVC   LINE+66(1),ENTC          SAY WHICH ENTRY POINT USED.     58360015
         L     BR,APBFA                                                 58380015
         BALR  RF,BR                                                    58400015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC016-TSS 58410019
         LOAD  EP=IHEZZFA               BRING IN IHEZZF.                58420015
         ST    R0,SVAD                   AND SAVE ITS ADDRESS.          58440015
*        ----------------------------------------------------ZZC016-TSS 58540000
EXITO    L     DR,OFDR(DR)                                              58740015
         LM    LR,PR,OFLR(DR)                                           59100015
         BR    LR                                                       59400015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC017-TSS 59405019
         SPACE 4                                                        59410015
NDDDD    MVC   LINE+9(WTOL),WTOM                                        59420015
         MVC   LINE+29(1),ENTC          SAY WHICH ENTRY POINT USED.     59430015
         MVC   LINE(12),LINE+9                                          59440015
         EXTRACT LCAD,'S',FIELDS=(TIOT),MF=(E,DECM)                     59450015
         L     RA,LCAD                                                  59460015
         MVC   LINE+12(8),0(RA)         MOVE IN JOBNAME                 59470015
         LA    R1,LINE                                                  59480015
         WTO   MF=(E,(1))               NO DD CARD FOR PL1DUMP.         59490015
NOPEN    OI    ENTP,X'F9'                                               59500015
         B     EXITO                                                    59510015
F006     DC    F'6'                                                     59520015
WTOM     DS    0A                                                       59530015
         DC    AL2(WTOL+9)                                              59540015
         DC    AL2(0)                                                   59550015
         DC    C'IHE009I - IHEDUM . NO PL1DUMP DD CARD.'      CAS 45960 59556056
         DC    C'EXECUTION TERMINATED'                        CAS 45960 59562056
WTOL     EQU   *-WTOM                                                   59570015
DCB      DCB   RECFM=VBA,                                              /59700015
               MACRF=W,                                                /60000015
               BLKSIZE=882,                                            X60300001
               LRECL=125,                                              /60600015
               DSORG=PS,                                               /60900015
               DDNAME=PL1DUMP                                           61200015
         WRITE DWRIT,SF,DCB,MF=L                                        61500015
         SNAP  SDATA=(CB,Q),PDATA=(ALL),MF=L                            61800015
LDCB     EQU   *-DCB                                                    62100015
PLID     EQU   DCB+DCBDDNAM-IHADCB                                      62170015
OPNX     OPEN  (,(OUTPUT,LEAVE)),MF=L                                   62240015
         USING WORK,DR                                                  62310015
         EJECT                                                          62400015
IHEZZCC  CSECT                                                          62700015
         STM   LR,PR,OFLR(DR)                                           63000015
         BALR  WR-1,0                                                   63300015
         USING *,WR-1                                                   63600015
*        ----------------------------------------------------ZZC017-TSS 63700000
         ST    DR,SAV2+OFDR                                             63900015
         LA    DR,SAV2                                                  64200015
         USING SAV2,DR                                                  64500015
         L     RB,PRVA                  ADDRESS PRV FOR TASK.           64510015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC018-TSS 64510119
         LH    RD,QSPR                                                  64510215
         L     RD,8(RD,RB)              ADDRESS SYSPRINT FCB.           64510415
         LTR   RD,RD                    BUT IF NOT OPENED FORGET IT.    64510615
         BNP   ZENSP                                                    64510815
         MVC   LINE+5(LSYS),SYSP                                        64511015
         L     BR,APBFC                                                 64511215
         BALR  RF,BR                    OUTPUT SYSPRINT HEADING.        64511415
         USING IHEZAPE,RD                                               64511615
         TM    TFRC,TMUN                U-FORMAT..                      64511815
         BZ    ZENIT                    NO.                             64512015
         LH    RH,TMAX                  LENGTH OF RECORD.               64512215
         BCTR  RH,0                     FORGET ASA CONTROL.             64512415
         SH    RH,TREM                  NUMBER OF BYTES USED.           64512615
         BZ    ZENIT                    NONE - FORGET IT.               64512815
         LA    RH,1(RH)                 ALLOW FOR ASA CONTROL.          64513015
         MVC   LINE+1(L'INTR),INTR      INDICATE INT BUFFER.            64513215
         L     RE,TREC                                                  64513415
         L     BR,APBFB                 OUTPUT HEAD.                    64513615
         BALR  RF,BR                                                    64513815
         BAL   RG,PUTRC                 OUTPUT RECORD.                  64514015
ZENIT    L     RA,TDCB                                                  64514215
         USING IHADCB,RA                                                64514415
         L     RE,DCBBUFCB              ADDRESS BUFFER CTL BLOCK.       64514615
         DROP  RA                                                       64514815
         LH    RI,4(RE)                 NUMBER OF BUFFERS.              64515015
         LH    RH,6(RE)                 LENGTH OF EACH BUFFER.          64515215
         LA    RE,8(RE)                 ADDRESS OF FIRST BUFFER.        64515415
         SR    PR,PR                                                    64515615
NXTBF    LA    PR,1(PR)                 INCREMENT BUFF NO.              64515815
         LA    RA,LINE+4                                                64516015
         LR    BR,PR                                                    64516215
         BAL   LR,ZEADD                                                 64516415
         MVC   LINE+1(L'BUFF),BUFF                                      64516615
         MVI   LINE+7,BLNK                                              64516815
         L     BR,APBFB                 IDENTIFY BUFFER.                64517015
         BALR  RF,BR                                                    64517215
         LA    RG,NEXTB                                                 64517415
PUTRC    MVI   OUTL,SPC2                BLANK LINE FIRST TIME.          64517615
         LR    RC,RH                                                    64517815
COMPR    CH    RC,H120                                                  64518015
         BNH   MVREC                                                    64518215
         MVC   LINE,0(RE)               MOVE 120 BYTES.                 64518415
         L     BR,APBFA                  AND OUTPUT THIS PART.          64518615
         BALR  RF,BR                                                    64518815
         SH    RC,H120                                                  64519015
         LA    RE,120(RE)                                               64519215
         B     COMPR                    GO AND PUT REST.                64519415
         SPACE                                                          64519615
MVREC    BCTR  RC,0                     OUTPUT LAST BIT OF BUFFER.      64519815
         EX    RC,MVBUF                                                 64520015
         L     BR,APBFA                                                 64520215
         LR    RF,RG                    SET RETURN ADDRESS.             64520415
         BR    BR                                                       64520615
         SPACE                                                          64520815
NEXTB    LA    RE,1(RC,RE)                                              64521015
         BCT   RI,NXTBF                                                 64521215
         SPACE 2                                                        64521415
*        ----------------------------------------------------ZZC018-TSS 64521519
ZENSP    LH    RC,QCFL                                                  64521615
         L     RC,8(RC,RB)                                              64521815
         LA    RH,0(RC)                                                 64522015
         LTR   RH,RH                    IS THERE A CURRENT FILE..       64522215
         BZ    ZENCF                    NO.                             64522415
         L     RH,0(RD)                                                 64522615
         MVC   LINE+5(LCRF),CRFL                                        64522815
         L     BR,APBFC                 OUTPUT CURRENT FILE HEAD.       64523015
         BALR  RF,BR                                                    64523215
         LH    RI,0(RH)                                                 64523415
         L     RE,8(RI,RB)              PICK UP ADDR OF FCB.            64523615
         LA    RF,ZENCF                                                 64523815
         TM    TFTY,TMST                GET/PUT STRING..                64524015
         BNO   ZEPUT                    NO.                             64524215
         MVC   LINE+1(L'CSTR),CSTR                                      64524415
         LA    RA,LINE+23                                               64524615
         L     BR,TACM                                                  64524815
         BAL   LR,ZEADD                                                 64525015
         L     BR,APBFB                                                 64525215
         BR    BR                                                       64525415
         SPACE 2                                                        64525615
ZENCF    LR    RC,RB                                                    64525815
ZEFOP    LH    RD,QFOP                                                  64530015
         L     RD,8(RD,RC)              PICK UP FIRST FILE FROM IHEQFOP 64540015
         LTR   RD,RD                     BUT IF NONE WERE OPENED BY     64550015
         BZ    ZENFC                     THIS TASK  TRY THE NEXT TASK.  64560015
         CR    RC,RB                    IS THIS THE CURRENT TASK..      64570015
         BE    ZECTF                    YES.                            64580015
         NI    FLAG3,X'FE'              RESET SUBS TIME FLAG.           64590015
         USING IHEZAPE,RD                                               64600015
ZENXF    L     RE,TDCB                  ADDRESS DCB.                    64610015
         L     RH,TDCL                  ADDRESS DCLCB.                  64620015
         USING IHEZDCL,RH                                               64630015
         LH    RI,DPRO                  PR OFFSET TO FILE REGISTER.     64640015
         C     RD,8(RB,RI)              CHECK THAT FILE IS KNOWN TO     64650015
         BNE   ZENOF                     THE TASK BEING DUMPED.         64660015
         TM    FLAG3,X'01'              IS THIS THE FIRST ONE FOUND..   64670015
         BO    ZEPTF                    NO.                             64680015
         MVC   LINE+5(L'FKNN),FKNN      WE MUST IDENTIFY TASK.          64690015
         CLI   0(RC),MPRV               IS THIS THE MAJOR TASK..        64700015
         BNE   ZEDTT                    NO.                             64710015
         MVC   LINE+1+L'FKNN(L'MTSK),MTSK  SAY THAT IT IS MAJOR TASK    64720015
         B     ZENTN                                                    64730015
ZEDTT    LR    BR,RC                                                    64740015
         AH    BR,LNPR             ADD LEN OF PRV                       64750001
         L     BR,OFTV(BR)                                              64760015
         L     BR,TSYM(BR)              NAME OF TASK.                   64770015
         LTR   BR,BR                                                    64780015
         BZ    ZENTN                    THERE IS NO TASK NAME.          64790015
         SR    LR,LR                                                    64795015
         IC    LR,0(BR)                                                 64800015
         LTR   LR,LR               TEST LENGTH OF TASK NAME.      H237  64801001
         BZ    GARBZ               IF ZERO = INVALID              H237  64802001
         CH    LR,H031                  VALID TASK NAME..               64803015
         BH    GARBZ                    DEFINITELY NOT.                 64806015
         BCTR  LR,0                                                     64810015
         EX    LR,ZEMVT                 MOVE TASK NAME.                 64820015
         B     ZENTN                                                    64822015
         SPACE                                                          64824015
GARBZ    MVI   LINE+6+L'FKNN,C'*'                                       64826015
         MVC   LINE+7+L'FKNN(7),LINE+6+L'FKNN                           64828015
ZENTN    L     BR,APBFC                 OUTPUT HEADING.                 64830015
         BALR  RF,BR                                                    64840015
         OI    FLAG3,X'01'                                              64850015
         TM    ENTP,DUMC                DUMPING ALL TASKS..             64860015
         BO    ZENPR                    NO, GIVING ONLY FILE NAME.      64870015
         MVC   LINE+5(L'CPRS),CPRS                                      64880015
         LA    RA,LINE+6+L'CPRS                                         64890015
         LA    BR,8(RC)                                                 64900015
         BAL   LR,ZEADD                 SAY WHERE PR'S START.           64910015
         L     BR,APBFA                                                 64920015
         BALR  RF,BR                                                    64930015
ZENPR    MVI   OUTL,SPC2                SET TO SKIP A LINE.             64940015
ZEPTF    BAL   RF,ZEPUT                                                 64950015
ZENOF    L     RD,TFOP                  ADDRESS NEXT FILE.              64960015
         LA    RD,0(RD)                                                 64970015
         LTR   RD,RD                                                    64980015
         BNZ   ZENXF                    IF THERE IS ONE.                64990015
ZENFC    CLI   0(RC),MPRV               HAVE WE CHECKED THE MOTHER TASK 65000015
         BE    ZEXIT                    YES.                            65010015
         AH    RC,LNPR             NO, CHAIN BACK TO ATTACHER           65020001
         L     RC,OPRV(RC)                                              65030015
         LA    RC,0(RC)                                                 65040015
         B     ZEFOP                    HAVE A LOOK AT THIS ONE.        65050015
ZECTF    MVC   LINE+5(L'CTOP),CTOP                                      65060015
         L     BR,APBFC                                                 65070015
         BALR  RF,BR                    OUTPUT HEADING FOR CURRENT TASK 65080015
         MVI   OUTL,SPC2                SET TO SKIP A LINE.             65090015
ZENXT    L     RE,TDCB                  ADDRESS DCB.                    65100015
         L     RH,TDCL                  ADDRESS DCLCB.                  65110015
         LH    RI,DPRO                  PR OFFSET TO FILE REGISTER.     65120015
         BAL   RF,ZEPUT                                                 65130015
         L     RD,TFOP                  ADDRESS NEXT FILE               65140015
         LA    RD,0(RD)                                                 65150015
         LTR   RD,RD                     IF THERE IS ONE.               65160015
         BNZ   ZENXT                    YES.                            65170015
         B     ZENFC                    TRY THE NEXT TASK UP.           65180015
ZEXIT    EQU   *                                                        65190015
         L     DR,OFDR(DR)                                              65400015
         LM    LR,PR,OFLR(DR)                                           66000015
         BR    LR                                                       66300015
         SPACE 2                                                        66306015
ZEPUT    SR    BR,BR                                                    66312015
         IC    BR,DFLN                                                  66318015
         CH    BR,H031                  VALID FILE NAME..               66321015
         BNL   GARBF                    DEFINITELY NOT.                 66322015
         EX    BR,ZEMFL                 NAME THE FILE.                  66324015
CTASK    EQU   *                                                        66327015
         CR    RC,RB                    FOR THE CURRENT TASK..          66330015
         BE    ZERST                    YES.                            66336015
         TM    ENTP,DUMC                DUMPING ALL TASKS..             66342015
         BO    ZEPTI                    NO, JUST PUT FILE NAME.         66348015
ZERST    MVC   LINE+33(L'CDCL),CDCL                                     66354015
         LA    RA,LINE+39                                               66360015
         LR    BR,RH                    ADDRESS OF DCLCB.               66366015
         BAL   LR,ZEADD                                                 66372015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC019-TSS 66374019
*        ----------------------------------------------------ZZC019-TSS 66376019
         MVC   LINE+47(L'CFCB),CFCB                                     66378015
         LA    RA,LINE+51                                               66384015
         LR    BR,RD                    ADDRESS OF FCB.                 66390015
         BAL   LR,ZEADD                                                 66396015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC020-TSS 66398019
*        ----------------------------------------------------ZZC020-TSS 66400019
         MVC   LINE+59(L'CDCB),CDCB                                     66402015
         LA    RA,LINE+63                                               66408015
         LR    BR,RE                    ADDRESS OF DCB.                 66414015
         BAL   LR,ZEADD                                                 66420015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC021-TSS 66422019
*        ----------------------------------------------------ZZC021-TSS 66424019
         LR    BR,RI                                                    66426015
         LA    RA,LINE+78                                               66432015
         BAL   LR,ZEADD                                                 66438015
         MVC   LINE+71(L'CPRO),CPRO     PR OFFSET.                      66444015
ZEPTI    L     BR,APBFA                 OUTPUT INFO ABOUT FILE.         66450015
         BR    BR                                                       66456015
         SPACE                                                          66457015
GARBF    MVI   LINE+1,C'*'                                              66458015
         MVC   LINE+2(7),LINE+1                                         66459015
         B     CTASK                                                    66460015
         SPACE 2                                                        66462015
ZEADD    ST    BR,PACK                                                  66468015
         UNPK  UNPK(7),PACK+1(4)        TRANSLATE FROM HEX INTERNAL     66474015
         MVN   0(6,RA),UNPK                                             66480015
         TR    0(6,RA),ZETAB-BLNK        TO HEX EXTERNAL.               66486015
         BR    LR                                                       66492015
         EJECT                                                          66498015
ZEMVT    MVC   LINE+6+L'FKNN(*-*),1(BR)                                 66504015
ZEMFL    MVC   LINE+1(*-*),DFIL                                         66510015
MVBUF    MVC   LINE(*-*),0(RE)                                          66510615
H120     DC    H'120'                                                   66511215
FCFL     EQU   X'01'                                                    66511815
SYSP     DC    C'SYSPRINT '                                             66512415
BUFF     DC    C'BUFFER'                                                66513015
         DC    C'S'                                                     66513615
LSYS     EQU   *-SYSP                                                   66514215
CSTR     DC    C'GET/PUT STRING - SDV AT'                               66514815
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC022-TSS 66515119
INTR     DC    C'INTERMEDIATE BUFFER(U-FORMAT)'                         66515415
ZETAB    DC    C'0123456789ABCDEF'                                      66516015
*        ----------------------------------------------------ZZC022-TSS 66519019
CPRO     DC    CL10'PR OFFSET'                                          66522015
CDCB     DC    C'DCB'                                                   66528015
CFCB     DC    C'FCB'                                                   66534015
FKNN     DC    C'FILES KNOWN TO THIS TASK - OPENED BY TASK'             66540015
CDCL     DC    C'DCLCB'                                                 66546015
CPRS     DC    C'WHOSE PSEUDO-REGISTERS START AT'                       66552015
CRFL     DC    C'CURRENT '                                              66554015
LCRF     EQU   *-CRFL+4                                                 66556015
CTOP     DC    C'FILES OPENED BY THIS TASK'                             66558015
MTSK     DC    C'MAJOR TASK'                                            66564015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*ZZC023-TSS 66567019
         USING WORK,DR                                                  66570015
         EJECT                                                          68100015
IHEZZCE  CSECT                                                          74100015
         STM   LR,PR,OFLR(DR)                                           74400015
         BALR  WR-1,0                                                   74700015
         USING *,WR-1                                                   75000015
         ST    DR,SAV2+OFDR                                             75300015
         LA    DR,SAV2                                                  75600015
         USING SAV2,DR                                                  75900015
         L     RF,SNPP                                                  77700015
         TM    1(RB),X'80'                                              77800015
         BZ    NOTSK                    NOT TASKING.                    77900015
         SNAP  DCB=DIAG,ID=(RF),TCB=(RD),MF=(E,SNPSNP)                  78000015
SNPTT    EQU   *                                                        78100015
         LTR   BR,BR                                                    78200015
         BNZ   SNERR                                                    78300015
EEXIT    MVC   SNPSNP(LSNP),SSNP                                        78400015
         L     DR,OFDR(DR)                                              78600015
         LM    LR,PR,OFLR(DR)                                           79200015
         BR    LR                                                       79500015
NOTSK    EQU   *                                                        79540001
         SNAP  DCB=DIAG,ID=(RF),MF=(E,SNPSNP)                           79580001
         B     SNPTT                                                    79620015
SNERR    OI    ENTP,X'F9'                                               79680015
         B     EEXIT                                                    79740015
SSNP     SNAP  SDATA=(CB,Q),PDATA=(SPLS),MF=L                           81600015
LSNP     EQU   *-SSNP                                                   81900015
*        ----------------------------------------------------ZZC023-TSS 82000019
         END                                                            82200015
