* TITLE:CRATL-CREATE AN ATTENTION LEVEL                                 00300013
* STATUS:CHANGE LEVEL 0                                                 00600013
* FUNCTION:TO ESTABLISH THE FIRST OR ONLY ATTENTION LEVEL OR TO ESTAB-  00900013
*          LISH A NEW ACTIVE ATTENTION LEVEL BELOW THE CURRENTLY ACTIVE 01200013
*          LEVEL.                                                       01500013
* ENTRY:ENTERED AT IFFACA00 VIA A CALL TO CRATL.                        01800013
* INPUT:GR#1 CONTAINS THE ADDRESS OF A WORK/SAVE AREA.THE FIRST WORD    02100013
*       CONTAINS THE ADDRESS OF A PARAMETER LIST CONSTRUCTED AS FOLLOWS 02400013
*         1.DEVICENAME-ADDRESS OF A VARIABLE CONTAIN THE ADDRESS OF THE 02700013
*           GTMCB.                                                      03000013
*         2.ATTNLEVEL-ADDRESS OF A USER LOCATION WHERE THE ADDRESS OF   03300013
*           THE NEWLY CREATED ATTENTION LEVEL IS TO BE PLACED.          03600013
*         3.DEQUECT-ADDRESS OF A VALUE INDICATING WHETHER ATTENTIONS    03900013
*           MADE AVAILABLE TO THE USER ARE DEQUEUED ANY TIME(VALUE=1)   04200013
*           OR ONLY WHEN ATTENTION LEVEL IS ACTIVE(VALUE=2).            04500013
* OUTPUT:ATTENTION LEVEL AND A QUEUE ARE CREATED.                       04800013
* EXIT:RETURN TO CALLING PROGRAM                                        05100013
* RETURN CODES: 4,0 INCORRECT NUMBER OF PARAMETERS.                     05400013
*               4,1 NOT A VALID DEVICENAME.                             05700013
*               4,3 DEQUECT NOT VALID                                   06000013
*               3,4 MAIN STORAGE NOT AVAILABLE                          06300013
*               0,0 SUCCESSFULL EXECUTION                               06600013
* ATTRIBUTES:RE-ENTRANT,PROBLEM PROGRAM MODE                            06900013
* NOTES:THE FOLLOWING CONTROL BLOCKS ARE EXAMINED BY THIS ROUTINE:      07200013
*       1.GTMCB                                                         07500013
*       2.GSPCB                                                         07800013
*EXTERNAL ROUTINES:ATTNINQ                                              08100013
*                  GIOCR                                                08400013
REG0     EQU   0                       PARAM REG 0                      08700013
REG1     EQU   1                       PARAM REG1                       09000013
RLIST    EQU   2                       INPUT PARAMETER REG              09300013
RPARM    EQU   3                       PARAMETER LIST REG               09600013
RGTMCB   EQU   4                       GTMCB REG                        09900013
RATL     EQU   5                       ATTENTION LEVEL                  10200013
SPARE1   EQU   6                       SPARE REG                        10500013
RWORKD   EQU   7                       WORK REG D                       10800013
RDEQ     EQU   8                       DEQUECT REG                      11100013
RBASE    EQU   9                       BASE REGISTER                    11400013
RGSPCB   EQU   10                      GSPCB ADR                        11700013
RD       EQU   10                      WORK REG                         12000013
RWORKC   EQU   11                      WORK REG C                       12300013
SPARE2   EQU   12                      RSVD PL1                         12600013
RSAVE    EQU   13                      SAVE AREA REG                    12900013
RWORKA   EQU   14                      WORK REG A                       13200013
RWORKB   EQU   15                      WORK REG B                       13500013
ADD0     EQU   0                       ADD INFO 0                       13800013
ADD1     EQU   1                       ADD INFO 1                       14100013
ADD2     EQU   2                       ADD INFO 2                       14400013
ADD3     EQU   3                       ADD INFO 3                       14700013
ADD4     EQU   4                       ADD INFO 4                       15000013
BPID     EQU   X'01'                   BP ID                            15300013
CORE     EQU   256                     CORE REQUEST                     15600013
COUNT    EQU   7                       NUMBER OF DATA ENTRIES           15900013
DATSRT   EQU   80                      DATA START                       16200013
DATSIZE  EQU   24                      DATA ENTRY SIZE                  16500013
DEQOPT   EQU   X'04'                   DEQUEUE OPTION                   16800013
DEQ1     EQU   1                       DEQUECT=1                        17100013
DEQ2     EQU   2                       DEQUECT=2                        17400013
EIGHT    EQU   8                       EIGHT                            17700013
EOS      EQU   X'40'                   EOS RESTART BIT                  17800013
FOUR     EQU   4                       FOUR                             18000013
GACBOFF  EQU   0                       OFFSET TO GACB                   18300013
GACBPLUS EQU   8                       OFFSET TO GACB ADDRESS           18600013
GTMCBID  EQU   X'02'                   GTMCB ID                         18900013
HASPFK   EQU   X'10'                   HAS PF KEYBOARD                  19000013
ID1      EQU   X'F2'                   ID                               19200013
ID2      EQU   X'04'                   ID                               19500013
IOK      EQU   X'7F'                   I/O SUCCESSFULL CODE             19600013
LAST     EQU   X'80'                   LAST ENTRY IN LIST               19800013
LITE     EQU   X'01'                   LIGAT OPTION                     20100013
LIT2     EQU   X'02'                   OPTION 2                         20400013
LIT3     EQU   X'03'                   OPTION 3                         20700013
LP       EQU   X'08'                   LP RESTART BIT                   20800013
LPRST    EQU   45                      LP RESTART BYTE                  21000013
OFFSAVE  EQU   8                       SAVE AREA CHAIN                  21300013
PFK0     EQU   X'80'                   PFK0                             21600013
PFMSK    EQU   8                       OFFSET TO PFMSK                  21900013
RCC3     EQU   X'10'                   RETURN CODE 3                    22200013
RCC4     EQU   X'08'                   RETURN CODE 4                    22500013
RC3      EQU   12                      OFFSET TO RTN CODE 3             22800013
RC4      EQU   16                      OFFSET TO RTN CODE 4             23100013
RC5      EQU   X'04'                   I/O ERROR                        23200013
TWO      EQU   2                       TWO                              23400013
UPHF     EQU   256                     UPPER HALF OF ATTN LEVEL         23700013
ZERO     EQU   0                       ZERO                             24000013
IFFACA00 CSECT                                                          24300013
*2101,471000-528000                                                000A 24400019
         SAVE  (14,12)                 SAVE REGISTERS                   24600013
         BALR  RBASE,0                 SET UP BASE REG                  24900013
         USING *,RBASE                 DEFINE BASE REG                  25200013
         LR    RLIST,REG1              SAVE REGISTER                    25500013
         USING LIST,RLIST              DEFINE INPUT CSECT               25800013
         ST    RSAVE,SAVE+4            SAVE-SAVE AREA PTR               26100013
         LA    RD,SAVE                 LOAD ADR OF MY SAVE AREA         26400013
         ST    RD,OFFSAVE(RSAVE)       STORE IN USER SAVE AREA          26700013
         LA    RSAVE,SAVE              ESTABLISH NEW SAVE AREA          27000013
         L     RWORKA,RCODE            LOAD RETURN CODE ARRAY ADR       27300013
         XC    ZERO(20,RWORKA),ZERO(RWORKA) CLEAR RETURN CODE ARRAY     27600013
         B     AROUND                  BRANCH                           27900013
