* TITLE:MPATL-MODIFY POSITION OF AN ATTENTION LEVEL                     00200013
* STATUS:CHANGE LEVEL 0                                                 00400013
* FUNCTION:TO CHANGE THE RELATIVE POSITION OF A SPECIFIED  ATTENTION    00600013
*          LEVEL WITHIN THE HIERARCHY OF ALL ATTENTION LEVELS           00800013
*          CURRENTLY ASSOCIATED WITH ITS GTMCB.                         01000013
* ENTRY:ENTERED AT IFFACA04 VIA A CALL TO MPATL.                        01200013
* INPUT:GR#1 CONTAINS THE ADDRESS OF A WORK/SAVE AREA.THE FIRST WORD    01400013
*       CONTAINS THE ADDRESS OF A PARAMETER LIST CONSTRUCTED AS FOLLOWS 01600013
*       1.ATTNLEVEL-ADDRESS OF A VARIABLE WHICH CONTAINS THE ADDRESS    01800013
*         OF AN ATTENTION LEVEL.                                        02000013
*       2.DIRECTION-ADDRESS OF A VALUE INDICATING:                      02200013
*         A POSITIVE VALUE-DEFINES THE NUMBER OF LEVELS THAT THE SPEC-  02400013
*         IFIED ATTENTION LEVEL IS TO BE MOVED UP THE ATTENTION LEVEL   02600013
*         HIERARCHY FROM ITS PRESENT LOCATION OR, IF THE 'RELATTNLEVEL' 02800013
*         ARGUMENT IS SPECIFIED,THE NUMBR OF LEVELS THAT THE SPECIFIED  03000013
*         ATTENTION LEVEL IS TO BE PLACED ABOVE THE RELATIVE ATTENTION  03200013
*         LEVEL.                                                        03400013
*         A NEGATIVE VALUE-SAME AS POSITIVE EXCEPT THE SPECIFIED        03600013
*         ATTENTION LEVEL MOVES DOWN THE HIERARCHY.                     03800013
*       3.RELATTNLEVEL-ADDRESS OF A VARIABLE WHICH CONTAINS THE ADDRESS 04000013
*         OF THE RELATIVE ATTENTION LEVEL.                              04200013
* OUTPUT:RESTRUCTURE WITHIN THE ATTENTION LEVEL HIERARCHY.              04400013
* EXIT:RETURN TO CALLING PROGRAM VIA REGISTER 14.                       04600013
* RETURN CODES:4,0 INSUFFICIENT PARAMETERS                              04800013
*              4,1 INVALID ATTNLEVEL PARAMETER                          05000013
*              4,2 INVALID DIRECTION PARAMETER                          05200013
*              4,3 INVALID RELATTNLEVEL PARAMETER                       05400013
*              0,0 SUCCESSFULL                                          05600013
* ATTRIBUTES:RE-ENTRANT,PROBLEM PROGRAM MODE                            05800013
* EXTERNAL ROUTINES:ATTNINQ                                             06000013
*                   GIOCR                                               06200013
* NOTES:THIS ROUTINE EXAMINES THE FOLLOWING CONTROL BLOCKS:             06400013
*       1.GTMCB                                                         06600013
*       2.GSPCB                                                         06800013
*       3.MAIN LINE GACB                                                07000013
*       4.DIRECT ENTRY GACB                                             07200013
* EXAMPLES:THE FOLLOWING EXAMPLES ARE SHOWN TO AVOID ANY POSSIBLE       07400013
*          MISUNDERSTANDING OF HOW THE INPUT PARAMETERS ARE SPECIFIED.  07600013
*                                                                       07800013
* ******   *****   *****   *****   *****   *****   *******              08000013
* *    *   * 0 *   * A *   * B *   * C *   * D *   *  E  * FORWARD PTR  08200013
* ******   *****   *****   *****   *****   *****   *******              08400013
* * A  *   * B *   * C *   * D *   * E *   * F *   *GTMCB* BACKWARD PTR 08600013
* ******   *****   *****   *****   *****   *****   *******              08800013
* *    *  * LVLA *  LVLB *  LVLC *  LVLD *  LVLE *  LVLF   *            09000013
* ****** ***    ***     ***     ***     ***     ***       ***           09200013
*  GTMCB  *      *       *       *       *       *         *            09400013
*        POS1   POS2    POS3    POS4    POS5    POS6      POS7          09600013
*                                                                       09800013
*                             *** EXAMPLE A ***                         10000013
*  THE FOLLOWING METHODS MAY BE USED TO MOVE   LVLF TO POS2.            10200013
*   1.ATTNLEVEL=LVLF  DIRECTION=+1  RELATTNLEVEL=LVLA                   10400013
*   2.ATTNLEVEL=LVLF  DIRECTION=-4                                      10600013
*   3.ATTNLEVEL=LVLF  DIRECTION=-1  RELATTNLEVEL=LVLB                   10800013
*                             *** EXAMPLE B ***                         11000013
*  THE FOLLOWING METHODS MAY BE USED TO MOVE   LVLA TO POS6.            11200013
*   1.ATTNLEVEL=LVLA  DIRECTION=-1  RELATTNLEVEL=LVLF                   11400013
*   2.ATTNLEVEL=LVLA  DIRECTION=+4                                      11600013
*   3.ATTNLEVEL=LVLA  DIRECTION=+1  RELATTNLEVEL=LVLE                   11800013
*                             *** EXAMPLE C ***                         12000013
*  THE FOLLOWING METHODS MAY BE USED TO MOVE   LVLB TO POS7.            12200013
*   1.ATTNLEVEL=LVLB  DIRECTION=+1  RELATTNLEVEL=LVLF                   12400013
*   2.ATTNLEVEL=LVLB  DIRECTION=+4                                      12600013
*                             *** EXAMPLE D ***                         12800013
* THE FOLLOWING METHODS MAY BE USED TO MOVE   LVLE TO POS3.             13000013
*   1.ATTNLEVEL=LVLE  DIRECTION=-1  RELATTNLEVEL=LVLC                   13200013
*   2.ATTNLEVEL=LVLE  DIRECTION=-2                                      13400013
*   3.ATTNLEVEL=LVLE  DIRECTION=+1  RELATTNLEVEL=LVLB                   13600013
*   THE ABOVE EXAMPLES DID NOT SHOW ALL OF THE POSSIBLE COMBINATIONS.   13800013
*   THEY ARE INTENDED ONLY AS BASIC EXAMPLES TO SHOW HOW THE INPUT      14000013
*   PARAMETERS ARE SPECIFIED AND HOW A VALUE FOR DIRECTION IS DETERMIN- 14200013
*   ED BY THE USER.                                                     14400013
R0       EQU   0                       PARM REG 0                       14600013
R1       EQU   1                       PARM REG 1                       14800013
RLIST    EQU   2                       WORK AREA REG                    15000013
RPARM    EQU   3                       PARAM LIST REG                   15200013
RATNLV   EQU   4                       ATTN LEVEL REG                   15400013
RREL     EQU   5                       REL ATTN LEVEL REG               15600013
RDIRECT  EQU   6                       DIRECTION REG                    15800013
RGTMCB   EQU   7                       GTMCB ADR                        16000013
RLVL     EQU   8                       INSERTION ATNLEVEL ADR           16200013
RBASE    EQU   9                       BASE REG                         16400013
RA       EQU   10                      WORK REG                         16600013
RB       EQU   11                      WORK REG                         16800013
SPARE    EQU   12                      RSVD PL/1                        17000013
RSAVE    EQU   13                      SAVE AREA PTR                    17200013
RC       EQU   14                      WORK REG                         17400013
RD       EQU   15                      WORK REG                         17600013
ADD1     EQU   1                       ADD INFO 1                       17800013
ADD2     EQU   2                       ADD INFO 2                       18000013
ADD3     EQU   3                       ADD INFO 3                       18200013
AID      EQU   X'04'                   ATTN LEVEL ID                    18400013
AN       EQU   12                      OFFSET TO AN MASK IN GACB        18600013
BKPT     EQU   4                       BACKWARD PTR                     18800013
BPID     EQU   X'01'                   BACK PTR TO                      19000013
BPT      EQU   X'1E'                   OFFSET TO BPID                   19200013
DATA     EQU   8                       START OF DATE IN ENTRY BLOCK     19400013
FWPT     EQU   0                       FORWARD PTR                      19600013
GACBOFF  EQU   8                       OFFSET TO START OF GACB          19800013
HASPFK   EQU   X'10'                   HAS PF KEYBOARD                  19860013
IOK      EQU   X'7F'                   I/O SUCCESSFULL CODE             19920013
LAST     EQU   X'80'                   LAST PARAM                       20000013
LIT1     EQU   X'01'                   OPTION 1                         20200013
LIT2     EQU   X'02'                   OPTION 2                         20400013
LIT3     EQU   X'03'                   OPTION 3                         20600013
LP       EQU   X'08'                   LP RESTART OPTION                20800013
OFFSAVE  EQU   8                       SAVE AREA CHAIN                  21000013
ONE      EQU   1                       ONE                              21200013
PF       EQU   8                       OFFSET TO PFMASK IN GACB         21400013
RCC4     EQU   16                      OFFSET TO ADD INFO               21600013
RC4      EQU   X'08'                   RTN CODE 4                       21800013
RC5      EQU   X'04'                   I/O ERROR                        21900013
ZERO     EQU   0                       ZERO                             22000013
IFFACA04 CSECT                                                          22200013
*2238,442000-476000                                                000A 22300018
         SAVE  (14,12)                 SAVE REGISTERS                   22400013
         BALR  RBASE,0                 SET UP BASE REG                  22600013
         USING *,RBASE                 DEFINE BASE REG                  22800013
         LR    RLIST,R1                LOAD DSECT REG                   23000013
         USING WORKAREA,RLIST          DEFINE DSECT                     23200013
         L     RPARM,PLIST             LOAD ADR USER PARM LIST          23400013
         USING PARAM,RPARM             DEFINE DSECT                     23600013
         L     RA,RCA                  LOAD ADR RTN CODE ARRAY          23800013
         XC    ZERO(20,RA),ZERO(RA)    INITIALIZE ARRAY                 24000013
         SR    RREL,RREL               INITIALIZE REG                   24200013
         ST    RSAVE,SAVE+4            SAVE-SAVE AREA PTR               24400013
         LA    RD,SAVE                 LOAD ADR OF MY SAVE AREA         24600013
         ST    RD,OFFSAVE(RSAVE)       STORE IN USER SAVE AREA          24800013
         LA    RSAVE,SAVE              * SAVE AREAS                     25000013
         B     AROUND                  BRANCH                           25200013
