* TITLE:MLITS-MODIFY PROGRAM FUNCTION INDICATOR LIGHTS                  00300013
* STATUS:CHANGE LEVEL 0                                                 00600013
* FUNCTION:TO DEFINE WHICH PROGRAM FUNCTION INDICATOR LIGHTS ARE TO BE  00900013
*          ON AND WHICH ARE TO BE OFF.                                  01200013
* ENTRY:ENTERED AT IFFACA07 VIA A CALL TO MLITS                         01500013
* INPUT:GR#1 CONTAINS THE ADDRESS OF A WORK/SAVE AREA.THE FIRST WORD    01800013
*       CONTAINS THE ADDRESS OF A PARAMETER LIST CONSTRUCTED AS FOLLOWS 02100013
*       1.DEVICENAME/ATTNLEVEL-ADDRESS OF A VARIABLE CONTAINING EITHER  02400013
*         THE ADDRESS OF A GTMCB OR AN ATTENTION LEVEL.                 02700013
*       2.STATUS-ADDRESS OF A VALUE WHICH INDICATES:                    03000013
*         A. 1-USE CURRENTLY APPLICABLE SYSTEM DEFAULT                  03300013
*         B. 2-TURN OFF ALL PROGRAM FUNCTION INDICATORS                 03600013
*         C. 3-LIGHT PROGRAM FUNCTION INDICATORS TO CORRESPOND TO       03900013
*              CURRENTLY ENABLED PROGRAM FUNCTION KEYS.                 04200013
*         D. 4-USE LIGHTS ARGUMENTS AS PREVIOUSLY SPECIFIED BY ANOTHER  04500013
*              CALL OR AS FOLLOWS.                                      04800013
*       3.LIGHTS-ADDRESS(ES) OF A VALUE(S) SPECIFYING WHICH PROGRAM     05100013
*         FUNCTION INDICATOR LIGHTS ARE TO BE TURNED ON IN GTMCB OR     05400013
*         ATTENTION LEVEL LIGHT MASK.                                   05700013
* OUTPUT:DESIGNATED PROGRAM FUNCTION INDICATORS ARE LIGHTED.            06000013
* EXIT:RETURN TO CALLING PROGRAM                                        06300013
* RETURN CODES: 4,0 INCORRECT NUMBER OF PARAMETERS                      06600013
*               4,1 INVALID DEVICENAME/ATTNLEVEL                        06900013
*               4,2 INVALID STATUS                                      07200013
*               4,3-N INVALID LIGHTS ARGUMENT                           07500013
*               0,0-SUCCESSFULL EXECUTION.                              07800013
* ATTRIBUTES:RE-ENTRANT,PROBLEM PROGRAM MODE                            08100013
* NOTES:THE FOLLOWING CONTROL BLOCKS ARE EXAMINED BY THIS ROUTINE       08400013
*       1.GTMCB                                                         08700013
*       2.GSPCB                                                         09000013
* EXTERNAL ROUTINES:GIOCR                                               09300013
R0       EQU   0                       PARM REG 0                       09600013
R1       EQU   1                       PARM REG 1                       09900013
RLIST    EQU   2                       WORK AREA REG                    10200013
RSOURCE  EQU   2                       SOURCE ADR REG                   10500013
RFIRST   EQU   3                       FIRST ARG REG                    10800013
RPARM    EQU   3                       USER PARAM LIST REG              11100013
RATL     EQU   4                       ATLV ADR REG                     11400013
RLIGHTS  EQU   4                       LIGHT MASK REG                   11700013
RGTMCB   EQU   5                       GTMCB ADR REG                    12000013
RINFO    EQU   5                       ADD INFO REG                     12300013
RGSPCB   EQU   6                       GSPCB ADR REG                    12600013
RVAL     EQU   6                       ARG VALUE REG                    12900013
RARG     EQU   7                       ARG ADR REG                      13200013
RE       EQU   8                       WORK REG                         13500013
RSHIFT   EQU   8                       SHIFT REG                        13800013
RBASE    EQU   9                       BASE REG                         14100013
RC       EQU   10                      WORK REG                         14400013
RPREV    EQU   10                      PREVIOUS ARG VALUE REG           14700013
RD       EQU   11                      WORK REG                         15000013
SPARE1   EQU   12                      RSVD FOR PL1                     15300013
RSAVE    EQU   13                      SAVE AREA REG                    15600013
RA       EQU   14                      WORK REG                         15900013
RB       EQU   15                      WORK REG                         16200013
ADD1     EQU   1                       ADD INFO 1                       16500013
ADD2     EQU   2                       ADD INFO 2                       16800013
ADD3     EQU   3                       ADD INFO 3                       17100013
AID      EQU   X'04'                   ATTN LVL ID                      17400013
BPID     EQU   X'01'                   BP ID                            17700013
GID      EQU   X'02'                   GTMCB ID                         18000013
HASPFK   EQU   X'10'                   HAS PF KEYBOARD                  18100013
IOK      EQU   X'7F'                   I/O SUCCESSFULL CODE             18200013
LAST     EQU   X'80'                   LAST PARAM                       18300013
LIT1     EQU   X'01'                   OPTION 1                         18600013
LIT2     EQU   X'02'                   OPTION 2                         18900013
LIT3     EQU   X'03'                   OPTION 3                         19200013
LIT4     EQU   X'04'                   OPTION 4                         19500013
NEG      EQU   X'80'                   NEG ARG                          19800013
NEXT     EQU   4                       NEXT ARG                         20100013
OFFSAVE  EQU   8                       SAVE AREA CHAIN                  20400013
ONEA     EQU   1                       ONE                              20700013
PFK0     EQU   X'80'                   PFK 0                            21000013
RCC4     EQU   16                      OFFSET TO RTN CODE 4             21300013
RC4      EQU   X'08'                   RTN CODE 4                       21600013
RC5      EQU   X'04'                   I/O ERROR                        21700013
ZERO     EQU   0                       ZERO                             21900013
IFFACA07 CSECT                                                          22200013
         TITLE 'MLITES - MODIFY PF LIGHTS'                              22500013
         SAVE  (14,12)                 SAVE REGS                        22800013
         BALR  RBASE,0                 SET UP BASE REG                  23100013
         USING *,RBASE                 DEFINE BASE REG                  23400013
         LR    RLIST,R1                LOAD REG                         23700013
         USING WORKAREA,RLIST          DEFINE DSECT                     24000013
         L     RPARM,PLIST             LOAD ADR USER PARAM LIST         24300013
         USING PARAM,RPARM             DEFINE DSECT                     24600013
         ST    RSAVE,SAVE+4            SAVE-SAVE AREA PTR               24900013
         LA    RD,SAVE                 LOAD ADR OF MY SAVE AREA         25200013
         ST    RD,OFFSAVE(RSAVE)       STORE IN USER SAVE AREA          25500013
         LA    RSAVE,SAVE              ESTABLISH NEW SAVE AREA          25800013
         L     RA,RCA                  LOAD RTN CODE ARRAY ADR          26100013
         XC    ZERO(20,RA),ZERO(RA)    INITIALIZE ARRAY                 26400013
         XC    DECB(36),DECB           CLEAR I/O AREA                   26700013
         B     AROUND                  BRANCH                           27000013
