 TITLE 'IHIFSA - OS/360 ALGOL FIXED STORAGE AREA'                       00020000
*STATUS.. CHANGE LEVEL 0                                                00040000
*FUNCTION/OPERATION..                                                   00060000
*   THIS MODULE (KNOWN AS THE FSA) IS A COLLECTION OF ABOUT 20          00080000
*   ROUTINES WHICH ARE REQUIRED FOR THE EXECUTION OF ALMOST ANY ALGOL   00100000
*   PROGRAM. THE ENTRY POINT AND PURPOSE OF EACH ROUTINE IS LISTED      00120000
*   UNDER 'ENTRY POINTS' BELOW. DETAILED INFORMATION ON THE FUNCTION,   00140000
*   CALLING SEQUENCE, TRANSMISSION OF PARAMETERS ETC. CAN BE FOUND      00160000
*   IN THE COMMENTARY WHICH PRECEDES THE PROGRAM LISTING FOR EACH       00180000
*   ROUTINE.                                                            00200000
*                                                                       00220000
*   THE MODULE CONSISTS OF TWO CONTROL SECTIONS, IHIFSARA AND IHIFSARB. 00240000
*   IHIFSARA CONTAINS THE ROUTINES, TABLES AND OTHER INFORMATION USED   00260000
*   DURING THE EXECUTION OF THE ALGOL OBJECT PROGRAM.                   00280000
*   IHIFSARB CONTAINS MAINLY THE INITIALIZATION AND TERMINATION         00300000
*   ROUTINES WITH THEIR ASSOCIATED TABLES AND WORK AREAS.               00320000
*                                                                       00340000
*   REG. 13(FSA) IS THE BASE REGISTER FOR IHIFSARA.                     00360000
*   REG. 7(GRF) IS THE BASE REGISTER FOR IHIFSARB.                      00380000
*                                                                       00400000
*ENTRY POINTS..MOST OF THE ENTRY POINTS LISTED HERE ARE COLLECTED IN    00420000
*   A BRANCH LIST LOCATED AT BRLIST. THE ENTRY POINTS CONTAINED IN THIS 00440000
*   BRANCH LIST ARE MARKED WITH AN ASTERISK AFTER THE NAME IN THE       00460000
*   LISTING BELOW.                                                      00480000
*                                                                       00500000
*        CAP1*- CALL ACTUAL PARAMETER, PART 1. ENTER THUNK ROUTINE      00520000
*   FROM A PROCEDURE.                                                   00540000
*        CAP2*- CALL ACTUAL PARAMETER, PART 2. RETURN FROM THE THUNK    00560000
*   ROUTINE TO THE PROCEDURE.                                           00580000
*        PROLOGP*- ENTER A PROCEDURE WHEN IT IS CALLED VIA AN ACTUAL    00600000
*   PARAMETER.                                                          00620000
*        PROLOG*- ENTER A BLOCK OR A PROCEDURE.                         00640000
*        RETPROG*- LEAVE A BLOCK OR PROCEDURE VIA A 'GO TO' STATEMENT.  00660000
*        EPILOGP*- RETURN FROM A PROCEDURE VIA THE 'END' STATEMENT.     00680000
*        EPILOGB*- LEAVE A BLOCK VIA THE 'END' STATEMENT.               00700000
*        FRDSA - FREE STORAGE FOR DSA AND ARRAYS. SYNONYM FOR EPILOGB   00720000
*   WHEN USED AS A SUBROUTINE BY THE ERROR ROUTINE IHGERROR.            00740000
*        CSWE1*- CALL SWITCH ELEMENT, PART 1.                           00760000
*        CSWE2*- CALL SWITCH ELEMENT, PART 2.                           00780000
*        LOADPP*- LOAD A PRECOMPILED PROCEDURE.                         00800000
*        SPDECL - STANDARD PROCEDURE DECLARATION ROUTINE. (ENTERED VIA  00820000
*   THE PROLOG ROUTINE).                                                00840000
*        VALUCALL*- HANDLE FORMAL PARAMETERS CALLED BY VALUE.           00860000
*        GETMSTO*- GET MAIN STORAGE FOR ARRAYS.                         00880000
*        CNVIRD - CONVERT INTEGER TO REAL.                              00900000
*        CNVRDI - CONVERT REAL TO INTEGER.                              00920000
*        ENTIER - EXECUTE ALGOL ENTIER FUNCTION.                        00940000
*        TRACE*- STORE THE CURRENT SEMICOLON NUMBER.                    00960000
*        IHGFSAIN - INITIALIZE FOR PROGRAM EXECUTION AND GIVE CONTROL   00980000
*   TO THE OBJECT MODULE.                                               01000000
*        TERMNTE*- TERMINATE THE EXECUTION.                             01020000
*        PIEROUT - PROGRAM INTERRUPT ROUTINE.                           01040000
*        FSAERR - STORE ERROR NUMBER AND LINK TO THE ERROR ROUTINE      01060000
*   IHIERROR.                                                           01080000
*                                                                       01100000
*INPUT.. IF THE TRACE OPTION IS USED, THE TERMINATION ROUTINE MAY READ  01120000
*   A TABLE OF SEMICOLON NUMBERS, WHICH HAS BEEN WRITTEN ON SYSUT1 BY   01140000
*   THE TRACE ROUTINE.                                                  01160000
*                                                                       01180000
*OUTPUT.. IF THE TRACE OPTION IS USED, THE TRACE ROUTINE MAY WRITE A    01200000
*   TABLE OF SEMICOLON NUMBERS ON SYSUT1. THIS TABLE IS READ AND THEN   01220000
*   WRITTEN ON SYSPRINT IN EDITED FORMAT BY THE TERMINATION ROUTINE.    01240000
*   THE MESSAGE 'END OF ALGOL PROGRAM EXECUTION' IS WRITTEN ON SYSPRINT 01260000
*   AS THE FINAL OUTPUT FROM THE EXECUTION.                             01280000
*                                                                       01300000
*EXTERNAL ROUTINES..                                                    01320000
*                                                                       01340000
*        IHIIOROP - OPEN A DATA SET (USED ONLY FOR SYSPRINT).           01360000
*        IHIIORCL - CLOSE A DATA SET (USED ONLY FOR SYSPRINT).          01380000
*        IHIIORCP - CLOSE ALL OPEN DATA SETS (EXCEPT SYSUT1).           01400000
*        IHIIORNX - HANDLE THE NEXT I/O RECORD.                         01420000
*        IHIERROR - EDIT AND PRINT AN ERROR MESSAGE AND, IF REQUESTED,  01440000
*   AN ALGOL STORAGE DUMP. (ENTERED BY LINK).                           01460000
*                                                                       01480000
*   THE FOLLOWING TWO EXTERNAL TABLES ARE IN THE OBJECT MODULE.         01500000
*                                                                       01520000
*        IHIENTIF - INFORMATION NEEDED FOR ENTERING THE OBJECT MODULE.  01540000
*   FORMAT.. IHIENTIF DC A(PBTAB)  ADDRESS OF PROGRAM BLOCK TABLE       01560000
*                     DC A(LATAB)  ADDRESS OF LABEL ADDRESS TABLE       01580000
*                     DC X'SL'     X'02' OR X'00' FOR SHORT/LONG PREC.  01600000
*                     DC AL3(ENTRYPOINT)  ADDRESS OF FIRST INSTRUCTION  01620000
*                                                                       01640000
*        IHIDSTAB - INFORMATION ABOUT THE STATUS OF EACH DATA SET USED. 01660000
*   FORMAT AND USE.. SEE THE DUMMY SECTION DDSTAB AND THE LISTING OF    01680000
*   THE I/O SUBROUTINE MODULE IHIIORTN.                                 01700000
*                                                                       01720000
*EXITS - NORMAL.. THE TERMINATION ROUTINE IS ENTERED BY A BRANCH TO     01740000
*   TERMNTE, AND A FINAL RETURN IS BY A RETURN MACRO WITH THE RETURN    01760000
*   CODE ZERO IN REG. 15.                                               01780000
*                                                                       01800000
*EXITS - ERRORS.. ON RETURN FROM THE ERROR ROUTINE IHIERROR, THE        01820000
*   TERMINATION ROUTINE IS ENTERED BY A BRANCH TO ALGTRMA, AND A FINAL  01840000
*   RETURN IS MADE BY A RETURN MACRO WITH THE RETURN CODE 4 IN REG. 15. 01860000
*                                                                       01880000
*TABLES/WORK AREAS..                                                    01900000
*   THE LOWER PART OF IHIFSARA CONTAINS A BLOCK OF WORK AREAS AND       01920000
*   CONSTANTS WHICH ARE USED IN COMMON BY SEVERAL ROUTINES. THE MOST    01940000
*   IMPORTANT ARE..                                                     01960000
*                                                                       01980000
*        SAVE - STANDARD SAVE AREA USED BY ALL FIRST-LEVEL SUBROUTINES  02000000
*   EXCEPT THOSE CONTAINED IN THIS MODULE.                              02020000
*        ASAVE - SAVE AREA USED BY SOME ROUTINES IN THIS MODULE.        02040000
*        FCTVALST - STORAGE FOR THE RESULT OF AN ALGOL FUNCTION.        02060000
*        PROLPBN - PROGRAM BLOCK NUMBER OF A BLOCK OR PROCEDURE TO BE   02080000
*   ENTERED VIA THE PROLOG ROUTINE.                                     02100000
*        PGOPSW - THE OLD PSW IN CASE OF A PROGRAM INTERRUPT.           02120000
*        SCRCS - THE CURRENT SEMICOLON NUMBER.                          02140000
*        OPTSW - FLAG BITS REPRESENTING EXECUTION TIME OPTIONS AND      02160000
*   SWITCHES FOR CONTROLLING THE PROGRAM FLOW.                          02180000
*        FSAERCOD - ERROR NUMBER IDENTIFYING AN EXECUTION ERROR.        02200000
*        IHIFSARS - FOUR POINTERS FOR CONTROLLING THE RETURN ADDRESS    02220000
*   STACK.                                                              02240000
*        BRLIST - A LIST OF ENTRY POINTS TO MOST OF THE ROUTINES        02260000
*   MENTIONED UNDER 'ENTRY POINTS'. THE LIST CONSISTS MAINLY OF         02280000
*   BRANCH INSTRUCTIONS.                                                02300000
*        IHIFSAER - A LIST OF BAL INSTRUCTIONS, EACH CORRESPONDING TO   02320000
*   ONE TYPE OF ERROR, THE NUMBER OF WHICH IS DETERMINED BY ITS         02340000
*   POSITION IN THE LIST.                                               02360000
*                                                                       02380000
*   OTHER WORK AREAS AND CONSTANTS OF GENERAL INTEREST ARE..            02400000
*        PARMLIST - A LIST OF THE VALID EXECUTION OPTION PARAMETERS.    02420000
*        TRBUF - BUFFER POINTERS AND RECORD COUNTER FOR CONTROLLING     02440000
*   THE OUTPUT OF TRACING INFORMATION ON SYSUT1.                        02460000
*        PIETAB - A LIST OF 16 ADDRESS CONSTANTS EACH POINTING TO AN    02480000
*   ENTRY IN IHIFSAER, WHICH CORRESPONDS TO A TYPE OF PROGRAM INTERRUPT 02500000
*        FPINST - A LIST OF FLOATING POINT INSTRUCTIONS USED BY THE     02520000
*   VALUCALL AND SPDECL ROUTINES.                                       02540000
*        CNVINSTE - INSTRUCTIONS TO BE INSERTED INTO THE CONVERT        02560000
*   ROUTINE FOR SHORT PRECISION.                                        02580000
*        CNVINSTD - INSTRUCTIONS TO BE INSERTED INTO THE CONVERT        02600000
*   ROUTINE FOR LONG PRECISION.                                         02620000
*                                                                       02640000
*ATTRIBUTES.. THIS MODULE IS SERIALLY REUSABLE.                         02660000
*                                                                       02680000
*NOTES..THIS MODULE IS ONLY INTENDED TO BE USED WHEN LINKAGE EDITED     02700000
*   TOGETHER WITH AN OS/360 ALGOL OBJECT MODULE AND WITH THE OS/360     02720000
*   ALGOL I/O ROUTINES. FOR REASONS OF EFFICIENCY CERTAIN LOCAL         02740000
*   CONVENTIONS ARE OBEYED IN THE COMMUNICATION BETWEEN THESE MODULES.  02760000
*                                                                       02780000
*   REGISTER SAVING AND RESTORING IS ONLY DONE WHEN REQUIRED AND THEN   02800000
*   GENERALLY IN A NON-STANDARD FASHION.                                02820000
*                                                                       02840000
*   USE OF GENERAL REGISTERS WHEN COMMUNICATING WITH THE OBJECT MODULE. 02860000
*                                                                       02880000
*   REG. 8 (ADR) IS SOMETIMES USED  AS RETURN REGISTER AND PARAMETER    02900000
*   POINTER.                                                            02920000
*   REG. 10 (CDSA) POINTS AT THE CURRENT ACTIVE DATA STORAGE AREA.      02940000
*   REG. 11(PBT) POINTS AT THE PROGRAM BLOCK TABLE IN THE OBJECT MODULE 02960000
*   REG. 12(LAT) POINTS AT THE LABEL ADDRESS TABLE IN THE OBJECT MODULE 02980000
*   REG. 13(FSA) SERVES BOTH AS THE STANDARD SAVE AREA REGISTER AND     03000000
*   AS BASE REGISTER FOR THE CONTROL SECTION IHIFSARA.                  03020000
*   REG. 14(STH) IS USED TO TRANSMIT INTEGER VALUES TO OR FROM THE      03040000
*   CONVERT ROUTINES.                                                   03060000
*   REG. 15(BRR) IS NORMALLY USED AS RETURN REGISTER AND PARAMETER      03080000
*   POINTER.                                                            03100000
*   F.P. REG. 0 IS USED TO TRANSMIT REAL VALUES TO OR FROM THE CONVERT  03120000
*   ROUTINES.                                                           03140000
*                                                                       03160000
*   USE OF GENERAL REGISTERS WHEN COMMUNICATING WITH THE I/O ROUTINES.. 03180000
*                                                                       03200000
*   REG. 5(DSN) POINTS AT THE RELEVANT ENTRY IN THE DATA SET TABLE.     03220000
*   REG. 6(DSNR) CONTAINS THE DATA SET NUMBER.                          03240000
*   REG. 12(FSAA) CONTAINS THE BASE ADDRESS OF IHIFSARA.                03260000
*   REGISTERS 13, 14 AND 15 ARE USED AS STANDARD SAVE, RETURN AND ENTRY 03280000
*   REGISTERS.                                                          03300000
*                                                                       03320000
*   PARAMETER VALUES AND OTHER INFORMATION ARE OFTEN TRANSMITTED        03340000
*   IMPLICITLY VIA THE COMMONLY ACCESSIBLE WORKING STORAGE IN THE       03360000
*   LOWER PART OF IHIFSARA AND (FOR I/O ROUTINES) VIA THE DATA SET      03380000
*   TABLE IN THE OBJECT MODULE.                                         03400000
*                                                                       03420000
*   THE MODULE WORKS FOR EITHER SINGLE OR DOUBLE FLOATING POINT         03440000
*   PRECISION. IT SENSES THE PRECISION FOR WHICH THE OBJECT MODULE WAS  03460000
*   COMPILED AND INITIALIZES ITSELF ACCORDINGLY. THE AREAS AFFECTED     03480000
*   ARE THE LIST OF FLOATING POINT INSTRUCTIONS AT FPINST AND THE       03500000
*   BLOCK OF INSTRUCTIONS STARTING AT CNVINST IN THE CONVERT ROUTINES.  03520000
*                                                                       03540000
*   THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL               03560000
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT    03580000
*   TO THE ONE USED AT ASSEMBLY TIME.                                   03600000
*   THE MODULE ALSO DEPENDS UPON DECIMAL NUMBERS TO BE CODED SO THAT    03620000
*   THE LOW ORDER FOUR BITS, WHEN CONSIDERED AS A BINARY INTEGER,       03640000
*   IDENTIFY THE VALUE OF THE DIGIT. THE MVI INSTRUCTION AT ALGTRMZ     03660000
*   IS USED FOR INSERTING THE PROPER ZONE BITS FOR UNPACKED DECIMAL     03680000
*   NUMBERS.                                                            03700000
         EJECT                                                          03720000
IHIFSARA START 0                                                        03740000
* RELEASE 19 CHANGES                                                    03745019
* 352400-352600                                                  A22570 03750019
* 128000,132200,138000                                           A28225 03753019
*                                                                A28226 03756019
*C138512,A138516,A143300                                         A39600 03758021
         SPACE 3                                                        03760000
*  USE OF GENERAL REGISTERS                                             03780000
         SPACE 3                                                        03800000
*              COMMON WORK REGISTERS                                    03820000
R0       EQU   0                                                        03840000
GR0      EQU   0                                                        03860000
R1       EQU   1                                                        03880000
GR1      EQU   1                                                        03900000
GP1      EQU   1                                                        03920000
R2       EQU   2                                                        03940000
GR2      EQU   2                                                        03960000
GP2      EQU   2                                                        03980000
R3       EQU   3                                                        04000000
GR3      EQU   3                                                        04020000
GP3      EQU   3                                                        04040000
R4       EQU   4                                                        04060000
GR4      EQU   4                                                        04080000
R5       EQU   5                                                        04100000
GRA      EQU   2                                                        04120000
GRB      EQU   3                                                        04140000
GRC      EQU   4                                                        04160000
GRD      EQU   5                                                        04180000
GRE      EQU   6                                                        04200000
GRF      EQU   7                        (ALSO IHIFSARB BASE REGISTER)   04220000
GRG      EQU   8                                                        04240000
GRH      EQU   9                                                        04260000
GRI      EQU   10                                                       04280000
         SPACE                                                          04300000
*              REGISTERS FOR COMMUNICATION WITH THE OBJECT MODULE       04320000
ADR      EQU   8                        ADDRESSING REGISTER             04340000
GDSA     EQU   9                        GLOBAL DSA                      04360000
CDSA     EQU   10                       CURRENT DSA                     04380000
PBT      EQU   11                       PROGRAM BLOCK TABLE             04400000
LAT      EQU   12                       LABEL ADDRESS TABLE             04420000
FSA      EQU   13                       IHIFSARA BASE REGISTER          04440000
STH      EQU   14                       TEMPORARY STORAGE               04460000
BRR      EQU   15                       BRANCH REGISTER                 04480000
         SPACE                                                          04500000
