 TITLE 'IHIFDD, POWER ROUTINE, REAL**REAL, LONG PRECISION'              00020000
*STATUS: CHANGE LEVEL 000                                             * 00040000
*                                                                     * 00060000
*FUNCTION/OPERATION: SEE CODE.                                        * 00080000
*                                                                     * 00100000
*ENTRY POINT:                                                         * 00120000
*        IHIFDD - POWER FUNCTION, REAL**REAL, LONG LA  1,PARMLIST     * 00140000
*                                                  BALR 14,15         * 00160000
*                                                  DATA PASSED BY NAME* 00180000
*   THE MODULE IS ENTERED FROM THE GENERATED OBJECT MODULE.           * 00200000
*                                                                     * 00220000
*INPUT: N/A                                                           * 00240000
*                                                                     * 00260000
*OUTPUT: N/A                                                          * 00280000
*                                                                     * 00300000
*EXTERNAL ROUTINES:                                                   * 00320000
*        IHILLO - LOGARITHM FUNCTION, LONG PRECISION                  * 00340000
*        IHILEX - EXPONENTIAL FUNCTION, LONG PRECISION                * 00360000
*                                                                     * 00380000
*EXIT-NORMAL: RETURN BY MEANS OF   BR  14.  RESULT IN FPR0.           * 00400000
*                                                                     * 00420000
*EXIT-ERROR: IF BASE IS ZERO AND EXPONENT NOT POSITIVE GO TO ERROR    * 00440000
*   ROUTINE VIA     B     FSAERR+35*4(13)                             * 00460000
*                                                                     * 00480000
*TABLES/WORKAREAS: N/A                                                * 00500000
*                                                                     * 00520000
*ATTRIBUTES: THE MODULE IS SERIALLY REUSABLE.                         * 00540000
*                                                                     * 00560000
*NOTES: CHARACTER CODE DEPENDENCE                                     * 00580000
*   THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A SPECIAL       * 00600000
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 00620000
       SPACE                                                            00640000
IHIFDDXP CSECT                                                          00660000
       EXTRN   IHILLO                                                   00680000
       EXTRN   IHILEX                                                   00700000
       ENTRY   IHIFDD                                                   00720000
       DC      CL7'IHIFDD'             ENTRY-POINT IDENTIFIER           00740000
       DC      X'06'                                                    00760000
           USING *,LINK            MAKE LINK REG THE BASE ADDRESS REG   00780000
IHIFDD STM     RTN,ADDR,12(SAVE)       SAVE REGISTERS                   00800000
           L     ADDR,0(0,PLIST)   LOAD PLIST OF BASE NO IN ADDR REG    00820000
           LD    BASE,0(0,ADDR)    LOAD BASE NO INTO BASE NO REG        00840000
           L     ADDR,4(0,PLIST)   LOAD PLIST OF EXPONENT IN ADDR REG   00860000
           LD    EXPN,0(0,ADDR)    LOAD EXPONENT INTO EXPN REG          00880000
           BALR  BASADD,0          ESTABLISH LINKAGE TO BASADD REG      00900000
           USING *,BASADD          MAKE BASADD REG NEW BASE ADDRESS REG 00920000
           LTDR  BASE,BASE         CHECK IF BASE NO PLUS, MINUS,OR ZERO 00940000
           BC    8,ERROR           IF BASE NO IS ZERO, BRANCH TO ERROR  00960000
         BC    4,ERROR+6     BRANCH TO ERROR IF NEGATIVE UNDEFINED      00980000
           LTDR  EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 01000000
           BC    8,LOAD1           IF EXPONENT IS ZERO, BRANCH TO LOAD1 01020000
           LR    ADDR,SAVE         LOAD SAVE AREA ADDRESS INTO ADDR REG 01040000
           LA    SAVE,SAVREG       LOAD NEW SAVE AREA ADDR IN SAVE REG  01060000
           ST    ADDR,4(SAVE)      STORE FORMER SAVE REG AREA ADDRESS   01080000
           ST    SAVE,8(ADDR)      STORE NEW SAVE REGISTER AREA ADDRESS 01100000
           STD   EXPN,PARAM        STORE EXPONENT FOR LATER USE IN RTN  01120000
           L     LINK,ACDLOG       LOAD ADCON OF DLOG RTN IN LINK REG   01140000
           BALR  RTN,LINK          BRANCH TO DLOG RTN FOR LOG OF BASE   01160000
           LD    EXPN,PARAM        RELOAD EXPN REG WITH EXPONENT        01180000
           MDR   BASE,EXPN         MULTIPLY LOG OF BASE NO BY EXPONENT  01200000
           STD   BASE,PARAM        STORE RESULT AS EXP RTN PARAMETER    01220000
           LA    PLIST,ADCPAR      MOD PLIST TO POINT TO EXP RTN PARAM  01240000
           L     LINK,ACDEXP       LOAD ADCON OF DEXP RTN IN LINK REG   01260000
           BALR  RTN,LINK          BRANCH TO DEXP RTN TO COMPUTE RESULT 01280000
           L     SAVE,4(SAVE)      RESTORE THIS RTNS SAVE REG AREA ADDR 01300000
           BC    15,EXIT           BRANCH TO EXIT (RESULT IN BASE REG)  01320000
