*   NAME                                                                00200013
*        ENATN                                                          00400013
*   MODULE NAME                                                         00600013
*        IFFAC02                                                        00800013
*                                                                       01000013
*   FUNCTION                                                            01200013
*        TO ENABLE PROCESSING OF ATTENTION OCCURRENCE(S)                01400013
*        ON THE DESIGNATED SOURCE(S) WHEN THE ASSOCIATED                01600013
*        ATTENTION LEVEL IS ACTIVE.                                     01800013
*                                                                       02000013
*   ENTRY                                                               02200013
*        CSECT NAME                                                     02400013
*                                                                       02600013
*   INPUT                                                               02800013
*        REGISTER 1 CONTAINS THE ADDRESS OF A WORK/SAVE AREA.           03000013
*        THE FIRST WORD CONTAINS THE ADDRESS OF A PARAMETER LIST        03200013
*        COMPOSED OF.                                                   03400013
*              1. ADDRESS OF A VARIABLE CONTAINING THE ATTENTION        03600013
*                 TABLE ADDRESS(ATTNLEVEL).                             03800013
*              2. ADDRESS OF ATTENTION SOURCE(S) (ATTNSOURCE).          04000013
*                 1-31   PROGRAM FUNCTION KEYS 1-31                     04200013
*                 32     END KEY                                        04400013
*                 33     CANCEL KEY                                     04600013
*                 34     LIGHT PEN                                      04800013
*                 35     EOS                                            05000013
*                 36     ASYNCHRONOUS ERROR                             05200013
*                 TO GIVE INDIVIDUAL SOURCES, GIVE A NUMBER.            05400013
*                 TO GIVE SOURCES 5 TO 10, FOR EXAMPLE, 5 IS            05600013
*                 POSITIVE AND 10 IS NEGATIVE.                          05800013
*   OUTPUT                                                              06000013
*        ENABLE MASK TO ATTENTION TABLE AND DELETION OF ANY             06200013
*        ATTENTIONS FROM THE QUEUE THAT MATCH THOSE ATTENTION           06400013
*        TYPES JUST ENABLED.                                            06600013
*   EXIT                                                                06800013
*        TO CALLER VIA REGISTER 14                                      07000013
*   RETURN CODES                                                        07200013
*        4,1   INVALID ATTENTION LEVEL                                  07400013
*        4,N   INVALID SOURCE CODE                                      07600013
*   ATTRIBUTES                                                          07800013
*        REENTRANT, PROBLEM PROGRAM MODE                                08000013
*   FLOWCHARTS                                                          08200013
*        CG, CH, CI                                                     08400013
IFFACA02 CSECT                                                          08600013
*2101,462000-504000                                                000A 08700018
         TITLE  'ENATN - ENABLE ATTENTIONS'                             08800013
