* TITLE:ENATL-END AN ATTENTION LEVEL                                    00300013
* STATUS:CHANGE LEVEL 0                                                 00600013
* FUNCTION:TO TERMINATE THE SPECIFIED ATTENTION LEVEL AND ANY OTHER     00900013
*          ATTENTION LEVEL(S) LOWER IN THE HIERARCHY FOR ITS GTMCB,     01200013
*          MAKING THE NEXT HIGHER REMAINING ATTENTION LEVEL,IF ANY,     01500013
*          ACTIVE.                                                      01800013
*          TO TERMINATE ALL ATTENTION LEVEL(S) LOWER IN THE HIERARCHY   02100013
*          FOR ITS GTMCB THAN THE SPECIFIED ATTENTION LEVEL,MAKING THE  02400013
*          SPECIFIED ATTENTION LEVEL ACTIVE.                            02700013
* ENTRY:ENTERED AT IFFACA01 VIA A CALL TO ENATL.                        03000013
* INPUT:GR#1 CONTAINS THE ADDRESS OF A WORK/SAVE AREA.THE FIRST WORD    03300013
*       CONTAINS THE ADDRESS OF A PARAMETER LIST CONSTRUCTED AS FOLLOWS 03600013
*         1.ATTNLEVEL-ADDRESS OF A VARIABLE WHICH CONTAINS THE ADDRESS  03900013
*           OF THE ATTENTION LEVEL.                                     04200013
*         2.RANGECODE-ADDRESS OF A VALUE INDICATING :                   04500013
*           A. 1-TERMINATE SPECIFIED AND ALL LOWER (ASSUMED IF OMITTED) 04800013
*           B. 2-TERMINATE ALL LOWER                                    05100013
* OUTPUT:ATTENTION LEVEL(S) AND QUEUE(S) DELETED.                       05400013
* EXIT:RETURN TO CALLING PROGRAM.                                       05700013
* RETURN CODES:4,1 ATTNLEVEL DID NOT REFER TO A VALID OR EXISTING       06000013
*                  ATTENTION LEVEL.                                     06300013
*              4,2 RANGE CODE INVALID                                   06600013
*              0,0 SUCCESSFULL EXECUTION                                06900013
* ATTRIBUTES:RE-ENTRANT,PROBLEM PROGRAM MODE                            07200013
* NOTES:THE FOLLOWING CONTROL BLOCKS ARE EXAMINED BY THIS ROUTINE:      07500013
*       1.GTMCB                                                         07800013
*       2.GSPCB                                                         08100013
* EXTERNAL ROUTINES:ATTNINQ                                             08400013
*                   GIOCR                                               08700013
R0       EQU   0                       PARM REG 0                       09000013
R1       EQU   1                       PARM REG 1                       09300013
RPARAM   EQU   2                       WORK AREA ADR                    09600013
RLIST    EQU   3                       USER PARAM LIST                  09900013
RATL     EQU   4                       ATTN LEVEL REG                   10200013
RGTMCB   EQU   5                       GTMCB REG                        10500013
RET      EQU   6                       INTERVAL RETURN                  10800013
SPARE1   EQU   7                       SPARE REG 1                      11100013
RC       EQU   8                       WORK REG                         11400013
RBASE    EQU   9                       BASE REG                         11700013
RA       EQU   10                      WORK REG                         12000013
RB       EQU   11                      WORK REG                         12300013
SPARE2   EQU   12                      RSVD PL1                         12600013
RSAVE    EQU   13                      SAVE AREA PTR                    12900013
RD       EQU   14                      WORK REG                         13200013
RE       EQU   15                      WORK REG                         13500013
ADD1     EQU   1                       ADD INFO 1                       13800013
ADD2     EQU   2                       ADD INFO 2                       14100013
AN       EQU   12                      OFFSET TO A/N MASK               14400013
ATLID    EQU   X'04'                   ATN LEVEL ID                     14700013
ATLV     EQU   256                     SIZE OF ATTN LEVEL               15000013
BPID     EQU   X'01'                   BACK PTR ID                      15300013
DERB     EQU   32                      SIZE OF DERB                     15600013
GACBOFF  EQU   8                       OFFSET TO GACB                   15900013
HASPFK   EQU   X'10'                   HAS PF KEYBOARD                  16000013
IOK      EQU   X'7F'                   I/O SUCCESSFULL CODE             16100013
LAST     EQU   X'80'                   LAST PARAM                       16200013
LIT1     EQU   X'01'                   OPTION 1                         16500013
LIT2     EQU   X'02'                   OPTION 2                         16800013
LIT3     EQU   X'03'                   OPTION 3                         17100013
LP       EQU   X'01'                   RESTART=YES                      17400013
LPSTRT   EQU   X'08'                   LP RESTART OPTION                17700013
NEXT     EQU   0                       NEXT GACB ADR                    18000013
OFFSAVE  EQU   8                       SAVE AREA CHAIN                  18300013
PF       EQU   8                       OFFSET TO PF MASK                18600013
PFK0     EQU   X'80'                   PFK0 BIT                         18900013
RCC4     EQU   X'08'                   RETURN CODE 4                    19200013
RC4      EQU   16                      OFFSET TO RC 4                   19500013
RC5      EQU   X'04'                   I/O ERROR                        19600013
START    EQU   45                      OFFSET TO START BIT              19800013
ZERO     EQU   0                       ZERO                             20100013
IFFACA01 CSECT                                                          20400013
*2101,645000-687000                                                000A 20500018
         SAVE  (14,12)                 SAVE REGS                        20700013
         BALR  RBASE,0                 SET UP BASE REG                  21000013
         USING *,RBASE                 DEFINE BASE REG                  21300013
         LR    RPARAM,R1               SAVE WORK AREA ADR               21600013
         USING WORKAREA,RPARAM         DEFINE DSECT                     21900013
         L     RLIST,PLIST             LOAD ADR OF USER PARM LIST       22200013
         USING PARAM,RLIST             DEFINE DSECT                     22500013
         ST    RSAVE,SAVE+4            SAVE-SAVE AREA PTR               22800013
         LA    RD,SAVE                 LOAD ADR OF MY SAVE AREA         23100013
         ST    RD,OFFSAVE(RSAVE)       STORE IN USER SAVE AREA          23400013
         LA    RSAVE,SAVE              ESTABLISH NEW SAVE AREA          23700013
         L     RA,RTNARAY              LOAD RTN CODE ARRAY ADR          24000013
         XC    ZERO(20,RA),ZERO(RA)    INITIALIZE RTN CODE ARRAY        24300013
         B     AROUND                  BRANCH                           24600013