*              REGISTERS FOR COMMUNICATION WITH I/O SUBROUTINES         04520000
DSN      EQU   5                        DATA SET TABLE POINTER          04540000
DSNR     EQU   6                        DATA SET NUMBER                 04560000
FSAA     EQU   12                       ALTERNATE FSA BASE REGISTER     04580000
RETURN   EQU   14                                                       04600000
ENTRY    EQU   15                                                       04620000
         SPACE                                                          04640000
*              REGISTERS USED BY TRACE AND TERMINATION ROUTINES         04660000
RBUFP    EQU   4                        BYTE POINTER IN TRACE BUFFER    04680000
RSC      EQU   5                        SEMICOLON NUMBER                04700000
RBEG     EQU   6                        LOWER TRACE LIMIT               04720000
REND     EQU   7                        UPPER TRACE LIMIT               04740000
RBUF     EQU   8                        TRACE BUFFER ADDRESS            04760000
RBUFA    EQU   9                        ALTERNATE TRACE BUFFER ADDR.    04780000
RBUFL    EQU   10                       LENGTH OF TRACE BUFFER          04800000
RBUFC    EQU   11                       NUMBER OF TRACE RECORDS         04820000
         SPACE                                                          04840000
*              REGISTER USED BY SPDECL ROUTINE                          04860000
SPDABASE EQU   5                                                        04880000
         SPACE                                                          04900000
*              FLOATING POINT REGISTER                                  04920000
         SPACE                                                          04940000
FPR0     EQU   0                                                        04960000
         SPACE                                                          04980000
*  BIT PATTERNS                                                         05000000
         SPACE                                                          05020000
BETABM   EQU   X'0C'                    MASK FOR BETA BLOCK FLAG IN PBT 05040000
CODEPRM  EQU   X'10'                    MASK FOR CODE PROCEDURE IN PBT  05060000
PIMASK   EQU   X'04'                    MASK FOR PI-PROCEDURE IN PBT    05080000
RASLOADM EQU   X'FE'                    LOAD PROCEDURE ENTRY IN RAS     05100000
RASPARMM EQU   X'00'                    CAP OR CSWE ENTRY IN RAS        05120000
SHORTBIT EQU   X'10'                    F.P. OPCODE MODIFIER            05140000
DS0      EQU   X'80'                    ***                             05160000
DS15     EQU   X'01'                                               0219 05170015
DS3      EQU   X'10'                      * FLAGS IN                    05180000
DS236    EQU   X'32'                      *  DATA SET TABLE             05200000
DS11     EQU   X'10'                    ***                             05220000
         SPACE                                                          05240000
*  SWITCHES IN OPTSW                                                    05260000
         SPACE                                                          05280000
DPSW     EQU   X'80'                    DUMP  OPTION SWITCH             05300000
TRSW     EQU   X'40'                    TRACE OPTION SWITCH             05320000
SHSW     EQU   X'20'                    SHORT PRECISION OPTION SWITCH   05340000
TERMSW   EQU   X'10'                    TERMINATION ROUTINE ENTERED     05360000
ERROR    EQU   X'08'                    ERROR ROUTINE ENTERED           05380000
UT1ERR   EQU   X'04'                    ERROR ON SYSUT1                 05400000
PRNTERR  EQU   X'02'                    ERROR ON SYSPRINT               05420000
UCTRSW   EQU   X'41'                    UNCONDITIONAL TRACE OPTION      05440000
PPTRSW   EQU   X'01'                    TRACE PRECOMP. PROCEDURES       05460000
         SPACE                                                          05480000
*  ESD SYMBOLS                                                          05500000
         SPACE                                                          05520000
         ENTRY IHIFSAIN                                                 05540000
         SPACE                                                          05560000
         EXTRN IHIDSTAB                                                 05580000
         EXTRN IHIENTIF                                                 05600000
         EXTRN IHIIOROP,IHIIORCL,IHIIORNX,IHIIORCI,IHIIOREV        0226 05610015
         EXTRN IHIIOROQ,IHIIOREN,IHIIORGP,IHIIORCP,IHIIORER        0226 05620015
         EJECT                                                          05640000
         COPY  FSAREA                                                   05660000
         EJECT                                                          05680000
         COPY  FSACONV                                                  05700000
         SPACE                                                          05720000
         ORG   FSAREA+ADSTAB                                            05740000
         DC    A(IHIDSTAB)                                              05760000
         EJECT                                                          05780000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 05800000
*                                                                     * 05820000
*        INSTRUCTIONS INSERTED INTO THE BRANCH LIST AT BRLIST         * 05840000
*                                                                     * 05860000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 05880000
         SPACE 3                                                        05900000
         ORG   BRLIST                                                   05920000
         USING IHIFSARA,FSA                                             05940000
         SPACE                                                          05960000
          B    CAP1A                    CAP1                            05980000
         B     CAP2A                    CAP2                            06000000
         B     PROLP                    PROLOGP                         06020000
         B     PROL                     PROLOG                          06040000
         B     RETPROGA                 RETPROG                         06060000
         B     EPILP                    EPILOGP                         06080000
         B     EPILB                    EPILOGB                         06100000
         B     EPIL3                    EPILPR3                         06120000
         B     CSWE1A                   CSWE1                           06140000
         B     CSWE2A                   CSWE2                           06160000
         B     LOADPPA                  LOADPP                          06180000
*                                  TRACE                                06200000
         MVC   SCRCS(2,FSA),0(BRR)      INSERT SEMICOLON NUMBER         06220000
         B     2(BRR)                   MODIFIED TO NOP IF TRACE        06240000
         B     TRACEA                                                   06260000
*                                                                       06280000
         B     TERMN                    TERMNTE                         06300000
         BCR   0,BRR                    BCR                             06320000
         B     GETMAIN                  GETMSTO                         06340000
         B     VALUCAL                  VALUCALL                        06360000
         DC    A(ADRLST)                                           0226 06370015
         EJECT                                                          06380000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 06400000
*                                                                     * 06420000
*        E X I T S  F O R  E X E C U T I O N  E R R O R S             * 06440000
*                                                                     * 06460000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 06480000
         SPACE 3                                                        06500000
*        THIS ROUTINE CONTAINS ENTRY POINTS FOR ALL TYPES OF EXECUTION  06520000
*  ERRORS. IT STORES THE ERROR NUMBER AND LINKS TO THE ERROR ROUTINE    06540000
*  IHIFSAER.                                                            06560000
*        THE NUMBER OF EACH ERROR IS DETERMINED BY ITS POSITION IN      06580000
*  THE BRANCH LIST.                                                     06600000
         SPACE                                                          06620000
*  CALLING SEQUENCE                                                     06640000
*        BC    ERRORCONDITION,FSAERR+4*ERRORNUMBER(FSA)                 06660000
         SPACE                                                          06680000
         ORG   FSAERR+FSAREA                                            06700000
IHIFSAER EQU   *                                                        06720000
         BAL   GR1,FSAERRL               0                              06740000
         BAL   GR1,FSAERRL               1                              06760000
         BAL   GR1,FSAERRL               2                              06780000
         BAL   GR1,FSAERRL               3                              06800000
         BAL   GR1,FSAERRL               4                              06820000
         BAL   GR1,FSAERRL               5                              06840000
         BAL   GR1,FSAERRL               6                              06860000
         BAL   GR1,FSAERRL               7                              06880000
         BAL   GR1,FSAERRL               8                              06900000
         BAL   GR1,FSAERRL               9                              06920000
         BAL   GR1,FSAERRL              10                              06940000
         BAL   GR1,FSAERRL              11                              06960000
         BAL   GR1,FSAERRL              12                              06980000
         BAL   GR1,FSAERRL              13                              07000000
         BAL   GR1,FSAERRL              14                              07020000
         BAL   GR1,FSAERRL              15                              07040000
         BAL   GR1,FSAERRL              16                              07060000
         BAL   GR1,FSAERRL              17                              07080000
NOMAIN   EQU   *-FSAREA                                                 07100000
         BAL   GR1,FSAERRL              18                              07120000
         BAL   GR1,FSAERRL              19                              07140000
ERROR20  EQU   *                                                        07160000
OERR20   EQU   *-FSAREA                                                 07180000
PARERR   EQU   *-FSAREA                                                 07200000
         BAL   GR1,FSAERRL              20                              07220000
ERROR21  EQU   *                                                        07240000
         BAL   GR1,FSAERRL              21                              07260000
         BAL   GR1,FSAERRL              22                              07280000
         BAL   GR1,FSAERRL              23                              07300000
         BAL   GR1,FSAERRL              24                              07320000
         BAL   GR1,FSAERRL              25                              07340000
         BAL   GR1,FSAERRL              26                              07360000
ERROR27  EQU   *                                                        07380000
         BAL   GR1,FSAERRL              27                              07400000
ERROR28  EQU   *                                                        07420000
         BAL   GR1,FSAERRL              28                              07440000
ERROR29  EQU   *                                                        07460000
         BAL   GR1,FSAERRL              29                              07480000
ERROR30  EQU   *                                                        07500000
         BAL   GR1,FSAERRL              30                              07520000
ERROR31  EQU   *                                                        07540000
         BAL   GR1,FSAERRL              31                              07560000
ERROR32  EQU   *                                                        07580000
         BAL   GR1,FSAERRL              32                              07600000
ERROR33  EQU   *                                                        07620000
         BAL   GR1,FSAERRL              33                              07640000
ERROR34  EQU   *                                                        07660000
SWDMERR  EQU   *-FSAREA                                                 07680000
         BAL   GR1,FSAERRL              34                              07700000
ERROR35  EQU   *                                                        07720000
         BAL   GR1,FSAERRL              35                              07740000
ERROR36  EQU   *                                                        07760000
RASOVERF EQU   *-FSAREA                                                 07780000
         BAL   GR1,FSAERRL              36                              07800000
         BAL   GR1,FSAERRL              37                              07820000
         BAL   GR1,FSAERRL              38                              07840000
         BAL   GR1,FSAERRL              39                              07860000
         BAL   GR1,FSAERRL              40                              07880000
DDERROR  EQU   *-FSAREA                                                 07900000
         BAL   GR1,FSAERRL              41                              07920000
INVOPT   EQU   *-FSAREA                                                 07940000
         BAL   GR1,FSAERRL              42                              07960000
         BAL   GR1,FSAERRL              43                              07980000
         SPACE                                                          08000000
FSAERRL  EQU   *                   LINK TO ERROR ROUTINE IHIFSAERR      08020000
          N     GR1,=X'00FFFFFF'                                        08040000
         S     GR1,=A(IHIFSAER+4)       (ERRORNUMBER*4) IN GR1          08060000
         STC   GR1,FSAERCOD(FSA)                                        08080000
         TM    OPTSW(FSA),ERROR         TO PREVENT ENTERING             08100000
         BO    TERMAA                    ERROR ROUTINE                  08120000
         OI    OPTSW(FSA),ERROR           MORE THAN ONCE                08140000
 LINK EP=IHIERROR,PARAM=(FRDSA,SPDAP,IHIIOROP,IHIIORCP,IHIIORNX)   0219 08160015
         SPACE                                                          08180000
         USING IHIFSARB,GRF                                             08200000
TERMA    EQU   *                   ABNORMAL TERMINATION                 08220000
         L     GRF,=A(IHIFSARB)                                         08240000
         TM    OPTSW(FSA),TERMSW                                        08260000
         BO    ALGTRMAA                 IF ERROR IN TERM. ROUTINE       08280000
         B     ALGTRMA                                                  08300000
         SPACE                                                          08320000
TERMAA   EQU   *                   VERY ABNORMAL TERMINATION            08340000
         L     GRF,=A(IHIFSARB)                                         08360000
         B     ALGTRMAA                                                 08380000
         SPACE                                                          08400000
TERMN    EQU   *                   NORMAL TERMINATION                   08420000
         L     GRF,=A(IHIFSARB)                                         08440000
         B     ALGTRMN                                                  08460000
         DROP  GRF                                                      08480000
         ORG                                                            08500000
         EJECT                                                          08520000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 08540000
*                                                                     * 08560000
*    INSTRUCTIONS FOR SHORT OR LONG FLOATING POINT PRECISION          * 08580000
*                                                                     * 08600000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 08620000
         SPACE 3                                                        08640000
*  THE FOLLOWING INSTRUCTIONS ARE MODIFIED BY THE INITIALIZATION        08660000
*  ROUTINEFOR SHORT OR LONG PRECISION AS REQUIRED.                      08680000
         SPACE                                                          08700000
FPINST   EQU   *                                                        08720000
*                                       USED BY VALUCALL                08740000
VALLD    LE    0,0(R1)                                                  08760000
VALST    STE   0,0(R2)                                                  08780000
          SPACE                                                         08800000
*                                       USED BY SPDECL                  08820000
LINSTR   LE    0,0(GR2)                                                 08840000
STINSTR  STE   0,FCTVALST(FSA)                                          08860000
LTRINSTR LTER  0,0                                                      08880000
         NOPR  0                                                        08900000
FPINSTE  EQU   *                                                        08920000
LPRINSTR LPER  0,0                                                      08940000
         SPACE                                                          08960000
FPINSTAD DC    A(FPINST,4,FPINSTE)                                      08980000
         SPACE                                                          09000000
*  ONE OF THE FOLLOWING SETS OF INSTRUCTIONS IS INSERTED INTO THE       09020000
*  CONVERT ROUTINE BY THE INITIALIZATION ROUTINE IN ORDER TO SET UP     09040000
*  FOR LONG OR SHORT PRECISION AS REQUIRED.                             09060000
         SPACE                                                          09080000
CNVINSTE EQU   *                   SHORT PRECISION                      09100000
         STD   FPR0,CNVBUF2                                             09120000
         MVC   CNVBUF2+1(3),CNVCNST1+1                                  09140000
         AD    FPR0,CNVBUF2                                             09160000
         BR    ADR                                                      09180000
         STE   FPR0,CNVBUF3                                             09200000
         LD    FPR0,CNVBUF3                                             09220000
         B     ENTIER1                                                  09240000
         STE   FPR0,CNVBUF3                                             09260000
         LD    FPR0,CNVBUF3                                             09280000
         SPACE                                                          09300000
CNVINSTD EQU   *                   LONG PRECISION                       09320000
         BR    ADR                                                      09340000
         DC    14X'FF'                                                  09360000
         B     ENTIER1                                                  09380000
         DC    8X'FF'                                                   09400000
         AD    FPR0,CNVCNST2                                            09420000
         B     ENTIER1                                                  09440000
CNVINSTL EQU   *-CNVINSTD                                               09460000
         EJECT                                                          09480000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 09500000
*                                                                     * 09520000
*              G E T M A I N   R O U T I N E                          * 09540000
*                                                                     * 09560000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 09580000
         SPACE 3                                                        09600000
*        THIS ROUTINE ISSUES A CONDITIONAL GETMAIN IN RESPONSE TO A     09620000
*  REQUEST BY THE OBJECT MODULE FOR STORAGE FOR AN ARRAY. IF STORAGE    09640000
*  IS NOT AVAILABLE, AN ERROR EXIT IS TAKEN.                            09660000
         SPACE                                                          09680000
*  CALLING SEQUENCE                (ENTRY VIA BRLIST)                   09700000
*        BAL   ADR,GETMSTO(FSA)         LENGTH OF AREA IN GR0           09720000
*        ---                            RETURN WITH ADDRESS IN GR1      09740000
         SPACE                                                          09760000
GETMAIN  LR    GR2,GR0                  LENGTH VALUE                    09780000
         GETMAIN EC,LV=(GR2),A=GETMAINA                                 09800000
         LTR   ENTRY,ENTRY                                              09820000
         BNZ   NOMAIN(FSA)                                              09840000
         L     GR1,GETMAINA                                             09860000
          BR    ADR                     RETURN TO CALLING PROG          09880000
GETMAINA DC    A(0)                     ADDRESS OF THE AREA             09900000
         EJECT                                                          09920000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 09940000
*                                                                     * 09960000
*        C A L L  A C T U A L  P A R A M E T E R  R O U T I N E       * 09980000
*                                                                     * 10000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 10020000
         SPACE 3                                                        10040000
CAP1A    EQU   *                                                        10060000
CAPA     EQU   *                                                        10080000
         SPACE                                                          10100000
*        THIS ROUTINE IS AN INTERMEDIATE LINK BETWEEN A PROCEDURE       10120000
*  AND THE THUNK FOR AN ACTUAL PARAMETER TO THE PROCEDURE. IT SEARCHES  10140000
*  THE DSA CHAIN FOR THE DSA OF THE PROCEDURE DECLARATION. THEN IT      10160000
*  LOADS THE THUNK ADDRESS FROM THIS DSA, LOADS CDSA WITH THE DSA       10180000
*  ADRESS OF THE ENCLOSING BLOCK AND BRANCHES TO THE THUNK.             10200000
         SPACE                                                          10220000
*  CALLING SEQUENCE                (ENTRY VIA BRLIST)                   10240000
*        BAL    BRR,CAP1(FSA)                                           10260000
*        DC    H'PBN1'                  PBN OF PROCEDURE                10280000
*        DS    H                                                        10300000
*        L     ADR,DISPL(CDSA)          LOAD ADDRESS OF THUNK           10320000
*        ---                            RETURN FROM THUNK VIA CAP2      10340000
*                                       WITH PARAM ADDRESS IN ADR       10360000
         SPACE                                                          10380000
         L     STH,RASPT(FSA)           RAS POINTER FROM TOP            10400000
         ST    BRR,12(STH)             SAVE RETURN ADDRESS IN RAS  0050 10410018
         LH    GP1,0(BRR)              PBN OF PROCEDURE            0050 10420018
         LA    GP1,0(GP1,PBT)          PROCEDURE ENTRY IN PBT      0050 10430018
CAPI1    LA    STH,8(STH)               RESERVE ONE ENTRY IN RAS        10440000
         C     STH,RASPB(FSA)           CHECK FOR STACK                 10460000
         BNL   RASOVERF(FSA)            *OVERFLOW                       10480000
         ST    CDSA,0(0,STH)            SAVE DSA-POINTER IN RAS         10500000
         AH    PBT,8(CDSA)             ADDR OF CURRENT PBT ENTRY   0050 10550018
         L     GP2,0(CDSA)              LAST GENERATION DSA-POINTER IS  10600000
         ST    GP2,0(PBT)              *STORED IN PBT ENTRY        0050 10610018
         CR    GP1,PBT                 RIGHT PROCEDURE REACHED     0050 10620018
         EX    0,4(0,BRR)               LOAD ADDRESS OF THUNK           10640000
         L     CDSA,4(0,CDSA)           LOAD DYNAMICALLY ENCLOSING DSA  10660000
         LM    PBT,LAT,16(CDSA)         PBT AND LAT CAN BE DIFFERENT    10680000
         ST    STH,RASPT(FSA)           SAVE RAS TOP POINTER            10720000
         BCR   8,ADR                   TO THUNK OF ACTUAL PARAM    0050 10726018