ERROR    L     RA,RCA                  LOAD RTN CODE ARRAY ADR          25400013
         STC   RB,ZERO(RA)             STORE RTN CODE                   25600013
         ST    RC,ZERO(RA,RD)          STORE ADD INFO                   25800013
OUTRTN   L     RSAVE,SAVE+4            RESTORE OLD SAVE AREA PTR        26000013
         RETURN (14,12),T              RETURN TO CALLER                 26200013
AROUND   TM    ATNLV,LAST              LAST PARAM                       26400013
         BC    14,MP01                 BRANCH IF NO                     26600013
MP02     SR    RC,RC                   ADD INFO=0                       26800013
MP03     LA    RB,RC4                  LOAD RTN CODE                    27000013
         LA    RD,RCC4                 LOAD ADD INFO OFFSET             27200013
         B     ERROR                   BRANCH                           27400013
MP01     L     RATNLV,ATNLV            LOAD INDIRECT PTR TO ATTN LEVEL  27600013
         L     RATNLV,ZERO(RATNLV)     LOAD ATN LEVEL ADR               27800013
         USING ATTNLEVL,RATNLV         DEFINE DSECT                     28000013
         CLI   ATTNLVID+1,AID          VALID ATTN LEVEL                 28200013
         BE    MP04                    BRANCH IF YES                    28400013
         LA    RC,ADD1                 LOAD ADD INFO                    28600013
         B     MP03                    BRANCH                           28800013