ERROR    L     RA,RCA                  LOAD RTN CODE ARRAY ADR          27300013
         STC   RB,ZERO(RA)             STORE RETURN CODE                27600013
         ST    RC,ZERO(RA,RD)          STORE ADD INFO                   27900013
OUTRTN   L     RSAVE,SAVE+4            RESTORE OLD SAVE AREA PTR        28200013
         RETURN (14,12),T              RETURN TO CALLING PROGRAM        28500013
AROUND   TM    DVCENAME,LAST           LAST PARAM                       28800013
         BC    14,ML01                 BRANCH IF NOT LAST PARAM         29100013
ML11     SR    RC,RC                   ADD INFO=0                       29400013
ML02     LA    RB,RC4                  LOAD RTN CODE                    29700013
         LA    RD,RCC4                 LOAD OFFSET                      30000013
         B     ERROR                                                    30300013
ML01     L     RATL,ATNLV              LOAD PTR                         30600013
         L     RATL,ZERO(RATL)         LOAD CONTROL BLOCK ADR           30900013
         USING ATTNLEVL,RATL           DEFINE DSECT                     31200013
         CLI   ATTNLVID+1,AID          IS THIS AN ATLCB                 31500013
         BNE   ML03                    BRANCH IF NO                     31800013
         ST    RATL,LEVEL              SAVE ADR                         32100013
         XC    DEVICE(4),DEVICE        CLEAR DEVICE ADR                 32400013
         LR    RA,RATL                 SAVE REG                         32700013
ML32     CLI   ATTNBPID,BPID           ATTN LEVEL POINT TO A GTMCB      33000013
         BE    ML31                    BRANCH IF YES                    33300013
         L     RATL,ATTNBKPT           LOAD PTR NEXT HIGHER ATTN LEVEL  33600013
         B     ML32                    BRANCH                           33900013