ERROR    L     RWORKA,RCODE            LOAD RETURN CODE ADR             28200013
         STC   RWORKB,ZERO(RWORKA)     STORE RETURN CODE IN ARRAY       28500013
         ST    RWORKC,ZERO(RWORKD,RWORKA) STORE ADD INFO AT PROPER      28800013
*                                      OFFSET IN ARRAY                  29100013
OUTRTN   L     RSAVE,SAVE+4            RESTORE OLD SAVE AREA PTR        29400013
         RETURN (14,12),T              RETURN TO CALLING PROGRAM        29700013
AROUND   L     RPARM,PLIST             LOAD ADR OF PARAM LIST           30000013
         USING PARAMS,RPARM            DEFINE DSECT REG                 30300013
         L     RGTMCB,DEVICE           LOAD INDIRECT ADR OF GTMCB       30600013
         L     RGTMCB,ZERO(RGTMCB)     LOAD GTMCB ADR                   30900013
         USING GTMCB,RGTMCB            DEFINE DSECT REG                 31200013
         CLI   GTMTERID,GTMCBID        TEST TO SEE IF VALID GTMCB       31500013
         BE    CR01                    BRANCH IF VALID                  31800013
CR02     LA    RWORKC,ADD1             LOAD ADD INFO CODE               32100013
CR03     LA    RWORKB,RCC4             LOAD RETURN CODE                 32400013
         LA    RWORKD,RC4              LOAD OFFSET                      32700013
         B     ERROR                   BRANCH                           33000013