MP04     LR    RA,RATNLV               SAVE REG                         29000013
MP06     CLI   ATTNBPID,BPID           ATN LEVEL POINT TO GTMCB         29200013
         BE    MP05                    BRANCH IF YES                    29400013
         L     RATNLV,ATTNBKPT         LOAD PTR TO NEXT HIGHER LEVEL    29600013
         B     MP06                    BRANCH                           29800013
MP05     L     RGTMCB,ATTNBKPT         LOAD GTMCB ADR                   30000013
         USING GTMCB,RGTMCB            DEFINE DSECT                     30200013
         LR    RATNLV,RA               RESTORE REG                      30400013
         L     RA,GTMGSPCB             LOAD GSPCB ADR                   30600013
         USING GSPCB,RA                DEFINE DSECT                     30800013
         L     RB,DIRECTON             LOAD ADR OF DIRECTION PARAM      31000013
         LA    RB,ZERO(RB)             ZERO HI ORDER BYTE               31200013
         CL    RB,GSPNULLV             DIRECTION=NULL                   31400013
         BE    MP02                    BRANCH IF DIRECTION=NULL         31600013
         L     RDIRECT,ZERO(RB)        LOAD VALUE OF DIRECTION          31800013
         LTR   RDIRECT,RDIRECT         IS DIRECTION VALUE = 0           31860013
         BZ    OUTRTN                  YES, EXIT IMMEDIATELY            31920013