ML31     L     RGTMCB,ATTNBKPT         LOAD GTMCB ADR                   34200013
         LR    RATL,RA                 RESTORE REG                      34500013
         B     ML04                    BRANCH                           34800013
ML03     CLI   ATTNLVID+1,GID          IS THIS A GTMCB                  35100013
         BE    ML05                    BRANCH IF YES                    35400013
ML06     LA    RC,ADD1                 LOAD ADD INFO                    35700013
         B     ML02                    BRANCH                           36000013
ML05     LR    RGTMCB,RATL             LOAD REG                         36300013
         USING GTMCB,RGTMCB            DEFINE DSECT                     36600013
         CL    RGTMCB,GTMGTMCB         HAS THIS GTMCB BEEN INITIALIZE   36900013
         BNE   ML06                    BRANCH IF NO                     37200013
         ST    RGTMCB,DEVICE           SAVE ADR                         37500013
         XC    LEVEL(4),LEVEL          CLEAR LEVEL ADR                  37800013
ML04     L     RE,STATUS               LOAD PTR TO STATUS               38100013
         LA    RE,ZERO(RE)             CLEAR HIGH ORDER BYTE            38400013
         L     RGSPCB,GTMGSPCB         LOAD GSPCB ADR                   38700013
         USING GSPCB,RGSPCB            DEFINE DSECT                     39000013
         CL    RE,GSPNULLV             STATUS=ADR OF NULL               39300013
         BE    ML30                    BRANCH IF YES                    39600013
         L     RE,ZERO(RE)             LOAD STATUS VALUE                39900013
         CL    RE,ONE                  STATUS=1                         40200013
         BE    ML07                    BRANCH IF YES                    40500013
         CL    RE,TWO                  STATUS=2                         40800013
         BE    ML08                    BRANCH IF YES                    41100013
         CL    RE,THREE                STATUS=3                         41400013
         BE    ML09                    BRANCH IF YES                    41700013
         CL    RE,FOUR                 STATUS=4                         42000013
         BE    ML10                    BRANCH IF YES                    42300013
ML30     LA    RC,ADD2                 LOAD ADD INFO                    42600013
         B     ML02                    BRANCH                           42900013
ML07     CLC   LEVEL(4),ZERO1          LEVEL SPECIFIED                  43200013
         BE    ML11                    BRANCH IF LEVEL NOT SPECIFIED    43500013
         L     RATL,LEVEL              LOAD LEVEL ADR                   43800013
         LA    RE,LIT1                 LOAD OPTION                      44100013
         STC   RE,ATTNLITE             STORE OPTION                     44400013
ML13     CLC   ATTNFWPT(4),ZERO1       LEVEL ACTIVE                     44700013
         BNE   OUTRTN                  BRANCH IF NO                     45000013
ML12     LR    RE,RATL                 SAVE REG                         45300013
ML15     CLI   ATTNBPID,BPID           POINT TO GTMCB                   45600013
         BE    ML14                    BRANCH IF YES                    45900013
         L     RATL,ATTNBKPT           LOAD ADR OF NEXT LEVEL           46200013
         B     ML15                    BRANCH                           46500013
ML14     L     RGTMCB,ATTNBKPT         LOAD GTMCB ADR                   46800013
         LR    RATL,RE                 RESTORE REG                      47100013
         CLI   ATTNLITE,LIT1           OPTION 1                         47400013
         BE    ML16                    BRANCH IF YES                    47700013
         CLI   ATTNLITE,LIT2           OPTION 2                         48000013
         BE    ML19                    BRANCH IF YES                    48300013
         CLI   ATTNLITE,LIT3           OPTION 3                         48600013
         BE    ML18                    BRANCH IF YES                    48900013
         MVC   DATA(4),ATTNPFLM        MOVE IN LIGHT MASK               49200013
         B     ML19                    BRANCH                           49500013
ML18     MVC   DATA(4),ATTNPFEN        MOVE IN ENABLED KEYS             49800013
         B     ML19                    BRANCH                           50100013
ML16     CLI   GTMLIGHT,LIT2           OPTION 2                         50400013
         BE    ML19                    BRANCH IF YES                    50700013
         CLI   GTMLIGHT,LIT3           OPTION 3                         51000013
         BE    ML18                    BRANCH IF YES                    51300013
         MVC   DATA(4),GTMPFKSS        MOVE IN LIGHT MASK               51600013