REG0     EQU   0                       PARAM REG 0                      09000013
REG1     EQU   1                       PARAM REG 1                      09200013
RLIST    EQU   2                       INPUT PARAM LIST                 09400013
RPARAM   EQU   3                       USER PARAM LIST                  09600013
RATL     EQU   4                       ATTENTION LEVEL ADDR             09800013
RGTMCB   EQU   5                       GTMCB ADR                        10000013
RWORKF   EQU   6                                                        10200013
RWORKD   EQU   7                       WORK REG                         10400013
RBASE    EQU   9                       BASE REG                         10600013
RWORKC   EQU   11                      WORK REG                         10800013
RSAVE    EQU   13                      SAVE AREA REG                    11000013
RWORKA   EQU   14                      WORK REG                         11200013
RWORKB   EQU   15                      WORK REG                         11400013
RSOURCE  EQU   2             CONVERTA  ATTNSOURCE ADR REG               11600013
RFIRST   EQU   3             CONVERTA  FIRST ARG REG                    11800013
RINFO    EQU   4             CONVERTA  ADD INFO REG                     12000013
RPFA     EQU   5             CONVERTA  PF REG                           12200013
RANA     EQU   6             CONVERTA  A/N REG                          12400013
RA       EQU   7             CONVERTA  WORK REG A                       12600013
RB       EQU   8             CONVERTA  WORK REG B                       12800013
* RBASE  EQU   9                       BASEREG DUMMY                    13000013
RC       EQU   10            CONVERTA  WORK REG C                       13200013
RD       EQU   11            CONVERTA  WORK REG D                       13400013
RE       EQU   12            CONVERTA  WORK REG E                       13600013
ADD0     EQU   0                       ADD INFO 0                       13800013
ADD1     EQU   1                                                        14000013
ADD5     EQU   2                       ADD INFO EQUAL 2 FOR ENATTN      14200013
AID      EQU   X'04'                   ATTN LEVEL ID                    14400013
ANTYPE   EQU   X'01'                   A/N END KEY                      14600013
ATYPE    EQU   11                                                       14800013
BPIND    EQU   19                      BACK POINTER INDICATOR           15000013
EGHT     EQU   8                                                        15200013
GACBPLUS EQU   8                       OFFSET TO GACB ADDR              15400013
HASPFK   EQU   X'10'                   HAS PF KEYBOARD                  15500013
HEX00    EQU   X'00'                                                    15600013
HEX01    EQU   X'01'                                                    15800013
HEX03    EQU   X'03'                                                    16000013
HEX04    EQU   X'04'                                                    16200013
HEXFF    EQU   X'FF'                                                    16400013
IOK      EQU   X'7F'                   I/O SUCCESSFULL CODE             16500013
KEYNUM   EQU   10                                                       16600013
L4       EQU   4                                                        16800013
LAST     EQU   X'80'                   LAST PARAMETER                   17000013
NEG      EQU   X'80'                   NEGATIVE VALUE                   17200013
NEXT     EQU   4                       NEXT SOURCE                      17400013
ONE      EQU   1                                                        17600013
PFK0     EQU   X'80'                   PFK0 BIT                         17800013
PFTYPE   EQU   X'02'                                                    18000013
RCC4     EQU   X'08'                   RETURN CODE 4                    18200013
RC4      EQU   16                      OFFSET TO RC4                    18400013
RC5      EQU   X'04'                   I/O ERROR                        18500013
TWO      EQU   2                                                        18600013
TWLV     EQU   12                                                       18800013
ZERO     EQU   0                       ZERO                             19000013
         SAVE  (14,12)                 SAVE REGISTERS                   19200013
         BALR  RBASE,0                 SET UP BASE REG                  19400013
         USING *,RBASE                 DEFINE BASE REG                  19600013
         LR    RLIST,REG1              SAVE INPUT PARAM                 19800013
         USING WORKAREA,RLIST          DEFINE DSECT                     20000013
         L     RPARAM,PARAM            LOAD ADDR USER PARAM LIST        20200013
         USING PLIST,RPARAM            DEFINE DSECT                     20400013
         ST    RSAVE,SAVE+4            MY SAVE ARE ADDR                 20600013
         LA    RSAVE,SAVE              LOAD ADDR MY SAVE AREA           20800013
         ST    RSAVE,SAVE+8            SAVE USERS R13                   21000013
         L     RWORKA,RCA              LOAD RETURN CODE ARRAY ADDR      21200013
         XC    ZERO(20,RWORKA),ZERO(RWORKA)  ZERO ARRAY                 21400013
         B     AROUND                                                   21600013
ERROR    EQU   *                                                        21800013
*   RETURN CODE MUST BE LOADED INTO REG RWORKB (15)                     22000013
*   ADD INFO MUST BE LOADED INTO REG RWORKC (R11)                       22200013
*   OFFSET MUST BE LOADED INTO REG RWORKD (R12)                         22400013
*   UPON ENTRY TO ERROR ROUTINE                                         22600013
         L     RWORKA,RCA              LOAD RETURN CODE ARRAY ADDR      22800013
         STC   RWORKB,ZERO(RWORKA)     STORE RETURN CODE                23000013
         ST    RWORKC,ZERO(RWORKD,RWORKA) STO ADD INFO AT PROPER OFFSET 23200013