CR01     L     RWORKA,GTMGTMCB         LOAD ADR FLD                     33300013
         CLR   RWORKA,RGTMCB           HAS GTMCB BEEN INITIALIZED       33600013
         BNE   CR02                    BRANCH IF NO                     33900013
         L     RGSPCB,GTMGSPCB         LOAD ADR OF GSPCB                34200013
         USING GSPCB,RGSPCB            DEFINE DSECT                     34500013
         TM    DEVICE,LAST             IS THIS THE LAST PARAMETER       34800013
         BC    14,CR04                 BRANCH IF NO                     35100013
CR05     LA    RWORKC,ADD0             LOAD ADD INFO                    35400013
         B     CR03                    BRANCH                           35700013
CR04     L     RWORKA,GSPNULLV         LOAD ADR OF NULL                 36000013
         L     RWORKB,ATTNL            LOAD ATTNLEVEL PARAM             36300013
         LA    RWORKB,ZERO(RWORKB)     ZERO HI ORDER BYTE               36600013
         CLR   RWORKA,RWORKB           IS IT ADR OF NULL                36900013
         BE    CR05                    BRANCH IF YES                    37200013
         LTR   RWORKB,RWORKB           VALUE=0                          37500013
         BC    8,CR05                  BRANCH IF YES                    37800013
         TM    ATTNL,LAST              IS THIS LAST PARAM               38100013
         BC    14,CR06                 BRANCH IF NO                     38400013
CR07     LA    RDEQ,DEQ1               ASSUME DEQUECT OF 1              38700013
         B     CR08                    BRANCH                           39000013
CR06     L     RDEQ,DEQUECT            LOAD INDIRECT ADR OF DEQUECT     39300013
         LA    RDEQ,ZERO(RDEQ)         ZERO HI ORDER BYTE               39600013
         CLR   RWORKA,RDEQ             EQUAL ADR OF NULL                39900013
         BE    CR07                    BRANCH IF YES                    40200013
         L     RDEQ,ZERO(RDEQ)         LOAD DEQUECT PARAMETER           40500013
         LA    RWORKA,DEQ1             LOAD CONSTANT                    40800013
         CLR   RDEQ,RWORKA             DEQUECT=1                        41100013
         BE    CR08                    BRANCH IF YES                    41400013
         LA    RWORKA,DEQ2             LOAD CONSTANT                    41700013
         CLR   RWORKA,RDEQ             DEQUECT#2                        42000013
         BE    CR08                    BRANCH IF YES                    42300013
         LA    RWORKC,ADD3             LOAD ADD INFO CODE               42600013
         B     CR03                    BRANCH                           42900013
CR08     XC    MAINCORE(20),MAINCORE   CLEAR PARAMETER LIST AREA        43200013
         LA    REG1,MAINCORE           LOAD ADR OF PARAMETER LIST       43500013
         LA    RWORKC,CORE             LOAD BYTE REQUEST                43800013
         LA    RWORKD,ADDRESS          LOAD LOC TO PUT ADR OF CORE      44100013
         GETMAIN EC,LV=(11),A=(7),MF=(E,(1))                            44400013
         LTR   RWORKB,RWORKB           WAS CORE REQUEST SATISFIED       44700013
         BC    8,CR09                  BRANCH IF YES                    45000013
         LA    RWORKB,RCC3             LOAD RETURN CODE                 45300013
         LA    RWORKC,ADD4             LOAD ADD INFO                    45600013
         LA    RWORKD,RC3              LOAD OFFSET                      45900013
         B     ERROR                   BRANCH                           46200013
CR09     CLC   GTMLATBL(4),ZERO1       IS THERE AN ACTIVE LEVEL         46500013
         BE    CR10                    BRANCH IF NO                     46800013
CR12     EQU   *                                                   000A 48800019
         XC    LFORM(64),LFORM                                     000A 50800019
         L     RWORKA,GTMGACBA                                     000A 51000019
         LA    RWORKA,GACBPLUS(RWORKA)                             000A 51200019
         L     RWORKD,ZERO(RWORKA)                                 000A 51400019
         LA    RWORKB,COM                                          000A 51600019
         ST    RWORKB,ZERO(RWORKA)                                000A  51800019
         LR    SPARE1,RWORKA                                       000A 52000019
         ATTNINQ (6),MODE=(C,CR11),TYP=ANY,MF=(E,LFORM)           000A  52200019
         L     RWORKA,GTMGACBA         LOAD GACB ADR                    53100013
         LA    RWORKA,GACBPLUS(RWORKA) LOAD PTR TO TRUE START OF GACB   53400013
         ST    RWORKD,ZERO(RWORKA)     RESTORE OLD COMMAREA             53700013
         B     CR10                    BRANCH                           54000013