ML19     EQU   *                                                        51900013
         LA    RC,DATA                 LOAD ADR OF DATA                 52200013
         L     RD,GTMGRDCB             LOAD DCB ADR                     52500013
         LA    R1,DECB                 LOAD I/O AREA ADR                52800013
         TM    GTMFEATS+1,HASPFK       DOES DEVICE HAVE A PF KEYBOARD   52900013
         BC    14,OUTRTN               BRANCH-NO                        53000013
         GCNTRL (1),IND,(11),(10),MF=E                                  53100013
         WAIT  ECB=(1)                                                  53400013
         CLI   DECB,IOK                I/O SUCCESSFULL                  53460013
         BE    OUTRTN                  BRANCH-I/O OK                    53520013
         L     RA,RCA                  LOAD RTN CODE ARRAY ADR          53580013
         OI    ZERO(RA),RC5            INDICATE I/O ERROR               53640013
         B     OUTRTN                  BRANCH                           53700013
ML08     CLC   DEVICE(4),ZERO1         DEVICE OR LEVEL                  54000013
         BE    ML20                    BRANCH-LEVEL                     54300013
         L     RGTMCB,DEVICE           LOAD GTMCB ADR                   54600013
         LA    RE,LIT2                 LOAD OPTION                      54900013
ML22     STC   RE,GTMLIGHT             STORE OPTION                     55200013
         L     RATL,GTMLATBL           LOAD ADR ACTIVE LEVEL            55500013
         LTR   RATL,RATL               IS THERE AN ACTIVE LEVEL         55800013
         BZ    OUTRTN                  BRANCH-NO ACTIVE LEVEL           56100013
         CLI   ATTNLITE,LIT1           OPTION 1                         56400013
         BE    ML16                    BRANCH IF OPT 1                  56700013
         B     OUTRTN                  BRANCH                           57000013
ML20     L     RATL,LEVEL              LOAD LEVEL ADR                   57300013
         LA    RE,LIT2                 LOAD OPTION                      57600013
ML23     STC   RE,ATTNLITE             STORE OPTION                     57900013
         B     ML13                    BRANCH                           58200013
ML09     CLC   DEVICE(4),ZERO1         DEVICE OR LEVEL                  58500013
         BE    ML21                    BRANCH-LEVEL                     58800013
         L     RGTMCB,DEVICE           LOAD GTMCB ADR                   59100013
         LA    RE,LIT3                 LOAD OPTION                      59400013
         B     ML22                    BRANCH                           59700013
ML21     L     RATL,LEVEL              LOAD LEVEL ADR                   60000013
         LA    RE,LIT3                 LOAD OPTION                      60300013
         B     ML23                    BRANCH                           60600013
ML10     TM    STATUS,LAST             LIGHTS ARGUMENT                  60900013
         BC    1,ML24                  BRANCH IF NO                     61200013
         BAL   RA,CONVERT              BRANCH TO CONVERT                61500013
         LTR   RB,RB                   LIGHTS OK                        61800013
         BZ    ML25                    BRANCH IF YES                    62100013
         LR    RC,RB                   LOAD RTN CODE                    62400013
         B     ML02                    BRANCH                           62700013
ML25     CLC   DEVICE(4),ZERO1         DEVICE OR LEVEL                  63000013
         BE    ML26                    BRANCH-LEVEL                     63300013
         L     RGTMCB,DEVICE           LOAD GTMCB ADR                   63600013
         ST    R0,GTMPFKSS             STORE MASK                       63900013
ML28     LA    RE,LIT4                 LOAD OPTION                      64200013
         B     ML22                    BRANCH                           64500013
ML26     L     RATL,LEVEL              LOAD LEVEL ADR                   64800013
         ST    R0,ATTNPFLM             STORE MASK                       65100013
ML29     LA    RE,LIT4                 LOAD OPTION                      65400013
         B     ML23                    BRANCH                           65700013
ML24     CLC   DEVICE(4),ZERO1         DEVICE OR LEVEL                  66000013
         BE    ML27                    BRANCH-LEVEL                     66300013
         L     RGTMCB,DEVICE           LOAD GTMCB ADR                   66600013
         B     ML28                    BRANCH                           66900013
ML27     L     RATL,LEVEL              LOAD LEVEL ADR                   67200013
         B     ML29                    BRANCH                           67500013
CONVERT  SAVE  (2,12)                  SAVE REGS                        67800013
         LA    RSOURCE,LIGHTS          LOAD ADR OF FIRST ARG            68100013
         LA    RFIRST,NEXT             INDICATE 1ST ARG                 68400013
         SR    RLIGHTS,RLIGHTS         CLEAR REG                        68700013
         LA    RINFO,ADD3              LOAD 1ST ADD INFO                69000013
         B     MLA18                   BRANCH                           69300013