LOAD1      LD    BASE,ONE          LOAD PLUS 1 AS RESULT IN BASE NO REG 01340000
EXIT       LM    RTN,ADDR,12(SAVE) RELOAD FORMER VALUES OF GP REG 14 -3 01360000
           MVI   12(SAVE),X'FF'    STORE ALL 1 BITS IN SAVE AREA WORD 4 01380000
           BCR   15,RTN            BRANCH TO ADDRESS IN RETURN REG RTN  01400000
ERROR      LTDR  EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 01420000
           BC    2,EXIT            IF EXPN IS POSITIVE, BRANCH TO EXIT  01440000
         B     FSAERR+35*4(13)     BASENO EQUAL ZERO AND EXPONENT      X01460000
                                   NO GREATER THAN ZERO, UNDERFINED     01480000
*                FLOATING POINT REGISTERS                               01500000
BASE       EQU   0                 REGISTER FOR BASE NO, PASSING RESULT 01520000
EXPN       EQU   2                 REGISTER FOR EXPONENT IN COMPUTATION 01540000
*                GENERAL PURPOSE REGISTERS                              01560000
SAVE       EQU   13                REGISTER CONTAINS SAVE REG AREA ADDR 01580000
RTN        EQU   14                REGISTER FOR RETURN TO PREVIOUS RTN  01600000
LINK       EQU   15                REGISTER FOR LINKAGE TO ANOTHER RTN  01620000
PLIST      EQU   1                 REGISTER USED FOR PARAMETER LIST REF 01640000
BASADD     EQU   2                 REGISTER USED FOR SECOND BASE ADDR   01660000
ADDR       EQU   3                 REGISTER FOR INDEXING PARAMETER ADDR 01680000
*                CONSTANTS AND ADCON AREAS                              01700000
SAVREG     DS    10F                    SAVE AREA FOR GP REG 13 THRU 4  01720000
PARAM      DS    D                      PARAM FOR DATA IN DEXP MATH RTN 01740000
ONE        DC    X'4110000000000000'    CONSTANT ONE IN DOUBLE PREC F P 01760000
ADCPAR     DC    AL4(PARAM)             ADCON OF PARAMETER FOR EXP RTN  01780000
ACDLOG DC      AL4(IHILLO)             ADCON OF LOG MATH LIBRARY ROUTIN 01800000
ACDEXP DC      AL4(IHILEX)             ADCON OF EXP MATH LIBRARY ROUTIN 01820000
FSAERR   EQU   X'1CC'                                                   01840000
           END                                                          01860000