*                                           IF RIGHT BLOCK REACHED 0050 10732018
         SR    GP2,GP2                 ZERO TO RETURN ENTRY IN     0050 10738018
         ST    GP2,12(STH)             *RAS INSTEAD OF BRR         0050 10744018
         B     CAPI1                                               0050 10750018
         SPACE 3                                                        10760000
CAP2A    EQU   *                                                        10780000
CAPB     EQU   *                                                        10800000
         SPACE                                                          10820000
*        THIS ROUTINE HANDLES THE TRANSFER FROM THE THUNK BACK TO THE   10840000
*  PROCEDURE. IT RELOADS CDSA WITH THE ADDRESS OF THE DSA THAT WAS      10860000
*  ACTIVE WHEN CAP1 WAS ENTERED.                                        10880000
         SPACE                                                          10900000
*  CALLING SEQUENCE                (ENTRY VIA BRLIST)                   10920000
         SPACE                                                          10940000
*        B     CAP2(FSA)                                                10960000
         SPACE                                                          10980000
         L     STH,RASPT(FSA)           RAS POINTER FROM TOP            11000000
CAPI3    L     CDSA,0(0,STH)            DSA-POINTER FROM RAS            11020000
         LM    PBT,LAT,16(CDSA)         PBT AND LAT CAN BE DIFFERENT    11040000
         L     BRR,4(STH)               RETURN ADDRESS FROM RAS         11060000
         SH    STH,EIGHT(FSA)           RELEASE ONE ENTRY IN RAS        11080000
         LH    GP1,8(CDSA)              PROGRAM BLOCK NUMBER TO REG     11100000
         ST    CDSA,0(GP1,PBT)          CURRENT DSA POINTER TO PBT      11120000
         LTR   BRR,BRR                  CALLING BLOCK REACHED           11140000
         BZ    CAPI3                    NO CONTINUE                     11160000
CAPI4    ST    STH,RASPT(FSA)           SAVE RAS TOP POINTER            11180000
         B     8(0,BRR)                 RETURN TO CALLING SEQUENCE      11200000
         EJECT                                                          11220000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 11240000
*                                                                     * 11260000
*              P R O L O G U E   P R O G R A M                        * 11280000
*                                                                     * 11300000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 11320000
         SPACE 3                                                        11340000
*        THIS ROUTINE IS EXECUTED WHENEVER A BLOCK OR PROCEDURE IS TO   11360000
*  BE ENTERED. IT CREATES AND INITIALIZES A NEW DSA. FOR A PROCEDURE    11380000
*  WITH PARAMETERS IT MOVES THE PARAMETER LIST TO THE DSA AND CHECKS IT 11400000
*  AGAINST THE FORMAL PARAMETER LIST IN THE PROCEDURE DECLARATION.      11420000
*  THEN IT ENTERS THE BLOCK OR PROCEDURE.                               11440000
*        THE ENTRY POINT PROLOGP IS USED ONLY WHEN THE PROCEDURE IS     11460000
*  CALLED VIA AN ACTUAL PARAMETER TO ANOTHER PROCEDURE.                 11480000
         SPACE                                                          11500000
*  CALLING SEQUENCE                (ENTRY VIA BRLIST)                   11520000
*        BAL   BRR,PROLOG(FSA)                                          11540000
*        MVI   PROLPBN(FSA),PBN         PBN OF BLOCK TO BE ENTERED      11560000
*                                  PARAMETER LIST FOR PROCEDURE         11580000
*        DC    A(THUNK1)                ADDR. OF THUNK FOR 1ST PARAM    11600000
*        DC    H'CH'                    CHARACTERISTICS OF 1ST PARAM    11620000
*        DC    H'N'                     NUMBER OF PARAMETERS            11640000
*         .                                                             11660000
*         .                                                             11680000
*         .                                                             11700000
*        DC    A(THUNKN)                ADDR OF THUNK FOR LAST PARAM    11720000
*        DC    H'CH'                                                    11740000
*        DC    H'0'                                                     11760000
         SPACE                                                          11780000
PROLP    EQU   *                                                        11800000
         MVI   PROLPBN-1(FSA),X'00'                              A28226 11806019
*  SET OFF SW SET BY GENERATE PROG TO DETECT ERR, SEE BELOW.     A28226 11812019
         LM    PBT,LAT,PROLREG(FSA)     UPDATE PBT AND LAT              11820000
         SPACE                                                          11840000
PROL     EQU   *                                                        11860000
         SPACE                                                          11880000
         LH    R3,PROLPBN-1(FSA)        CALLED PROGRAM BLOCK NUMBER     11900000
         SLL   R3,3                     CALCULATE PBT-DISPLACEMENT      11920000
         LTR   R2,R3                    STANDARD PROCEDURE CALLED       11940000
         BZ    SPDECL(0,FSA)            BRANCH IF YES                   11960000
         BM    OERR21(FSA)             ERROR, ACTUAL PROCEDURE   A28226 11964019
*  PARAMETER IS PARAMETERLESS WHILE FORMAL PROCEDURE IS CALLED   A28226 11968019
*  WITH PARAMETERS. PROLPBN-1 WAS SET TO X'FF' BY GENERATED PROG A28226 11972019
*  BEFORE CAP1 WAS CALLED.                                       A28226 11976019
         AR    R3,PBT                   ADDRESS OF PBT-ENTRY            11980000
         TM    6(R3),BETABM             PROCEDURE CALLED                12000000
         BZ    PROLOG1                  NO                              12020000
         C     ADR,ASTLOC(0,FSA)        COMP.CONT.OF ADR.WITH ADDR.OF   12040000
*                                       *FUNCTIONVALUESTORAGE           12060000
         BE    OERR21(0,FSA)            BRANCH IF EQUAL                 12080000
         TM    6(R3),CODEPRM            CODE PROCDURE CALLED            12100000
         BO    PROLOG2                  YES                             12120000
PROLOG1  LH    R0,4(R3)                 LENGTH OF DSA TO REG 0          12140000
         LR    R4,BRR                   SAVE BRR DURING GETMAIN         12160000
         GETMAIN R,LV=(0)               GETMAIN FOR DSA                 12180000
         LR    BRR,R4                                                   12200000
         L     R0,0(R2,PBT)             LOAD POINTER OF LAST GENERATION 12220000
         ST    R0,0(0,R1)               AND STORE IT IN DSA             12240000
         ST    CDSA,4(0,R1)             STORE POINTER OF EMBRACING PB.  12260000
         STH   R2,8(0,R1)               STORE PBT DISPLACEMENT          12280000
         MVI   10(R1),X'00'             ZEROS TO VALUE ARRAY AND        12300000
         MVC   11(5,R1),10(R1)          *ARRAY POINTERS                 12320000
         ST    R1,0(R2,PBT)             STORE CURR.DSA POINTER IN PBT   12340000
         LR    CDSA,R1                  SET CDSA POINTER                12360000
         STM   PBT,LAT,16(CDSA)                                         12380000
         L     STH,RASPT(FSA)           RAS-POINTER TOP                 12400000
         LA    STH,8(STH)               RESERVE ONE ENTRY               12420000
         C     STH,RASPB(FSA)           COMPARE WITH RAS-POINTER BOTTOM 12440000
         BNL   RASOVERF(FSA)            STACK OVERFLOW                  12460000
         ST    CDSA,0(0,STH)           *                                12480000
         MVI   0(STH),X'FF'            *                                12500000
         ST    STH,RASPT(FSA)           SAVE POINTER                    12520000
         TM    6(R3),BETABM             PROCEDURE CALLED                12540000
         BCR   8,BRR                    NO,USUAL BLOCK RETURN,EXIT 1    12560000
         SPACE 2                                                        12580000
A4       CLI   7(R3),X'00'              ANY FORMAL PARAMETERS           12600000
         BE    F4                       BRANCH IF ZERO                  12620000
         CLC   7(1,R3),7(BRR)           COMP.NR.OF FORM AND ACT.PARAM.  12640000
         BNE   OERR21(0,FSA)            BRANCH IF NOT EQUAL             12660000
         SR    R2,R2                                                    12680000
         IC    R2,7(R3)                 FETCH NUMBER OF PARAMETERS      12700000
         LR    R4,R2                    SAVE NUMBER IN REG 4            12720000
         SLL   R2,3                     CALCULATE LENGTH OF PARAMETER   12740000
         BCTR  R2,0                     *ENTRY-1                        12760000
         LA    R1,24(CDSA)             START OF PARAM. IF PROC.  A28225 12770019
         TM    6(R3),PIMASK             FUNCTION PROCEDURE CALLED       12780000
         BZ    PROLOG3                 YES                       A28225 12800019
         EX    R2,PIMOVE                                                12820000
         B     LOOP                                                     12840000
PIMOVE   MVC   24(1,CDSA),0(BRR)        MOVE PROCEDURE PARAMETERS       12860000
PHIMOVE  MVC   32(1,CDSA),0(BRR)        MOVE FUNCTION PARAMETERS        12880000
PROLOG3  EX    R2,PHIMOVE                                               12900000
         LA    R1,8(R1)                START OF PARAM. IF TYPE   A28225 12910019
LOOP     TM    0(ADR),X'01'             IS FORM.PAR.'STRING'            12920000
         BO    STRTST                   IF YES GO TO STRINGTEST         12940000
         CLI   1(ADR),X'D0'             IS FORM.PAR.'PROC.' WITHOUT TYP 12960000
         BE    PROTST                   IF YES GO TO PROCEDURETEST      12980000
         CLI   1(ADR),X'1C'             IS FORM.PAR.'SWITCH'            13000000
         BE    SWTTST                   IF YES GO TO SWITCHTEST         13020000
         TM    1(ADR),X'08'             IS FORM.PAR. 'LABEL'            13040000
         BO    LBLTST                   IF YES GO TO LABELTEST          13060000
         TM    1(ADR),X'04'             IS FORM.PAR. 'ARRAY'            13080000
         BO    ARRTST                   IF YES GO TO ARRAYTEST          13100000
         TM    1(ADR),X'C0'             IS FORM.PAR.A TYPPROCEDURE      13120000
         BO    TPRTST                   IF YES GO TO TYPPROCEDURETEST   13140000
         TM    5(BRR),X'04'             IS ACT.PAR. 'ARRAY'        5605 13146017
         BO    OERR20(0,FSA)            IF YES ERR.20              5605 13152017
TYPTST   TM    1(ADR),X'03'             TEST TYP                        13160000
         BM    ARITST                   IF ARITHM.TYP GO TO ARITH.TEST  13180000
         TM    5(BRR),X'03'             TEST IF ACT.PAR.IS BOOL         13200000
         BO    ASSFLAG                 YES, SPECIAL ASGNMENT TST A28225 13220019
         B     OERR20(0,FSA)            IF NOT GO TO ERR.20             13240000
STRTST   TM    4(BRR),X'01'             TEST IF ACT.PAR.IS 'STRING'     13260000
         BO    EXIT                     IF YES TEST NEXT PAR.           13280000
         B     OERR20(0,FSA)            IF NOT BRANCH TO OBJ.T.ERR.20   13300000
PROTST   TM    5(BRR),X'C0'             TEST IF ACT.PAR.IS 'PROCEDURE'  13320000
         BZ    OERR20(0,FSA)            IF NOT ERR.20                   13340000
         B     EXIT                     IF YES TEST NEXT PAR.           13360000
SWTTST   TM    5(BRR),X'0C'             TEST IF ACT.PAR.IS 'SWITCH'     13380000
         B     STRTST+4  IF YES TEST NEXT PAR.IF NOT GO TO ERR.20       13400000
LBLTST   TM    5(BRR),X'08'             TEST IF ACT.PAR.IS 'LABEL'      13420000
         BZ    OERR20(0,FSA)            IF NOT ERR.20                   13440000
         TM    5(BRR),X'04'             TEST IF ACT.PAR.IS 'SWITCH'     13460000
         BO    OERR20(0,FSA)            IF YES ERR.20                   13480000
         B     EXIT                     TEST NEXT PAR.                  13500000
ARRTST   TM    5(BRR),X'04'             TEST IF ACT.PAR.IS 'ARRAY'      13520000
         BZ    OERR20(0,FSA)            IF NOT ERR.20                   13540000
         B     TYPTST                   IF YES GO TO TYPTEST            13560000
TPRTST   TM    5(BRR),X'C0'             TEST IF ACT.PAR.IS 'PROCEDURE'  13580000
         BZ    OERR20(0,FSA)            IF NOT ERR.20                   13600000
         B     TYPTST                   IF YES GO TO TYPTEST            13620000
ARITST   TM    5(BRR),X'03'             ACTUAL PAR. ARITHMETIC          13640000
         BC    9,OERR20(FSA)            NO                              13660000
         TM    1(ADR),X'10'             FORMAL PARAMETER CALLED BY NAME 13680000
         BZ    PARAMPR                  NO                              13700000
         TM    1(ADR),X'02'             FORMAL PARAMETER REAL TYPE      13720000
         BZ    INTTST                   NO INTEGER TYPE                 13740000
         TM    5(BRR),X'02'             ACTUAL PARAMETER REAL           13760000
         BZ    OERR20(FSA)              NO ERROR                        13780000
         B     ASSFLAG2                SPECIAL ASGNMENT TST      A28225 13800019
INTTST   TM    5(BRR),X'01'        ACTUAL PARAMETER INTEGER             13820000
         BZ    OERR20(FSA)              NO ERROR                        13840000
         SPACE                                                          13840419
*  SPECIAL TST IF ACT PARAMETER IS FORMAL BY NAME AND THEN MOVE  A28225 13840819
*  THE ASGNMENT FLAG FR ACT PARAMETER ENT IN DSA TO THE NEW      A28225 13841619
*  PARAMETER ENT IN DSA OF BLK TO BE ENTERED.                    A28225 13842419
         SPACE                                                          13842519
*  NOTE: THIS CODE IS EXTREMELY DEPENDENT ON CODE GENERATED FOR  A28225 13842619
*        FORMAL PARAMETERS CALLED BY NAME.                       A28225 13842719
         SPACE                                                          13842819
ASSFLAG  TM    1(ADR),X'10'            FORMAL PARM. BY NAME      A28225 13843219
         BZ    PARAMPR                 NO                        A28225 13844019
ASSFLAG2 TM    5(BRR),X'10'            CHK IF ACT IS TYPE        A28225 13844819
         BZ    PARAMPR                      CALLED BY NAME       A28225 13845619
         TM    5(BRR),X'20'            IF NOT GO TO SPECIAL      A28225 13846419
         BO    PARAMPR                      PARAMETERLESS PR TST A28225 13847219
         L     R2,4(CDSA)              DSA OF CALLING SEQUENSE   A28225 13848019
         L     R2,16(R2)               PBT ADDR OF CALLING SEQ.  A28225 13848819
         L     R3,0(R1)                ADDR OF THUNK OF ACT PARM A28225 13849619
*                                           WHICH IS FORMAL      A28225 13850419
         MVC   ORI+5(1),11(R3)         MOVE DISPL OF PARAM FOUND A28225 13850619
*                                       IN THUNK CODE TO OR INST A28225 13850819
         IC    R3,4(R3)            DISPLACEMENT OF               A39600 13851221
         N     R3,MASKFF           PROCEDURE IN PBT              A39600 13851621
         L     R3,0(R3,R2)             ADDR OF DSA OF PROCEDURE  A28225 13852019
         LA    R3,4(R3)                ADDR CHARACTERISTIC PART  A28225 13854419
*                                           OF PARAMETER ENTRY   A28225 13855219
ORI      OC    4(1,R1),0(R3)           MOVE ASGNMENT BIT FROM    A28225 13856019
*                                       CALLING PARAMETER ENT IN A28225 13856819
*                                       DSA TO NEW DSA ENT       A28225 13857619
PARAMPR  EQU   *                   TEST IF ACTUAL PARAMETER IS          13860000
*                                  PARAMETERLESS PROCEDURE              13880000
         TM    5(BRR),X'C0'             ACTUAL PARAMETER PROCEDURE      13900000
         BZ    EXIT                     NO                              13920000
         TM    5(BRR),X'30'                                        0050 13926017
         BM    EXIT                                                0050 13932017
         TM    1(ADR),X'D0'             FORMAL PROC. CALLED BY NAME     13940000
         BO    EXIT                     YES EXIT                        13960000
         TM    4(BRR),X'C0'        PROCEDURE CALLED                     13980000
         BO    OERR20(FSA)                                         0050 14000017
EXIT     LA    BRR,8(0,BRR)             GET NEXT ACT.PAR.ADDR.          14020000
         LA    ADR,2(0,ADR)             GET NEXT FORM.PAR.ADDR.         14040000
         LA    R1,8(R1)                NEXT PARAMETER IN DSA     A28225 14050019
         BCT   R4,LOOP                  IF A NEXT PAR.OCCURS GO TO LOOP 14060000
F4       ST    BRR,4(0,STH)             STORE RETURN ADDRESS IN RAS     14080000
         BR    ADR                      EXIT 2                          14100000
         SPACE 2                                                        14120000
PROLOG2  EQU   *                   PRECOMPILED PROCEDURE CALLED         14140000
         L     R1,0(R3)                 ADDRESS OF PRECOMP PR CONST     14160000
         LM    PBT,LAT,0(R1)            LOAD NEW PBT AND LAT ADDRESSES  14180000
         CLC   7(1,R3),15(PBT)          PARAMETER DEFINITION IN CODE    14200000
*                                       *PROCEDURE SAME AS IN LOADED    14220000
*                                       *PRECOMPILED PROCEDURE          14240000
         BNE   OERR21(FSA)              NO,ERROR 21                     14260000
         L     ADR,8(R1)                PROCEDURE DECLAR.ENTRY POINT    14280000
         MVI   PROLPBN(FSA),1           PBN OF PROCEDURE IS 1           14300000
         B     PROLOG(FSA)              CALL PRECOMPILED PROCEDURE      14320000
MASKFF   DC    X'000000FF'         MASK TO CLEAR 3 BYTES OF REG  A39600 14330021
         EJECT                                                          14340000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 14360000
*                                                                     * 14380000
*              V A L U E  C A L L  R O U T I N E                      * 14400000
*                                                                     * 14420000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 14440000
         SPACE 3                                                        14460000
