 TITLE 'IHIFRI, POWER ROUTINE, REAL**INTEGER, SHORT PRECISION'          00020000
*STATUS: CHANGE LEVEL 000                                             * 00040000
*                                                                     * 00060000
*FUNCTION/OPERATION: SEE CODE.                                        * 00080000
*                                                                     * 00100000
*ENTRY POINT:                                                         * 00120000
*        IHIFRI - POWER FUNCTION, REAL**INT, SHORT LA  1,PARMLIST     * 00140000
*                                                  BALR 14,15         * 00160000
*                                                  DATA PASSED BY NAME* 00180000
*   THE MODULE IS ENTERED FROM THE GENERATED OBJECT MODULE.           * 00200000
*                                                                     * 00220000
*INPUT: N/A                                                           * 00240000
*                                                                     * 00260000
*OUTPUT: N/A                                                          * 00280000
*                                                                     * 00300000
*EXTERNAL ROUTINES: N/A                                               * 00320000
*                                                                     * 00340000
*EXIT-NORMAL: RETURN BY MEANS OF   BR  14.  RESULT IN FPR0.           * 00360000
*                                                                     * 00380000
*EXIT-ERROR: IF BASE IS ZERO AND EXPONENT NOT POSITIVE GO TO ERROR    * 00400000
*   ROUTINE VIA     B     FSAERR+35*4(13)                             * 00420000
*                                                                     * 00440000
*TABLES/WORKAREAS: N/A                                                * 00460000
*                                                                     * 00480000
*ATTRIBUTES: THE MODULE IS SERIALLY REUSABLE.                         * 00500000
*                                                                     * 00520000
*NOTES: CHARACTER CODE DEPENDENCE                                     * 00540000
*   THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A SPECIAL       * 00560000
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 00580000
       SPACE                                                            00600000
IHIFRIXP CSECT                                                          00620000
       ENTRY   IHIFRI                                                   00640000
       DC      CL7'IHIFRI'             ENTRY-POINT IDENTIFIER           00660000
       DC      X'06'                                                    00680000
           USING *,LINK            MAKE LINK REG THE BASE ADDRESS REG   00700000
IHIFRI STM     RTN,ADDR,12(SAVE)       SAVE REGISTERS                   00720000
           L     ADDR,0(0,PLIST)   LOAD PLIST OF BASE NO IN ADDR REG    00740000
           LE    BASE,0(0,ADDR)    LOAD BASE NO INTO BASE NO REG        00760000
           L     ADDR,4(0,PLIST)   LOAD PLIST OF EXPONENT IN ADDR REG   00780000
           L     EXPN,0(0,ADDR)    LOAD EXPONENT INTO EXPN REG          00800000
           LTER  BASE,BASE         CHECK IF BASE NO PLUS, MINUS,OR ZERO 00820000
           BC    8,ERROR           IF BASE NO IS ZERO, BRANCH TO ERROR  00840000
           SR    EXPSW,EXPSW       SET NEGATIVE EXPN SWITCH REG TO ZERO 00860000
           LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 00880000
           BC    2,PLUS            IF EXPN IS POSITIVE, BRANCH TO PLUS  00900000
           BC    8,LOAD1           IF EXPONENT IS ZERO, BRANCH TO LOAD1 00920000
           LCR   EXPN,EXPN         EXPN MINUS, CONVERT TO 2S COMPLIMENT 00940000
           LA    EXPSW,1(EXPSW)    SET EXP SW REG TO ONE FOR MINUS EXPN 00960000
PLUS       LE    FACTOR,ONE        LOAD FACTOR OF ONE IN FACTOR REG     00980000
LOOP       SRDL  EXPN,1            SHIFT LOW BIT EXPN REG INTO ADDR REG 01000000
           LTR   ADDR,ADDR         TEST SIGN POS ADDR REG FOR MINUS BIT 01020000
           BC    10,JUMP           IF SIGN BIT NOT MINUS,BRANCH TO JUMP 01040000
           MER   FACTOR,BASE       MULTIPLY FACTOR REG BY BASE NO REG   01060000
JUMP       LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 01080000
           BC    8,NEXT            IF EXPONENT NOW ZERO, BRANCH TO NEXT 01100000
           MER   BASE,BASE         MULTIPLY BASE NO BY DOUBLING ITSELF  01120000
           BC    15,LOOP           BRANCH TO LOOP TO TEST NEXT EXPN BIT 01140000
NEXT       LTR   EXPSW,EXPSW       TEST IF EXPSW REG PLUS,MINUS,OR ZERO 01160000
           BC    8,SWAP            IF EXPN IS NOT MINUS, BRANCH TO SWAP 01180000
           LE    BASE,ONE          LOAD ONE IN BASE NO REG AS DIVIDEND  01200000
           DER   BASE,FACTOR       DIV BASE REG BY FACTOR REG (RESULT)  01220000
           BC    15,EXIT           BRANCH TO EXIT (RESULT IN BASE REG)  01240000
SWAP       LER   BASE,FACTOR       LOAD FACTOR REG INTO BASE NO REG     01260000
           BC    15,EXIT           BRANCH TO EXIT (RESULT IN BASE REG)  01280000
LOAD1      LE    BASE,ONE          LOAD PLUS 1 AS RESULT IN BASE NO REG 01300000
EXIT       LM    RTN,ADDR,12(SAVE) RELOAD FORMER VALUES OF GP REG 14-3  01320000
           MVI   12(SAVE),X'FF'    STORE ALL 1 BITS IN SAVE AREA WORD 4 01340000
           BCR   15,RTN            BRANCH TO ADDRESS IN RETURN REG RTN  01360000
ERROR      LTR   EXPN,EXPN         CHECK IF EXPONENT PLUS,MINUS,OR ZERO 01380000
           BC    2,EXIT            IF EXPN IS POSITIVE, BRANCH TO EXIT  01400000
         B     FSAERR+35*4(13)     BASE NO EQUAL ZERO AND EXPONENT     X01420000
                                  NOT GREATER THAN ZERO ,UNDEFINED      01440000
*                FLOATING POINT REGISTERS                               01460000
BASE       EQU   0                 REGISTER FOR BASE NO, PASSING RESULT 01480000
FACTOR     EQU   2                 REGISTER FOR FACTOR,COMPUTING RESULT 01500000
*                GENERAL PURPOSE REGISTERS                              01520000
SAVE       EQU   13                REGISTER CONTAINS SAVE REG AREA ADDR 01540000
RTN        EQU   14                REGISTER FOR RETURN TO PREVIOUS RTN  01560000
LINK       EQU   15                REGISTER FOR LINKAGE TO ANOTHER RTN  01580000
EXPSW      EQU   0                 REGISTER FOR TESTING FOR MINUS EXPN  01600000
PLIST      EQU   1                 REGISTER USED FOR PARAMETER LIST REF 01620000
EXPN       EQU   2                 REGISTER FOR EXPONENT IN COMPUTATION 01640000
ADDR       EQU   3                 REGISTER FOR INDEXING PARAMETER ADDR 01660000
*                ADCONS AND CONSTANTS AREA                              01680000
           DS    0F                    FORCE TO NEXT FULL WORD BOUNDARY 01700000
ONE        DC    X'41100000'            CONSTANT ONE IN SINGLE PREC F P 01720000
FSAERR   EQU   X'1CC'                                                   01740000
       END                                                              01760000