MLAOK    SR    RB,RB                   ZERO RETURN CODE                 69600013
         LR    R0,RLIGHTS              LOAD LIGHTS ARG                  69900013
         B     MLA19                   BRANCH                           70200013
MLAERR   LR    RB,RINFO                LOAD RETURN CODE                 70500013
MLA19    RETURN (2,12)                 RETURN                           70800013
MLA18    L     RARG,ZERO(RSOURCE)      LOAD ADR OF ARG                  71100013
         LA    RARG,ZERO(RARG)         ZERO HI ORDER BYTE               71400013
         TM    ZERO(RARG),NEG          ARG NEG                          71700013
         BO    MLANEG                  BRANCH IF NEG                    72000013
         L     RVAL,ZERO(RARG)         LOAD VALUE OF ARG                72300013
MLA24    CL    RVAL,MAX                VALUE GREATER THAN ALLOWABLE     72600013
         BC    2,MLAERR                BRANCH IF YES                    72900013
MLA23    L     RSHIFT,PRIME            PRIME REG                        73200013
         SRL   RSHIFT,ZERO(RVAL)       POSITION BIT                     73500013
         OR    RLIGHTS,RSHIFT          ADD BIT TO LIGHT MASK            73800013
MLA26    TM    ZERO(RARG),NEG          ARG NEG                          74100013
         BO    MLA21                   BRANCH IF YES                    74400013
MLA22    TM    ZERO(RSOURCE),LAST      MORE ARGS                        74700013
         BO    MLAOK                   BRANCH-NO MORE ARGS              75000013
         L     RPREV,ZERO(RARG)        SAVE VALUE PRESENT ARG           75300013
         LA    RSOURCE,NEXT(RSOURCE)   STEP TO NEXT ARG                 75600013
         SR    RFIRST,RFIRST           INDICATE NOT 1ST ARG             75900013
         LA    RINFO,ONEA(RINFO)       INCREMENT ADD INFO               76200013
         B     MLA18                   BRANCH                           76500013
MLA21    LA    RSHIFT,ONEA             LOAD CONSTANT                    76800013
         SR    RVAL,RSHIFT             DECREMENT ARG BY ONE             77100013
         CLR   RPREV,RVAL              VALUE=PREVIOUS VALUE             77400013
         BE    MLA22                   BRANCH IF YES                    77700013
         B     MLA23                   BRANCH                           78000013
MLANEG   LTR   RFIRST,RFIRST           FIRST ARG                        78300013
         BC    7,MLAERR                BRANCH IF YES                    78600013
         LTR   RPREV,RPREV             PREV ARG NEGATIVE                78900013
         BC    4,MLAERR                BRANCH IF YES                    79200013
         L     RVAL,ZERO(RARG)         LOAD VALUE OF ARG                79500013
         LPR   RVAL,RVAL               MAKE ARG POSITIVE                79800013
         CLR   RVAL,RPREV              VALUE GREATER THAN PREV ARG      80100013
         BC    2,MLA24                 BRANCH IF YES                    80400013
         B     MLAERR                  BRANCH                           80700013
         DS    0F                                                       81000013
ZERO1    DC    1F'0'                                                    81300013
ONE      DC    A(1)                                                     81600013
TWO      DC    A(2)                                                     81900013
THREE    DC    A(3)                                                     82200013
FOUR     DC    A(4)                                                     82500013
MAX      DC    A(31)                                                    82800013
PRIME    DC    X'80'                                                    83100013
         DC    AL3(0)                                                   83400013
         CNOP  0,8                                                      83700013
         COPY  ATTNLEVL                                                 84000013
         COPY  GTMCB                                                    84300013
         COPY  GSPCB                                                    84600013
PARAM    DSECT                                                          84900013
DVCENAME DS    0F                                                       85200013
ATNLV    DS    1F                                                       85500013
STATUS   DS    1F                                                       85800013
LIGHTS   DS    1F                                                       86100013
WORKAREA DSECT                                                          86400013
PLIST    DS    1F                                                       86700013
RCA      DS    1F                                                       87000013
SAVE     DS    18F                                                      87300013
DECB     DS    8F                                                       87600013
DATA     DS    1F                                                       87900013
DEVICE   DS    1F                                                       88200013
LEVEL    DS    1F                                                       88500013
         END                                                            88800013
