 TITLE 'IHIFII, POWER ROUTINE, INTEGER**INTEGER'                        00020000
*STATUS: CHANGE LEVEL 000                                             * 00040000
*                                                                     * 00060000
*FUNCTION/OPERATION: SEE CODE.                                        * 00080000
*                                                                     * 00100000
*ENTRY POINT:                                                         * 00120000
*        IHIFII - POWER FUNCTION, INT**INT         LA   1,PARMLIST    * 00140000
*                                                  BALR 14,15         * 00160000
*                                                  DATA PASSED BY NAME* 00180000
*   THE MODULE IS ENTERED FROM THE GENERATED OBJECT MODULE.           * 00200000
*                                                                     * 00220000
*INPUT: N/A                                                           * 00240000
*                                                                     * 00260000
*OUTPUT: N/A                                                          * 00280000
*                                                                     * 00300000
*EXTERNAL ROUTINES: N/A                                               * 00320000
*                                                                     * 00340000
*EXIT-NORMAL: RETURN BY MEANS OF   BR  14.  RESULT IN FPR0.           * 00360000
*                                                                     * 00380000
*EXIT-ERROR: IF BASE IS ZERO AND EXPONENT NOT POSITIVE GO TO ERROR    * 00400000
*   ROUTINE VIA     B     FSAERR+35*4(13)                             * 00420000
*                                                                     * 00440000
*TABLES/WORKAREAS: N/A                                                * 00460000
*                                                                     * 00480000
*ATTRIBUTES: THE MODULE IS SERIALLY REUSABLE.                         * 00500000
*                                                                     * 00520000
*NOTES: CHARACTER CODE DEPENDENCE                                     * 00540000
*   THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A SPECIAL       * 00560000
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 00580000
       SPACE                                                            00600000
IHIFIIXP CSECT                                                          00620000
       ENTRY   IHIFII                                                   00640000
       DC      CL7'IHIFII'             ENTRY-POINT IDENTIFIER           00660000
       DC      X'06'                                                    00680000
           USING *,LINK            MAKE LINK REG THE BASE ADDRESS REG   00700000
IHIFII STM     RTN,ADDR,12(SAVE)       SAVE REGISTERS                   00720000
           L     ADDR,0(0,PLIST)   LOAD PLIST OF BASE NO IN ADDR REG    00740000
           L     BASE,0(0,ADDR)    LOAD BASE NO INTO BASE NO REG        00760000
           L     ADDR,4(0,PLIST)   LOAD PLIST OF EXPONENT IN ADDR REG   00780000
           L     EXPN,0(0,ADDR)    LOAD EXPONENT INTO EXPN REG          00800000
           LR    RESULT,BASE       LOAD BASE NO INTO RESULT REG         00820000
           LTR   BASE,BASE         CHECK IF BASE NO PLUS, MINUS,OR ZERO 00840000
           BC    8,ERROR           IF BASE NO IS ZERO, BRANCH TO ERROR  00860000
           LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 00880000
           BC    8,LOAD1           IF EXPONENT IS ZERO, BRANCH TO LOAD1 00900000
           BCTR  BASE,0            DECREMENT BY ONE VALUE OF BASE NO    00920000
           LTR   BASE,BASE         CHECK IF BASE NO PLUS, MINUS,OR ZERO 00940000
           BC    8,EXIT            IF BASE NO NOW ZERO, BRANCH TO EXIT  00960000
           LA    BASE,2(BASE)      INCREMENT BY TWO VALUE OF BASE NO    00980000
           LTR   BASE,BASE         CHECK IF BASE NO PLUS, MINUS,OR ZERO 01000000
           BC    8,TEST            IF BASE NO NOW ZERO, BRANCH TO TEST  01020000
           LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 01040000
           BC    2,PLUS            IF EXPN IS POSITIVE, BRANCH TO PLUS  01060000
           SR    RESULT,RESULT     EXPN MINUS,MAKE VALUE OF RESULT ZERO 01080000
           BC    15,EXIT           BRANCH TO EXIT TO LEAVE THIS ROUTINE 01100000