ERROR    L     RA,RTNARAY              LOAD RTN CODE ARRAY ADR          24900013
         STC   RB,ZERO(RA)             STORE RETURN CODE                25200013
         ST    RC,ZERO(RD,RA)          STORE ADD INFO AT PROPER OFFSET  25500013
OUTRTN   L     RSAVE,SAVE+4            RESTORE OLD SAVE AREA PTR        25800013
         RETURN (14,12),T              RETURN TO CALLING PROGRAM        26100013
AROUND   L     RATL,ATNLVL             LOAD PTR TO ATLCB ADR            26400013
         LA    RATL,ZERO(RATL)         ZERO HI ORDER BYTE               26700013
         L     RATL,ZERO(RATL)         LOAD ATLCB ADR                   27000013
         USING ATTNLEVL,RATL           DEFINE DSECT                     27300013
         CLI   ATTNLVID+1,ATLID        IS THIS A VALID ATLCB            27600013
         BE    END01                   BRANCH IF VALID                  27900013
         LA    RC,ADD1                 LOAD ADD INFO CODE               28200013
END02    LA    RB,RCC4                 LOAD RETURN CODE                 28500013
         LA    RD,RC4                  LOAD OFFSET TO RETURN CODE       28800013
         B     ERROR                   BRANCH                           29100013
END01    LR    RE,RATL                 SAVE REG                         29400013
END04    CLI   ATTNBPID,BPID           LEVEL POINT TO GTMCB             29700013
         BE    END03                   BRANCH IF YES                    30000013
         L     RATL,ATTNBKPT           LOAD ADR OF NEXT LEVEL           30300013
         B     END04                   BRANCH                           30600013
END03    L     RGTMCB,ATTNBKPT         LOAD GTMCB ADR                   30900013
         USING GTMCB,RGTMCB            DEFINE DSECT                     31200013
         LR    RATL,RE                 RESTORE REGISTER                 31500013
         L     RA,GTMGSPCB             LOAD GSPCB ADR                   31800013
         USING GSPCB,RA                DEFINE DESECT                    32100013
         TM    ATNLVL,LAST             IS THIS LAST PARAM               32400013
         BC    1,END05                 BRANCH IF YES                    32700013
         L     RE,RANGECDE             LOAD RANGE CODE PARAM ADR        33000013
         LA    RE,ZERO(RE)             ZERO HI ORDER BYTE               33300013
         CL    RE,GSPNULLV             IS RANGE CODE ADR OF NULL        33600013
         BE    END05                   BRANCH IF YES                    33900013
         L     RE,ZERO(RE)             LOAD RANGE CODE PARAM            34200013
         CL    RE,ONE                  RANGE CODE=1                     34500013
         BE    END05                   BRANCH IF YES                    34800013
         CL    RE,TWO                  RANGE CODE=2                     35100013
         BE    END06                   BRANCH IF YES                    35400013
         LA    RC,ADD2                 LOAD ADD INFO CODE               35700013
         B     END02                   BRANCH                           36000013