MP07     TM    DIRECTON,LAST           LAST PARAM                       32000013
         BO    MP08                    BRANCH-LAST PARAM                32200013
         L     RB,RELATNLV             LOAD INDIRECT PTR TO REL ATTN    32400013
*                                      LEVEL                            32600013
         LA    RB,ZERO(RB)             ZERO HI ORDER BYTE               32800013
         CL    RB,GSPNULLV             REL ATTN LEVEL=NULL              33000013
         BE    MP08                    BRANCH IF YES                    33200013
         L     RREL,ZERO(RB)           LOAD ADR REL ATN LEVEL           33400013
         USING ATNLEVL,RREL            DEFINE DSECT                     33600013
MP09     CLI   ATNLVID+1,AID           VALID ATTN LEVEL                 33800013
         BE    MP10                    BRANCH IF YES                    34000013
         LA    RC,ADD3                 LOAD ADD INFO                    34200013
         B     MP03                    BRANCH                           34400013
MP10     LR    RB,RREL                 SAVE ADR                         34600013
         SR    RA,RA                   ZERO COUNT REG                   34800013
MP11     CLI   ATNBPID,BPID            REL ATTN LEVEL POINT TO GTMCB    35000013
         BE    MP12                    BRANCH IF YES                    35200013
         L     RREL,ATNBKPT            LOAD BACK PTR                    35400013
         CLR   RREL,RATNLV             BACK PTR=SPEC ATTN LEVEL ADR     35600013
         BE    MP13                    BRANCH IF YES                    35800013
         LA    RA,ONE(RA)              INCREMENT COUNT BY ONE           36000013
         B     MP11                    BRANCH                           36200013
MP12     SR    RA,RA                   ZERO COUNT REG                   36400013
         LR    RREL,RB                 RESTORE REL ATN LEVEL ADR REG    36600013
MP14     CLC   ATNFWPT(4),ZERO1        FORWARD PTR=0                    36800013
         BE    MP02                    BRANCH IF YES                    37000013
         L     RREL,ATNFWPT            LOAD FORWARD PTR                 37200013
         CLR   RREL,RATNLV             FORWARD PTR = ADR OF SPEC'D      37400013
         BE    MP15                    BRANCH IF YES                    37600013
         LA    RA,ONE(RA)              INCREMENT COUNT                  37800013
         B     MP14                    BRANCH                           38000013
MP13     LA    RA,1(RA)                BIAS COUNT BY ONE                38100013
         LNR   RA,RA                   MAKE COUNT NEGATIVE              38200013
MP15     LR    RREL,RB                 RESTORE REL ATN LEVEL REG        38400013
         LA    RB,ONE                                                   38470013
         LTR   RA,RA                   CHECK DIRECTION TO RELATIVE      38540013
*                                      BLOCK                            38610013
         BM    MP15A                                                    38680013
         LTR   RDIRECT,RDIRECT         LESS THAN ZERO, CHECK DIRECTION  38750013
         BP    MP16                    IF POSITIVE, DIRECTION OK        38780013
         AR    RDIRECT,RB              INCREMENT DIRECTION BY ONE       38820013
         B     MP16                    GET FINAL DIRECTION              38890013