OUT      L     RSAVE,SAVE+4            RESTABLISH OLD SAVE AREA         23400013
         RETURN (14,12),T              RETURN TO CALLER                 23600013
AROUND   TM    ATNLVL,LAST             LAST PARAM                       23800013
         BC    14,REQ01                BRANCH IF NO                     24000013
         LA    RWORKC,ADD0             LOAD ADD INFO                    24200013
REQ03    LA    RWORKB,RCC4             LOAD RETURN CODE                 24400013
         LA    RWORKD,RC4              LOAD OFFSET                      24600013
         B     ERROR                                                    24800013
REQ01    L     RATL,ATNLVL             LOAD INDIRECT PTR TO ATTN LEVEL  25000013
         L     RATL,ZERO(RATL)         LOAD ATTN LEVEL ADDR             25200013
         USING ATTNLEVL,RATL           DEFINE DSECT                     25400013
         CLI   ATTNLVID+1,AID          IS THIS VALID ATTN LEVEL         25600013
         BNE   REQ40                   BRANCH IF NO ADD INFO EQUAL1     25800013
*   TEST FOR ANY ATTNSOURCES SPECIFIED                                  26000013
         L     RWORKC,ATNSRCE          LOAD ADDR OF DATA                26200013
         LA    RWORKC,ZERO(RWORKC)     ZERO HI ORDER BIT                26400013
         LTR   RWORKC,RWORKC           IS THERE AN ADDR THERE           26600013
         BZ    INFOADD0                NO                               26800013
         BAL   RWORKA,CONVERTA         BRANCH TO ATTNSOURCE CONVERSION  27000013
         LTR   RWORKB,RWORKB           RC=0                             27200013
         BZ    GOOD                    YES                              27400013
         LR    RWORKC,RWORKB           LOAD ADD INFO                    27600013
         B     REQ03                                                    27800013
REQ40    EQU   *                                                        28000013
         LA    RWORKC,ADD1             LOAD ADD INFO CODE OF 1          28200013
         B     REQ03                                                    28400013
INFOADD0 EQU   *                                                        28600013
*   NO ATTN SOURCE PARAMETER SPECIFIED                                  28800013
         LA    RWORKC,ADD5             LOAD ADD INFO CODE OF 2          29000013
         B     REQ03                                                    29200013
GOOD     EQU   *                                                        29400013
         ST    REG0,ANMASK             SAVE AN MASK                     29600013
         ST    REG1,PFMASK             SAVE PF MASK                     29800013
         OC    ATTNANEN,ANMASK         OR AN MASK TO PERM MASK IN ATLV  30000013
         OC    ATTNPFEN,PFMASK         OR PF MASK TO PERM MASK IN ATLV  30200013
         CLC   ATTNFWPT(4),ZERO1       IS LEVEL ACTIVE                  30400013
         BE    ATNQ                    CONSTRUCT ATTNINQ-IF YES         30600013
TESTATTN EQU   *                                                        30800013
*   TEST ENTRIES ON ATTNMLEN QUEUE FOR MATCH TO NEWLY ENABLED SOURCES   31000013
REQ60    CLC   ATTNMLEN,ZERO1          ANY DATA                         31200013
         BE    TSTATDTA                NO-TEST ATTNDATA QUEU            31400013
         L     RWORKA,ATTNMLEN         LOAD ADDR OF FIRST ENTRY         31600013
         SR    RWORKF,RWORKF           CLEAR PREVIOUS ENTRY REG         31800013
         MVI   ATNFLAG,HEX00           CLEAR ATTNDATA SWITCH            32000013