END06    CLC   ATTNFWPT(4),ZERO1       ATLCB FP=0                       36300013
         BNE   END07                   BRANCH IF NO                     36600013
         SR    RC,RC                   ADD INFO=0                       36900013
         B     END02                   BRANCH                           37200013
END07    L     RA,GTMGACBA             LOAD GACB ADR                    37500013
         LA    RB,GACBOFF(RA)          LOAD PTR TO START OF GACB        37800013
         LR    RC,RB                   LOAD REG                         38100013
         LA    RET,END19               LOAD RET ADR                     38400013
         B     END20                   BRANCH                           38700013
END19    EQU   *                                                        39000013
         SAEC  PFKMSK=NULL,ATTNTYP=NULL,RESTART=NO,MF=(E,(11))          39300013
         L     RA,NEXT(RA)             LOAD ADR OF NEXT GACB            39600013
         LA    RB,GACBOFF(RA)          LOAD PTR TO START OF GACB        39900013
         SAEC  PFKMSK=NULL,ATTNTYP=NULL,RESTART=NO,MF=(E,(11))          40200013
         ST    RATL,GTMLATBL           PUT ADR OF NEW ACTIVE LEVEL      40500013
*                                      IN GTMCB                         40800013
         L     RA,ATTNFWPT             SAVE ADR OF 1ST LEVEL TO FREE    41100013
         XC    ATTNFWPT(4),ATTNFWPT    INDICATE LEVEL NOW ACTIVE        41400013
         B     END08                   BRANCH                           41700013
END05    L     RB,GTMGACBA             LOAD GACB ADR                    42000013
         LA    RC,GACBOFF(RB)          LOAD START ADR OF GACB           42300013
         LA    RET,END21               LOAD RETN ADR                    42600013
         B     END20                   BRANCH                           42900013
END21    EQU   *                                                        43200013
         SAEC  PFKMSK=NULL,ATTNTYP=NULL,RESTART=NO,MF=(E,(8))           43500013
         L     RB,NEXT(RB)             LOAD ADR OF NEXT GACB            43800013
         LA    RC,GACBOFF(RB)          LOAD START ADR OF GACB           44100013
         SAEC  PFKMSK=NULL,ATTNTYP=NULL,RESTART=NO,MF=(E,(8))           44400013
         CLI   ATTNBPID,BPID      LEVEL POINT TO GTMCB                  44700013
         BE    END09              BRANCH IF YES                         45000013
         MVC   GTMLATBL(4),ATTNBKPT ESTABLISH NEW ACTIVE LEVEL          45300013
         LR    RA,RATL            SAVE ADR OF 1ST LEVEL TO FREE         45600013
         L     RATL,ATTNBKPT      LOAD ADR OF NEW ACTIVE LEVEL          45900013
         XC    ATTNFWPT(4),ATTNFWPT INDICATE THIS IS ACTIVE LEVEL       46200013
         B     END08              BRANCH                                46500013
END09    XC    GTMLATBL(4),GTMLATBL INDICATE NO ACTIVE LEVELS           46800013
         LR    RA,RATL            LOAD ADR OF 1ST LEVEL TO FREE         47100013
         XC    DECB(36),DECB      CLEAR I/O AREA                        47400013
END10    L     RB,GTMGRDCB        LOAD DCB ADR                          47700013
         LA    RC,DATA            LOAD DATA ADR                         48000013
         LA    R1,DECB            LOAD PARAM LIST ADR                   48300013
         LA    RET,END11          LOAD RETURN ADR                       48600013
         TM    GTMFEATS+1,HASPFK       DOES DEVICE HAVE A PF KEYBOARD   48700013
         BC    14,END11A               BRANCH-NO                        48800013
         GCNTRL (1),IND,(11),(8),MF=E                                   48900013
         WAIT  ECB=(1)                                                  49200013
         CLI   DECB,IOK                I/O SUCCESSFULL                  49250013
         BE    END11A                  BRANCH-I/O OK                    49300013
         L     R1,RTNARAY              LOAD RTN CODE ARRAY ADR          49350013
         OI    ZERO(R1),RC5            INDICATE I/O ERROR               49400013
END11A   EQU   *                                                        49450013
         BR    RET                RETURN                                49500013
END08    L     RATL,GTMLATBL      LOAD ADR OF ACTIVE LEVEL              49800013
         L     RB,GTMGACBA        LOAD GACB ADR                         50100013
         LA    RC,GACBOFF(RB)     LOAD GACB START ADR                   50400013
         MVC   PF(4,RC),ATTNPFEN  MOVE IN ENABLED PF KEYS FOR LEVEL     50700013
         MVC   AN(4,RC),ATTNANEN  MOVE IN ENABLED A/N SOURCES FOR LVL   51000013
         TM    ATTNFLGA,LPSTRT    RESTART WANTED FOR LP                 51300013
         BC    14,END12                BRANCH IF NO                     51600013
         MVI   START(RC),LP            MOVE IN RESTART                  51900013