MP15A    AR    RA,RB                   REMOVE BIAS                      38960013
         LTR   RDIRECT,RDIRECT         IS DIRECTION POSITIVE            39030013
         BM    MP16                    LESS THAN 0, GET FINAL COUNT     39100013
         SR    RDIRECT,RB              DECREMENT DIRECTION BY ONE       39200013
MP16     AR    RDIRECT,RA              ADD COUNT TO DIRECTION           39400013
         LTR   RDIRECT,RDIRECT         DIRECTION = ZERO                 39460013
         BZ    OUTRTN                  YES, EXIT IMMEDIATELY            39520013
MP08     SR    RA,RA                   CLEAR COUNT REG                  39600013
         LR    RB,RATNLV               SAVE REG CONTENTS                39800013
         LTR   RDIRECT,RDIRECT         DIRECTION NEGATIVE               40000013
         BC    4,MP17                  BRANCH-NEGATIVE                  40200013
MP19     CLI   ATTNBPID,BPID           ATN LEVEL POINT TO GTMCB         40400013
         BE    MP18                    BRANCH IF YES                    40600013
         L     RATNLV,ATTNBKPT         LOAD PTR TO NEXT HIGHER LEVEL    40800013
         LA    RA,ONE(RA)              INCREMENT COUNT BY ONE           41000013
         B     MP19                    BRANCH                           41200013
MP18     CLR   RDIRECT,RA              COUNT = OR GT DIRECTION          41400013
         BC    12,MP20                 BRANCH IF YES                    41600013
MP22     LA    RC,ADD2                 LOAD ADD INFO                    41800013
         B     MP03                    BRANCH                           42000013
MP17     L     RATNLV,ATTNFWPT         LOAD FORWARD PTR                 42200013
         LTR   RATNLV,RATNLV           FORWARD PTR=0                    42400013
         BZ    MP21                    BRANCH ON ZERO                   42600013
         LA    RA,ONE(RA)              INCREMENT COUNT                  42800013
         B     MP17                    BRANCH                           43000013
MP21     LNR   RA,RA                   MAKE COUNT NEGATIVE              43200013
         CR    RDIRECT,RA              COUNT = OR LT DIRECTION          43400013
         BL    MP22                    NO, ERROR EXIT                   43600013
MP20     L     RATNLV,GTMLATBL         LOAD ADR OF ACTIVE LEVEL         44000013
MP23     EQU   *                                                   000A 44400018
         ST    RPARM,ATTSAVE                                       000A 44800018
         L     RPARM,GTMGACBA          GACB ADDRESS                000A 45200018
         LA    RPARM,PF(RPARM)          TRUE GACB ADDR             000A 45600018
         L     RA,ZERO(RPARM)           COMMAREA ADDR              000A 46000018
         XC    LFORM(64),LFORM          ZERO LIST                  000A 46400018
         ATTNINQ (3),MODE=(C,MP24),TYP=ANY,MF=(E,LFORM)            000A 46800018
         L     RPARM,ATTSAVE                                       000A 47200018
         B     MP25                    BRANCH                           47800013
MP24     CLC   ATTNAVAL(4),ZERO1       ANY ENTRIES AVAILABLE            48000013
         BE    MP23                    BRANCH IF NO                     48200013
         L     RC,ATTNAVAL             LOAD ADR OF AVAILABLE ENTRY      48400013
         MVC   ATTNAVAL(4),ZERO(RC)    UPDATE CHAIN                     48600013
         MVC   DATA(4,RC),ZERO(RA)     MOVE DATA INTO ENTRY             48800013
         CLC   ATTNMLEN(4),ZERO1       DATA ON QUEUE                    49000013
         BNE   MP26                    BRANCH IF YES                    49200013
         MVC   ZERO(4,RC),ATTNMLEN     * HANG ENTRY                     49400013
         ST    RC,ATTNMLEN             * ON QUEUE                       49600013
         B     MP23                    BRANCH                           49800013
MP26     L     RD,ATTNMLEN             LOAD ADR OF 1ST ENTRY            50000013
MP28     CLC   ZERO(4,RD),ZERO1        ANY MORE ENTRIES                 50200013
         BE    MP27                    BRANCH IF NO                     50400013
         L     RD,ZERO(RD)             LOAD ADR OF NEXT ENTRY           50600013
         B     MP28                    BRANCH                           50800013