*               SUBROUTINE FOR HANDLING FORMAL PARAMETERS               14480000
*              CALLED BY VALUE                                          14500000
* USED FOR FORMAL PARAMETERS OF TYPE REAL,INTEGER OR BOOLEAN,INCLUDING  14520000
* ARRAYS.                                                               14540000
         SPACE                                                          14560000
*  CALLING SEQUENCE                (ENTRY VIA BRLIST)                   14580000
*        CALL ACTUAL PA{AMETER                                          14600000
*        BAL   BRR,VALUCALL(FSA)                                        14620000
*        DC    H'DISPL'                 FORMAL PARAMETER DISPLACEMENT   14640000
*        DC    XL2'  '                  CHARACTERISTIC OF PARAMETER     14660000
*        ---                            RETURN FROM VALUCALL            14680000
*  DISPL(CDSA) CONTAINS IF PARAMETER IS AN ARRAY ADDRESS OF SMF         14700000
*  OTHERWISE VALUE OF THE ACTUAL PARAMETER,CONVERTED IF NECESSARY       14720000
*                                                                       14740000
         SPACE                                                          14760000
VALUCAL  EQU   *                                                        14780000
         MVI   CONVFL,X'00'        ZERO TO CONVERSION FLAG              14800000
         ST    BRR,BRRSAVE         SAVE BRR,ADR                         14820000
         ST    ADR,ADRSAVE                                              14840000
         LH    R1,0(BRR)                                                14860000
VALUC10  LA    STH,0(R1,CDSA)                                           14880000
*                                                                       14900000
*              INSERT COMPONENT SIZE OF ORIGINAL                        14920000
*                                                                       14940000
         MVI   CSIZORIG+1,X'01'    ONE TO COMP SIZE INCASE BOOLEAN      14960000
         TM    5(STH),X'03'        TEST ACTUAL PARAMETER TYPE           14980000
         BO    VALUC12             BR IF BOOLEAN                        15000000
         MVI   CSIZORIG+1,X'04'    FOUR TO COMPONENT SIZE               15020000
         TM    5(STH),X'01'        TEST IF ACTUAL PAR 'INTEGER'         15040000
         BO     VALUC00            BR IF INTEGER                        15060000
         TM     OPTSW(FSA),X'20'   TEST PRECISION                       15080000
          BO    VALUC00            BR IF SHORT PRECISION                15100000
          MVI  CSIZORIG+1,X'08'    EIGHT TO COMPONENT SIZE              15120000
*                                                                       15140000
VALUC00  EQU   *                                                        15160000
         TM    5(STH),X'02'        TEST IF ACTUAL PARAMETER 'REAL'      15180000
         BO    VALUC11             BR IF YES                            15200000
*        ACTUAL PARAMETER INTEGER                                       15220000
*                                                                       15240000
         TM    3(BRR),X'01'        TEST IF FORMAL PAR 'INTEGER'         15260000
         BO    VALUC12                  BRANCH IF YES                   15280000
*                                                                       15300000
         MVI   CONVFL,X'01'        1 (= INTEGER TO REAL) TO FLAG        15320000
         B     VALUC12                                                  15340000
*                                                                       15360000
*        ACTUAL PARAMETER REAL                                          15380000
VALUC11  EQU   *                                                        15400000
         TM    3(BRR),X'02'        TEST IF FORMAL PAR 'REAL'            15420000
         BO    VALUC12                  BRANCH IF YES                   15440000
         MVI   CONVFL,X'03'        3 (=REAL TO INTEGER) TO FLG          15460000
*                                                                       15480000
VALUC12  EQU   *                                                        15500000
         MVC   CSIZCOPY+1(1),CSIZORIG+1      COPY COMPONENT SIZE        15520000
         TM    3(BRR),X'04'                                             15540000
         BO    VALUC21             BR IF ARRAY                          15560000
*                                                                       15580000
VALUC13  EQU   *                                                        15600000
         MVC   0(8,STH),0(ADR)     MOVE CONT OF 'ADR' TO CDSA           15620000
*                                                                       15640000
         LR    R1,STH                   ADDRESS OF FORMAL PARAM ENTRY   15660000
         LR    R2,R1                    STORE BACK AFTER CONVERSION     15680000
         LA    R5,4(BRR)           RETURN ADDRESS                       15700000
VALUC14  TM    CONVFL,X'03'             CONVERSION NECESSARY            15720000
         BCR   8,R5                     NO RETURN                       15740000
         BO    VALUC15                  REALL-INTEGER                   15760000
*  CALL INTEGER REAL CONVERSION ROUTINE                                 15780000
         L     STH,0(R1)                                                15800000
         BAL   ADR,CNVIRD(FSA)                                          15820000
         EX    0,VALST                                                  15840000
         BR    R5                       RETURN                          15860000
*CALL REAL-INTEGER CONVERSION ROUTINE                                   15880000
VALUC15  EX    0,VALLD                                                  15900000
         BAL   ADR,CNVRDI(FSA)                                          15920000
         ST    STH,0(R2)                                                15940000
         BR    R5                       RETURN                          15960000
*                                                                       15980000
*                                                                       16000000
*              HANDLE VALUE CALL OF ARRAY                               16020000
*                                                                       16040000
VALUC21  EQU   *                                                        16060000
         MVC   SIZEARR(4),16(ADR)         SIZE OF ORIGINAL ARRAY        16080000
         L     BRR,8(ADR)                                               16100000
         S     BRR,4(ADR)          DIFF (ADDRLOWCOMP - ADRZEROCOMP)     16120000
         ST    BRR,DIFFLZ                                               16140000
*                                                                       16160000
         MVI   SMFFL,X'00'          ZERO TO SMF-FLAG                    16180000
*                                                                       16200000
         TM    OPTSW(FSA),X'20'    TEST PRECISION                       16220000
         BO    VALUC31             BR IF SHORT PRECISION                16240000
         TM    CONVFL,X'03'        TEST CONV FLAG                       16260000
         BZ    VALUC31             BR IF NO CONV NECESS                 16280000
         MVC   SMFFL(1),CONVFL     CONV FLAG TO SMF-FLAG                16300000
*                                                                       16320000
         L     BRR,SIZEARR                                              16340000
         L     STH,DIFFLZ                                               16360000
         LH    R1,CSIZCOPY                                              16380000
         BO    VALUC25                                                  16400000
*                                                                       16420000
*              INCREM 'SIZEOFARRAY', DIFF AND COMPONENT SIZE            16440000
*                                                                       16460000
         SLA   BRR,1                                                    16480000
         SLA   STH,1                                                    16500000
         SLA   R1,1                                                     16520000
         B     VALUC26                                                  16540000
*                                                                       16560000
*              DECREMENT 'SIZE OF ARRAY', DIFF AND COMPONENT SIZE       16580000
*                                                                       16600000
VALUC25  EQU   *                                                        16620000
         SRA   BRR,1                                                    16640000
         SRA   STH,1                                                    16660000
         SRA   R1,1                                                     16680000
VALUC26  EQU   *                                                        16700000
         ST    BRR,SIZEARR                                              16720000
         ST    STH,DIFFLZ                                               16740000
         STH   R1,CSIZCOPY                                              16760000
*                                                                       16780000
*              EXECUTE SUBROUTINE WITH 'GETMAIN'                        16800000
*                                                                       16820000
VALUC31  EQU   *                                                        16840000
         SR    BRR,BRR                                                  16860000
         IC    BRR,0(ADR)          NUMBER OF SUBSCRIPTS                 16880000
         LA    BRR,5(BRR)                                               16900000
         SLA   BRR,2                                                    16920000
         CLI   CSIZCOPY+1,X'08'         REAL ARRAY LONG                 16940000
         BNE   VALUC32                  NO                              16960000
         TM    0(ADR),X'01'             SMF LENGTH DOUBLE WORDS         16980000
         BO     VALUC32                 YES                             17000000
         LA    BRR,4(BRR)               FOURCE ARRAY TO DOUBLE WORD     17020000
VALUC32  EQU   *                                                        17040000
         STC   BRR,SIZESMF+1       INSERT SIZE OF SMF                   17060000
         LH    0,SIZESMF                                                17080000
         A     0,SIZEARR           NUMBER OF BYTES REQUESTED            17100000
         BAL   ADR,GETMSTO(FSA)                                         17120000
*                                                                       17140000
*              COPY SMF                                                 17160000
*                                                                       17180000
         L     ADR,ADRSAVE                                              17200000
VALUC33  MVC   0(1,R1),0(ADR)                                           17220000
*                                                                       17240000
*              INSERT FIRST FOUR WORDS INTO SMF-COPY                    17260000
*                                                                       17280000
         MVC   2(2,R1),10(CDSA)         CHAIN DISPL FROM DSA            17300000
         L     BRR,BRRSAVE                                              17320000
         LH    R2,0(BRR)                DISPL OF OF FORMAL PARAM. ENTRY 17340000
         STH   R2,10(CDSA)              CHAIN DISPL                     17360000
         ST    R1,0(R2,CDSA)            ADDRESS OF VALUE ARRAY          17380000
*                                       TO FORMAL PARAMETER ENTRY       17400000
         LR     BRR,R1                                                  17420000
         AH     BRR,SIZESMF                                             17440000
         ST    BRR,8(R1)                                                17460000
         S     BRR,DIFFLZ                                               17480000
         ST    BRR,4(R1)                                                17500000
         A     BRR,DIFFLZ                                               17520000
         A     BRR,SIZEARR                                              17540000
         ST    BRR,12(R1)                                               17560000
*                                                                       17580000
*      COPY,   DOUBLE OR HALF P-VALUES INTO NEW SMF                     17600000
*                                                                       17620000
         LA    BRR,16(R1)                                               17640000
         LA    R2,16(ADR)                                               17660000
*                                                                       17680000
VALUC35  L     STH,0(R2)                                                17700000
         TM    SMFFL,X'03'         TEST IF P-VALUES MUST CHANGE         17720000
         BZ    VALUC36                                                  17740000
         SLL   STH,1                                                    17760000
         BM    VALUC36             BR IF FLAG=1 (INCREM IS OK)          17780000
         SRL   STH,2               DECREMENT INSTEAD                    17800000
VALUC36  ST    STH,0(BRR)                                               17820000
         LA    BRR,4(BRR)                                               17840000
         LA    R2,4(R2)                                                 17860000
         C     BRR,8(R1)                                                17880000
         BL    VALUC35                                                  17900000
*                                                                       17920000
*              COPY ARRAY                                               17940000
*                                                                       17960000
VALUC41  EQU   *                                                        17980000
*                                                                       18000000
*              INITIALIZE COPYING                                       18020000
*                                                                       18040000
         L     R3,SIZEARR               SIZE OF ARRAY                   18060000
         L     R2,8(R1)                 ADDRESS OF COPY ARRAY           18080000
         L     R1,8(ADR)                ADDRESS OF ORIGINAL ARRAY       18100000
         TM    CONVFL,X'03'             CONVERSION NESSESARRY           18120000
         BZ    VALUC61                  NO MOVE ARRAY                   18140000
VALUC51  BAL   R5,VALUC14          CONVERT ONE ELEMENT ,STORE IT        18160000
         AH    R1,CSIZORIG              NEXT ELEMENT FROM ORIGINAL      18180000
         AH    R2,CSIZCOPY              NEXT ELEMENT FROM "OPY          18200000
         SH    R3,CSIZCOPY                                              18220000
         BP    VALUC51                  CONTINUE IF ELEMENTS LEFT       18240000
VALUC52  L     BRR,BRRSAVE                                              18260000
         B     4(BRR)              RETURN                               18280000
VALUC61  LA    R4,255                   MAX IN ONE MOVE                 18300000
         BCTR  R3,0                     SIZE-1                          18320000
         CR    R3,R4                                                    18340000
         BNH   VALUC62                  NOT MORE THAN 256 BYTES         18360000
         EX    R4,VALUC63               MOVE 256 BYTES                  18380000
         SR    R3,R4                    REDUCE SIZE                     18400000
         LA    R1,256(R1)                                               18420000
         LA    R2,256(R2)                                               18440000
         B     VALUC61+4                CONTINUE                        18460000
VALUC62  EX    R3,VALUC63          MOVE LAST PART OF ARRAY              18480000
         B     VALUC52                  RETURN                          18500000
VALUC63  MVC   0(0,R2),0(R1)            ORIGINAL ARRAY TO COPY          18520000
*              WORK AREA                                                18540000
*                                                                       18560000
BRRSAVE  DC    F'0'                STORAGE OF BRR                       18580000
ADRSAVE  DC    F'0'                STORAGE AF 'ADR'                     18600000
DIFFLZ   DC    F'0'                DIFF BETW LOW AND ZERO COMPONENTS    18620000
SIZEARR  DC    F'0'                     SIZE OF ARRAY                   18640000
SIZESMF  DC    H'0'                SIZE OF SMF                          18660000
CSIZORIG DC    H'0'                COMPON SIZE, ORIGINAL                18680000
CSIZCOPY DC    H'0'                COMPON SIZE, COPY                    18700000
CONVFL   DC    X'00'               CONVERSION FLAG                      18720000
SMFFL    DC    X'00'                ARRAY SIZE FLAG                     18740000
*                                                                       18760000
         EJECT                                                          18780000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 18800000
*                                                                     * 18820000
*              R E T U R N   P R O G R A M                            * 18840000
*                                                                     * 18860000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 18880000
         SPACE 3                                                        18900000
*        THIS ROUTINE IS ENTERED WHEN A BRANCH IS MADE OUT OF A BLOCK   18920000
*  OR PROCEDURE BY MEANS OF A 'GO TO' STATEMENT. IT SEARCHES RAS FOR AN 18940000
*  ENTRY POINTING TO THE DSA OF THE TARGET BLOCK. FOR EACH BLOACK THAT  18960000
*  IS BYPASSED, THE FREEDSA ROUTINE IS INVOKED TO RELEASE STORAGE FOR   18980000
*  DSA AND ARRAYS.                                                      19000000
         SPACE                                                          19020000
*  CALLING SEQUENCE                (ENTRY VIA BRLIST)                   19040000
*        B     RETPROG(FSA)                                             19060000
         SPACE                                                          19080000
RETPROGA EQU   *                                                        19100000
         BALR  BRR,0                    SET RETURN REGISTER             19120000
         L     STH,RASPT(FSA)           FETCH RAS TOP POINTER           19140000
RETPR1   CLI   0(STH),RASPARMM          RAS PARAMETER ENTRY             19160000
         BNE   PBNENTRY                 NO                              19180000
         SH    STH,EIGHT(0,FSA)    CLEAR PARAMETERENTRY                 19200000
         B     RETPR1                   TEST NEXT ENTRY                 19220000
PBNENTRY IC    R1,0(STH)                SAVE FLAG                       19240000
         MVI   0(STH),X'00'             CLEAR FLAG                      19260000
         L     CDSA,0(STH)             UPDATE DSA REG              1512 19270018
         C     GDSA,0(0,STH)       COMPARE DSA-ADDRESS                  19280000
         STC   R1,0(STH)                RESTORE FLAG                    19300000
         ST    STH,RASPT(FSA)           SAVE RAS POINTER                19320000
         BCR   8,ADR                    IF EQUAL EXIT TO ADDRESS IN ADR 19340000
         B     FREEDSA(FSA)             FREE DSA SUBROUTINE IN EPILOG   19360000
         EJECT                                                          19380000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 19400000
*                                                                     * 19420000
*              E P I L O G U E   P R O G R A M                        * 19440000
*                                                                     * 19460000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 19480000
         SPACE 3                                                        19500000
*        THIS ROUTINE IS EXECUTED WHENEVER AN EXIT IS MADE FROM A       19520000
*  PROCEDURE (ENTRY POINT EPILOGP) OR BLOCK (ENTRY POINT EPILOGB) VIA   19540000
*  THE 'END' STATEMENT. IT CLEARS THE CORRESPONDING ENTRY FROM RAS AND  19560000
*  FREES THE STORAGE FOR DSA AND ARRAYS. IF THE EXIT WAS FROM A         19580000
*  PRECOMPILED PROCEDURE, THE PROCEDURE IS DELETED.                     19600000
         SPACE                                                          19620000
*  CALLING SEQUENCE                (ENTRY VIA BRLIST)                   19640000
*        B     EPILOGP(FSA)                                             19660000
         SPACE                                                          19680000
EPILP    EQU   *                                                        19700000
         MVC   FCTVALST(8,FSA),24(CDSA)     FUNCTION BALUE TO FSA       19720000
         LA    ADR,FCTVALST(FSA)        FUNCTION VALUE ADDRESS TO ADR   19740000
         BAL   BRR,FREEDSA(FSA)         LEAVE BLOCK AND UPDATE REG.     19760000
         L     STH,RASPT(FSA)                                           19780000
         L     BRR,12(STH)              RETURN ADDRESS FROM RAS         19800000
         BR    BRR                      RETURN                          19820000
         SPACE 3                                                        19840000
*  CALLING SEQUENCE                (ENTRY VIA BRLIST)                   19860000
*        B     EPILOGB(FSA)                                             19880000
         SPACE                                                          19900000
EPILB    EQU   *                                                        19920000
FREEDSA  EQU   EPILOGB             LEAVE A BLOCK,FREEMAIN UPDATE REG    19940000
FRDSA    EQU   *                                                        19960000
         ST    BRR,BRRST(FSA)           SAVE RETURN ADDRESS             19980000
         L     STH,RASPT(FSA)           FETCH RAS-POINTER               20000000
         SH    STH,EIGHT(FSA)           REDUCE RETURN ADDRESS STACK     20020000
         ST    STH,RASPT(FSA)           SAVE RAS-POINTER                20040000
         CLI   8(STH),RASLOADM          LOAD PROCEDURE ENTRY            20060000
         BNE   VTEST                    NO                              20080000
         L     R1,RASPB(FSA)            FETCH ADDRESS OF NAME OF        20100000
         LR    R0,R1                    *PROCEDURE TO BE DELETED        20120000
         LA    R1,8(R1)                 CLEAR PRECOMPILED PROCEDURE     20140000
         ST    R1,RASPB(FSA)            *NAME FROM RAS                  20160000
         DELETE  EPLOC=(0)                                              20180000
         B     FRDSA+4                  CONTINUE                        20200000
         SPACE 3                                                        20220000
********       V A L U E   A R R A Y   H A N D L I N G                  20240000
         SPACE 3                                                        20260000
EPIL3    EQU   *                                                        20280000
VTEST    SR    0,0                 CLEAR A WORKREGISTER                 20300000
         CH    0,10(0,CDSA)        TEST VALUE ARRAY FIELD               20320000
         BE    ATEST               IF ZERO GO TO NEXT TEST              20340000
         LH    R2,10(0,CDSA)       LOAD LAST VALUE ARRAY DISPLACEMENT   20360000
         L     R1,0(R2,CDSA)       LOAD ADDRESS OF STOR.MAP.FCT.        20380000
         L     R0,16(0,R1)         LOAD LENGTH OF ARRAY                 20400000
         LH    R2,2(0,R1)          LOAD BEFORE LAST VALUE ARRAY DISPL.  20420000
         STH   R2,10(0,CDSA)       STORE BEFORELAST VALUE ARRAY DISPL.  20440000
         SR    R2,R2               CLEAR A WORKREGISTER                 20460000
         IC    R2,0(0,R1)       ***                                     20480000
         LA    R2,1(0,R2)         *CALCULATE LENGTH OF STORAGE          20500000
         SLL   R2,2(0)            *   MAPPING FUNCTION                  20520000
         LA    R2,16(0,R2)      ***                                     20540000
         AR    R0,R2               ADD ST.MAP.FUCT.LENGTH AND ARR.LGTH. 20560000
         FREEMAIN R,LV=(0),A=(1)   FREEMAIN FOR VAL.ARR.INCL.ST.MAP.FCT 20580000
         B     VTEST               RETURN TO VALUE ARRAY TEST           20600000
         SPACE 3                                                        20620000
********       A R R A Y   H A N D L I N G                              20640000
         SPACE 3                                                        20660000
ATEST    SR    R0,R0               CLEAR A WORKREGISTER                 20680000
         CH    R0,14(0,CDSA)       TEST ARRAY FIELD                     20700000
         BE    DSAHDL              IF ZERO GO TO DSAHDL                 20720000
         LH    R2,14(0,CDSA)       LOAD LAST ARRAY DISPL.               20740000
         LH    R3,2(R2,CDSA)       LOAD BEFORE LAST ARRAY DISPL.        20760000
         STH   R3,14(0,CDSA)       STORE BEFORELAST ARRAY DISPL         20780000
         L     R1,8(R2,CDSA)       LOAD ADDRESS OF LOWEST COMPON.       20800000
         L     R0,16(R2,CDSA)      LOAD LENGTH OF ARRAY                 20820000
         FREEMAIN R,LV=(0),A=(1)   FREEMAIN FOR ARRAY                   20840000
         B     ATEST               RETURN TO ARRAY TEST                 20860000
         SPACE 3                                                        20880000
********       D S A   H A N D L I N G                                  20900000
         SPACE 3                                                        20920000
DSAHDL   LR    R1,CDSA             LOAD DSA-ADDRESS                     20940000
         LH    R2,8(CDSA)               LOAD PBT-DISPL.                 20960000
         L     R3,0(CDSA)               UPDATE DSA-ADDRESS              20980000
         ST    R3,0(R2,PBT)             *IN PBT                         21000000
         LH    R0,4(R2,PBT)             LENGTH OF DSA TO REG 0          21020000
         L     CDSA,4(0,CDSA)      RESET CDSA-POINTER                   21040000
         LM    PBT,LAT,16(CDSA)         UPDATE PBT AND LAT REGISTERS    21060000
         FREEMAIN R,LV=(0),A=(1)   FREEMAIN FOR DSA                     21080000
         L     BRR,BRRST(FSA)           RESTORE RETURN ADDRESS          21100000
         BR    BRR                 BRANCH                               21120000
         EJECT                                                          21140000
         SPACE                                                          21160000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 21180000
*                                                                     * 21200000
*        STANDARD PROCEDURE DECLARATION RUTINE                        * 21220000
*                                                                     * 21240000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 21260000
         SPACE 3                                                        21280000
*        ENTERED FROM THE PROLOG ROUTINE IF PBN IS ZERO, I. E. A        21300000
*  STANDARD PROCEDURE IS CALLED VIA AN ACTUAL PARAMETER TO AN ANOTHER   21320000
*  PROCEDURE.                                                           21340000
*        ON ENTRY, BRR CONTAINS THE ADDRESS OF THE PARAMETER LIST,      21360000
*  WHILE ADR CONTAINS THE INTERNAL NAME OF THE STANDARD PROCEDURE.      21380000
*        THE ROUTINE BUILDS THE PARAMETER LIST AND EXECUTES THE CALL    21400000
*  IN THE SAME WAY AS WOULD NORMALLY BE DONE BY THE GENERATED OBJECT    21420000
*  CODE. SINCE THE ROUTINE MAY BE ENTERED REPEATEDLY DURING THE         21440000
*  EVALUATION OF THE ACTUAL PARAMETERS, THE PARAMETER LIST AND OTHER    21460000
*  INFORMATION IS STORED IN A DYNAMIC AREA CALLED SPDA.                 21480000
         SPACE 3                                                        21500000
         DS    0H                                                       21520000
SPDECL   EQU   *-FSAREA                                                 21540000
         SPACE 3                                                        21560000
*  TEST FOR AUXILIARY ROUTINE INPUT OR OUTPUT                           21580000
         SPACE                                                          21600000
         LTR   ADR,ADR                                                  21620000
         BCR   2,ADR                    TO ROUTINE INPUT OR OUTPUT      21640000
         SPACE                                                          21660000
*  GET DYNAMIC STORAGE AREA                                             21680000
         SPACE                                                          21700000
SPDECL00 EQU   *                                                        21720000
         LR    GR2,BRR                  SAVE BRR DURING GETMAIN         21740000
         GETMAIN R,LV=SPDALG                                            21760000
         LR    BRR,GR2                                                  21780000
         MVC   0(4,GR1),SPDAP           INSERT CHAIN ADDRESS            21800000
         ST    GR1,SPDAP                STORE CURRENT AREA POINTER      21820000
         LR    SPDABASE,GR1                                             21840000
         USING SPDA,SPDABASE                                            21860000
         SPACE                                                          21880000
         ST    ADR,PRID                                                 21900000
         LR    GR4,LAT                  GR4 IS NOW LAT POINTER          21920000
         LR    GR0,ADR                                                  21940000
         LR    GR2,GR0                                                  21960000
         SRL   GR2,12                                                   21980000
         N     GR0,=F'3'                NUMBER OF FORMAL PARAMETERS     22000000
         BNZ   *+8                      ZERO MEANS ONE PARAMETER        22020000
         LA    GR0,1                                                    22040000
         CH    GR0,6(BRR)               COMPARE NUMBER OF ACTUAL PARAM. 22060000
         BNE   ERROR21                                                  22080000
         SPACE                                                          22100000
*  INITIALIZE FOR CREATING PARAMETER LIST                               22120000
         SPACE                                                          22140000
         LA    GR1,PARLIST                                              22160000
         LA    GR3,PARAMS                                               22180000
         MVI   0(GR1),0                                                 22200000
         MVC   1(11,GR1),0(GR1)         RESET PARAMETER LIST            22220000
SPDECL02 STC   GR2,FPTYPA                                               22240000
         STC   GR2,FPTYP                                                22260000
         XC    FPTYP,5(BRR)             COMPARE WITH ACTUAL PAR. CHAR.  22280000
         TM    FPTYP,X'07'                                              22300000
         BZ    SPDECL15                 IDENTICAL TYPES                 22320000
         BO    PARERR(FSA)              NOT COMPATIBLE TYPES            22340000
         SPACE                                                          22360000
*  TYPES ARE NOT IDENTICAL BUT MAY BE COMPATIBLE                        22380000
         SPACE                                                          22400000
         TM    FPTYPA,X'08'        TEST FOR VALUE OR NAME               22420000
         BO    PARERR(FSA)              CALL BY NAME AND NOT SAME TYPE  22440000
         TM    FPTYP,X'03'              TEST IF REAL-INTEGER COMPATIBLE 22460000
         BNO   PARERR(FSA)                                              22480000
         TM    5(BRR),X'03'             TEST ACTUAL PARAMETER           22500000
         BNM   PARERR(FSA)              IF NOT REAL OR INTEGER          22520000
         OI    0(GR1),X'80'             SET TYPE CONVERSION FLAG        22540000
         SPACE                                                          22560000
*  ACTIVATE THUNK TO GET ADDRESS OF ACTUAL PARAMETER                    22580000
         SPACE                                                          22600000
SPDECL15 STM   BRR,GR4,SPSAVE                                           22620000
         MVC   SPTHAD(4),0(BRR)         THUNK ADDR TO FULLWORD LOC.     22640000
         L     GR3,RASPT(FSA)                                           22660000
         LA    GR3,8(GR3)               NEXT ENTRY IN RAS               22680000
         C     GR3,RASPB(FSA)                                           22700000
         BNL   RASOVERF(FSA)            IF RAS FULL                     22720000
         ST    GR3,RASPT(FSA)                                           22740000
         ST    CDSA,0(GR3)              DSA POINTER TO RAS              22760000
         LM    PBT,LAT,16(CDSA)                                         22780000
          LA   GR2,SPDECL17-8                                           22800000
         ST    GR2,4(GR3)               ADDRESS USED BY CAP2            22820000
         L     BRR,SPTHAD               ADDRESS OF THUNK                22840000
         BR    BRR                      BRANCH TO THUNK                 22860000
         SPACE                                                          22880000
*  RETURN HERE VIA CAP2                                                 22900000
*  REG ADR CONTAINS ADDRESS OF ACTUAL PARAM                             22920000
         SPACE                                                          22940000
SPDECL17 EQU   *                                                        22960000
         L     SPDABASE,SPDAP           RESTORE SPDA POINTER            22980000
         LM    BRR,GR4,SPSAVE           RESTORE REGISTERS               23000000
         C     ADR,ASTLOC(FSA)                                          23020000
         BNE   SPDECL19                                                 23040000
         MVC   0(8,GR3),0(ADR)          SAVE PARAM VALUE IN SPDA        23060000
         LR    ADR,GR3                                                  23080000
SPDECL19 O     ADR,0(GR1)               COMBINE FLAGS AND PARAM ADDR    23100000
         ST    ADR,0(GR1)               STORE PARAM ADDR IN PARLIST     23120000
         TM    PRID,X'03'               TEST IF I/O PROCEDURE           23140000
         BNZ   SPDECL01                 BR. IF OTHER                    23160000
         SPACE                                                          23180000
*  I/O PROCEDURE                                                        23200000
         SPACE                                                          23220000
         TM    PRID+2,X'02'             TEST IF SYSACT                  23240000
         BZ    SPDECL01                 BR IF NO                        23260000
         CH    GR0,=H'1'                TEST IF THIRD PARAM             23280000
         BNE   SPDECL01                 BR IF NO                        23300000
         TM    4(BRR),X'08'             TEST IF ASSIGNMENT POSSIBLE     23320000
         BZ    SPDECL01                 BR IF YES                       23340000
         OI    0(GR1),X'40'             SET NO ASSIGNMENT FLAG          23360000
         SPACE                                                          23380000
SPDECL01 LA    GR1,4(0,GR1)             STEP PARLIST POINTER            23400000
         LA    GR3,8(0,GR3)             STEP PARAMETER POINTER          23420000
         LA    BRR,8(0,BRR)             STEP ACTUAL PARAMETER POINTER   23440000
         SRL   GR2,4                                                    23460000
         BCT   GR0,SPDECL02             BR IF MORE PARAMETERS           23480000
         SPACE                                                          23500000
*  PARAMETER LIST COMPLETE - ACTIVATE THE PROCEDURE                     23520000
         SPACE                                                          23540000
         ST    BRR,SPSAVE               SAVE RETURN ADDRESS             23560000
         LA    GR1,PARLIST                                              23580000
         TM    PRID+3,X'80'             TEST IF ABS/SIGN/LENGTH/ENTIER  23600000
         BO    SPDECL03                 BR IF YES                       23620000
         IC    GR2,PRID+3                                               23640000
         N     GR2,=X'000000FC'         GET DISPLACEMENT IN LAT         23660000
         L     ENTRY,0(GR2,GR4)         LOAD ADDRESS OF PROCEDURE       23680000
         TM    PRID,X'03'               TEST IF I/O PROCEDURE           23700000
         BNZ   SPDECL04                 BR IF NO                        23720000
         SPACE                                                          23740000
*  I/O PROCEDURE EXIT                                                   23760000
         SPACE                                                          23780000
         BALR  RETURN,ENTRY                                             23800000
         B     SPDECL18                                                 23820000
         SPACE                                                          23840000
SPDECL03 TM    PRID+3,X'50'                                             23860000
         BNM   SPDECL04                 BR IF ABS OR ENTIER FUNCTION    23880000
         TM    PRID+3,X'20'                                             23900000
         BZ    SPDECL05                 BR IF SIGN FUNCTION             23920000
         SPACE                                                          23940000
*  LENGTH FUNCTION                                                      23960000
         SPACE                                                          23980000
         L     GR1,0(GR1)                                               24000000
         MVC   HW(2,FSA),0(GR1)                                         24020000
         LH    GR0,HW(FSA)              LENGTH OF ENTIRE STRING FIELD   24040000
         BCTR  GR0,0                    REDUCE BY TWO TO GET            24060000
         BCTR  GR0,0                      ACTUAL STRING LENGTH          24080000
         ST    GR0,FCTVALST(FSA)                                        24100000
         B     SPDECL13                                                 24120000
         SPACE                                                          24140000
*  SIGN FUNCTION                                                        24160000
         SPACE                                                          24180000
SPDECL05 L     GR2,0(GR1)               LOAD PARAMETER ADDRESS          24200000
         SR    GR0,GR0                  INITIALIZE OUTPUT VALUE         24220000
         TM    0(GR1),X'80'             TEST FOR TYPE CONVERSION        24240000
         BO    SPDECL06                 BRANCH IF YES                   24260000
         EX    0,LINSTR                 VALUE TO F.P. REG. 0            24280000
         EX    0,LTRINSTR               TEST SIGN                       24300000
         B     SPDECL07                                                 24320000
SPDECL06 L     GR0,0(GR2)               VALUE TO G.P. REG. 0            24340000
         LTR   GR0,GR0                  TEST SIGN                       24360000
SPDECL07 BZ    SPDECL08                                                 24380000
         LA    GR0,1                    FUNCTION VALUE=1                24400000
         BP    SPDECL08                                                 24420000
         LCR   GR0,GR0                  FUNCTION VALUE=-1               24440000
SPDECL08 ST    GR0,FCTVALST(0,FSA)                                      24460000
         B     SPDECL13                                                 24480000
         SPACE                                                          24500000
*  MATHEMATICAL FUNCTIONS (INCLUDING ABS, ENTIER)                       24520000
         SPACE                                                          24540000
SPDECL04 L     GR2,0(GR1)                                               24560000
         TM    0(GR1),X'80'             TEST IF TYPE CONVERSION         24580000
         BZ    SPDECL09                                                 24600000
         L     STH,0(GR2)               LOAD PARAMETER VALUE            24620000
         BAL   ADR,CNVIRD(FSA)                                          24640000
         EX    0,STINSTR                                                24660000
         MVC   0(4,GR1),ASTLOC(FSA)     CHANGE PARAMETER ADDRESS        24680000
         B     SPDECL10                                                 24700000
SPDECL09 EX    0,LINSTR                                                 24720000
SPDECL10 CLI   PRID+3,X'80'             TEST IF ABS                     24740000
         BNE   SPDECL11                 BR IF NO                        24760000
         SPACE                                                          24780000
*  ABS FUNCTION                                                         24800000
         SPACE                                                          24820000
         EX    0,LPRINSTR               ABS VALUE TO F.P. REG 0         24840000
         B     SPDECL14                                                 24860000
         SPACE                                                          24880000
SPDECL11 CLI   PRID+3,X'F0'             TEST IF ENTIER                  24900000
         BNE   SPDECL12                                                 24920000
         SPACE                                                          24940000
*  ENTIER FUNCTION                                                      24960000
         SPACE                                                          24980000
         BAL   ADR,ENTIER(FSA)                                          25000000
         ST    STH,FCTVALST(FSA)                                        25020000
         B     SPDECL13                                                 25040000
         SPACE                                                          25060000
*  ALL OTHER FUNCTIONS                                                  25080000
         SPACE                                                          25100000
SPDECL12 BALR  RETURN,ENTRY             BR TO SUBROUTINE                25120000
SPDECL14 EX    0,STINSTR                                                25140000
SPDECL13 L     ADR,ASTLOC(FSA)          ADDRESS OF FUNCTION VALUE       25160000
         SPACE                                                          25180000
SPDECL18 EQU   *                   COMMON EXIT                          25200000
         SPACE                                                          25220000
         LR    GR1,SPDABASE                                             25240000
         MVC   SPDAP(4),0(GR1)          RESTORE PREV. D.A. POINTER      25260000
         L     GR2,SPSAVE               LOAD RETURN ADDR. (PREV. BRR)   25280000
         FREEMAIN R,A=(1),LV=SPDALG                                     25300000
         LM    PBT,LAT,16(CDSA)                                         25320000
         BR    GR2                      RETURN TO CALLING PROGRAM       25340000
         DROP  SPDABASE                                                 25360000
         SPACE                                                          25380000
*  CONSTANTS AND WORK AREAS                                             25400000
         SPACE                                                          25420000
SPTHAD   DC    F'0'                     TEMP. STORAGE FOR THUNK ADDR.   25440000
SPDAP    DC    F'0'                     POINTER TO CURRENT DYNAMIC AREA 25460000
FPTYP    DS    C                        TYPE OF FORMAL PARAMETER        25480000
FPTYPA   DS    C                        SAVE AREA FOR FPTYP             25500000
         SPACE                                                          25520000
*  DYNAMIC STORAGE AREA                                                 25540000
         SPACE                                                          25560000
SPDA     DSECT                                                          25580000
         DS    F                        LINK TO LOWER D.A.              25600000
SPSAVE   DS    6F                       REGS BRR,GR0,GR1,GR2,GR3,GR4    25620000
PRID     DS    F                        PROCEDURE IDENTIFICATION        25640000
PARLIST  DS    3F                       PARAMETER LIST                  25660000
PARAMS   DS    3D                       PARAMETER VALUES                25680000
SPDALG   EQU   *-SPDA                                                   25700000
         SPACE                                                          25720000
IHIFSARA CSECT                                                          25740000
         EJECT                                                          25760000
         SPACE                                                          25780000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 25800000
*                                                                     * 25820000
*              CALL SWITCH ELEMENT SUBROUTINE                         * 25840000
*                                                                     * 25860000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 25880000
         SPACE 3                                                        25900000
*  THIS ROUTINE IS AN INTERMEDIATE LINK BETWEEN A SWITCH DESIGNATOR     25920000
*  ANDA SWITCH LIST.IT SEARCHES THE DSA CHAIN FOR THE DSA OF THE        25940000
*  SWITCH LIST AND BRANCHES TO THE CALLED SWITCH LIST ENTRY             25960000
*  CALLING SEQUENCE                (ENTRY VIA BRLIST)                   25980000
* ADDRESS OF SWITCH LIST IN REG ADR,ADDRESS OF DSA FOR BLOCK IN WHICH   26000000
* SWITCH IS DECLARED IN REG GDSA AND THE SWITCH ELEMENT NUMBER IN BRR   26020000
         SPACE                                                          26040000
*        BAL   STH,CSWE1(FSA)                                           26060000
*         ---                           RETURN VIA CSWE2 WITH BRANCH    26080000
*                                       ADDRESS IN ADR AND ADDRESS OF   26100000
*                                       DSA IN GDSA                     26120000
         SPACE                                                          26140000
CSWE1A   EQU   *                                                        26160000
         SPACE 3                                                        26180000
         LTR   BRR,BRR                  ELEMENT NUMBER POSITIV          26200000
         BNH   SWDMERR(FSA)             NO,DIMENSION ERROR              26220000
         CH    BRR,2(ADR)               COMPARE NR WITH SWITCH LIST NR  26240000
         BH    SWDMERR(FSA)             DIMENSION ERROR                 26260000
         SLL   BRR,2                                                    26280000
         SPACE                                                          26300000
         L     GP3,RASPT(FSA)           RAS POINTER FROM TOP            26320000
CSWEI1   LA    GP3,8(GP3)               RESERVE ONE ENTRY IN RAS        26340000
         C     GP3,RASPB(FSA)           CHECK FOR STACK                 26360000
         BNL   RASOVERF(FSA)            *OVERFLOW                       26380000
         ST    CDSA,0(GP3)              STORE CDSA IN RAS               26400000
         ST    STH,4(GP3)               SAVE RETURN ADDRESS IN STACK    26420000
         SR    STH,STH                  NOT CALLING BLOCK INDICATION    26440000
         CR    CDSA,GDSA                SWITCH BLOCK REACHED            26460000
         BNE   CSWEI2                   NO                              26480000
         ST    GP3,RASPT(FSA)           SAVE RAS TOP POINTER            26500000
         L     BRR,0(BRR,ADR)           ADDRESS OF SWITCH ELEMENT       26520000
         BR    BRR                                                      26540000
         SPACE                                                          26560000
CSWEI2   LH    GP1,8(CDSA)              PROGRAM BLOCK DISPL.TO REG      26580000
         L     GP2,0(CDSA)              LAST GENERATION DSA-POINTER IS  26600000
         ST    GP2,0(GP1,PBT)           *STORED IN PROGRAM BLOCK TABLE  26620000
         L     CDSA,4(CDSA)             LOAD DYNAMICALLY ENCLOSING DSA  26640000
         LM    PBT,LAT,16(CDSA)         PBT AND LAT CAN BE DIFFERENT    26660000
         B     CSWEI1                   CONTINUE                        26680000
         SPACE 3                                                        26700000
         SPACE 3                                                        26720000
*  THIS ROUTINE HANDLES THE TRANSFER FROM THE SWITCH LIST BACK TO THE   26740000
*  SWITCH DESIGNATOR . IT RELOADS CDSA WITH THE ADDRESS OF THE DSA THAT 26760000
*  WAS ACTIVE WHEN CSWEU WAS ENTERED                                    26780000
*  CALLING SEQUENCE                (ENTRY VIA BRLIST)                   26800000
*        B     CSWE2(FSA)                                               26820000
         SPACE 3                                                        26840000
CSWE2A   EQU   *                                                        26860000
         SPACE                                                          26880000
         L     GP3,RASPT(FSA)           RAS POINTER FROM TOP            26900000
CSWEI3   L     STH,4(GP3)               RETURN ADDRESS FROM STACK       26920000
         SH    GP3,EIGHT(FSA)           RELEASE ONE ENTRY IN RAS        26940000
         ST    GP3,RASPT(FSA)           SAVE RAS TOP POINTER            26960000
         LTR   STH,STH                  RETURN ADDRESS FOUND            26980000
         BCR   7,STH                    YES RETURN                      27000000
         L     CDSA,0(GP3)             NEW DSA-POINTER FROM RAS    0050 27010018
         LH    GP1,8(CDSA)              PROGRAM BLOCK DISPL. TO REG     27020000
         ST    CDSA,0(GP1,PBT)          CURRENT DSA-POINTER TO PBT      27040000
         LM    PBT,LAT,16(CDSA)         PBT AND LAT CAN BE DIFFERENT    27080000
         B     CSWEI3                   CONTINUE                        27100000
         EJECT                                                          27120000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 27140000
*                                                                     * 27160000
*        L O A D  P R E C O M P I L E D  P R O C E D U R E            * 27180000
*                                                                     * 27200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 27220000
         SPACE 3                                                        27240000
*        THIS ROUTINE IS ENTERED FROM THE DECLARATION OF A 'CODE'       27260000
*  PROCEDURE. IT SEARCHES THE BOTTOM PART OF RAS FOR THE NAME OF THE    27280000
*  PROCEDURE. IF IT IS NOT FOUND, THE PRECOMPILED PROCEDURE WITH THE    27300000
*  SAME NAME IS LOADED AND ENTRIES ARE MADE IN RAS FOR THE NAME AND     27320000
*  FOR THE ENTRY POINT.                                                 27340000
*        THE ENTRY POINT ADDRESS IS ALSO STORED IN THE PROGRAM          27360000
*  BLOCK TABLE.                                                         27380000
         SPACE                                                          27400000
*  CALLING SEQUENCE                (ENTRY VIA BRLIST)                   27420000
*        BAL   ADR,LOADPP(FSA)                                          27440000
*        DC    CL8(PPNAME)              NAME OF PRECOMP. PROCEDURE      27460000
*        DC    H'PBN'                   PROG BLOCK NUMBER               27480000
         SPACE                                                          27500000
LOADPPA  EQU   *                                                        27520000
         LM    R3,R4,RASEND(FSA)        RASEND AND RASPB TO REG.        27540000
         LA    R2,8                     INCREMENT 8                     27560000
LOADPP2  CR    R3,R4                                                    27580000
         BNH   LOADPP1                  BRANCH IF STACK EMPTY           27600000
         CLC   0(8,R4),0(ADR)           PROCEDURE ALREADY LOADED        27620000
         LA    R4,8(R4)                 STEP TO NEXT PP NAME            27640000
         BNE   LOADPP2                  NO,NAME NOT FOUND               27660000
         L     R3,RASPT(FSA)            RAS POINTER FROM TOP            27680000
         S     R4,RASPB(FSA)                                            27700000
         SRL   R4,3                     NAME FOUND IN ENTRY NR R4       27720000
LOADPP3  SR    R3,R2                                                    27740000
         CLI   8(R3),RASLOADM           LOAD PROCEDURE ENTRY            27760000
         BNE   LOADPP3                  NO,CONTINUE SEARCH              27780000
         BCT   R4,LOADPP3               BRANCH IF NOT RIGH ENTRY        27800000
         L     R0,12(R3)                FETCH ADDRESS OF CONSTANTS      27820000
         B     LOADPP4                                                  27840000
LOADPP1  EQU   *                   PROCEDURE MUST BE LOADED             27860000
         L     R3,RASPT(FSA)                                            27880000
         L     R4,RASPB(FSA)                                            27900000
         AR    R3,R2                    RESERVE ONE ENTRY FROM TOP      27920000
         SR    R4,R2                    RESERVE ONE ENTRY FROM BOTTOM   27940000
         CR    R3,R4                    CHECK FOR                       27960000
         BNL   RASOVERF(FSA)            *STACK OVERFLOW                 27980000
         ST    R4,RASPB(FSA)            STORE UPDATED STACK POINTER     28000000
         ST    R3,RASPT(FSA)                                            28020000
         MVC   0(8,R4),0(ADR)           ENTER NAME IN STACK             28040000
         LR    R0,R4                    R0 POINT TO NAME                28060000
         LOAD  EPLOC=(0)                                                28080000
         ST    CDSA,0(R3)               SAVE CDSA IN RAS-ENTRY          28100000
         MVI   0(R3),RASLOADM           INSERT LOAD PROCEDURE FLAG      28120000
         ST    R0,4(R3)                 STORE ADDRESS TO ENTRY CONSTANT 28140000
LOADPP4  LH    R3,8(ADR)                FETCH PBN CODE PROCEDURE        28160000
         ST    R0,0(R3,PBT)             ADDR.OF PRECOMPILED PROCEDURE   28180000
*                                       CONSTANT TO CODE PROC.PBT ENTRY 28200000
*                                       CONSTANT A(PBT),A(LAT),A(ENTRY) 28220000
         B     10(ADR)                  RETURN TO DECLARATION END       28240000
         EJECT                                                          28260000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 28280000
*                                                                     * 28300000
*                       T R A C E  R O U T I N E                      * 28320000
*                                                                     * 28340000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 28360000
         SPACE 3                                                        28380000
*        THIS ROUTINE IS EXECUTED WHENEVER THE END OF AN ALGOL          28400000
*  STATEMENT IS REACHED, IF ANY OF THE PARAMETERS TRACE, TRBEG OR       28420000
*  TREND WAS SPECIFIED. IT CHECKS IF THE SEMICOLON NUMBER IS            28440000
*  WITHIN A TRACE AREA AND, IF THIS IS THE CASE, STORES IT IN A BUFFER  28460000
*  FOR OUTPUT ON SYSUT1 WHEN THE BUFFER OVERFLOWS.                      28480000
*        WHEN A DISCONTINUITY IS ENCOUNTERED (TRANSFER INTO A TRACE     28500000
*  AREA OR BETWEEN THE MAIN PROGRAM AND A PRECOMPILED PROCEDURE),       28520000
*  THE NAME OF THE ACTIVE MODULE IS ALSO STORED IN THE BUFFER.          28540000
*        THE FORMAT OF THE INFORMATION IN THE BUFFER IS                 28560000
*        DC    H'LENGTH'                POINTER TO NEXT FREE PLACE      28580000
*        DS    H                        NOT USED                        28600000
*        DC    H'SC'                    SEMICOLON NUMBER                28620000
*         .                                                             28640000
*         .                                                             28660000
*        DC    H'0'                     FLAG FOR MODULE NAME            28680000
*         DC    CL4'NAME'               MODULE NAME (FIRST 4 CHAR)      28700000
*        DC    H'SC'                    SEMICOLON NUMBER                28720000
*         .                                                             28740000
*         .                                                             28760000
*                                                                       28780000
*        THE ROUTINE IS ENTERED VIA INSTRUCTIONS IN THE BRANCH LIST     28800000
*  AT BRLIST. THESE INSTRUCTIONS STORE THE SEMICOLON NUMBER AND THEN    28820000
*  EXECUTE A BRANCH EITHER TO THIS ROUTINE OR, IF TRACE WAS NOT         28840000
*  REQUESTED, DIRECTLY BACK TO THE ALGOL PROGRAM.                       28860000
         SPACE                                                          28880000
         SPACE                                                          28900000
*  CALLING SEQUENCE                                                     28920000
*        BAL   BRR,TRACE(FSA)                                           28940000
*        DC    H'SC'                    SEMICOLON NUMBER                28960000
*        ---                       (RETURN POINT)                       28980000
         SPACE 3                                                        29000000
TRACEA   STM   14,12,TRSAVE                                             29020000
         L     GR3,=A(IHIFSARB)                                         29040000
         USING IHIFSARB,GR3                                             29060000
         LR    GR1,PBT                                                  29080000
         LM    RBEG,REND,TRBEG          LOAD TRACE LIMITS               29100000
         LM    RBUF,RBUFC,TRBUF         LOAD BUFFER PARAMETERS          29120000
         LH    RBUFP,0(0,RBUF)          LOAD BYTE POINTER               29140000
         LH    GR2,TRL1                 LENGTH OF NORMAL TRACE ITEM     29160000
         SPACE                                                          29180000
         CLC   4(4,GR1),TRMPNAME        TEST IF MAINP OR PRECOMP PROC   29200000
         BE    TRACE10                  MAINP                           29220000
         TM    OPTSW(FSA),PPTRSW        TEST FOR TRACE IN PRECOMP. PR.  29240000
         BZ    TRACE6                   NO P.P. TRACE              0207 29250014
         TM    TRFLAG,X'03'             P.P.CALLED FROM TRACE AREA 0207 29260014
         BM    TRACE0                   YES TRACE REQUIRED         0207 29270014
         B     TRACE6                   CONDITIONAL - NO P.P. TRACE     29280000
TRACE10  LH    RSC,SCRCS(FSA)           LOAD CURRENT SEMICOLON NR       29300000
         CR    REND,RBEG                TEST INTERVAL LIMITS            29320000
         BNH   TRACE13                  SINGLE INTERVAL                 29340000
         CR    RSC,RBEG                 CHECK SC AGAINST LIMITS         29360000
         BL    TRACE15                  OUTSIDE INTERVAL                29380000
         CR    RSC,REND                                                 29400000
         BH    TRACE15                  OUTSIDE INTERVAL                29420000
         B     TRACE16                  INSIDE INTERVAL                 29440000
TRACE13  CR    RSC,REND                 DOUBLE INTERVAL                 29460000
         BH    TRACE14                                                  29480000
TRACE16  MVI   TRFLAG1,1                INSIDE LOWRE INTERVAL           29500000
         B     TRACE18                                                  29520000
TRACE14  CR    RSC,RBEG                                                 29540000
         BL    TRACE15                  OUTSIDE BOTH INTERVALS          29560000
         MVI   TRFLAG1,2                INSIDE HIGHER INTERVAL          29580000
TRACE18  CLC   TRFLAG1,TRFLAG           HAS BORDER BEEN CROSSED         29600000
         BE    TRACE0                   BR IF SAME INTERV. AS BEFORE    29620000
         MVC   TRFLAG,TRFLAG1                                           29640000
         B     TRACE5                                                   29660000
TRACE15  MVI   TRFLAG,0                 NO TRACE THIS TIME              29680000
         B     TRACE6                                                   29700000
         SPACE                                                          29720000
TRACE0   CLC   4(4,GR1),TRPGID+2        HAS PROGID CHANGED              29740000
         BE    TRACE1                                                   29760000
TRACE5   MVC   TRPGID+2(4),4(GR1)       STORE NEW PROGID                29780000
         LH    GR2,TRL2                 LENGTH OF ITEM WITH PROGID      29800000
TRACE1   LR    GR0,GR2                  IS BUFFER FILLED                29820000
         AR    GR0,RBUFP                                                29840000
         CR    GR0,RBUFL                                                29860000
         BL    TRACE2                   BR IF STILL ROOM                29880000
*                                                                       29900000
         LTR   RBUFC,RBUFC              IF NO RECORDS WRITTEN,          29920000
         BZ    TRACE4                     BYPASS CHECK                  29940000
         CHECK TRCHECK                                                  29960000
TRACE4   WRITE TRCHECK,SF,,(RBUF),MF=E                                  29980000
         LR    GR0,RBUF                 ***                             30000000
         LR    RBUF,RBUFA                 *  SWITCH BUFFERS             30020000
         LR    RBUFA,GR0                  *                             30040000
         LA    RBUFP,4                  ***  AND RESET POINTER          30060000
         LA    RBUFC,1(0,RBUFC)         STEP RECORD COUNTER             30080000
*                                                                       30100000
TRACE2   CH    GR2,TRL1                 TEST FOR NEW PROGID             30120000
         BE    TRACE3                                                   30140000
*                                                                       30160000
         LR    GR1,RBUF                                                 30180000
         AR    GR1,RBUFP                                                30200000
         MVC   0(6,GR1),TRPGID          PROGID TO BUFFER                30220000
         LA    RBUFP,6(0,RBUFP)                                         30240000
*                                                                       30260000
TRACE3   LR    GR1,RBUF                                                 30280000
         AR    GR1,RBUFP                                                30300000
         MVC   0(2,GR1),SCRCS(FSA)      SEMICOLON COUNTER TO BUFFER     30320000
         LA    RBUFP,2(0,RBUFP)                                         30340000
         STH   RBUFP,0(0,RBUF)                                          30360000
         STM   RBUF,RBUFC,TRBUF                                         30380000
TRACE6   LM    14,12,TRSAVE                                             30400000
         B     2(BRR)                   RETURN TO ALGOL PROGRAM         30420000
*                                                                       30440000
TRL1     DC    H'2'                     LENGTH OF SEMICOLON FIELD       30460000
TRL2     DC    H'8'                     LENGTH OF NEW NAME + SEMICOLON  30480000
TRPGID   DC    H'0'                     FLAG FOR PROGID                 30500000
         DC    2H'0'                    FIRST FOUR BYTES OF PROGR. NAME 30520000
         DC    X'FFFF'                  INITIAL VALUE FOR TREND         30540000
TRBEG    DC    F'0'                     BEGINNING OF TRACE AREA         30560000
TREND     DC   F'0'                     END OF TRACE AREA               30580000
TRFLAG   DC    X'00'                    STATUS INDICATOR                30600000
*                                         00 - OUTSIDE BOTH TRACE AREAS 30620000
*                                         01 - INSIDE LOWER AREA        30640000
*                                         02 - INSIDE HIGHER AREA       30660000
TRFLAG1  DC    X'00'                    PREVIOUS VALUE OF TRFLAG        30680000
TRMPNAME DC    CL4' '                   NAME OF MAIN PROGRAM            30700000
         SPACE                                                          30720000
TRSAVE   EQU   FSAREA+ASAVE+12                                          30740000
         DROP  GR3                                                      30760000
         EJECT                                                          30780000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 30800000
*                                                                     * 30820000
*        P R O G R A M  I N T E R R U P T  R O U T I N E              * 30840000
*                                                                     * 30860000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 30880000
         SPACE 3                                                        30900000
PIEROUT  EQU   *                                                        30920000
         USING PIEROUT,ENTRY                                            30940000
         L     FSA,=A(IHIFSARA)                                         30960000
         MVC   PGOPSW(8,FSA),4(GR1)                                     30980000
         LH    GR2,PGOPSW+2(0,FSA)      LOAD INTERRUPTION CODE          31000000
         N     GR2,PGCMASK              REMOVE IMPRECISE CODES (M/91)   31020000
         SLA   GR2,2                                                    31040000
         LA    GR2,PIETAB(GR2)          GET ENTRY IN ERROR TABLE        31060000
PIEROUT2 MVC   9(3,GR1),1(GR2)          CHANGE RETURN ADDR IN OPSW      31080000
         BR    RETURN                                                   31100000
         DROP  ENTRY                                                    31120000
         SPACE                                                          31140000
         DS    0A                                                       31160000
PGCMASK  DC    X'0000000F'              MASK FOR INTERRUPT CODE         31180000
PIETAB   EQU   *                                                        31200000
         DC    A(ERROR33)               PSW CODE 0 - ONLY WITH MOD/91   31220000
         DC    A(ERROR33)     ***                                       31240000
         DC    A(ERROR33)       *                                       31260000
         DC    A(ERROR33)       *                                       31280000
         DC    A(ERROR33)       *  PSW CODES 1-7                        31300000
         DC    A(ERROR33)       *                                       31320000
         DC    A(ERROR33)       *                                       31340000
         DC    A(ERROR33)     ***                                       31360000
         DC    A(ERROR28)     FIXED PT OVFL     PSW CODE  8             31380000
         DC    A(ERROR30)     FIXED PT DIVIDE   PSW CODE  9             31400000
         DC    A(ERROR33)    (DECIMAL OVERFLOW  PSW CODE 10 CANT OCCUR) 31420000
         DC    A(ERROR33)    (DECIMAL DIVIDE    PSW CODE 11 - MASKED)   31440000
         DC    A(ERROR29)     EXPONENT OVERFLOW PSW CODE 12             31460000
         DC    A(ERROR33)    (EXPONENT UNDERFL  PSW CODE 13 - MASKED)   31480000
         DC    A(ERROR33)    (FLOAT PT SIGNIF.  PSW CODE 14 - MASKED)   31500000
         DC    A(ERROR31)     FLOAT PT DIVIDE   PSW CODE 15             31520000
         EJECT                                                     0226 31521015
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *  0226 31522015
*                                                               *  0226 31523015
*   ADDRESSLIST OF ENTRYPOINTS IN IHIIOR USED BY I/O ROUTINES   *  0226 31524015
*                                                               *  0226 31525015
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *  0226 31526015
         SPACE 3                                                   0226 31527015
ADRLST   DC    A(IHIIORCI)                                         0226 31528015
         DC    A(IHIIORCL)                                         0226 31529015
         DC    A(IHIIOREV)                                         0226 31530015
         DC    A(IHIIORNX)                                         0226 31531015
         DC    A(IHIIOROP)                                         0226 31532015
         DC    A(IHIIOROQ)                                         0226 31533015
         DC    A(IHIIOREN)                                         0226 31535015
         DC    A(IHIIORGP)                                         0226 31537015
         DC    A(IHIIORER)                                         0226 31538015
         EJECT                                                          31540000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 31560000
*                                                                     * 31580000
*              I N I T I A L  E N T R Y  P O I N T                    * 31600000
*                                                                     * 31620000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 31640000
         SPACE 3                                                        31660000
         DROP  FSA                                                      31680000
         DS    0H                                                       31700000
IHIFSAIN EQU   *                                                        31720000
         USING IHIFSAIN,ENTRY                                           31740000
         SAVE  (14,12)                                                  31760000
         L     FSAA,=A(IHIFSARA)                                        31780000
         ST    FSA,4(0,FSAA)            LINK SAVE AREAS TOGETHER        31800000
         ST    FSAA,8(0,FSA)                                            31820000
         LR    FSA,FSAA                                                 31840000
         L     GRF,=A(IHIFSARB)                                         31860000
         USING IHIFSARB,GRF                                             31880000
         B     ALGIN                    TO INITIALIZATION ROUTINE       31900000
         DROP  ENTRY                                                    31920000
         DROP  GRF                                                      31940000
         EJECT                                                          31960000
IHIFSARB CSECT                                                          31980000
         SPACE                                                          32000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 32020000
*                                                                     * 32040000
*         I N I T I A L I Z A T I O N  R O U T I N E                  * 32060000
*                                                                     * 32080000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 32100000
         SPACE 3                                                        32120000
*    THIS IS THE FIRST ROUTINE EXECUTED WHEN AN ALGOL PROGRAM IS        32140000
*  CALLED FROM THE O.S. OR FROM A CALLING PROGRAM.                      32160000
*    IT PERFORMS CERTAIN INITIALIZING FUNCTIONS AND THEN TRANSFERS      32180000
*  CONTROL TO THE ALGOL OBJECT PROGRAM.                                 32200000
*                                                                       32220000
         USING IHIFSARA,FSA                                             32240000
         USING IHIFSARB,GRF                                             32260000
         SPACE 3                                                        32280000
ALGIN    EQU   *                                                        32300000
*                                                                       32320000
         SPIE  PIEROUT,((1,9),12,15)    EXIT FOR RELEVANT PROG. CHECKS  32340000
         ST    GR1,FSAPICA(0,FSA)                                       32360000
         SPACE                                                          32380000
*  GET STORAGE FOR RETURN ADDRESS STACK AND INITIALIZE RAS POINTERS     32400000
         SPACE                                                          32420000
         GETMAIN R,LV=2048                                              32440000
         SH    GR1,EIGHT(0,FSA)                                         32460000
         ST    GR1,RASPT(0,FSA)                                         32480000
         ST    GR1,RASSTART(0,FSA)                                      32500000
         LA    GR1,2056(0,GR1)                                          32520000
         ST    GR1,RASPB(0,FSA)                                         32540000
         ST    GR1,RASEND(0,FSA)                                        32560000
         SPACE                                                          32580000
         SR    CDSA,CDSA                                           0173 32584014
         L     DSN,ADSTAB(FSA)         INITILIZE DSENTRIES FOR     0214 32584214
         L     GRA,0(0,DSN)            S P K Q                     0214 32584414
         LA    DSN,4(0,DSN)                                        0214 32584614
         LTR   GRA,GRA                 Q. IS THERE A PGCF          0214 32584814
         BM    ALGIN01-4                                           0214 32585014
         LA    GR1,2048                YES                         0214 32585214
         ST    GR1,16(0,GRA)           INSERT BE LENGTH            0214 32585414
         ST    CDSA,24(0,GRA)          INITILIZE S, TYP IN PGCF    0214 32585614
         N     GRA,=X'00FFFFFF'                                    0214 32585814
ALGIN01  CR    GRA,DSN                                             0214 32586014
         BE    ALGIN02                                             0214 32586214
         MVC   20(6,DSN),DSINIT                                    0214 32586414
         LA    DSN,LTH(0,DSN)                                      0214 32586614
         B     ALGIN01                                             0214 32586814
ALGIN02  STH   CDSA,TRPGID             INITILIZE TRACE COUNTERS    0214 32587014
         ST    CDSA,TRPGID+2                                       0214 32587214
         STC   CDSA,TRFLAG                                         0214 32587414
         MVI   TRPGID+6,X'FF'                                      0214 32587614
         MVI   TRPGID+7,X'FF'                                      0214 32587814
         STH   CDSA,SCRCS(FSA)          INITIALIZE SEMICOLON COUNT 0173 32588014
         ST    CDSA,ANOTTAB(FSA)        RESET NOTE TABLE ADDRESS   0173 32592014
         ST    CDSA,SPDAP               RESET SPECIAL DECL.POINTER 0173 32596014
*  TEST EXECUTION TIME OPTIONS AND SET SWITCHES                         32600000
         SPACE                                                          32620000
*  TEST FOR SHORT/LONG PRECISION                                        32640000
         SPACE                                                          32660000
         L     GRA,=A(IHIENTIF)         GET S/L SWITCH                  32680000
         MVC   OPTSW(1,FSA),8(GRA)        FROM THE OBJECT MODULE        32700000
         MVC   CNVINST(CNVINSTL),CNVINSTE  ASSUME SHORT                 32720000
         LA    GRA,SETSHORT                                             32740000
         TM    OPTSW(FSA),SHSW                                          32760000
         BO    ALGIN4              IF SHORT                             32780000
          MVC  CNVINST(CNVINSTL),CNVINSTD    MODIFY CONVERT ROUTINE     32800000
         LA    GRA,4(0,GRA)                                             32820000
ALGIN4   EQU   *                                                        32840000
         LM    GRB,GRD,FPINSTAD         MODIFY FLOATING POINT           32860000
         EX    0,0(GRA)                  INSTRUCTIONS                   32880000
         BXLE  GRB,GRC,*-4                                              32900000
         SPACE                                                          32920000
*  CHECK EXECUTION PARAMETERS DUMP AND TRACE                            32940000
         SPACE                                                          32960000
ALGIN0   EQU   *                                                        32980000
         OI    TRACE+7(FSA),X'F0'       DEACTIVATE BRANCH TO TRACE RT.  33000000
         MVC   TRPGID+2(4),TRPGID+1     RESET PROGID FOR TRACE          33020000
         MVC   TRBEG(8),TRPGID          INITIALIZE TRACE LIMITS         33040000
         L     GRA,4(0,FSA)                                             33060000
         L     GRA,24(0,GRA)            ADDR OF PARAMETER LIST          33080000
         LTR   GRA,GRA                                                  33100000
         BZ    ALGIN1                   BRANCH IF NO PARAMETERS         33120000
         L     GRA,0(0,GRA)        ADDR OF PARAMETER FIELD              33140000
         LA    GRA,0(0,GRA)             RESET HIGH ORDER BYTE           33160000
         LH    GRB,0(0,GRA)                                             33180000
         LTR   GRB,GRB                  LENGTH OF PARAMETER FIELD       33200000
         BZ    ALGIN1                   NO PARAMETERS                   33220000
         AR    GRB,GRA                  END OF PARAMETER FIELD          33240000
         LA    GRD,LASTPARM             END OF PARAMETER LIST           33260000
         SR    GRE,GRE                                                  33280000
FNDCOMMA CLI   2(GRA),C','                                              33300000
         BNE   FNDPAR                                                   33320000
STEP1    LA    GRA,1(0,GRA)                                             33340000
COMP1    CR    GRA,GRB                                                  33360000
         BL    FNDCOMMA                                                 33380000
         B     ALGIN2                   WHOLE PARM FIELD SCANNED        33400000
FNDPAR   LA    GRC,PARMLIST                                             33420000
         USING PARMLIST,GRC                                             33440000
NXTPAR   IC    GRE,PARMLG               LENGTH OF PARAMETER             33460000
         EX    GRE,COMPINST             COMPARE WITH ENTRY IN LIST      33480000
         BNE   NOTFOUND                                                 33500000
         LA    GR1,1(GRA,GRE)                                           33520000
         EX    0,PABRANCH                                               33540000
CHKCOMMA CLI   2(GR1),C','              CHECK FOR COMMA AFTER PARAM     33560000
         BE    SETBIT                                                   33580000
         CR    GR1,GRB                  IF NO COMMA CHECK FOR END OF    33600000
         BL    STEP1                      PARAMETER FIELD               33620000
SETBIT   LR    GRA,GR1                                                  33640000
         EX    0,PARMSET                                                33660000
         B     COMP1                                                    33680000
NOTFOUND CR    GRC,GRD                  CHECK FOR END OF LIST           33700000
         LA    GRC,PARLG(0,GRC)                                         33720000
         BL    NXTPAR                   NEXT ENTRY IN LIST              33740000
         B     INVOPT(FSA)              OPTION NOT FOUND IN LIST        33760000
         SPACE                                                          33780000
COMPINST CLC   2(0,GRA),PARM                                            33800000
         DROP  GRC                                                      33820000
         SPACE                                                          33840000
*  EVALUATE TRBEG OR TREND PARAMETER                                    33860000
         SPACE                                                          33880000
TRLIM1   LA    GRG,TRBEG                                                33900000
         B     TRLIM2+4                                                 33920000
TRLIM2   LA    GRG,TREND                                                33940000
         CLI   2(GR1),C'='                                              33960000
         BNE   INVOPT(FSA)                                              33980000
         LA    GRH,5(0,GR1)             END OF NUMBER FIELD             34000000
         SR    GRI,GRI                  RESET NUMBER ACCUMULATOR        34020000
TRLIM4   LA    GR1,1(0,GR1)             STEP TO NEXT DIGIT              34040000
         CR    GR1,GRB                                                  34060000
         BNL   TRLIM3                   BR IF END OF WHOLE PARAM FIELD  34080000
         CLI   2(GR1),C','                                              34100000
         BE    TRLIM3                   BR IF END OF THIS PARAMETER     34120000
         CR    GR1,GRH                                                  34140000
         BH    INVOPT(FSA)              BR IF TOO MANY DIGITS           34160000
         CLI   2(GR1),C'0'              CHECK FOR VALID DIGIT           34180000
         BL    INVOPT(FSA)                                              34200000
         CLI   2(GR1),C'9'                                              34220000
         BH    INVOPT(FSA)                                              34240000
         MVN   TRLDIG+1(1),2(GR1)       EXTRACT NEW DIGIT               34260000
         MH    GRI,=H'10'                                               34280000
         AH    GRI,TRLDIG               ACCUMULATE SUM                  34300000
         B     TRLIM4                                                   34320000
TRLIM3   ST    GRI,0(GRG)               STORE AS TRBEG OR TREND         34340000
         B     SETBIT                                                   34360000
         SPACE                                                          34380000
TRLDIG   DC    H'0'                     TEMP. STORAGE FOR DIGIT         34400000
         SPACE                                                          34420000
*  PREPARE FOR PROGRAM TRACING                                          34440000
         SPACE                                                          34460000
ALGIN2   EQU   *                                                        34480000
         TM    DTSW(FSA),TRSW           IS TRACE REQUESTED              34500000
         BZ    ALGIN1                                                   34520000
         OPEN  (DCBUT1,(OUTIN))         OPEN SYSUT1 FOR USE BY TRACE    34540000
         LA    GRB,DCBUT1                                               34560000
         USING IHADCB,GRB                                               34580000
         TM    DCBOFLGS,X'10'           CHECK IF SYSUT1 OPENED          34600000
         BO    ALGIN3                                                   34620000
         NI    DTSW(FSA),255-TRSW       TRACE SWITCH OFF                34640000
         LA    DSNR,17                                                  34660000
         B     DDERROR(FSA)                                             34680000
ALGIN3   EQU   *                                                        34700000
         NI    TRACE+7(FSA),X'0F'       ACTIVATE BRANCH TO TRACE ROUT   34720000
         LH    GR0,DCBBLKSI             GET BLOCK SIZE FROM DCB         34740000
         DROP  GRB                                                      34760000
         ST    GR0,TRBUFL               STORE AS BUFFER LENGTH          34780000
         SLA   GR0,1                                                    34800000
         GETMAIN R,LV=(0)               GET TWO BUFFERS FOR SYSUT1      34820000
         ST    GR1,TRBUF                ADDRESS OF FIRST BUFFER         34840000
         SR    GR0,GR0                                                  34860000
         ST    GR0,TRCNT                RESET RECORD COUNTER            34880000
         LA    GR0,4                    SET BYTE POINTER                34900000
         STH   GR0,0(0,GR1)                                             34920000
         A     GR1,TRBUFL                                               34940000
         ST    GR1,TRBUFA               ALTERNATE BUFFER                34960000
         SPACE                                                          34980000
*  INITIALIZE REGISTERS AND ENTER OBJECT MODULE                         35000000
         SPACE                                                          35020000
ALGIN1   EQU   *                                                        35040000
         SR    CDSA,CDSA                                                35060000
         L     ENTRY,=A(IHIENTIF)                                       35120000
         LM    PBT,LAT,0(ENTRY)                                         35140000
         L     GRA,16                                                   35160000
         L     GRA,0(GRA)                                               35180000
         L     GRA,4(GRA)               GET TCB ADDRESS                 35200000
         L     GRA,0(GRA)               GET REQUEST BLOCK ADDRESS       35220000
         L     GRA,12(0,GRA)           INSERT MODULE             A22570 35230019
         MVC   4(4,PBT),8(GRA)              NAME INTO            A22570 35240019
         MVC   TRMPNAME,8(GRA)                   PBTAB           A22570 35250019
         L     ENTRY,8(0,ENTRY)                                         35280000
         BR    ENTRY                    ENTER ALGOL PROGRAM             35300000
         SPACE                                                          35320000
*  DCB EXIT ROUTINE FOR SYSUT1                                          35340000
         SPACE                                                          35360000
         USING IHADCB,GR1                                               35380000
         DS    0F                                                       35400000
DCBEXIT  DC    X'85',AL3(DCBEXIT+4)                                     35420000
         LH    GRA,DCBBLKSI                                             35440000
         LTR   GRA,GRA                  CHECK IF BLOCKSIZE SPECIFIED    35460000
         BNZ   DCBEXIT1                 BR. IF YES                      35480000
DCBEXIT2 LA    GRA,TRBUFST              OTHERWISE USE STANDARD SIZE     35500000
         STH   GRA,DCBBLKSI                                             35520000
DCBEXIT3 RETURN                                                         35540000
DCBEXIT1 CH    GRA,TRBUFMIN             CHECK BLOCKSIZE                 35560000
         BL    DCBEXIT2                 (IF TOO LOW OR TOO HIGH,        35580000
         CH    GRA,TRBUFMAX              USE STANDARD SIZE)             35600000
         BH    DCBEXIT2                                                 35620000
         B     DCBEXIT3                                                 35640000
         DROP  GR1                                                      35660000
         SPACE                                                          35680000
TRBUFMIN DC    H'14'                    MINIMUM TRACE BUFFER SIZE       35700000
TRBUFMAX DC    H'32760'                 MAXIMUM TRACE BUFFER SIZE       35720000
TRBUFST  EQU   2048                     STANDARD TRACE BUFFER SIZE      35740000
DSINIT   DC    X'000100500200'         INITILIZE DSTAB             0214 35746014
LTH      EQU   X'24'                                               0214 35752014
*                                                                       35760000
         SPACE                                                          35780000
SETSHORT OI    0(GRB),SHORTBIT          MODIFY F.P. INSTR FOR SHORT     35800000
         NI    0(GRB),255-SHORTBIT                         OR LONG PR.  35820000
         SPACE 3                                                        35840000
********       TABLE FOR DECODING OPTION PARAMETERS            ******** 35860000
         SPACE 3                                                        35880000
PARMLIST DS    0H                                                       35900000
PARMLG   DC    AL1(3)                   (LENGTH - 1) OF KEYWORD         35920000
PARM     DC    CL5'DUMP'                OPTION KEYWORD                  35940000
PABRANCH B     CHKCOMMA                 EXIT TO EVALUATION ROUTINE      35960000
PARMSET  OI    DTSW(FSA),DPSW           SET FLAG BIT                    35980000
PARLG    EQU   *-PARMLG                                                 36000000
         DC    AL1(4)                                                   36020000
         DC    CL5'TRACE'                                               36040000
         B     CHKCOMMA                                                 36060000
         OI    DTSW(FSA),UCTRSW                                         36080000
         SPACE                                                          36100000
         DC    AL1(4)                                                   36120000
         DC    CL5'TRBEG'                                               36140000
         B     TRLIM1                                                   36160000
         OI    DTSW(FSA),TRSW                                           36180000
LASTPARM EQU   *                                                        36200000
         DC    AL1(4)                                                   36220000
         DC    CL5'TREND'                                               36240000
         B     TRLIM2                                                   36260000
         OI    DTSW(FSA),TRSW                                           36280000
         EJECT                                                          36300000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 36320000
*                                                                     * 36340000
*              T E R M I N A T I O N  R O U T I N E                   * 36360000
*                                                                     * 36380000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 36400000
         SPACE 3                                                        36420000
*    THIS ROUTINE IS ENTERED EITHER FROM THE ALGOL PROGRAM UPON PASSING 36440000
*  THE FINAL 'END' STATEMENT (NORMAL TERMINATION) OR FROM THE ERROR     36460000
*  ROUTINE (ABNORMAL TERMINATION).  IN EITHER CASE IT EDITS AND PRINTS  36480000
*  THE TRACE INFORMATION IF ANY, CLOSES ALL DATA SETS AND RESTORES THE  36500000
*  REGISTERS AS THEY WERE AT THE TIME OF ENTRY TO THE ALGOL PROGRAM.    36520000
*  THEN IT RETURNS TO OS OR THE CALLING PROGRAM. THE COMPLETION CODE    36540000
*  IS SET TO ZERO (NORMAL) OR FOUR (ABNORMAL TERMINATION).              36560000
         SPACE                                                          36580000
ALGTRMA  MVI   COMPCODE+3,4             ENTRY IN CASE OF ERROR          36600000
         B     ALGTRM0                                                  36620000
         SPACE                                                          36640000
ALGTRMN  EQU   *                   NORMAL ENTRY                         36660000
         MVI   COMPCODE+3,0                                             36680000
ALGTRM0  EQU   *                                                        36700000
         LR    FSAA,FSA                 PREPARE FOR                     36720000
         L     DSN,ADSTAB(0,FSA)         OUTPUT TO SYSPRINT             36740000
         LA    DSN,DSTLG+4(0,DSN)         BY MEANS OF I/O ROUTINES      36760000
         LA    DSNR,1                                                   36780000
         USING DDSTAB,DSN                                               36800000
         TM    COMPCODE+3,X'04'                                    0219 36805015
         BO    ALGTRM00                                            0219 36810015
         OI    DS+1,DS15            FLAG CLOSE FROM IHIFSA         0219 36815015
         L     ENTRY,=V(IHIIORCP)       CLOSE ALL DATA SETS USED        36820000
         BALR  RETURN,ENTRY                                             36840000
ALGTRM00 OI    OPTSW(FSA),TERMSW    FLAG TERM. ROUTINE ENTERED     0219 36860015
         TM    OPTSW(FSA),PRNTERR                                       36880000
         BZ    ALGTRM16                 IF SYSPRINT OK                  36900000
         SPACE                                                          36920000
         WTO   MF=(E,WTOTRM)            WRITE END EXEC MESSAGE          36940000
         B     ALGTRM10                                                 36960000
         SPACE                                                          36980000
ALGTRM16 OI    DS+1,DS11                RE-OPEN SYSPRINT FOR            37000000
         OI    DS,DS236                   TRACE AND TERM. OUTPUT        37020000
         TM    COMPCODE+3,X'04'                                    0219 37026015
         BO    ALGTRM1A                                            0219 37032015
         L     ENTRY,=V(IHIIOROP)                                       37040000
         BALR  RETURN,ENTRY                                             37060000
         B     ALGTRM1B                                            0219 37065015
ALGTRM1A MVI   S+1,X'32'                                           0219 37070015
ALGTRM1B BAL   RETURN,BLANK                                        0219 37075015
         OI    DS,DS3                                                   37100000
         L     ENTRY,=V(IHIIORNX)                                       37120000
         BALR  RETURN,ENTRY                                             37140000
ALGTRM1  TM    DTSW(FSA),TRSW                                           37160000
         BZ    ALGTRM11                 BR. IF NO TRACE OPTION          37180000
         TM    OPTSW(FSA),UT1ERR                                        37200000
         BO    ALGTRM18                 IF SYSUT1 ERROR                 37220000
         LM    RBUF,RBUFC,TRBUF         LOAD BUFFER PARAMETERS          37240000
         LTR   RBUFC,RBUFC                                              37260000
         BZ    ALGTRM2                  BR. IF NO RECORDS WRITTEN       37280000
         CHECK TRCHECK                  CHECK LAST RECORD WRITTEN       37300000
         LH    RBUFP,0(0,RBUF)                                          37320000
         CH    RBUFP,=H'4'                                              37340000
         BNH   ALGTRM3                  BR. IF CURRENT BUFFER EMPTY     37360000
         WRITE TRCHECK,SF,,(RBUF),MF=E  WRITE LAST RECORD               37380000
         CHECK TRCHECK                                                  37400000
         LA    RBUFC,1(0,RBUFC)                                         37420000
ALGTRM3  CLOSE (DCBUT1,REREAD),TYPE=T   CLOSE TEMPORARY                 37440000
         READ  TRCHECK,SF,,(RBUF),MF=E  READ FIRST RECORD               37460000
ALGTRM2  EQU   *                                                        37480000
         BAL   RETURN,TRHEAD            PRINT TRACE HEADLINES           37500000
ALGTRM4  LTR   RBUFC,RBUFC                                              37520000
         BNZ   ALGTRM9                  IF RECORDS ON SYSUT1            37540000
         LR    RBUFA,RBUF                                               37560000
         B     ALGTRM5                                                  37580000
ALGTRM9  CHECK TRCHECK                  CHECK PREVIOUS READ             37600000
         LM    RBUF,RBUFA,TRBUF                                         37620000
         LR    GR1,RBUF                 SWITCH BUFFERS                  37640000
         LR    RBUF,RBUFA                                               37660000
         LR    RBUFA,GR1                                                37680000
         STM   RBUF,RBUFA,TRBUF                                         37700000
         BCT   RBUFC,ALGTRM6            DECR. RECORD COUNTER            37720000
         B     ALGTRM5                  BR. IF NO MORE RECORDS          37740000
ALGTRM6  READ  TRCHECK,SF,,(RBUF),MF=E                                  37760000
ALGTRM5  LH    RBUFP,0(0,RBUFA)         LOAD BYTE COUNT                 37780000
         AR    RBUFP,RBUFA              ADDRESS OF LAST BYTE PLUS ONE   37800000
         LA    RBUFA,4(0,RBUFA)         RBUFA IS NOW BYTE POINTER       37820000
         L     GRA,R                    SYSPRINT BYTE POINTER           37840000
         B     ALGTRM7                                                  37860000
*                                                                       37880000
ALGTRM8  CLC   0(2,RBUFA),TRPGID        IS NEXT ITEM A PROGID           37900000
         BNE   ALGTRM12                 BR IF NO                        37920000
         MVC   PROGID(4),2(RBUFA)       STORE PROGID                    37940000
         LA    RBUFA,6(0,RBUFA)                                         37960000
         B     ALGTRM15                                                 37980000
ALGTRM12 LA    GRB,6(0,GRA)             CHECK IF ROOM FOR               38000000
         C     GRB,RE                     ONE MORE OUTPUT ITEM          38020000
         BL    ALGTRM13                 BR IF YES                       38040000
ALGTRM15 OI    DS,DS3                                                   38060000
         L     ENTRY,=V(IHIIORNX)                                       38080000
         BALR  RETURN,ENTRY                                             38100000
         CLC   S(2),=H'1'               TEST IF NEW PAGE                38120000
         BNE   ALGTRM14                 BR IF NO                        38140000
         BAL   RETURN,TRHEAD            PRINT PAGE HEADINGS             38160000
         B     ALGTRM15                                                 38180000
ALGTRM14 L     GRA,R                                                    38200000
         BAL   RETURN,BLANK             INITIALIZE WITH BLANKS          38220000
         MVC   0(10,GRA),PIDFIELD       PROGID AT START OF NEW LINE     38240000
         MVC   PROGID(4),PROGID-1       BLANKS TO RPOGID                38260000
         LA    GRA,PIDLGTH(0,GRA)                                       38280000
ALGTRM13 MVC   CONVBUF(2),0(RBUFA)      ***                             38300000
         LA    RBUFA,2(0,RBUFA)           *  CONVERT SEMICOLON COUNTER  38320000
         LH    GRB,CONVBUF                *  VALUE AND STORE IN         38340000
         CVD   GRB,CONVBUF                *  PRINT AREA                 38360000
ALGTRMZ  OI    CONVBUF+7,X'0F'            *                             38380000
         UNPK  1(5,GRA),CONVBUF(8)      ***                             38400000
         LA    GRA,6(0,GRA)             STEP OUTPUT BUFFER POINTER      38420000
         ST    GRA,R                                                    38440000
ALGTRM7  CR    RBUFA,RBUFP                                              38460000
         BL    ALGTRM8                  BR. IF NOT END OF SYSUT1 RECPRD 38480000
         LTR   RBUFC,RBUFC                                              38500000
         BNZ   ALGTRM9                  BR. IF MORE RECORDS TO READ     38520000
         OI    DS,DS3                   PRINT LAST LINE                 38540000
         L     ENTRY,=V(IHIIORNX)                                       38560000
         BALR  RETURN,ENTRY                                             38580000
         SPACE                                                          38600000
*  CLOSE SYSUT1 AND FREE BUFFER AREA                                    38620000
         SPACE                                                          38640000
ALGTRM18 CLOSE (DCBUT1)                                                 38660000
         LM    RBUF,RBUFA,TRBUF         GET LOWER                       38680000
         LR    GR1,RBUF                   BUFFER ADDRESS                38700000
         CR    RBUF,RBUFA                                               38720000
         BL    *+6                                                      38740000
         LR    GR1,RBUFA                                                38760000
         L     GR0,TRBUFL                                               38780000
         SLA   GR0,1                                                    38800000
         FREEMAIN R,LV=(0),A=(1)        FREE SYSUT1 BUFFER              38820000
         SPACE                                                          38840000
*  PRINT EXECUTION END MESSAGE                                          38860000
         SPACE                                                          38880000
ALGTRM11 EQU   *                                                        38900000
         L     GRA,R                    BYTE POINTER                    38920000
         MVC   0(TML,GRA),TRMSG         MOVE TERMINATION MESSAGE        38940000
         LA    GRA,TML(0,GRA)                                           38960000
         ST    GRA,R                    UPDATE BYTE POINTER             38980000
         LA    GRA,2                    LOOP COUNTER FOR BLANK LINES    39000000
ALGTRM19 EQU   *                                                        39020000
         BAL   RETURN,BLANK                                             39040000
         OI    DS,DS3                                                   39060000
         L     ENTRY,=V(IHIIORNX)                                       39080000
         BALR  RETURN,ENTRY                                             39100000
         BCT   GRA,ALGTRM19            ONE EXTRA BLANK LINE             39120000
         OI    DS+1,DS15          FLAG CLOSE FROM IHIFSA           0219 39130015
         L     ENTRY,=V(IHIIORCL)       CLOSE SYSPRINT                  39140000
         BALR  RETURN,ENTRY                                             39160000
         SPACE                                                          39180000
*  FINAL CLEAN-UP                                                       39200000
         SPACE                                                          39220000
ALGTRM10 EQU   *                                                        39240000
         SPACE                                                          39260000
         L     GR1,RASSTART(FSA)        FREE RETURN ADDRESS STACK       39280000
         LA    GR1,8(0,GR1)                                             39300000
         FREEMAIN R,LV=2048,A=(1)                                       39320000
ALGTRM17 L     GRA,FSAPICA(0,FSA)                                       39340000
          SPIE MF=(E,(GRA))              RESTORE PICA                   39360000
         SPACE                                                          39380000
ALGTRMAA EQU   *                                                        39400000
         SPACE                                                          39420000
         L     FSA,4(0,FSA)             RESTORE REGISTERS AND RETURN    39440000
         MVC   16(4,FSA),COMPCODE       TO REGISTER 15                  39460000
         RETURN (14,12)                   TO OS OR THE CALLING PROGRAM  39480000
         SPACE 3                                                        39500000
********   ROUTINE FOR FILLING A SYSPRINT RECORD WITH BLANKS            39520000
         SPACE 3                                                        39540000
BLANK    STM   GRA,GRB,BLANKS                                           39560000
         L     GRA,R                    CURRENT BYTE POINTER            39580000
         L     GRB,RE                   RECORD END POINTER              39600000
BLANKA   CR    GRA,GRB                                                  39620000
         BNL   BLANKB                   BRANCH IF RECORD END            39640000
         MVI   0(GRA),C' '              INSERT ONE BLANK                39660000
         LA    GRA,1(0,GRA)             STEP TO NEXT BYTE               39680000
         B     BLANKA                                                   39700000
BLANKB   ST    GRA,R               UPDATED BYTE POINTER                 39720000
         LM    GRA,GRB,BLANKS                                           39740000
         BR    RETURN                                                   39760000
BLANKS   DS    2F                                                       39780000
         SPACE 3                                                        39800000
********       ROUTINE FOR PRINTING TRACE OUTPUT HEADING                39820000
         SPACE 3                                                        39840000
TRHEAD   STM   14,12,TRHEADS                                            39860000
         LM    GRA,GRA+2,TRHADR         COUNTER FOR HEADLINES           39880000
TRHEAD1  EQU   *                                                        39900000
         L     GR1,R                                                    39920000
         BAL   RETURN,BLANK             INITIALIZE WITH BLANKS          39940000
         EX    0,0(GRA+2)               MOVE TEXT, OR NOP               39960000
         OI    DS,DS3                                                   39980000
         L     ENTRY,=V(IHIIORNX)                                       40000000
         BALR  RETURN,ENTRY                                             40020000
         BXLE  GRA+2,GRA,TRHEAD1                                        40040000
         BAL   RETURN,BLANK              BLANK LINE AFTER HEADING       40060000
         LM    14,12,TRHEADS                                            40080000
         BR    RETURN                                                   40100000
         SPACE                                                          40120000
TRHADR   DC    A(6,TRHEND,TRHLIST)                                      40140000
TRHLIST  EQU   *                                                        40160000
         NOP   0                        BLANK LINE                      40180000
         NOPR  0                                                        40200000
         MVC   0(TRHLA,GR1),TRHEADA                                     40220000
         NOP   0                        BLANK LINE                      40240000
         NOPR  0                                                        40260000
TRHEND   EQU   *                                                        40280000
         MVC   0(TRHLB,GR1),TRHEADB                                     40300000
         SPACE                                                          40320000
TRHEADA  DC    C'  ALGOL PROGRAM TRACE' FIRST HEADLINE                  40340000
TRHLA    EQU   *-TRHEADA                                                40360000
TRHEADB  DC    C'MODULE     SEMICOLON NUMBERS'  SECOND HEADLINE         40380000
TRHLB    EQU   *-TRHEADB                                                40400000
         SPACE                                                          40420000
TRHEADS  EQU   FSAREA+ASAVE+12                                          40440000
         SPACE                                                          40460000
WTOTRM   WTO   'END OF ALGOL PROGRAM EXECUTION',MF=L                    40480000
TRMSG    EQU    WTOTRM+4                                                40500000
TML      EQU   *-TRMSG                                                  40520000
         SPACE 3                                                        40540000
********       ERROR AND END OF DATA ROUTINE FOR SYSUT1                 40560000
         SPACE 3                                                        40580000
ERRUT1   EQU   *                                                        40600000
ENDUT1   EQU   *                                                        40620000
         OI    OPTSW(FSA),UT1ERR        SYSUT1 ERROR SWITCH ON          40640000
         LA    DSNR,17                  DUMMY DS NUMBER FOR SYSUT1      40660000
         B     ERROR32                                                  40680000
         SPACE                                                          40700000
*  PARAMETER LIST USED BY BOTH READ AND WRITE MACROS FOR SYSUT1         40720000
         SPACE                                                          40740000
         WRITE TRCHECK,SF,DCBUT1,MF=L                                   40760000
         SPACE                                                          40780000
*  PARAMETERS FOR TRACE BUFFER                                          40800000
         SPACE                                                          40820000
TRBUF    DS    F                        ADDRESS OF CURRENT BUFFER       40840000
TRBUFA   DS    F                        ADDRESS OF ALTERNATE BUFFER     40860000
TRBUFL   DS    F                        LENGTH OF BUFFER                40880000
TRCNT    DS    F                        RECORD COUNTER                  40900000
*  THE BYTE POINTER IS CONTAINED IN THE FIRST TWO BYTES OF THE          40920000
*  RECORD AND SERVES AS RECORD LENGTH FIELD                             40940000
         SPACE                                                          40960000
COMPCODE DC    F'0'                     COMPLETION CODE (0 OR 4)        40980000
         SPACE                                                          41000000
*        WORK STORAGE FOR EDITING THE TRACE LISTING                     41020000
         SPACE                                                          41040000
PIDFIELD DC    CL2' '                                                   41060000
PROGID   DC    CL4' '                   MODULE NAME                     41080000
         DC    CL4' '                                                   41100000
PIDLGTH  EQU   *-PIDFIELD                                               41120000
CONVBUF  DS    D                        FOR CONVERTING SEMICOLON NR     41140000
         EJECT                                                          41160000
         SPACE                                                          41180000
*  DCB FOR SYSUT1                                                       41200000
         SPACE                                                          41220000
DCBUT1   DCB   DSORG=PS,MACRF=(R,W),DDNAME=SYSUT1,RECFM=F,NCP=1,       X41240000
               EODAD=ENDUT1,EXLST=DCBEXIT,SYNAD=ERRUT1                  41260000
         EJECT                                                          41280000
         SPACE 3                                                        41300000
********            FORMAT OF THE DATA SET TABLE                        41320000
         SPACE 3                                                        41340000
DDSTAB   DSECT                                                          41360000
         SPACE                                                          41380000
ADCB     DS    A                                                        41400000
R        DS    A                                                        41420000
RE       DS    A                                                        41440000
NBB      DS    A                                                        41460000
BB       DS    A                                                        41480000
S        DS    H                                                        41500000
P        DS    H                                                        41520000
K        DS    HL1                                                      41540000
Q        DS    HL1                                                      41560000
DS       DS    2C                                                       41580000
NOTEADR  DS    A                                                        41600000
BL       DS    H                                                        41620000
         DS     H                                                       41640000
DSTLG    EQU   *-ADCB                                                   41660000
         EJECT                                                          41680000
         DCBD  DSORG=(BS),DEVD=(DA,TA)                                  41700000
         END                                                            41720000