PFATTNKY CLI   ATYPE(RWORKA),PFTYPE    PF ATTN                          32200013
         BE    PFATTN                  YES                              32400013
         LA    RWORKB,ONE              PRIME REG WITH VALUE ONE         32600013
         CLI   ATYPE(RWORKA),ANTYPE    END KEY ATTN                     32800013
         BE    ANDREG                  YES                              33000013
         SR    RWORKC,RWORKC                CLEAR REG                   33200013
         IC    RWORKC,ATYPE(RWORKA)         INSERT ATTN TYPE            33400013
         LA    RWORKD,TWO              LOAD CONSTANT                    33600013
         SR    RWORKC,RWORKD           DETERMINE SHIFT CONSTANT         33800013
         SLL   RWORKB,ZERO(RWORKC)     POSITION BIT                     34000013
ANDREG   N     RWORKB,ANMASK           DETERMINE IF MATCH               34200013
         LTR   RWORKB,RWORKB           WAS THERE A MATCH                34400013
         BC    7,MATCH                 WK REG EQUAL NON ZERO - BRANCH   34600013
SWPTRS   EQU   *                                                        34800013
SAVEADDR EQU   *                                                        35000013
*   PRESENT ENTRY TO PREVIOUS REGISTER                                  35200013
         LR    RWORKF,RWORKA           SAVE ADDR IN PREVIOUS ENTRY REG  35400013
         L     RWORKA,ZERO(RWORKA)     LOAD PTR TO NEXT ENTRY           35600013
         LTR   RWORKA,RWORKA           ANY MORE ENTRIES                 35800013
         BC    7,PFATTNKY              RWORKA EQUAL NON ZERO-BRANCH     36000013
         B     TSTATDTA                NO                               36200013
MATCH    EQU   *                                                        36400013
         CLI   ATNFLAG,HEX01           ENTRY FROM ATTNDATA              36600013
         BE    FLAGDEL                      YES                         36800013
         LTR   RWORKF,RWORKF           FIRST ENTRY                      37000013
         BZ    DEQENTRY                                                 37200013
*   MOVE FP OF ENTRY TO FP OF PREVIOUS                                  37400013
         MVC   ZERO(4,RWORKF),ZERO(RWORKA)  DEQUEUE ENTRY               37600013
         B     REQ61                                                    37800013
*   MOVE FP OF FIRST TO ATTNMLEN                                        38000013
DEQENTRY MVC   ATTNMLEN(4),ZERO(RWORKA)     DEQUEUE ENTRY               38200013
REQ61    MVC   ZERO(4,RWORKA),ATTNAVAL      ADD ENTRY TO TABLE          38400013
         ST    RWORKA,ATTNAVAL              AVAILABLE LIST              38600013
         B     REQ60                                                    38800013
PFATTN   L     RWORKB,PRIME            PRIME PF REG                     39000013
         SR    RWORKC,RWORKC                CLEAR REG                   39200013
         IC    RWORKC,KEYNUM(RWORKA)        INSERT KEY NUMBER           39400013
         SRL   RWORKB,ZERO(RWORKC)          POSITION BIT                39600013
         N     RWORKB,PFMASK                DETERMINE IF A MATCH        39800013
         LTR   RWORKB,RWORKB                WAS THERE A MATCH           40000013
         BC    7,MATCH                 WK REG EQUAL NON ZERO - BRANCH   40200013
         B     SAVEADDR                                                 40400013
TSTATDTA EQU   *                                                        40600013
         CLI   ATNFLAG,HEX01           BEEN HERE BEFORE                 40800013
         BE    ACTATNLV                YES                              41000013
         CLC   ATTNDATA,ZERO1          ANY DATA                         41200013
         BE    ACTATNLV                                                 41400013
         L     RWORKA,ATTNDATA              LOAD ADDR OF FIRST ENTRY    41600013
         MVI   ATNFLAG,HEX01           SET ATTNDATA ENTRY SWITCH ON     41800013
         SR    RWORKF,RWORKF           CLEAR PREVIOUS ENTRY REG         42000013
         B     PFATTNKY                                                 42200013