MP27     MVC   ZERO(4,RC),ZERO(RD)     * HANG ENTRY                     51000013
         ST    RC,ZERO(RD)             * ON QUEUE                       51200013
         B     MP23                    BRANCH                           51400013
MP25     LR    RATNLV,RB               RESTORE REG                      51600013
         L     RA,GTMGACBA             LOAD ADR OF ML GACB              51800013
         LA    RB,GACBOFF(RA)          LOAD START ADR OF GACB           52000013
         SAEC  RESTART=NO,MF=(E,(11))                                   52200013
         XC    PF(8,RB),PF(RB)         DISABLE ML GACB                  52400013
         L     RA,ZERO(RA)             LOAD ADR DE GACB                 52600013
         LA    RB,GACBOFF(RA)          LOAD START ADR OF GACB           52800013
         SAEC  RESTART=NO,MF=(E,(11))                                   53000013
         XC    PF(8,RB),PF(RB)         DISABLE DE GACB                  53200013
MP29     CLI   ATTNBPID,BPID           BACK PTR POINT TO GTMCB          53400013
         BE    MP30                    BRANCH IF YES                    53600013
         CLC   ATTNFWPT(4),ZERO1       FORWARD PTR=0                    53800013
         BE    MP31                    BRANCH IF YES                    54000013
         L     RA,ATTNBKPT             LOAD ADR NEXT HIGHER LEVEL       54200013
         MVC   FWPT(4,RA),ATTNFWPT     SPEC ATNLVL FP TO NEXT HIGHER    54400013
*                                      ATTN LEVEL FP                    54600013
         L     RA,ATTNFWPT             LOAD ADR NEXT LOWER LEVEL        54800013
         MVC   BKPT(4,RA),ATTNBKPT  -  SPEC ATLV BP TO NEXT LOWER       55000013
*                                      ATLV BP                          55200013
         B     MP32                    BRANCH                           55400013
MP31     L     RA,ATTNBKPT             LOAD ADR OF NEXT HIGHER LEVEL    55600013
         MVC   FWPT(4,RA),ATTNFWPT     SPEC ATLV FP TP NEXT HIGHER      55800013
*                                      ATLV FP                          56000013
         MVC   GTMLATBL(4),ATTNBKPT    SPEC ATLV BP TO GTMCB ATLV PTR   56200013
         B     MP32                                                     56400013
MP30     CLC   ATTNFWPT(4),ZERO1       SPEC ATLV FP=0                   56600013
         BE    MP33                    BRANCH IF YES                    56800013
         L     RA,ATTNFWPT             LOAD ADR NEXT LOWER LEVEL        57000013
         MVC   BKPT(4,RA),ATTNBKPT     SPEC ATLV BP TO NEXT LOWER       57200013
*                                      ATLV BP                          57400013
         OI    BPT(RA),BPID            INDICATE LOWER ATLV POINT        57600013
*                                      TO GTMCB                         57800013
         B     MP32                    BRANCH                           58000013
MP33     XC    GTMLATBL(4),GTMLATBL    ZERO GTMCB ATLV PTR              58200013
MP32     XC    ATTNBPID(1),ATTNBPID    TURN OFF BACK PTR ID             58400013
         LTR   RDIRECT,RDIRECT         DIRECTION NEGATIVE               58600013
         BC    4,MP34                  BRANCH IF NEGATIVE               58800013
MP36     L     RLVL,ATTNBKPT           LOAD BP OF SPEC LEVEL            59600013
MP38     LA    RA,ONE                  LOAD CONSTANT                    59800013
         SR    RDIRECT,RA              DECREMENT DIRECTION              60000013
         LTR   RDIRECT,RDIRECT         DIRECTION=0                      60200013
         BZ    MP37                    BRANCH IF 0                      60400013
         L     RLVL,BKPT(RLVL)         LOAD BACK PTR                    60600013
         B     MP38                    BRANCH                           60800013