CR11     L     RATL,GTMLATBL           LOAD ATTN LEVEL ADR              54300013
         USING  ATTNLEVL,RATL          DEFINE DSECT                     54600013
         CLC   ATTNAVAL(4),ZERO1       ANY ENTRY BLOCKS AVAILABLE       54900013
         BNE   CR13                    BRANCH IF YES                    55200013
         B     CR12                    BRANCH                           55500013
CR13     L     RWORKA,ATTNAVAL         LOAD AVAILABLE ENTRY ADDRESS     55800013
         MVC   ATTNAVAL(4),ZERO(RWORKA) UPDATE CHAIN                    56100013
         MVC   EIGHT(12,RWORKA),COM    MOVE DATA TO ENTRY               56400013
         CLC   ATTNMLEN(4),ZERO1       ANY ENTRIES NOW ON QUEUE         56700013
         BNE   CR21                    BRANCH IF ENTRIES ON QUEUE       57000013
         MVC   ZERO(4,RWORKA),ATTNMLEN UPDATE                           57300013
         ST    RWORKA,ATTNMLEN         CHAIN                            57600013
         B     CR12                    BRANCH                           57900013
CR21     L     REG1,ATTNMLEN           LOAD ADR OF 1ST ENTRY            58200013
CR23     CLC   ZERO(4,REG1),ZERO1      IS THIS LAST ENTRY               58500013
         BE    CR22                    BRANCH IF LAST ENTRY             58800013
         L     REG1,ZERO(REG1)         LOAD ADR OF NEXT ENTRY           59100013
         B     CR23                    BRANCH                           59400013
CR22     ST    RWORKA,ZERO(REG1)       ADD ENTRY TO LIST                59700013
         XC    ZERO(4,RWORKA),ZERO(RWORKA) INDICATE LAST ENTRY          60000013
         B     CR12                    BRANCH                           60300013
CR10     L     RWORKA,GTMGACBA         LOAD ML GACB ADR                 60600013
         LA    RWORKA,GACBPLUS(RWORKA) LOAD PTR TO TRUE START OF GACB   60900013
         SAEC  PFKMSK=NULL,ATTNTYP=NULL,RESTART=YES,MF=(E,(14))         61200013
         L     RWORKA,GTMGACBA         LOAD ADR OF ML GACB              61500013
         L     RWORKA,GACBOFF(RWORKA)  LOAD ADR OF DE GACB              61800013
         LA    RWORKA,GACBPLUS(RWORKA) LOAD PTR TO TRUE START OF GACB   62100013
         SAEC  PFKMSK=NULL,ATTNTYP=NULL,RESTART=YES,MF=(E,(14))         62400013
         L     RATL,ADDRESS            LOAD ADR OF GOTTEN CORE          62700013
         XC    ZERO(256,RATL),ZERO(RATL) CLEAR                          63000013
         LA    RWORKC,COUNT            LOAD LOOP COUNT                  63300013
         LA    RWORKD,DATSRT(RATL)     LOAD ADR OF FIRST ENTRY          63600013
CR14     MVC   ZERO(4,RWORKD),ATTNAVAL PLACE ENTRY-                     63900013
         ST    RWORKD,ATTNAVAL         ON CHAIN                         64200013
         LA    RWORKD,DATSIZE(RWORKD)  LOAD ADR OF NEXT ENTRY           64500013
         BCT   RWORKC,CR14             BRANCH IF MORE TO CREATE         64800013
         MVI   ATTNLVID,ID1            MOVE IN ID                       65100013
         MVI   ATTNLVID+1,ID2          MOVE IN ID                       65400013
         MVI   ATTNLITE,LITE           MOVE IN LIGHT OPTION             65700013
         OI    ATTNFLGA,LP+EOS         SET RESTART OPTIONS=YES          65800013
         LA    RWORKA,TWO              LOAD CONSTANT                    66000013
         CLR   RDEQ,RWORKA             DEQUECT=2                        66300013
         BNE   CR15                    BRANCH IF NO                     66600013
         OI    ATTNFLGA,DEQOPT         SET DEQUECT OPTION               66900013