FLAGDEL  EQU   *                                                        42400013
*   RWORKA HAS ADDR OF ENTRY ON ATTN QUEU                               42600013
         MVI   20(RWORKA),HEX01        SET PENDING DELETION FLAG        42800013
         B     SWPTRS                                                   43000013
ATNQ     EQU   *                                                        43200013
         ST    RATL,SAVE1              SAVE ATTN LVL ADDR               43400013
AGAIN    CLI   ATTNBPID,HEX01          ATBL BP POINT TO GTMCB           43600013
         BE    LBPTR                   YES                              43800013
         L     RATL,ATTNBKPT           LOAD BACKWARD PTR INTO BASE REG  44000013
         B     AGAIN                                                    44200013
LBPTR    L     RGTMCB,ATTNBKPT         LOAD BASE                        44400013
         USING GTMCB,RGTMCB            DEFINE DESECT                    44600013
         L     RATL,SAVE1              RESTORE ATTN LVL ADDR            44800013
*   REPLACE AN AND PF MASKS IN ATTN LVL 3 OF GACB                       45000013
         L     RWORKA,GTMGACBA         LOAD GACB ADR                    45200013
         LA    RWORKA,GACBPLUS(RWORKA) LOAD PTR TO TRUE START OF GACB   45400013
         MVC   EGHT(L4,RWORKA),PFMASK  PUT NEW PF MASK INTO GACB+8      45600013
         MVC   TWLV(L4,RWORKA),ANMASK  PUT NEW AN MASK INTO GACB+12     45800013
CR12     EQU   *                                                        46000013
         ST    RANA,ATTSAVE                                        000A 46600018
         L     RANA,GTMGACBA            GACB ADDR                  000A 47200018
         LA    RANA,GACBPLUS(RANA)      TRUE GACB ADDR             000A 47800018
         XC    LFORM(64),LFORM          ZERO LIST                  000A 48400018
         ATTNINQ (6),MODE=(C,CR12),TYP=ANY,MF=(E,LFORM)            000A 49000018
         L     RANA,ATTSAVE                                        000A 49600018
*   TEST ENTRIES ON ATTNDATA FOR MATCH TO NEWLY ENABLED SOURCES         50600013
         B     TESTATTN                                                 50800013
ACTATNLV EQU   *                                                        51000013
         CLC   ATTNFWPT(4),ZERO1       IS LEVEL ACTIVE                  51200013
         BNE   RETCODE0                NO                               51400013
*   PUT NEW PERM MASKS IN GACB3                                         51600013
         L     RWORKA,GTMGACBA         LOAD GACB ADDR                   51800013
         LA    RWORKA,GACBPLUS(RWORKA) LOAD PTR TO TRUE START OF GACB   52000013
         MVC   8(4,RWORKA),ATTNPFEN    PUT PF ATN LVL MASK INTO GACB    52200013
         MVC   12(4,RWORKA),ATTNANEN   PUT AN ATN LVL MASK INTO GACB    52400013
         TM    GTMFEATS+1,HASPFK       DOES DEVICE HAVE A PF KEYBOARD   52460013
         BC    14,OUT                  BRANCH-NO                        52520013
         L     RWORKA,ATTNPFEN         LOAD PF MASK                     52600013
         LTR   RWORKA,RWORKA           ANY PF KEYS ENABLED              52800013
         BZ    RETCODE0                NO                               53000013
         CLI   ATTNLITE,HEX03          ENABLED KEYS USED FOR PF LITES   53200013
         BE    TURNONL                                                  53400013
*   SET PF LITES ON AS PER ENABLED KEYS                                 53600013
         CLI   ATTNLITE,HEX01          SYS DEFAULT OPTION IN GTMCB      53800013
         BNE   RETCODE0                                                 54000013
         CLI   GTMLIGHT,HEX03          LIGHT ENABLED KEYS               54200013
         BNE   RETCODE0                NO                               54400013