END12    L     RB,NEXT(RB)             LOAD NEXT GACB ADR               52200013
         LA    RC,GACBOFF(RB)          LOAD GACB START ADR              52500013
         MVC   PF(4,RC),ATTNPFDE       MOVE IN ENABLED PF FOR DE        52800013
         MVC   AN(4,RC),ATTNANDE       MOVE IN ENABLED A/N FOR DE       53100013
         TM    ATTNFLGA,LPSTRT         RESTART WANTED                   53400013
         BC    14,END13                BRANCH IF NO                     53700013
         MVI   START(RC),LP            MOVE IN RESTART                  54000013
END13    XC    DECB(36),DECB           CLEAR I/O AREA                   54300013
         CLI   ATTNLITE,LIT1           OPTION 1                         54600013
         BE    END14                   BRANCH IF YES                    54900013
         CLI   ATTNLITE,LIT2           OPTION 2                         55200013
         BE    END15                   BRANCH IF YES                    55500013
         CLI   ATTNLITE,LIT3           OPTION 3                         55800013
         BE    END16                   BRANCH IF YES                    56100013
         MVC   DATA(4),ATTNPFLM        MOVE IN LIGHT MASK               56400013
         B     END10                   BRANCH                           56700013
END15    EQU   *                                                        57000013
         B     END10                   BRANCH                           57300013
END16    MVC   DATA(4),ATTNPFEN        MOVE IN ENABLED KEYS             57600013
         B     END10                   BRANCH                           57900013
END14    CLI   GTMLIGHT,LIT2           OPTION 2                         58200013
         BE    END15                   BRANCH IF YES                    58500013
         CLI   GTMLIGHT,LIT3           OPTION 3                         58800013
         BE    END16                   BRANCH IF YES                    59100013
         MVC   DATA(4),GTMPFKSS        MOVE IN LIGHT MASK               59400013
         B     END10                   BRANCH                           59700013
END11    LR    RATL,RA                 LOAD ADR OF      LEVEL TO FREE   60000013
         L     RA,ATTNFWPT             LOAD ADDR OF NEXT LEVEL TO FREE  60300013
END18    CLC   ATTNDERB(4),ZERO1       ANY DERBS TO FREE                60600013
         BE    END17                   BRANCH IF NO                     60900013
         L     R1,ATTNDERB             LOAD ADR OF DERB                 61200013
         MVC   ATTNDERB(4),ZERO(R1)    UPDATE CHAIN                     61500013
         LA    R0,DERB                 LOAD # OF BYTES TO FREE          61800013
         FREEMAIN R,LV=(0),A=(1)                                        62100013
         B     END18                   BRANCH                           62400013
END17    LR    R1,RATL                 LOAD ADR TO FREE                 62700013
         LA    R0,ATLV                 LOAD SIZE TO FREE                63000013
         FREEMAIN R,LV=(0),A=(1)                                        63300013
         LTR   RA,RA                   ANY MORE LEVELS TO FREE          63600013
         BC    7,END11                 BRANCH IF YES                    63900013
         B     OUTRTN                  BRANCH                           64200013
END20    EQU   *                                                   000A 65200018
         XC    LFORM(64),LFORM          ZERO LIST                  000A 66200018
         ATTNINQ (8),MODE=(C,END22),TYP=ANY,MF=(E,LFORM)           000A 67200018
         BR    RET                     RETURN                           69000013
END22    B     END20                   CONTINUE DATA FLUSH              69300013
         DS    0F                                                       69600013
ZERO1    DC    1F'0'                                                    69900013
ONE      DC    A(1)                                                     70200013
TWO      DC    A(2)                                                     70500013
         CNOP  0,8                                                      70800013
         COPY  GSPCB                                                    71100013
         COPY  GTMCB                                                    71400013
         COPY  ATTNLEVL                                                 71700013
PARAM    DSECT                                                          72000013
ATNLVL   DS    1F                                                       72300013
RANGECDE DS    1F                                                       72600013
WORKAREA DSECT                                                          72900013
PLIST    DS    1F                                                       73200013
RTNARAY  DS    1F                                                       73500013
SAVE     DS    18F                                                      73800013
DECB     DS    8F                                                       74100013
DATA     DS    1F                                                       74400013
GACB     DS    1F                      *                                74700013
TYPE     DS    BL1                     *                                75000013
OPT      DS    BL1                     ATTNINQ MACRO AREA               75300013
TYP      DS    1H                                                       75600013
BRANCH   DS    1F                      *                                75900013
LFORM    DS    16F                                                 000A 76000018
         END                                                            76200013