CR15     L     RWORKA,ATTNL            LOAD LOC TO PLACE ATNLVL ADR     67200013
         LA    RWORKA,ZERO(RWORKA)     ZERO HIGH ORDER BYTE             67500013
         ST    RATL,ZERO(RWORKA)       STORE ATLVL ADR IN USER AREA     67800013
         CLC   GTMLATBL(4),ZERO1       ANY LEVELS EXIST                 68100013
         BNE   CR16                    BRANCH IF YES                    68400013
         ST    RGTMCB,ATTNBKPT         GTMCB ADR TO BP                  68700013
         ST    RATL,GTMLATBL           ADR OF LEVEL TO GTMCB            69000013
         OI    ATTNBPID,BPID           INDICATE POINTS TO GTMCB         69300013
         B     CR17                    BRANCH                           69600013
CR16     L     RWORKA,GTMLATBL         LOAD ADR OF PRES ACT LEVEL       69900013
         ST    RATL,ZERO(RWORKA)       ADR OF NEW TO FP OF OLD          70200013
         ST    RWORKA,ATTNBKPT         ADR OF OLD TO BP OF NEW          70500013
         ST    RATL,GTMLATBL           ADR OF NEW TO GTMCB              70800013
CR17     XC    DECB(36),DECB           CLEAR I/O AREA                   71100013
         TM    GTMFEATS+1,HASPFK       DOES DEVICE HAVE A PF KEYBOARD   71200013
         BC    14,OUTRTN               BRANCH-NO KEYBOARD               71300013
         CLI   GTMLIGHT,LIT2           OPTION 2                         71400013
         BNE   CR18                    BRANCH IF NO                     71700013
         B     CR20                    BRANCH                           72000013
CR18     CLI   GTMLIGHT,LIT3           OPTION 3                         72300013
         BNE   CR19                    BRANCH IF NO                     72600013
         MVC   DATA(4),ATTNPFEN        MOVE IN ENABLED KEYS             72900013
         B     CR20                    BRANCH                           73200013
CR19     MVC   DATA(4),GTMPFKSS        MOVE IN LIGHT MASK               73500013
CR20     LA    REG1,DECB               LOAD DECB ADR                    73800013
         LA    RWORKC,DATA             LOAD DATA ADR                    74100013
         L     RWORKD,GTMGRDCB         LOAD DCB ADR                     74400013
         GCNTRL (1),IND,(7),(11),MF=E                                   74700013
         WAIT  ECB=(1)                                                  75000013
         CLI   DECB,IOK                I/O SUCCESSFULL                  75060013
         BE    OUTRTN                  BRANCH-I/O OK                    75120013
         L     RD,RCODE                LOAD RTN CODE ARRAY ADR          75180013
         OI    ZERO(RD),RC5            INDICATE I/O ERROR               75240013
         B     OUTRTN                  BRANCH                           75300013
ZERO1    DC    1F'0'                   ZERO                             75600013
         CNOP  0,8                                                      75900013
         COPY  ATTNLEVL                                                 76200013
         COPY  GSPCB                                                    76500013
         COPY  GTMCB                                                    76800013
         COPY  GDSCB                                                    77100013
LIST     DSECT                                                          77400013
PLIST    DS    1F                      ADDRESS OF PARAM LIST            77700013
RCODE    DS    1F                      ADDRESS OF RETURN CODE ARRAY     78000013
SAVE     DS    18F                     SAVE AREA                        78300013
DECB     DS    8F                      I/O DECB                         78600013
DATA     DS    1F                      DATA AREA FOR I/O                78900013
MAINCORE DS    4F                      GETMAIN PARAM LIST AREA          79200013
ADDRESS  DS    1F                      LOCATION TO PUT ADR OF GOTTEN    79500013
GACB     DS    1F                                                       79800013
TYPE     DS    BL1                                                      80100013
OPT      DS    BL1                                                      80400013
TYP      DS    1H                                                       80700013
BRANCH   DS    1F                                                       81000013
COM      DS    3F                                                       81300013
LFORM    DS    16F                                                 000A 81400019
PARAMS   DSECT                                                          81600013
DEVICE   DS    1F                      GTMCB                            81900013
ATTNL    DS    1F                      ATTN LEVEL                       82200013
DEQUECT  DS    1F                      DEQUECT                          82500013
         END                                                            82800013