*   TURN PF LIGHTS ON                                                   54600013
TURNONL  EQU   *                                                        54800013
         XC    DECB(36),DECB           CLEAR I/O AREA                   55000013
         L     RWORKD,GTMGRDCB         LOAD DCB ADDR                    55200013
         LA    RWORKC,DATA             LOAD DATA ADDR                   55400013
         LA    REG1,DECB               LOAD PARM LIST ADDR              55600013
         MVC   DATA(4),ATTNPFEN        PUT KEY MASK INTO DATA (LIGHTS)  55800013
         GCNTRL (1),IND,(7),(11),MF=E  TURN LIGHTS ON                   56000013
         WAIT  ECB=(1)                                                  56200013
         CLI   DECB,IOK                I/O SUCCESSFULL                  56230013
         BE    OUT                     BRANCH- I/O OK                   56260013
         L     REG1,RCA                LOAD RTN CODE ARRAY ADR          56290013
         OI    ZERO(REG1),RC5          INDICATE I/O ERROR               56320013
         B     OUT                     RETURN TO CALLER                 56350013
RETCODE0 EQU   *                                                        56600013
         B     OUT                     RETURN TO CALLER                 56700013
         LA    RWORKC,ADD0             LOAD ADD INFO                    56800013
         LA    RWORKB,ADD0             LOAD RETURN CODE                 57000013
         LA    RWORKD,RC4              LOAD OFFSET                      57200013
         B     ERROR                                                    57400013
         EJECT                                                          57600013
CONVERTA SAVE  (2,12)                  SAVE REGS                        57800013
         LA    RSOURCE,ATNSRCE         LOAD ADR OF 1ST ARG              58000013
         LA    RFIRST,NEXT             INDICATE 1ST ARG                 58200013
         SR    RPFA,RPFA               CLEAR PF REG                     58400013
         SR    RANA,RANA               CLEAR A/N REG                    58600013
         LA    RINFO,ADD5              LOAD 1ST ADD INFO CODE           58800013
         B     REQ18                   BRANCH                           59000013
REQOK    SR    RWORKB,RWORKB           ZERO RETURN CODE                 59200013
         LR    REG0,RANA               LOAD A/N MASK                    59400013
         LR    REG1,RPFA               LOAD P/F MASK                    59600013
         B     REQ19                   BRANCH                           59800013
REQERR   LR    RWORKB,RINFO            LOAD RETURN CODE                 60000013
REQ19    RETURN (2,12)                 RETURN                           60200013
REQ18    L     RC,ZERO(RSOURCE)        LOAD ADR OF ARG                  60400013
         TM    ZERO(RC),NEG            ARG NEGATIVE                     60600013
         BC    1,REQNEG                BRANCH IF NEG                    60800013
         L     RB,ZERO(RC)             LOAD VALUE OF ARG                61000013
REQ24    CL    RB,MAX                  VALUE GREATER THAN ALLOWABLE     61200013
         BC    2,REQERR                BRANCH IF YES                    61400013
REQ23    CL    RB,ANSIZE               VALUE GREATER THAN 31            61600013
         BC    2,REQ20                 BRANCH IF YES                    61800013
         L     RE,PRIME                PRIME REG                        62000013
         SRL   RE,ZERO(RB)             POSITION BIT                     62200013
         OR    RPFA,RE                 ADD TO PF MASK                   62400013
REQ26    TM    ZERO(RC),NEG            ARG NEG                          62600013
         BC    1,REQ21                 BRANCH IF YES                    62800013
REQ22    TM    ZERO(RSOURCE),LAST      MORE ARGS                        63000013
         BC    1,REQOK                 BRANCH IF NO                     63200013
         L     RA,ZERO(RC)             SAVE VALUE PRESENT ARG           63400013
         LA    RSOURCE,NEXT(RSOURCE)   STEP TO NEXT ARG                 63600013
         SR    RFIRST,RFIRST           INDICATE NOT 1ST ARG             63800013
         LA    RINFO,ONE(RINFO)        INCREMENT ADD INFO               64000013
         B     REQ18                   BRANCH TO MORE ARGS              64200013