PLUS       LR    BASE,RESULT       RELOAD ORG BASE NO FROM RESULT REG   01120000
           L     FACTOR,ONE        LOAD FACTOR OF ONE IN FACTOR REG     01140000
LOOP       SRDL  EXPN,1            SHIFT LOW BIT EXPN REG INTO ADDR REG 01160000
           LTR   ADDR,ADDR         TEST SIGN POS ADDR REG FOR MINUS BIT 01180000
           BC    10,JUMP           IF SIGN BIT NOT MINUS,BRANCH TO JUMP 01200000
           MR    FACT,BASE         MULTIPLY FACTOR REGS BY BASE NO REGS 01220000
         SLDA  FACT,32            CHECK  OVERFLOW                       01240000
         SRDA  FACT,32                                                  01260000
JUMP       LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 01280000
           BC    8,NEXT            IF EXPONENT NOW ZERO, BRANCH TO NEXT 01300000
           MR    BASE1,BASE        MULTIPLY BASE NO BY DOUBLING ITSELF  01320000
         SLDA  BASE1,32                                                 01340000
         SRDA  BASE1,32                                                 01360000
           BC    15,LOOP           BRANCH TO LOOP TO TEST NEXT EXPN BIT 01380000
NEXT     LR    RESULT,FACTOR      LOAD FFACTOR INTO RESULT REGISTER     01400000
           BC    15,EXIT           BRANCH TO EXIT TO LEAVE THIS ROUTINE 01420000
TEST       SRDL  EXPN,1            SHIFT LOW BIT EXPN REG INTO ADDR REG 01440000
           LTR   ADDR,ADDR         TEST SIGN POS ADDR REG FOR MINUS BIT 01460000
           BC    4,EXIT            IF SIGN MINUS (EXPN ODD), GO TO EXIT 01480000
LOAD1      L     RESULT,ONE        LOAD RESULT REG WITH VALUE OF PLUS 1 01500000
EXIT       LM    RTN,LINK,12(SAVE) RELOAD FORMER VALUES OF GP REG 14-15 01520000
           LM   FACT,ADDR,28(SAVE) RELOAD FORMER VALUES OF GP REG 2-7   01540000
           MVI   12(SAVE),X'FF'    STORE ALL 1 BITS IN SAVE AREA WORD 4 01560000
           BCR   15,RTN            BRANCH TO ADDRESS IN RETURN REG RTN  01580000
ERROR      LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 01600000
           BC    2,EXIT            IF EXPN IS POSITIVE, BRANCH TO EXIT  01620000
         B     FSAERR+35*4(SAVE)                                        01640000
*                GENERAL PURPOSE REGISTERS                              01660000
SAVE       EQU   13                REGISTER CONTAINS SAVE REG AREA ADDR 01680000
RTN        EQU   14                REGISTER FOR RETURN TO PREVIOUS RTN  01700000
LINK       EQU   15                REGISTER FOR LINKAGE TO ANOTHER RTN  01720000
RESULT     EQU   0                 REGISTER FOR PASSING ON FINAL RESULT 01740000
PLIST      EQU   1                 REGISTER USED FOR PARAMETER LIST REF 01760000
FACT       EQU   2                 REGISTER USED AS MPY REG FOR FACTOR  01780000
FACTOR     EQU   3                 REGISTER USED FOR FACTOR AND ANSWER  01800000
BASE1      EQU   4                 REGISTER USED AS MPY REG FOR BASE NO 01820000
BASE       EQU   5                 REGISTER FOR BASE NO IN COMPUTATION  01840000
EXPN       EQU   6                 REGISTER FOR EXPONENT IN COMPUTATION 01860000
ADDR       EQU   7                 REGISTER FOR INDEXING PARAMETER ADDR 01880000
*                ADCONS AND CONSTANTS AREA                              01900000
ONE        DC    F'1'              INTERGER CONSTANT OF ONE             01920000
FSAERR   EQU   X'1CC'                                                   01940000
           END                                                          01960000