MP37     EQU   *                                                        61000013
         DROP  RREL                                                     61200013
         USING ATNLEVL,RLVL                                             61400013
         MVC   ATTNBKPT(4),ATNBKPT     BP OF HIGHER ATLV TO BP OF       61600013
*                                      SPEC ATLV                        61800013
         MVC   ATTNBPID(1),ATNBPID     BPID OF HIGHER ATLV TO BPID      62000013
*                                      OF SPEC ATLV                     62200013
         ST    RLVL,ATTNFWPT           ADR OF HIGHER ATLV TO FP OF      62400013
*                                      SPEC ATLV                        62600013
         ST    RATNLV,ATNBKPT          ADR OF SPEC'D ATLV TO BP OF      62800013
*                                      HIGHER ATLV                      63000013
         CLI   ATTNBPID,BPID           SPEC ATNLV BP= X'01'             63200013
         BE    MP39                    BRANCH IF YES                    63400013
         L     RA,ATTNBKPT             LOAD ADR NEXT HIGHER LEVEL       63600013
         ST    RATNLV,FWPT(RA)         ADR OF SPEC ATNLV TO FP OF ATNLV 63800013
*                                      POINTED TO BY BP OF SPEC ATLV    64000013
         B     MP40                    BRANCH                           64200013
MP39     XC    ATNBPID(1),ATNBPID      ZERO BPID OF HIGHER LEVEL        64400013
         B     MP40                    BRANCH                           64600013
MP34     LPR   RDIRECT,RDIRECT         MAKE DIRECTION POSITIVE          64800013
         L     RLVL,ATTNFWPT           LOAD FP OF SPEC LEVEL            65000013
MP42     LA    RA,ONE                  LOAD CONSTANT                    65200013
         SR    RDIRECT,RA              DECREMENT DIRECTION              65400013
         LTR   RDIRECT,RDIRECT         DIRECT=0                         65600013
         BZ    MP41                    BRANCH=0                         65800013
         L     RLVL,FWPT(RLVL)         LOAD FORWARD PTR                 66000013
         B     MP42                    BRANCH                           66200013
MP41     MVC   ATTNFWPT(4),ATNFWPT     FP TO LOWER ATLV TO FP OF        66400013
*                                      SPEC'D ATLV                      66600013
         ST    RLVL,ATTNBKPT           ADR OF LOWER ATLV TO BP OF       66800013
*                                      SPEC ATLV                        67000013
         ST    RATNLV,ATNFWPT          ADR OF SPEC ATLV TO FP OF        67200013
*                                      LOWER ATLV                       67400013
         CLC   ATTNFWPT(4),ZERO1       FP OF SPEC ATLV=0                67600013
         BE    MP43                    BRANCH=0                         67800013
         L     RA,ATTNFWPT             LOAD FP OF SPEC                  68000013
         ST    RATNLV,BKPT(RA)         ADR OF SPEC ATLV TO BP OF ATLV   68200013
*                                      POINTED TO BY FP OF SPEC ATLV    68400013
         B     MP40                    BRANCH                           68600013
MP43     ST    RATNLV,GTMLATBL         ADR OF SPEC ATLV TO GTMCB        68800013
MP40     L     RATNLV,GTMLATBL         LOAD ADR OF ACTIVE LEVEL         69000013
         L     RA,GTMGACBA             LOAD GACB ADR                    69200013
         LA    RB,GACBOFF(RA)          LOAD START ADR ML GACB           69400013
         MVC   PF(4,RB),ATTNPFEN       ENABLE PF KEYS                   69600013
         MVC   AN(4,RB),ATTNANEN       ENABLE A/N SOURCES               69800013
         TM    ATTNFLGA,LP             RESTART WANTED ON LP             70000013
         BC    14,MP45                 BRANCH-NO                        70200013
         SAEC  RESTART=YES,MF=(E,(11))                                  70400013
MP45     L     RA,ZERO(RA)             LOAD ADR NEXT GACB               70600013
         LA    RB,GACBOFF(RA)          LOAD START ADR OF DE GACB        70800013
         MVC   PF(4,RB),ATTNPFDE       ENABLE PF KEYS                   71000013
         MVC   AN(4,RB),ATTNANDE       ENABLE A/N SOURCES               71200013
         TM    ATTNFLGA,LP             RESTART WANTED ON LP             71400013
         BC    14,MP46                 BRANCH-NO                        71600013
         SAEC  RESTART=YES,MF=(E,(11))                                  71800013