REQ21    LA    RE,ONE                  LOAD CONSTANT                    64400013
         SR    RB,RE                   DECREMENT ARG BY 1               64600013
         CLR   RA,RB                   VALUE=PREVIOUS VALUE             64800013
         BE    REQ22                   BRANCH IF YES                    65000013
         B     REQ23                   BRANCH                           65200013
REQNEG   LTR   RFIRST,RFIRST           FIRST ARG                        65400013
         BC    7,REQERR                BRANCH IF YES                    65600013
         LTR   RA,RA                   PREV ARG NEG                     65800013
         BC    4,REQERR                BRANCH IF YES                    66000013
         L     RB,ZERO(RC)             LOAD VALUE OF ARG                66200013
         LPR   RB,RB                   MAKE ARG POS                     66400013
         CLR   RB,RA                   VALUE GREATER THAN PREV ARG      66600013
         BC    2,REQ24                 BRANCH IF YES                    66800013
         B     REQERR                  BRANCH                           67000013
REQ20    LA    RD,END                  LOAD ADR OF CONSTANT             67200013
         LA    RE,ONE                  LOAD CONSTANT                    67400013
REQ27    CL    RB,ZERO(RD)             COMPARE                          67600013
         BE    REQ25                   BRANCH IF YES                    67800013
         SLL   RE,ONE                  SHIFT BIT                        68000013
         LA    RD,NEXT(RD)             LOAD NEXT CONSTANT ADR           68200013
         B     REQ27                   BRANCH                           68400013
REQ25    OR    RANA,RE                 ADD BIT TO MASK                  68600013
         B     REQ26                   BRANCH                           68800013
         SPACE 3                                                        69000013
*   CONSTANTS                                                           69200013
*   END,LP,EOS,CANCEL,MAX,ANSIZE FIELDS MUST BE IN SEQUENCE             69400013
END      DC    A(32)                                                    69600013
LP       DC    A(34)                                                    69800013
EOS      DC    A(35)                                                    70000013
CANCEL   DC    A(33)                                                    70200013
MAX      DC    A(36)                                                    70400013
ANSIZE   DC    A(31)                                                    70600013
PRIME    DC    X'80000000'             PF PRIME VALUE                   70800013
ZERO1    DC    1F'0'                                                    71000013
         EJECT                                                          71200013
WORKAREA DSECT                                                          71400013
PARAM    DS    1F                                                       71600013
RCA      DS    1F                                                       71800013
ANMASK   DS    1F                      SAVE AREA FOR ANMASK             72000013
PFMASK   DS    1F                      SAVE AREA FOR PFMASK             72200013
SAVE     DS    18F                                                      72400013
DECB     DS    8F                      I/O DECB                         72600013
SAVE1    DS    1F                                                       72800013
*   GACB,TYPE,OPT,TYP,BRANCH,COM FIELDS MUST BE IN SEQUENCE             73000013
GACB     DS    1F                                                       73200013
TYPE     DS    BL1                                                      73400013
OPT      DS    BL1                                                      73600013
TYP      DS    1H                                                       73800013
BRANCH   DS    1F                                                       74000013
COM      DS    3F                                                       74200013
DATA     DS    1F                      DATA AREA FOR IO                 74400013
ATNFLAG  DS    BL1                     ATTNDATA SWITCH                  74600013
ATTSAVE  DS    F                                                   000A 74660018
LFORM    DS    16F                                                 000A 74720018
         SPACE 3                                                        74800013
PLIST    DSECT                                                          75000013
ATNLVL   DS    1F                                                       75200013
ATNSRCE  DS    1F                                                       75400013
         EJECT                                                          75600013
         COPY  ATTNLEVL                                                 75800013
         COPY  GTMCB                                                    76000013
         COPY  GDSCB                                                    76200013
         COPY  GSPCB                                                    76400013
         END                                                            76600013