MP46     XC    DECB(36),DECB           CLEAR I/O AREA                   72000013
         TM    GTMFEATS+1,HASPFK       DOES DEVICE HAVE A PF KEYBOARD   72060013
         BC    14,OUTRTN               BRANCH-NO                        72120013
         CLI   ATTNLITE,LIT1           OPTION 1                         72200013
         BE    MP47                    BRANCH-YES                       72400013
         CLI   ATTNLITE,LIT2           OPTION 2                         72600013
         BNE   MP48                    BRANCH-NO                        72800013
MP51     LA    RA,DATA1                LOAD DATA ADR                    73000013
         B     MP49                    BRANCH                           73200013
MP48     CLI   ATTNLITE,LIT3           OPTION 3                         73400013
         BE    MP50                    BRANCH YES                       73600013
         LA    RA,ATTNPFLM             LOAD DATA ADR                    73800013
         B     MP49                    BRANCH                           74000013
MP50     LA    RA,ATTNPFEN             LOAD DATA ADR                    74200013
         B     MP49                    BRANCH                           74400013
MP47     CLI   GTMLIGHT,LIT2           OPTION 2                         74600013
         BE    MP51                    BRANCH-YES                       74800013
         CLI   GTMLIGHT,LIT3           OPTION 3                         75000013
         BE    MP50                    BRANCH-YES                       75200013
         LA    RA,GTMPFKSS             LOAD DATA ADR                    75400013
MP49     L     RB,GTMGRDCB             LOAD DCB ADR                     75600013
         LA    R1,DECB                 LOAD ADR PARAM LIST              75800013
         GCNTRL (1),IND,(11),(10),MF=E                                  76000013
         WAIT  ECB=(1)                                                  76200013
         CLI   DECB,IOK                I/O SUCCESSFULL                  76240013
         BE    OUTRTN                  BRANCH-YES                       76280013
         L     RA,RCA                  LOAD RTN CODE ARRAY ADR          76320013
         OI    ZERO(RA),RC5            INDICATE I/O ERROR               76360013
         B     OUTRTN                                                   76400013
         DS    0F                                                       76600013
ZERO1    DC    1F'0'                                                    76800013
         CNOP  0,8                                                      77000013
PARAM    DSECT                                                          77200013
ATNLV    DS    1F                                                       77400013
DIRECTON DS    1F                                                       77600013
RELATNLV DS    1F                                                       77800013
         COPY  ATTNLEVL                                                 78000013
         COPY  GSPCB                                                    78200013
         COPY  GTMCB                                                    78400013
ATNLEVL  DSECT                                                          78600013
ATNFWPT  DS    1F                                                       78800013
ATNBKPT  DS    1F                                                       79000013
ATNLVID  DS    1F                                                       79200013
ATNDERB  DS    1F                                                       79400013
ATNAVAL  DS    1F                                                       79600013
ATNDATA  DS    1F                                                       79800013
ATNMLEN  DS    1F                                                       80000013
ATNFLGA  DS    BL1                                                      80200013
ATNFLGB  DS    BL1                                                      80400013
ATNBPID  DS    BL1                                                      80600013
ATNLITE  DS    BL1                                                      80800013
ATNPFLM  DS    1F                                                       81000013
ATNPFEN  DS    1F                                                       81200013
ATNANEN  DS    1F                                                       81400013
ATNPFDE  DS    1F                                                       81600013
ATNANDE  DS    1F                                                       81800013
WORKAREA DSECT                                                          82000013
PLIST    DS    1F                                                       82200013
RCA      DS    1F                                                       82400013
SAVE     DS    18F                                                      82600013
GACB     DS    1F                                                       82800013
TYPE     DS    BL1                                                      83000013
OPT      DS    BL1                                                      83200013
TYP      DS    1H                                                       83400013
BRANCH   DS    1F                                                       83600013
DECB     DS    8F                                                       83800013
DATA1    DS    1F                                                       84000013
LFORM    DS    16F                                                 000A 84060018
ATTSAVE  DS    F                                                   000A 84120018
         END                                                            84200013
