* TITLE:RQATN-REQUEST ATTENTION INFORMATION                             00100013
* STATUS:CHANGE LEVEL 0                                                 00200013
* FUNCTION:TO DETERMINE IF ANY ATTENTION HAS OCCURRED ON ANY DESIGNATED 00300013
*          SOURCE WHICH HAD BEEN ENABLED WHILE A SPECIFIED ATTENTION    00400013
*          LEVEL WAS ACTIVE.TO DELAY EXECUTION OF THE USER PROGRAM      00500013
*          UNTIL AN EXPECTED ATTENTION OCCURS ON ANY ENABLED DESIGNATED 00600013
*          SOURCE AT THE CURRENTLY ACTIVE ATTENTION LEVEL.              00700013
* ENTRY:ENTERED AT IFFACA08 VIA A CALL TO RQATN.                        00800013
* INPUT:GR#1 CONTAINS THE ADDRESS OF A WORK/SAVE AREA.THE FIRST WORD    00900013
*       CONTAINS THE ADDRESS OF A PARAMETER LIST CONSTRUCTED AS FOLLOWS 01000013
*       1.ATTNLEVEL-ADDRESS OF A VARIABLE CONTAINING THE ADDRESS OF AN  01100013
*         ATTENTION LEVEL.                                              01200013
*       2.CODELOC-ADDRESS OF A LOCATION INTO WHICH A CODE IS PLACED     01300013
*         THAT SPECIFIES THE TYPE OF ATTENTION BEING RETURNED.          01400013
*       3.WAIT-ADDRESS OF A VALUE THAT INDICATES :                      01500013
*         A. 1-IMMEDIATE RETURN IF DATA NOT AVAILABLE                   01600013
*         B. 2-DO NOT RETURN(WAIT) UNTIL DATA IS AVAILABLE              01700013
*       4.ARRAYNAME-ADDRESS OF AN ARRAY WHERE ATTENTION INFORMATION     01800013
*         MAY BE RETURNED.                                              01900013
*       5.ATTNSOURCE-ADDRESS(ES) OF A VALUE(S) DESIGNATING ATTENTION    02000013
*         TYPES THE INFORMATION IS  DESIRED ABOUT.                      02100013
* OUTPUT:ATTENTION DATA TO USER AND A UNIQUE CODE SPECIFYING TYPE OF    02200013
*        DATA BEING RETURNED.                                           02300013
* EXIT:RETURN TO CALLING PROGRAM                                        02400013
* RETURN CODES: 4,0 INCORRECT NUMBER OF PARAMETERS OR UNABLE TO DETER-  02500013
*                   MINE THE SINGLE INDIVIDUAL PARAMETER AT FAULT.      02600013
*               4,1 ATTNLEVEL DID NOT REFER TO A VALID OR EXISTING      02700013
*                   ATTENTION LEVEL.                                    02800013
*               4,3 VALUE OF WAIT INVALID                               02900013
*               4,5-N VALUE OF ATTNSOURCE INVALID                       03000013
*               0,0 SUCCESSFULL EXECUTION                               03100013
* ATTRIBUTES:RE-ENTRANT,PROBLEM PROGRAM MODE                            03200013
* NOTES:THIS ROUTINE EXAMINES THE FOLLOWING CONTROL BLOCKS AND TABLES:  03300013
*       1.GSPCB                                                         03400013
*       2.GTMCB                                                         03500013
*       3.GDSCB                                                         03600013
*       4.KEY TABLE                                                     03700013
*       5.BUFFER CONTROL TABLE                                          03800013
* EXTERNAL ROUTINES:ATTNINQ                                             03900013
*                   GIOCR                                               04000013
*                   CNVRT                                               04100013
REG0     EQU   0                       PARAM REG 0                      04200013
REG1     EQU   1                       PARAM REG 1                      04300013
RLIST    EQU   2                       INPUT PARAM LIST                 04400013
RSOURCE  EQU   2                       ATTNSOURCE ADR REG               04500013
RFIRST   EQU   3                       FIRST ARG REG                    04600013
RPARAM   EQU   3                       USER PARAM LIST                  04700013
RATL     EQU   4                       ATTENTION LEVEL ADR              04800013
RINFO    EQU   4                       ADD INFO REG                     04900013
RGTMCB   EQU   5                       GTMCB ADR                        05000013
RKEY     EQU   5                       KEY TABLE ADR REG                05100013
RPFA     EQU   5                       PF REG                           05200013
RANA     EQU   6                       A/N REG                          05300013
RGSPCB   EQU   6                       GSPCB ADR                        05400013
RKEYEN   EQU   6                       PRESENT KEY ENTRY ADR REG        05500013
RA       EQU   7                       WORK REG A                       05600013
RGDSCB   EQU   7                       GDSCB ADR                        05700013
RB       EQU   8                       WORK REG B                       05800013
RWORKE   EQU   8                       WORK REG E                       05900013
RBASE    EQU   9                       BASE REGISTER                    06000013
RC       EQU   10                      WORK REG C                       06100013
RWORKF   EQU   10                      WORK REG F                       06200013
RD       EQU   11                      WORK REG D                       06300013
RWORKC   EQU   11                      WORK REG                         06400013
RE       EQU   12                      WORK REG E                       06500013
RWORKD   EQU   12                      WORK REG                         06600013
RSAVE    EQU   13                      SAVE AREA REG                    06700013
RWORKA   EQU   14                      WORK REG                         06800013
RWORKB   EQU   15                      WORK REG                         06900013
ADD0     EQU   0                       ADD INFO 0                       07000013
ADD1     EQU   1                       ADD INFO 1                       07100013
ADD2     EQU   2                       ADD INFO 2                       07200013
ADD3     EQU   3                       ADD INFO 3                       07300013
ADD4     EQU   4                       ADD INFO 4                       07400013
ADD5     EQU   5                       ADD INFO 5                       07500013
AEC      EQU   X'06'                   AE                               07600013
AID      EQU   X'04'                   ATTN LEVEL ID                    07700013
ANTYPE   EQU   X'01'                   A/N END KEY                      07800013
ATN99    EQU   99                      SOURCE 99                        07900013
ATYPE    EQU   11                      ATTN TYPE                        08000013
BCTFLAG  EQU   4                       BCT FLAGS                        08100013
BFRLEN   EQU   0                       BFR LENGTH FLD                   08200013
BFRSUB   EQU   X'28'                   BFR SUBROUTINE FLAG              08300013
BPID     EQU   X'01'                   BP ID                            08400013
CANCELC  EQU   X'05'                   CANCEL                           08500013
CCTA     EQU   6                       CHARACTER COUNT IN KEY           08520013
CCTB     EQU   5                       CHARACTER COUNT IN KEY           08540013
CCTC     EQU   8                       COUNT SHIFT VALUE                08560013
CNT      EQU   2                       CNT FLD                          08600013
CNTA     EQU   X'FF'                   COUNT FLD VALUE                  08700013
CORVAL   EQU   8                       CORVAL FLD                       08800013
DE       EQU   X'02'                   DIRECT ENTRY FLAG                08900013
DEQUEUE  EQU   X'04'                   DEQUEUE DATA OPTION              09000013
DIV256   EQU   8                       DIVIDE BY 256                    09100013
ENDC     EQU   X'01'                   END                              09200013
ENDTABLE EQU   8                       END OF TABLE                     09300013
ENTRYLEN EQU   12                      ENTRY LENGTH                     09400013
EOSC     EQU   X'04'                   EOS                              09500013
EOSRST   EQU   X'40'                   RESTART OPT FOR EOS              09600013
EOSXY    EQU   X'80'                   XY OPT FOR EOS                   09700013
EQUIV    EQU   X'08'                   EQUIVALENT GDS FALS              09750013
FIRSENT  EQU   12                      ADR OF 1ST KEY TBL ENTRY         09800013
GACBAN   EQU   12                      OFFSET TO A/N                    09900013
GACBOFF  EQU   8                       OFFSET TO START OF GACB          10000013
GACBPF   EQU   8                       OFFSET TO PF                     10100013
GACBRST  EQU   45                      OFFSET TO RESTART BYTE           10200013
GDOA     EQU   6                       GDOA ADJUSTMENT                  10300013
HIBIT    EQU   X'20'                   HI ORDER BIT                     10350013
IDVAL    EQU   X'80'                   FULL SEGMENT ID+1           0935 10400018
INBFR    EQU   X'80'                   EQUIV GDS IS IN BUFFER FLAG      10450013
IOK      EQU   X'7F'                   I/O SUCCESSFULL                  10470013
KEYNUM   EQU   10                      KEY NUMBER                       10500013
LAST     EQU   X'80'                   LAST PARAMETER                   10600013
LOGSTRT  EQU   2                       LOGICAL START FLD                10700013
LPC      EQU   X'03'                   LP                               10800013
LPCHAR   EQU   X'10'                   LP CHARACTER BIT                 10900013
LPCHRMD  EQU   X'20'                   CHARACTER MODE                   11000013
LPSTART  EQU   X'08'                   LP RESTART BIT                   11100013
LPXY     EQU   X'20'                   LP XY POS BIT                    11200013
LVL2     EQU   X'10'                   LEVEL 2 GDSCB                    11300013
MUL256   EQU   8                       MULTIPLY BY 256                  11400013
NEG      EQU   X'80'                   NEGATIVE VALUE                   11500013
NEXT     EQU   4                       NEXT SOURCE                      11600013
NEXTENTY EQU   4                       ADR OF NEXT ENTRY                11700013
NEXTKEY  EQU   0                       ADR OF NEXT KET TBL              11800013
OFFSAVE  EQU   8                       SAVE AREA CHAIN                  11900013
ONE      EQU   1                       ONE                              12000013
ORGEN    EQU   X'38'                   ORGEN KEY CODE                   12050013
OVLY     EQU   9                       OVERLAY CODE                     12100013
PENDET   EQU   X'01'                   PEN DETECT BIT                   12200013
PFC      EQU   X'02'                   RF                               12300013
PFTYPE   EQU   X'02'                   PF TYPE                          12400013
PTR      EQU   1                       PTR FLD                          12500013
RCC4     EQU   X'08'                   RETURN CODE 4                    12600013
RCC5     EQU   X'04'                   I/O ERROR                        12650013
RC4      EQU   16                      OFFSET TO RC4                    12700013
REQSRCH  EQU   X'80'                   REQATN SEARCHING QUEUE           12800013
RSTON    EQU   X'01'                   RESTART YES VALUE                12900013
RSVDA    EQU   8                       START OF DATA AREA               13000013
SCAN1    EQU   1                       VALUE OF 1                       13100013
SCAN2    EQU   2                       VALUE OF 2                       13200013
SEQNCE   EQU   X'20'                   SEQUENCE FLAG                    13300013
SOURCE99 EQU   99                      ATTN SOURCE 99                   13400013
TOBIT    EQU   X'18'                   SUBROUTINE LINKAGE               13450013
TWO      EQU   2                       TWO                              13500013
ZERO     EQU   0                       ZERO                             13600013
BSCSPC   EQU   56                 BASIC CHAR SPACING          LB A37965 13610021
LRGSPC   EQU   84                 LARGE CHAR SPACING          LB A37965 13620021
BSCSZE   EQU   X'0A'              MASK FOR BASIC SIZE CHARS   LB A37965 13630021
LRGSZE   EQU   X'05'              MASK FOR LARGE SIZE CHARS   LB A37965 13640021
NOSCISS  EQU   X'10'              MASK FOR 'NO SCISSORING'    LB A37965 13650021
XSCREEN  EQU   4092               MAX X FOR CHAR CENTER       LB A37965 13660021
YSCREEN  EQU   4092               MAX Y FOR CHAR CENTER       LB A37965 13670021
BSCLINE  EQU   80                 BASIC LINE SPACING          LB A37965 13680021
LRGLINE  EQU   120                LARGE LINE SPACING          LB A37965 13690021
YLOWER   EQU   0                  MIN Y FOR CHAR CENTER       LB A37965 13700021
IFFACA08 CSECT                                                          13750000
* A33055 FIXED IN COMPONENT IO523.  GSP BYPASS WITH PTF 40613           13752000
*0843,404000-415000,422000-435000                                  000A 13760018
*0843,104000                                                       0935 13770018
*D710000-711000,D713000                                          A37965 13780021
         SAVE  (14,12)                 SAVE REGISTERS                   13800013
         BALR  RBASE,0                 SET UP BASE REGISTER             13900013
         USING *,RBASE                 DEFINE BASE REG                  14000013
         LR    RLIST,REG1              SAVE INPUT PARAMETER             14100013
         USING WORKAREA,RLIST          DEFINE DSECT                     14200013
         L     RPARAM,PARAM            LOAD ADR USER PARAM LIST         14300013
         USING PLIST,RPARAM            DEFINE DSECT                     14400013
         ST    RSAVE,SAVE+4            SAVE-SAVE AREA PTR               14500013
         LA    RD,SAVE                 LOAD ADR OF MY SAVE AREA         14600013
         ST    RD,OFFSAVE(RSAVE)       STORE IN USER SAVE AREA          14700013
         LA    RSAVE,SAVE              * AREAS                          14800013
         L     RWORKA,RCA              LOAD RETURN CODE ARRAY ADR       14900013
         XC    ZERO(20,RWORKA),ZERO(RWORKA) ZERO ARRAY                  15000013
         B     AROUND                  BRANCH                           15100013
ERROR    L     RWORKA,RCA              LOAD RTN CODE ARRAY ADR          15200013
         STC   RWORKB,ZERO(RWORKA)     STORE RETURN CODE                15300013
         ST    RWORKC,ZERO(RWORKD,RWORKA) STORE ADD INFO AT PROPER      15400013
*                                         OFFSET                        15500013
OUTRTN   L     RSAVE,SAVE+4            RESTORE OLD SAVE AREA PTR        15600013
         RETURN (14,12),T              RETURN TO CALLER                 15700013
AROUND   TM    ATNLVL,LAST             LAST PARAM                       15800013
         BC    14,REQ01                BRANCH IF NO                     15900013
REQ02    LA    RWORKC,ADD0             LOAD ADD INFO                    16000013
REQ03    LA    RWORKB,RCC4             LOAD RETURN CODE                 16100013
         LA    RWORKD,RC4              LOAD OFFSET                      16200013
         B     ERROR                   BRANCH                           16300013
REQ01    L     RATL,ATNLVL             LOAD INDIRECT PTR TO ATTN LEVEL  16400013
         L     RATL,ZERO(RATL)         LOAD ATTN LEVEL ADR              16500013
         USING ATTNLEVL,RATL           DEFINE DSECT                     16600013
         CLI   ATTNLVID+1,AID          IS THIS VALID ATTN LEVEL         16700013
         BNE   REQ40                   BRANCH IF NO                     16800013
         LR    RWORKD,RATL             SAVE REG                         16900013
REQ06    CLI   ATTNBPID,BPID           THIS LEVEL POINT TO GTMCB        17000013
         BNE   REQ04                   BRANCH IF NO                     17100013
         L     RGTMCB,ATTNBKPT         LOAD GTMCB ADR                   17200013
         USING GTMCB,RGTMCB            DEFINE DSECT                     17300013
         LR    RATL,RWORKD             RESTORE REG                      17400013
         B     REQ05                   BRANCH                           17500013
REQ04    L     RATL,ATTNBKPT           LOAD ADR NEXT HIGHER LEVEL       17600013
         B     REQ06                   BRANCH                           17700013
REQ05    L     RGSPCB,GTMGSPCB         LOAD GSPCB ADR                   17800013
         USING GSPCB,RGSPCB            DEFINE DESECT                    17900013
         TM    CODELOC,LAST            IS THIS LAST PARAM               18000013
         BC    1,REQ02                 BRANCH IF YES                    18100013
         B     REQ07                   BRANCH                           18200013
REQ08    LA    RWORKC,ADD2             LOAD ADD INFO                    18300013
         B     REQ03                   BRANCH                           18400013
REQ07    CLC   CODELOC(4),GSPNULLV     IS THIS ADR OF NULL              18500013
         BE    REQ08                   BRANCH IF YES                    18600013
         CLC   CODELOC(4),ZERO1        CODE LOC ADR = ZERO              18700013
         BE    REQ08                   BRNANCH IF YES                   18800013
         TM    SCANWAIT,LAST           IS THIS THE LAST PARAM           18900013
         BC    1,REQ02                 BRANCH IF YES                    19000013
         B     REQ09                   BRANCH                           19100013
REQ10    LA    RWORKC,ADD3             LOAD ADR INFO                    19200013
         B     REQ03                   BRANCH                           19300013
REQ09    CLC   SCANWAIT(4),GSPNULLV    IS THIS ADR OF NULL              19400013
         BE    REQ10                   BRANCH IF YES                    19500013
         L     RWORKC,SCANWAIT         LOAD ADR OF SCANWAIT             19600013
         L     RWORKC,ZERO(RWORKC)     LOAD SCAN WAIT VALUE             19700013
         LA    RWORKD,SCAN1            LOAD CONSTANT                    19800013
         CLR   RWORKC,RWORKD           SCANWAIT=1                       19900013
         BE    REQ11                   BRANCH IF YES                    20000013
         LA    RWORKD,SCAN2            LOAD CONSTANT                    20100013
         CLR   RWORKC,RWORKD           SCAN WAIT=2                      20200013
         BNE   REQ10                   BRANCH IF NOT=2                  20300013
REQ11    TM    ARRAY,LAST              LAST PARAMETER                   20400013
         BC    1,REQ02                 BRANCH IF YES                    20500013
         B     REQ41                   BRANCH                           20600013
REQ13    LA    RWORKC,ADD4             LOAD ADD INFO                    20700013
         B     REQ03                   BRANCH                           20800013
REQ41    CLC   ARRAY(4),ZERO1          ARRAY ADR ZERO                   20900013
         BE    REQ13                   BRANCH IF YES                    21000013
REQ12    L     RWORKC,ATNSRCE          LOAD 1ST ATTN SOURCE ARG ADR     21100013
         LA    RWORKC,ZERO(RWORKC)     ZERO HI ORDER BYTE               21200013
         L     RWORKC,ZERO(RWORKC)     LOAD 1ST ATTN SOURCE ARG         21300013
         LA    RWORKD,SOURCE99         LOAD CONSTANT                    21400013
         CLR   RWORKC,RWORKD           IS ATTN SOURCE = 99              21500013
         BNE   REQ14                   BRANCH IF NO                     21600013
         TM    ATNSRCE,LAST            ONLY ATTN SOURCE ARG             21700013
         BC    1,REQ15                 BRANCH IF YES                    21800013
REQ16    LA    RWORKC,ADD5             LOAD ADD INFO                    21900013
         B     REQ03                   BRANCH                           22000013
REQ15    TM    ATTNFLGA,DE             ARE WE IN DIRECT ENTRY           22100013
         BC    1,REQ16                 BRANCH IF YES                    22200013
         B     ATTN99                  BRANCH TO PROCESS SOURCE 99      22300013
REQ14    BAL   RWORKA,CONVERTA         BRANCH TO ATTNSOURCE CONVERSION  22400013
         LTR   RWORKB,RWORKB           RC=0                             22500013
         BC    8,REQ17A                BRANCH IF YES                    22600013
         LR    RWORKC,RWORKB           LOAD ADD INFO                    22700013
         B     REQ03                   BRANCH                           22800013
REQ17A   ST    REG0,ANMASK             SAVE AN MASK                     22900013
         ST    REG1,PFMASK             SAVE PF MASK                     23000013
         NC    ANMASK(4),ATTNANEN      DELETE ANY ATTN SOURCES-         23100013
         NC    PFMASK(4),ATTNPFEN      NOT PREVIOUSLY ENABLED           23200013
         CLC   ANMASK(4),ZERO1         ANY SOURCES ENABLED              23300013
         BNE   REQ800                  BRANCH-YES                       23400013
         CLC   PFMASK(4),ZERO1         ANY SOURCES ENABLED              23500013
         BE    REQ62                   BRANCH-NO                        23600013
REQ800   EQU   *                                                        23700013
         L     RGDSCB,GTMGDSCB         LOAD ADR OF 1ST GDSCB            23800013
         USING GDSCB,RGDSCB            DEFINE DSECT                     23900013
REQ17    TM    ATTNFLGA,DE             ARE WE IN DIRECT ENTRY           24000013
         BC    1,DIRECT                BRANCH IF YES                    24100013
         B     NTDIRECT                BRANCH TO NOT DIRECT ENTRY       24200013
ATTN99   XC    ATTNAECB(4),ATTNAECB    CLEAR SOURCE 99 ECB              24300013
         CLI   ATTNSETA,ATN99          DATA AVAILABLE                   24400013
         BNE   REQ34                   BRANCH IF NO                     24500013
REQ39    L     RWORKA,ARRAY            LOAD ARRAY ADR                   24600013
         L     RWORKB,GSPNULLV         LOAD NULL ADR                    24700013
         CLR   RWORKA,RWORKB           IS THERE AN ARRAY                24800013
         BE    REQ35                   BRANCH IF NO                     24900013
         MVC   ZERO(8,RWORKA),ATTNSETA+4 MOVE DATA TO ARRAY             25000013
REQ35    XC    ATTNSETA(12),ATTNSETA   CLEAR DATA AREA                  25100013
         LA    RWORKB,ATN99            LOAD VALUE                       25200013
REQ36    L     RWORKA,CODELOC          LOAD CODELOC ADR                 25300013
         ST    RWORKB,ZERO(RWORKA)     STORE CODE LOC                   25400013
         B     OUTRTN                  RETURN TO CALLER                 25500013
REQ34    L     RWORKA,SCANWAIT         LOAD PTR TO SCAN WAIT            25600013
         CLC   SCANTWO(4),ZERO(RWORKA) IS A WAIT REQUESTED              25700013
         BE    REQ37                   BRANCH IF YES                    25800013
         SR    RWORKB,RWORKB           CLEAR REG                        25900013
         B     REQ36                   BRANCH                           26000013
REQ37    CLC   ATTNFWPT(4),ZERO1       IS LEVEL ACTIVE                  26100013
         BE    REQ38                   BRANCH IF YES                    26200013
         SR    RWORKC,RWORKC           ADD INFO=0                       26300013
         B     REQ03                   BRANCH                           26400013
REQ38    LA    REG1,ATTNAECB           LOAD ADR OF ECB                  26500013
         WAIT  ECB=(1)                                                  26600013
         B     REQ39                   BRANCH                           26700013
REQ40    LA    RWORKC,ADD1             LOAD ADD INFO CODE               26800013
         B     REQ03                   BRANCH                           26900013
CONVERTA SAVE  (2,12)                  SAVE REGS                        27000013
         LA    RSOURCE,ATNSRCE         LOAD ADR OF 1ST ARG              27100013
         LA    RFIRST,NEXT             INDICATE 1ST ARG                 27200013
         SR    RPFA,RPFA               CLEAR PF REG                     27300013
         SR    RANA,RANA               CLEAR A/N REG                    27400013
         LA    RINFO,ADD5              LOAD 1ST ADD INFO CODE           27500013
         B     REQ18                   BRANCH                           27600013
REQOK    SR    RWORKB,RWORKB           ZERO RETURN CODE                 27700013
         LR    REG0,RANA               LOAD A/N MASK                    27800013
         LR    REG1,RPFA               LOAD P/F MASK                    27900013
         B     REQ19                   BRANCH                           28000013
REQERR   LR    RWORKB,RINFO            LOAD RETURN CODE                 28100013
REQ19    RETURN (2,12)                 RETURN                           28200013
REQ18    L     RC,ZERO(RSOURCE)        LOAD ADR OF ARG                  28300013
         TM    ZERO(RC),NEG            ARG NEGATIVE                     28400013
         BC    1,REQNEG                BRANCH IF NEG                    28500013
         L     RB,ZERO(RC)             LOAD VALUE OF ARG                28600013
REQ24    CL    RB,MAX                  VALUE GREATER THAN ALLOWABLE     28700013
         BC    2,REQERR                BRANCH IF YES                    28800013
REQ23    CL    RB,ANSIZE               VALUE GREATER THAN 31            28900013
         BC    2,REQ20                 BRANCH IF YES                    29000013
         L     RE,PRIME                PRIME REG                        29100013
         SRL   RE,ZERO(RB)             POSITION BIT                     29200013
         OR    RPFA,RE                 ADD TO PF MASK                   29300013
REQ26    TM    ZERO(RC),NEG            ARG NEG                          29400013
         BC    1,REQ21                 BRANCH IF YES                    29500013
REQ22    TM    ZERO(RSOURCE),LAST      MORE ARGS                        29600013
         BC    1,REQOK                 BRANCH IF NO                     29700013
         L     RA,ZERO(RC)             SAVE VALUE PRESENT ARG           29800013
         LA    RSOURCE,NEXT(RSOURCE)   STEP TO NEXT ARG                 29900013
         SR    RFIRST,RFIRST           INDICATE NOT 1ST ARG             30000013
         LA    RINFO,ONE(RINFO)        INCREMENT ADD INFO               30100013
         B     REQ18                   BRANCH TO MORE ARGS              30200013
REQ21    LA    RE,ONE                  LOAD CONSTANT                    30300013
         SR    RB,RE                   DECREMENT ARG BY 1               30400013
         CLR   RA,RB                   VALUE=PREVIOUS VALUE             30500013
         BE    REQ22                   BRANCH IF YES                    30600013
         B     REQ23                   BRANCH                           30700013
REQNEG   LTR   RFIRST,RFIRST           FIRST ARG                        30800013
         BC    7,REQERR                BRANCH IF YES                    30900013
         LTR   RA,RA                   PREV ARG NEG                     31000013
         BC    4,REQERR                BRANCH IF YES                    31100013
         L     RB,ZERO(RC)             LOAD VALUE OF ARG                31200013
         LPR   RB,RB                   MAKE ARG POS                     31300013
         CLR   RB,RA                   VALUE GREATER THAN PREV ARG      31400013
         BC    2,REQ24                 BRANCH IF YES                    31500013
         B     REQERR                  BRANCH                           31600013
REQ20    LA    RD,END                  LOAD ADR OF CONSTANT             31700013
         LA    RE,ONE                  LOAD CONSTANT                    31800013
REQ27    CL    RB,ZERO(RD)             COMPARE                          31900013
         BE    REQ25                   BRANCH IF YES                    32000013
         SLL   RE,ONE                  SHIFT BIT                        32100013
         LA    RD,NEXT(RD)             LOAD NEXT CONSTANT ADR           32200013
         B     REQ27                   BRANCH                           32300013
REQ25    OR    RANA,RE                 ADD BIT TO MASK                  32400013
         B     REQ26                   BRANCH                           32500013
NTDIRECT CLC   ATTNMLEN,ZERO1          ANY DATA                         32600013
         BNE   REQ50                   BRANCH IF YES                    32700013
REQ53    CLC   ATTNFWPT,ZERO1          IS LEVEL ACTIVE                  32800013
         BE    REQ51                   BRANCH IF YES                    32900013
         L     RWORKC,SCANWAIT         LOAD PTR TO SCANWAIT             33000013
         CLC   SCANTWO(4),ZERO(RWORKC) IMMEDIATE RETURN WANTED          33100013
         BNE   REQ52                   BRANCH IF YES                    33200013
REQ62    LA    RWORKC,ADD0             LOAD ADD INFO                    33300013
         B     REQ03                   BRANCH                           33400013
REQ52    L     RWORKC,CODELOC          LOAD ADR OF CODE LOC             33500013
         SR    RWORKD,RWORKD           CLEAR REG                        33600013
         ST    RWORKD,ZERO(RWORKC)     CODE LOC=0                       33700013
         B     OUTRTN                  BRANCH                           33800013
REQ50    L     RWORKA,ATTNMLEN         LOAD ADR OF 1ST ENTRY            33900013
         SR    RWORKF,RWORKF           ZERO REG                         34000013
REQ57    CLI   ATYPE(RWORKA),PFTYPE    PF ATTN                          34100013
         BE    REQ54                   BRANCH IF YES                    34200013
         LA    RWORKB,ONE              PRIME REG                        34300013
         CLI   ATYPE(RWORKA),ANTYPE    END KEY ATTN                     34400013
         BE    REQ55                   BRANCH IF YES                    34500013
         SR    RWORKC,RWORKC           CLEAR REG                        34600013
         IC    RWORKC,ATYPE(RWORKA)    INSERT ATTN TYPE                 34700013
         LA    RWORKD,TWO              LOAD CONSTANT                    34800013
         SR    RWORKC,RWORKD           DETERMINE SHIFT CONSTANT         34900013
         SLL   RWORKB,ZERO(RWORKC)     POSITION BIT                     35000013
REQ55    N     RWORKB,ANMASK           DETERMINE IF MATCH               35100013
         LTR   RWORKB,RWORKB           WAS THERE A MATCH                35200013
         BC    7,REQ56                 BRANCH IF YES                    35300013
REQ58    LR    RWORKF,RWORKA           SAVE ADR                         35400013
         L     RWORKA,ZERO(RWORKA)     LOAD PTR TO NEXT ENTRY           35500013
         LTR   RWORKA,RWORKA           ANY MORE ENTRIES                 35600013
         BC    7,REQ57                 BRANCH IF YES                    35700013
         B     REQ53                   BRANCH                           35800013
REQ54    L     RWORKB,PRIME            PRIME PF REG                     35900013
         SR    RWORKC,RWORKC           CLEAR REG                        36000013
         IC    RWORKC,KEYNUM(RWORKA)   INSERT KEY NUMBER                36100013
         SRL   RWORKB,ZERO(RWORKC)     POSITION BIT                     36200013
         N     RWORKB,PFMASK           DETERMINE IF A MATCH             36300013
         LTR   RWORKB,RWORKB           WAS THERE A MATCH                36400013
         BC    8,REQ58                 BRANCH IF NO                     36500013
REQ56    MVC   RSVD(12),RSVDA(RWORKA)  MOVE DATA TO WORK AREA           36600013
         CLC   ATTNFWPT(4),ZERO1       LEVEL ACTIVE                     36700013
         BE    REQ1A                   BRANCH IF LEVEL ACTIVE           36800013
         LR    REG0,RWORKF             SAVE REG                         36900013
         LR    REG1,RWORKA             SAVE REG                         37000013
         TM    ATTNFLGA,DEQUEUE        MAY WE DEQUEUE FROM AN INACTIVE  37100013
*                                      LEVEL                            37200013
         BO    REQ60                   BRANCH IF NO                     37300013
REQ1A    EQU   *                                                        37400013
         LTR   RWORKF,RWORKF           1ST ENTRY                        37500013
         BC    8,REQ59                 BRANCH IF YES                    37600013
         MVC   ZERO(4,RWORKF),ZERO(RWORKA) DEQUEUE ENTRY                37700013
         B     REQ61                   BRANCH                           37800013
REQ59    MVC   ATTNMLEN(4),ZERO(RWORKA) DEQUEUE ENTRY                   37900013
REQ61    MVC   ZERO(4,RWORKA),ATTNAVAL  * ADD ENTRY TO                  38000013
         ST    RWORKA,ATTNAVAL          * AVAILABLE LIST                38100013
         B     REQ60                   BRANCH                           38200013
REQ51    SR    RWORKC,RWORKC           CLEAR REG                        38300013
         O     RWORKC,ATTNPFEN         ADD ENABLED PF KEYS FOR LEVEL    38400013
         O     RWORKC,PFMASK           ADD REQUESTED SOURCES            38500013
         X     RWORKC,ATTNPFEN         TEST IF REQUEST VALID            38600013
         LTR   RWORKC,RWORKC           REQUEST VALID                    38700013
         BC    7,REQ62                 BRANCH IF NO                     38800013
         O     RWORKC,ATTNANEN         ADD ENABLED A/N SOURCES FOR LVL  38900013
         O     RWORKC,ANMASK           ADD REQUESTED SOURCES            39000013
         X     RWORKC,ATTNANEN         DETERMINE IF VALID REQUEST       39100013
         LTR   RWORKC,RWORKC           VALID REQUEST                    39200013
         BC    7,REQ62                 BRANCH IF NO                     39300013
         L     RWORKC,GTMGACBA         LOAD PTR TO GACB                 39400013
         LA    RWORKC,GACBOFF(RWORKC)  LOAD PTR TO TRUE START OF GACB   39500013
         MVC   SAVE1(4),GACBAN(RWORKC) SAVE A/N MASK                    39600013
         MVC   SAVE2(4),GACBPF(RWORKC) SAVE P/F MASK                    39700013
         MVC   GACBAN(4,RWORKC),ANMASK MOVE IN A/N REQUEST              39800013
         MVC   GACBPF(4,RWORKC),PFMASK MOVE IN PF REQUEST               39900013
         XC    GACB(12),GACB           CLEAR MACRO AREA                 40000013
         L     RWORKA,SCANWAIT         LOAD PTR TO SCAN WAIT            40100013
         CLC   SCANTWO(4),ZERO(RWORKA) IMMEDIATE RETURN WANTED          40200013
         BNE   REQ63                   BRANCH IF YES                    40300013
         XC    LFORM(64),LFORM          ZERO LIST                  000A 40700018
         ATTNINQ (11),MODE=W,TYP=ANY,MF=(E,LFORM)                  000A 41100018
REQ66    MVC   GACBAN(4,RWORKC),SAVE1  RESTORE MASK                     41600013
         MVC   GACBPF(4,RWORKC),SAVE2  RESTORE MASK                     41700013
         L     RWORKD,ZERO(RWORKC)     LOAD COMAREA ADR                 41800013
         MVC   RSVD(12),ZERO(RWORKD)   DATA TO WORK AREA                41900013
         B     REQ60                   BRANCH                           42000013
REQ63    EQU   *                                                        42100013
         XC    LFORM(64),LFORM          ZERO LIST                  000A 42600018
         ATTNINQ (11),MODE=(C,REQ65),TYP=ANY,MF=(E,LFORM)          000A 43100018
         MVC   GACBAN(4,RWORKC),SAVE1  RESTORE MASK                     43600013
         MVC   GACBPF(4,RWORKC),SAVE2  RESTORE MASK                     43700013
         B     REQ52                   BRANCH                           43800013
REQ65    B     REQ66                   BRANCH                           43900013
REQ60    CLI   TYPE,LPC                LIGHT PEN                        44000013
         BE    REQ70                   BRANCH IF YES                    44100013
         CLI   TYPE,EOSC               EOS ATTN                         44200013
         BNE   REQ100                  BRANCH IF NO                     44300013
         CLC   ATTNFWPT(4),ZERO1       LEVEL ACTIVE                     44400013
         BE    REQ71                   BRANCH IF YES                    44500013
         XC    XPOS(4),XPOS            ENSURE XY=0                      44600013
         B     REQ101                  BRANCH                           44700013
REQ71    TM    ATTNFLGA,EOSXY          XY READ OUT WANTED               44800013
         BC    1,REQ72                 BRANCH IF YES                    44900013
REQ73    TM    ATTNFLGA,EOSRST         RESTART WANTED                   45000013
         BC    1,REQ74                 BRANCH IF YES                    45100013
         B     REQ101                  BRANCH                           45200013
REQ72    XC    DECB(36),DECB           CLEAR I/O AREA                   45300013
         XC    XPOS(4),XPOS            CLEAR DATA AREA                  45400013
         L     RWORKC,GTMGRDCB         LOAD DCB ADR                     45500013
         LA    RWORKD,XPOS             LOAD DATA AREA ADR               45600013
         LA    REG1,DECB               LOAD ADR OF PARAM LIST           45700013
         GREADR (1),XYP,(11),(12),MF=E                                  45800013
         WAIT  ECB=(1)                                                  45900013
         BAL   REG1,IOTEST             TO TEST I/O                      45950013
         B     REQ73                   BRANCH                           46000013
REQ74    XC    DECB(36),DECB           CLEAR I/O AREA                   46100013
         LA    RWORKC,SENSE+2          LOAD RESTART ADR                 46200013
         L     RWORKD,GTMGRDCB         LOAD DCB ADR                     46300013
         LA    REG1,DECB               LOAD DECB ADR                    46400013
         GCNTRL (1),STR,(12),(11),MF=E                                  46500013
         WAIT  ECB=(1)                                                  46600013
         BAL   REG1,IOTEST             TO TEST I/O                      46650013
         B     REQ101                  BRANCH                           46700013
REQ70    SR    RWORKC,RWORKC           CLEAR REG                        46800013
         LH    RWORKC,SENSE+2          LOAD BFR ADR                     46900013
         SRL   RWORKC,DIV256           DIVIDE NUMBER BY 256             47000013
         SR    RWORKF,RWORKF           CLEAR REG                        47100013
         M     RWORKF,THREE            MULTIPLY #  BY 3  RESULT=RWORKC  47200013
         L     RWORKF,GTMBCTBL         LOAD ADR OF BCT                  47300013
         LTR   RWORKF,RWORKF           IS THERE A BFR CONTROL TBL       47400013
         BC    8,REQ79                 BRANCH IF NO                     47500013
         AR    RWORKC,RWORKF           DETERMINE ADR OF BCT ENTRY       47600013
         LR    RWORKA,RWORKC           LOAD REG                         47700013
         CLC   ZERO(1,RWORKA),ZERO1    IS AN ID ASSIGNED                47800013
         BE    REQ79                   BRANCH IF NO ID                  47900013
         CLI   ZERO(RWORKA),IDVAL      IS A FULL SEGMENT ASSIGNED       48000013
         BC    4,REQ75                 BRANCH IF A FULL SEGMENT         48100013
         SR    RWORKC,RWORKC           CLEAR REG                        48200013
         SR    RWORKF,RWORKF           CLEAR REG                        48300013
         LH    RWORKC,SENSE+2          LOAD DIVIDEND                    48400013
         D     RWORKF,DIV256A          DIVIDE BY 256 RWORKF=REMAINDER   48500013
         CL    RWORKF,SUBSEG           UPPER OR LOWER HALF              48600013
         BC    4,REQ76                 BRANCH LOWER SEGMENT             48700013
         CLI   ZERO+ONE(RWORKA),IDVAL  SUB SEG ASSIGNED                 48800013
         BE    REQ79                   BRANCH IF NO                     48900013
         MVC   IDBYTE(1),ONE(RWORKA)   SAVE ID                          49000013
         B     REG755                                              7172 49100017
REQ76    CLI   ZERO(RWORKA),IDVAL      SUB REG ASSIGNED                 49200013
         BE    REQ79                   BRANCH IF NO                     49300013
REQ75    MVC   IDBYTE(1),ZERO(RWORKA)  SAVE ID                          49400013
REG755   L     RGDSCB,GTMGDSCB     GET NEXT REQUEST BLOCK          7172 49450017
REQ77    CLC   GDSBCTID(1),IDBYTE      GDS=MY ID                        49500013
         BE    REQ78                   BRANCH IF YES                    49600013
REQ80    EQU   *                                                        49650013
         CLC   GDSNXGDS(4),ZERO1       ANY MORE GDS                     49700013
         BE    REQ79                   BRANCH IF NO                     49800013
         L     RGDSCB,GDSNXGDS         LOAD ADR OF NEXT GDS             49900013
         B     REQ77                   BRANCH                           50000013
REQ78    EQU   *                                                        50010013
         TM    GDSFLAGS,EQUIV          IS THIS AN EQUIVALENT GDS        50020013
         BC    14,REQ81                BRANCH-NO                        50030013
         TM    GDSFLAGS,INBFR          GDS IN BFR                       50040013
         BO    REQ81                   BRANCH-YES                       50050013
         B     REQ80                   BRANCH                           50060013
REQ81    EQU   *                                                        50070013
         TM    GDSFLAGS,PENDET         LIGHT PEN DETECT ENABLED         50130013
         BC    1,REQ700                BRANCH IF YES                    50200013
         CLC   ATTNFWPT(4),ZERO1       LEVEL ACTIVE                     50300013
         BE    REQ79                   BRANCH IF LEVEL ACTIVE           50400013
         TM    ATTNFLGA,DEQUEUE        MAY WE DEQUEUE FROM AN INACTIVE  50500013
*                                      LEVEL                            50600013
         BC    14,NTDIRECT             BRANCH IF YES                    50700013
         LR    RWORKF,REG0             RESTORE REG                      50800013
         LR    RWORKA,REG1             RESTORE REG                      50900013
         LTR   RWORKF,RWORKF           1ST ENTRY                        51000013
         BZ    REQ59A                  BRANCH IF YES                    51100013
         MVC   ZERO(4,RWORKF),ZERO(RWORKA) DEQUEUE ENTRY                51200013
         B     REQ61A                  BRANCH                           51300013
REQ59A   MVC   ATTNMLEN(4),ZERO(RWORKA) DEQUEUE ENTRY                   51400013
REQ61A   MVC   ZERO(4,RWORKA),ATTNAVAL * ADD ENTRY TO                   51500013
         ST    RWORKA,ATTNAVAL         * AVAILABLE LIST                 51600013
         B     NTDIRECT                BRANCH                           51700013
REQ79    L     RWORKD,GTMGACBA         LOAD PTR TO GSP GACB             51800013
         LA    RWORKD,GACBOFF(RWORKD)  LOAD TRUE START GACB ADR         51900013
         CLI   GACBRST(RWORKD),RSTON   LP RESTART FLAG ON               52000013
         BE    NTDIRECT                BRANCH IF YES                    52100013
         XC    DECB(32),DECB           CLEAR I/O AREA                   52200013
         LA    REG1,DECB               LOAD ADR OF DECB                 52300013
         L     RWORKC,GTMGRDCB         LOAD DCB ADR                     52400013
         LA    RWORKD,SENSE+2          LOAD RESTART ADR PTR             52500013
         GCNTRL (1),STR,(11),(12),MF=E                                  52600013
         WAIT  ECB=(1)                                                  52700013
         BAL   REG1,IOTEST             TO TEST I/O                      52750013
         B     NTDIRECT                BRANCH                           52800013
REQ700   TM    ATTNFLGA,LPCHAR         CHARACTER WANTED                 52900013
         BC    14,REQ102               BRANCH IF NO                     53000013
         CLC   ATTNFWPT(4),ZERO1       LEVEL ACTIVE                     53100013
         BNE   REQ701                  BRANCH IF NOT ACTIVE             53200013
         TM    SENSE+1,LPCHRMD         LP IN CHARACTER MODE             53300013
         BC    14,REQ701               BRANCH IF NOT CHARACTER MODE     53400013
         XC    DECB(32),DECB           CLEAR I/O AREA                   53500013
         LA    REG1,DECB               LOAD ADR OF I/O AREA             53600013
         L     RWORKF,GTMGRDCB         LOAD DCB ADR                     53700013
         LA    RWORKC,CHARACTR         LOAD ADR OF DATA AREA            53800013
         LA    RWORKD,SENSE+2          LOAD ADR OF CHARACTER            53900013
         LA    RWORKE,ONE              LOAD NUMBER OF BYTES TO READ     54000013
         GREAD (1),BUF,(10),(8),(11),(12),MF=E                          54100013
         WAIT  ECB=(1)                                                  54200013
         BAL   REG1,IOTEST             TO TEST I/O                      54250013
         TM    ATTNFLGA,LPSTART        RESTART WANTED                   54300013
         BC    14,REQ102               BRANCH IF NO                     54400013
         XC    DECB(32),DECB           CLEAR I/O AREA                   54500013
         LA    REG1,DECB               LOAD ADR OF I/O AREA             54600013
         GCNTRL (1),STR,(10),(12),MF=E                                  54700013
         WAIT  ECB=(1)                                                  54800013
         BAL   REG1,IOTEST             TO TEST I/O                      54850013
         B     REQ102                  BRANCH                           54900013
REQ701   XC    CHARACTR(1),CHARACTR    CLEAR CHARACTER BYTE             55000013
         B     REQ102                  BRANCH                           55100013
REQ102   CLC   ARRAY(4),GSPNULLV       WAS AN ARRAY SPECIFIED           55200013
         BE    REQ103                  BRANCH IF NO                     55300013
         BAL   RWORKA,LPEOS            BRANCH TO ARRAY FILL IN          55400013
REQ103   L     RWORKC,CODELOC          LOAD ADR OF CODE LOC             55500013
         MVC   ZERO(4,RWORKC),LPD      CODE 34 TO CODE LOC              55600013
         B     OUTRTN                  BRANCH                           55700013
REQ101   CLC   ARRAY(4),GSPNULLV       WAS AN ARRAY SPECIFIED           55800013
         BE    REQ104                  BRANCH IF NO                     55900013
         BAL   RWORKA,LPEOS            BRANCH TO ARRAY FILL IN          56000013
REQ104   L     RWORKC,CODELOC          LOAD ADR OF CODE LOC             56100013
         MVC   ZERO(4,RWORKC),EOSD     CODE 35 TO CODE LOC              56200013
         B     OUTRTN                  BRANCH                           56300013
REQ100   L     RWORKC,CODELOC          LOAD ADR OF CODELOC              56400013
         CLI   TYPE,PFC                PF ATTN                          56500013
         BE    REQ105                  BRANCH IF YES                    56600013
         CLI   TYPE,ENDC               END KEY ATTN                     56700013
         BE    REQ106                  BRANCH IF YES                    56800013
         CLI   TYPE,AEC                AE ATTN                          56900013
         BE    REQ107                  BRANCH IF YES                    57000013
         MVC   ZERO(4,RWORKC),CANCELD  CODE 33 TO CODELOC               57100013
         B     OUTRTN                  BRANCH                           57200013
REQ106   MVC   ZERO(4,RWORKC),END      CODE 32 TO CODELOC               57300013
         B     OUTRTN                  BRANCH                           57400013
REQ107   MVC   ZERO(4,RWORKC),AED      CODE 36 TO CODELOC               57500013
         B     OUTRTN                  BRANCH                           57600013
REQ105   CLC   ARRAY(4),GSPNULLV       ARRAY SPECIFIED                  57700013
         BE    REQ108                  BRANCH IF NO                     57800013
         L     RWORKD,ARRAY            LOAD ARRAY ADR                   57900013
         SR    RWORKF,RWORKF           CLEAR REG                        58000013
         IC    RWORKF,OVERLAY          LOAD OVERLAY VALUE               58100013
         ST    RWORKF,ZERO(RWORKD)     OVERLAY CODE TO ARRAY            58200013
REQ108   SR    RWORKF,RWORKF           CLEAR REG                        58300013
         IC    RWORKF,KEYNO            LOAD KEY #                       58400013
         LTR   RWORKF,RWORKF            IS ATTN SOURCE PFK0        RSTH 58440016
         BNE   REQ109                   NO                         RSTH 58480016
         L     RWORKF,MIN1              SET CODE TO -1 FOR PFK0    RSTH 58520016
REQ109   ST    RWORKF,ZERO(RWORKC)      KEY= TO CODELOC            RSTH 58560016
         B     OUTRTN                  BRANCH                           58600013
LPEOS    L     RWORKE,ARRAY            LOAD ARRAY ADR                   58700013
         USING ARRAYUSE,RWORKE                                          58800013
         XC    W1(40),W1               CLEAR ARRAY                      58900013
         SR    RWORKC,RWORKC           CLEAR REG                        59000013
         LH    RWORKC,SENSE+2          LOAD BFR ADR                     59100013
         SRL   RWORKC,DIV256           DIVIDE BY 256                    59200013
         SR    RWORKF,RWORKF           CLEAR REG                        59300013
         M     RWORKF,THREE            MULTIPY BY 3                     59400013
         L     RWORKF,GTMBCTBL         LOAD ADR OF BCT                  59500013
         LTR   RWORKF,RWORKF           IS THERE A BFR CONTROL TBL       59600013
         BC    8,REQ500                BRANCH IF NO                     59700013
         AR    RWORKC,RWORKF           DETERMINE ADR OF BCT ENTRY       59800013
         LR    REG1,RWORKC             SAVE ADR                         59900013
         CLC   ZERO(1,REG1),ZERO1      IS AN ID ASSIGNED                60000013
         BE    REQ500                  BRANCH-NO ID                     60100013
         CLI   ZERO(REG1),IDVAL        IS A FULL SEGMENT ASSIGNED       60200013
         BC    4,REQ200                BRANCH IF YES                    60300013
         SR    RWORKC,RWORKC           CLEAR REG                        60400013
         SR    RWORKF,RWORKF           CLEAR REG                        60500013
         LH    RWORKC,SENSE+2          LOAD DIVIDEND                    60600013
         D     RWORKF,DIV256A          DIVIDE BY 256                    60700013
         CL    RWORKF,SUBSEG           UPPER OR LOWER HALF              60800013
         BC    4,REQ201                BRANCH LOWER SEGMENT             60900013
         CLI   ZERO+ONE(REG1),IDVAL    SUB SEG ASSIGNED                 61000013
         BE    REQ500                  BRANCH IF NO                     61100013
         MVC   IDBYTE(1),ONE(REG1)     SAVE ID                          61200013
         B     REQ202                  BRANCH                           61300013
REQ201   CLI   ZERO(REG1),IDVAL        SUB SEG ASSIGNED                 61400013
         BE    REQ500                  BRANCH IF NO                     61500013
REQ200   MVC   IDBYTE(1),ZERO(REG1)    SAVE ID                          61600013
REQ202   L     RGDSCB,GTMGDSCB         LOAD ADR OF FIRST GDSCB          61700013
REQ204   CLC   GDSBCTID(1),IDBYTE      GDS=MY ID                        61800013
         BE    REQ203                  BRANCH IF YES                    61900013
REQ205   EQU   *                                                        61950013
         CLC   GDSNXGDS(4),ZERO1       ANY MORE GDS                     62000013
         BE    REQ500                  BRANCH IF NO                     62100013
         L     RGDSCB,GDSNXGDS         LOAD ADR OF NEXT GDS             62200013
         B     REQ204                  BRANCH                           62300013
REQ203   EQU   *                                                        62310013
         TM    GDSFLAGS,EQUIV          IS THIS AN EQUIVALENT GDS        62320013
         BC    14,REQ206               BRANCH-NO                        62330013
         TM    GDSFLAGS,INBFR          GDS IN BFR                       62340013
         BO    REQ206                  BRANCH-YES                       62350013
         B     REQ205                  BRANCH                           62360013
REQ206   EQU   *                                                        62370013
         ST    RGDSCB,W1               GDS ADR TO WORD 1 ARRAY          62430013
         CLI   CNT(REG1),CNTA          COUNT FLD IN BCT =FF             62500013
         BNE   REQ400                  BRANCH IF NO                     62600013
         SR    RWORKC,RWORKC           CLEAR REG                        62700013
         SR    RWORKF,RWORKF           CLEAR REG                        62800013
         IC    RWORKC,PTR(REG1)        LOAD DIVIDEND                    62900013
         SLL   RWORKC,MUL256           MULTIPLY BY 256                  63000013
         SR    RWORKF,RWORKF           CLEAR REG                        63100013
         LH    RWORKF,SENSE+2          LOAD BFR ADR                     63200013
         SR    RWORKF,RWORKC           SUBTRACT RESULT FROM BFR ADR     63300013
         LA    RWORKC,TWO              LOAD CONSTANT                    63400013
         SR    RWORKF,RWORKC           DETERMINE LOGICAL DIFFERENCE     63500013
         ST    RWORKF,LOGDIF           SAVE VALUE                       63600013
         SR    RWORKF,RWORKF           CLEAR REG                        63700013
         IC    RWORKF,PTR(REG1)        LOAD PTR FROM BCT ENTRY          63800013
         MH    RWORKF,THREE+2          MULTIPLY BY THREE                63900013
         L     REG1,GTMBCTBL           LOAD BCT ADR                     64000013
         LA    REG1,ZERO(RWORKF,REG1)  HAVE BCT START ADR FOR THIS SEG  64100013
REQ402   SR    RWORKB,RWORKB           CLEAR REG                        64200013
         LH    RWORKB,GDSGDOAL         LOAD GDOA LENGTH                 64300013
         LA    RWORKC,GDOA             LOAD CONSTANT                    64400013
         SR    RWORKB,RWORKC           ADJUST GDOA LENGTH               64500013
         SR    RWORKC,RWORKC           CLEAR REG                        64600013
         IC    RWORKC,CNT(REG1)        INSERT COUNT                     64700013
         SR    RWORKF,RWORKF           CLEAR REG                        64800013
         MR    RWORKF,RWORKB           MULTIPY VALUES                   64900013
         A     RWORKC,LOGDIF           ADD LOGICAL DIFFERENCE           65000013
         ST    RWORKC,W3               STORE RESULT IN WORD 3 OF ARRAY  65100013
         ST    RWORKC,W3A              SAVE VALUE IN WORK AREA          65150013
         B     REQ401                  BRANCH                           65200013
REQ400   LR    RWORKC,REG1             ENTRY ADR TO WORK REG            65300013
         L     RWORKD,GTMBCTBL         LOAD ADR START OF BCT            65400013
         SR    RWORKC,RWORKD           DETERMINE PTR                    65500013
         SR    RWORKF,RWORKF           CLEAR REG                        65600013
         D     RWORKF,THREE            DIVIDE # BY 3                    65700013
         SLL   RWORKC,MUL256           MULTIPY RESULT BY 256            65800013
         SR    RWORKF,RWORKF           CLEAR REG                        65900013
         LH    RWORKF,SENSE+2          LOAD  BFR ADR                    66000013
         SR    RWORKF,RWORKC           SUBTRACT RESULT FROM BFR ADR     66100013
         LA    RWORKC,TWO              LOAD CONSTANT                    66200013
         SR    RWORKF,RWORKC           DETERMINE LOGICAL DIFFERENCE     66300013
         ST    RWORKF,LOGDIF           SAVE VALUE                       66400013
         B     REQ402                  BRANCH                           66500013
REQ401   TM    GDSFLAGS,LVL2           IS THIS A LEVEL 2 GDS            66600013
         BC    1,REQ500                BRANCH IF YES                    66700013
         CLC   GDSKEYTB(4),ZERO1       IS THERE A KEY TABLE             66800013
         BE    REQ500                  BRANCH IF NO                     66900013
REQ300   L     RKEY,GDSKEYTB           LOAD ADR OF FIRST KEY TABLE      67000013
REQ302   LA    RKEYEN,FIRSENT(RKEY)    LOAD ADR OF FIRST ENTRY          67100013
REQ304   CL    RKEYEN,NEXTENTY(RKEY)   IS SLOT BEING USED               67200013
         BNE   REQ301                  BRANCH IF SLOT BEING USED        67300013
         CLC   ZERO1(4),NEXTKEY(RKEY)  ANY MORE KEY TABLES              67400013
         BE    REQ500                  BRANCH IF NO MORE KEY TABLES     67500013
         L     RKEY,NEXTKEY(RKEY)      LOAD ADR OF NEXT KEY TABLE       67600013
         B     REQ302                  BRANCH                           67700013
REQ301   SR    RWORKC,RWORKC           CLEAR REG                        67800013
         LH    RWORKC,BFRLEN(RKEYEN)   LOAD BFR LENGTH                  67900013
         AH    RWORKC,LOGSTRT(RKEYEN)  ADD LOGICAL START                68000013
         CL    RWORKC,W3A              COMPARE VALUE TO GDS OFFSET VALU 68100013
         BC    2,REQ303                BRANCH IF WORD 3 VALUE LESS      68200013
         BE    REQ308                  BRANCH IF VALUES EQUAL           68250013
REQ305   LA    RKEYEN,ENTRYLEN(RKEYEN) LOAD ADR OF NEXT KEY ENTRY       68300013
         B     REQ304                  BRANCH                           68400013
REQ303   CLC   W3A+2(2),LOGSTRT(RKEYEN) COMPARE GDS OFFSET TO LOG START 68500013
         BC    4,REQ500                BRANCH IF WORD 3 LESS            68600013
         TM    BCTFLAG(RKEYEN),ORGEN   IS THIS AN ORGEN KEY             68630013
         BO    REQ307                  BRANCH-YES                       68660013
         TM    BCTFLAG(RKEYEN),BFRSUB  IS THIS A BFR SUBRTN KEY         68700013
         BC    1,REQ305                BRANCH IF BFR SURRTN KEY         68800013
         TM    BCTFLAG(RKEYEN),SEQNCE  IS THIS A SEQUENCE KEY           68900013
         BC    1,REQ306                BRANCH IF YES                    69000013
REQ307   EQU   *                                                        69050013
         MVC   W2(4),BFRLEN(RKEYEN)    KEY TO WORD 2 OF ARRAY           69100013
         MVC   W4(4),CORVAL(RKEYEN)    CORVAL TO WORD 4 OF ARRAY        69200013
         TM    SENSE+1,LPCHRMD         LP IN CHARACTER MODE             69205013
         BC    14,REQ309               BRANCH-NOT CHARACTER MODE        69210013
         LH    RWORKC,BFRLEN(RKEYEN)   LOAD BUFFER LENGTH               69215013
         AH    RWORKC,LOGSTRT(RKEYEN)  ADD LOGICAL START                69220013
         S     RWORKC,W3A              SUBTRACT GDS OFFSET              69225013
         STH   RWORKC,CCT              SAVE VALUE                       69230013
         SR    RWORKC,RWORKC           CLEAR REG                        69235013
         IC    RWORKC,CCTB(RKEYEN)     INSERT CHARACTER COUNT           69240013
         SLL   RWORKC,CCTC             SHIFT 1ST HALF OF COUNT          69245013
         IC    RWORKC,CCTA(RKEYEN)     INSERT CHARACTER COUNT           69250013
         SH    RWORKC,CCT              SUBTRACT SAVED VALUE             69255013
         LA    RWORKC,ADD1(RWORKC)     CHANGE OFFSET TO COUNT FOR ARRAY 69260013
         ST    RWORKC,W3               STORE RESULT IN ARRAY WORD 3     69265013
         B     REQ305                  BRANCH                           69270013
REQ309   EQU   *                                                        69275013
         L     RWORKC,W3A              LOAD GDS OFFSET VALUE            69280013
         SH    RWORKC,LOGSTRT(RKEYEN)  SUBTRACT LOGICAL START           69285013
         ST    RWORKC,W3               STORE VALUE IN WORD 3 OF ARRAY   69290013
         B     REQ305                  BRANCH                           69300013
REQ308   TM    BCTFLAG(RKEYEN),HIBIT   HIGH ORDER BIT ON                69310013
         BO    REQ305                  BRANCH-YES                       69320013
         TM    BCTFLAG(RKEYEN),TOBIT   LINK TO SUBR                     69330013
         BO    REQ307                  BRANCH-YES                       69340013
         B     REQ305                  BRANCH                           69350013
REQ306   MVC   W5(4),BFRLEN(RKEYEN)    KEY TO WORD5 OF ARRAY            69400013
         MVC   W7(4),CORVAL(RKEYEN)    CORVAL TO WORD 7 OF ARRAY        69500013
         L     RWORKC,W3A              LOAD GDS OFFSET VALUE            69600013
         SH    RWORKC,LOGSTRT(RKEYEN)  SUBTRACT LOGICAL START           69700013
         ST    RWORKC,W6               STORE VALUE IN WORD 6  OF ARRAY  69800013
         B     REQ305                  BRANCH                           69900013
REQ500   CLI   TYPE,LPC                LITE PEN ATN                     70000013
         BE    REQ501                  BRANCH IF YES                    70100013
         TM    ATTNFLGA,EOSXY          XY WANTED ON EOS                 70200013
         BC    1,REQ502                BRANCH IF YES                    70300013
         BR    RWORKA                  RETURN                           70400013
REQ502   CLC   XPOS(4),ZERO1           XY VALUE ZERO                    70500013
         BNE   REQ503                  BRANCH IF NO                     70600013
         BR    RWORKA                  RETURN                           70700013
REQ503   SR    RWORKC,RWORKC           CLEAR REG                        70800013
         SR    RWORKD,RWORKD           CLEAR REG                        70900013
         XC    GDSNAME(24),GDSNAME     CLEAR PARAM LIST                 71200013
         TM    SENSE+1,X'20'      CHECK IF CHAR ATTN          LF A37965 71202021
         BO    ADJUST             IF YES, ADJUST X, Y COORDS  LF A37965 71204021
         LH    RWORKC,XPOS        IF NO, SKIP ADJUST FIX      LF A37065 71204421
         LH    RWORKD,YPOS                                    LF A37965 71204821
         ST    RWORKC,XINPUT             USE DIRECT INPUT     LF A37965 71205221
         B     OLDCODE                                        LF A37965 71205621
         EJECT                                                          71206021
* THE FOLLOWING CODE ADJUSTS THE COORDINATE VALUES RETURNED BY   A37965 71212021
* HARDWARE FOLLOWING A DETECT ONA CHARACTER TO THE CENTER OF     A37965 71218021
* CHARACTER DETECTED. HARDWARE RETURNS THE CENTER POINT OF THE   A37965 71224021
* NEXT CHARACTER GRID.                                           A37965 71230021
ADJUST   LH    RWORKC,XPOS        LOAD X FOR CHAR DETECT      LB A37965 71236021
         LA    RWORKD,BSCSPC      BASIC CHAR SPACING          LB A37965 71242021
         LA    RWORKB,BSCLINE     BASIC LINE SPACING          LB A37965 71248021
         TM    GDSCHARS,LRGSZE    CHECK GDS FOR LARGE CHARS   LB A37965 71254021
         BZ    ADJUSTX            BRANCH IF NOT LARGE CHARS   LB A37965 71260021
         LA    RWORKD,LRGSPC      LARGE CHAR SPACING          LB A37965 71266021
         LA    RWORKB,LRGLINE     LARGE LINE SPACING          LB A37965 71272021
ADJUSTX  EQU   *                                              LB A37965 71278021
         SR    RWORKC,RWORKD      X MINUS CHAR SPACE          LB A37965 71284021
         BNM   XVALID             BRANCH IF X NOW VALID       LB A37965 71290021
         LA    RWORKC,XSCREEN     X=RIGHT LIMIT OF SCREEN     LB A37965 71296021
         TM    GDSSCISS,NOSCISS   CHECK GDS FOR NO SCISSORING LB A37965 71302021
         BO    ADJUSTY            BRANCH IF NO SCISSORING     LB A37965 71308021
         SR    RWORKC,RWORKD      X=(MAX CHAR CENTER X)-SPACE LB A37965 71314021
ADJUSTY  EQU   *                                              LB A37965 71320021
         ST    RWORKC,XINPUT      X POS TO PARM LIST          LB A37965 71326021
         LH    RWORKD,YPOS        LOAD Y FOR CHAR DETECT      LB A37965 71332021
         AR    RWORKD,RWORKB      Y = Y+LINE SPACING          LB A37965 71338021
         LA    RWORKC,YSCREEN     MAX Y VALUE FOR CHAR CENTER LB A37965 71344021
         CR    RWORKD,RWORKC      COMPARE Y TO SCREEN LIMIT   LB A37965 71350021
         BNH   YVALID             BRANCH IF Y NOW VALID       LB A37965 71356021
         LA    RWORKD,YLOWER      Y = MIN Y VALUE FOR CHAR    LB A37965 71362021
         B     YVALID             GO SET UP FOR CONVERT RTN   LB A37965 71368021
XVALID   EQU   *                                              LB A37965 71374021
         ST    RWORKC,XINPUT      X POS TO PARM LIST          LB A37965 71380021
         LH    RWORKD,YPOS        LOAD Y POS                  LB A37965 71386021
YVALID   EQU   *                                              LB A37965 71392021
OLDCODE  ST    RWORKD,YINPUT           Y POS TO PARM LIST               71400021
         ST    RGDSCB,GDSNAME          ADR OF GDSCB TO PARM LIST        71500013
         LA    RWORKC,ONE              LOAD CONSTANT                    71600013
         ST    RWORKC,CONVERT          STORE IN PARM LIST               71700013
         LA    RWORKC,GDSNAME          LOAD PARM ADR                    71800013
         ST    RWORKC,P1               STORE IN PARM LIST               71900013
         LA    RWORKC,CONVERT          LOAD ADR                         72000013
         ST    RWORKC,P2               STORE IN PARM LIST               72100013
         LA    RWORKC,XINPUT           LOAD ADR                         72200013
         ST    RWORKC,P3               STORE IN PARM LIST               72300013
         LA    RWORKC,YINPUT           LOAD ADR                         72400013
         ST    RWORKC,P4               STORE IN PARM LIST               72500013
         LA    RWORKC,XOUTPUT          LOAD ADR                         72600013
         ST    RWORKC,P5               STORE IN PARM LIST               72700013
         LA    RWORKC,YOUTPUT          LOAD ADR                         72800013
         ST    RWORKC,P6               STORE IN PARM LIST               72900013
         MVI   P6,LAST                 INDICATE LAST PARM               73000013
         L     RWORKC,RCA              LOAD RTN CODE ARRAY ADR          73100013
         ST    RWORKC,RCAB             STORE IN PARM LIST               73200013
         LA    RWORKC,P1               LOAD ADR                         73300013
         ST    RWORKC,PASS             STORE IN PARM LIST               73400013
         LA    REG1,PASS               LOAD PLIST ADR                   73500013
         LR    RGDSCB,RWORKA           SAVE RETN REG                    73600013
         LINK  EP=IFFAGA08,MF=(E,(1))                                   73700013
         MVC   W8(4),XOUTPUT           X POS TO WORD 8 OF ARRAY         73800013
         MVC   W9(4),YOUTPUT           Y POS TO WORD 9 OF ARRAY         73900013
         L     RWORKC,RCA              LOAD RTN CODE ARRAY ADR          74000013
         XC    ZERO(20,RWORKC),ZERO(RWORKC) INITIALIZE ARRAY            74100013
         BR    RGDSCB                  RETURN                           74200013
REQ501   TM    ATTNFLGA,LPCHAR         CHARACTER CODE WANTED            74300013
         BC    14,REQ504               BRANCH IF NO                     74400013
         MVC   W10(1),CHARACTR         CHARACTER TO WORD 10 OF ARRAY    74500013
REQ504   TM    ATTNFLGA,LPXY           XY POS WANTED                    74600013
         BC    1,REQ503                BRANCH IF YES                    74700013
         BR    RWORKA                  RETURN                           74800013
*********************************************************************** 74900013
*                  DIRECT ENTRY GOES HERE                             * 75000013
*                                                                     * 75100013
DIRECT   B     OUTRTN                                                   75200013
*                                                                     * 75300013
*                                                                     * 75400013
*********************************************************************** 75500013
IOTEST   CLI   DECB,IOK                I/O SUCCESSFULL CODE             75510013
         BCR   8,REG1                  BRANCH IF OK                     75520013
         L     RWORKA,RCA              LOAD RTN CODE ARRAY ADR          75530013
         OI    ZERO(RWORKA),RCC5       INDICATE I/O ERROR               75540013
         B     OUTRTN                  RETURN TO CALLER                 75550013
         DS    0F                                                       75600013
ZERO1    DC    1F'0'                   ZERO                             75700013
MIN1     DC    F'-1'                                               RSTH 75750016
PRIME    DC    X'80'                   PF PRIME BIT                     75800013
         DC    AL3(0)                                                   75900013
ANSIZE   DC    A(31)                   MAX PF SIZE                      76000013
MAX      DC    A(36)                   MAX ALLOWABLE SOURCE VALUE       76100013
END      DC    A(32)                   END                              76200013
LPD      DC    A(34)                   LP                               76300013
EOSD     DC    A(35)                   EOS                              76400013
CANCELD  DC    A(33)                   CANCEL                           76500013
AED      DC    A(36)                   AE                               76600013
SCANTWO  DC    A(2)                    SCAN VALUE OF TWO                76700013
THREE    DC    A(3)                    3                                76800013
DIV256A  DC    A(256)                  256                              76900013
SUBSEG   DC    A(128)                  SUB SEGMENT SPLIT POINT          77000013
         CNOP  0,8                                                      77100013
         COPY  ATTNLEVL                                                 77200013
         COPY  GDSCB                                                    77300013
         COPY  GTMCB                                                    77400013
         COPY  GSPCB                                                    77500013
PLIST    DSECT                                                          77600013
ATNLVL   DS    1F                      ATTN LEVEL                       77700013
CODELOC  DS    1F                      CODE LOC                         77800013
SCANWAIT DS    1F                      SCAN WAIT                        77900013
ARRAY    DS    1F                      ARRAY                            78000013
ATNSRCE  DS    1F                      1ST ATTN SOURCE                  78100013
WORKAREA DSECT                                                          78200013
PARAM    DS    1F                      USER PARAM LIST ADR              78300013
RCA      DS    1F                      RETURN CODE ARRAY ADR            78400013
SAVE     DS    18F                     SAVE AREA                        78500013
DECB     DS    8F                      I/O AREA DECB                    78600013
DATA     DS    1F                      I/O DATA AREA                    78700013
GACB     DS    1F                      *                                78800013
TYPEA    DS    BL1                     *                                78900013
OPT      DS    BL1                     ATTNINQ  MACRO AREA              79000013
TYP      DS    1H                      *                                79100013
BRANCH   DS    1F                      *                                79200013
ANMASK   DS    1F                      SAVE AREA FOR ANMASK             79300013
PFMASK   DS    1F                      SAVE AREA FOR PFMASK             79400013
RSVD     DS    BL1                     RSVD                             79500013
OVERLAY  DS    BL1                     OVERLAY CODE                     79600013
KEYNO    DS    BL1                     KEY NUMBER                       79700013
TYPE     DS    BL1                     ATTN TYPE                        79800013
SENSE    DS    1F                      SENSE / MI DATA                  79900013
XPOS     DS    1H                      X POS VALUE                      80000013
YPOS     DS    1H                      Y POS VALUE                      80100013
SAVE1    DS    1F                      GACB A/N MASK SAVE AREA          80200013
SAVE2    DS    1F                      GACB P/F MASK SAVE AREA          80300013
IDBYTE   DS    BL1                     GDS ID BYTE                      80400013
CHARACTR DS    BL1                     CHARACTER BYTE                   80500013
         DS    BL1                                                      80600013
         DS    BL1                                                      80700013
LOGDIF   DS    1F                      LOGICAL DIFFERENCE               80800013
GDSNAME  DS    1F                                                       80900013
CONVERT  DS    1F                                                       81000013
XINPUT   DS    1F                                                       81100013
YINPUT   DS    1F                                                       81200013
XOUTPUT  DS    1F                                                       81300013
YOUTPUT  DS    1F                                                       81400013
P1       DS    1F                                                       81500013
P2       DS    1F                                                       81600013
P3       DS    1F                                                       81700013
P4       DS    1F                                                       81800013
P5       DS    1F                                                       81900013
P6       DS    1F                                                       82000013
         ORG   WORKAREA+216            ALIGN TO A DOUBLE WORD BOUNDRY   82100013
PASS     DS    1F                                                       82200013
RCAB     DS    1F                                                       82300013
W3A      DS    1F                                                       82330013
CCT      DS    1H                                                       82360013
         DS    0F                                                  000A 82370018
LFORM    DS    16F                                                 000A 82380018
ARRAYUSE DSECT                                                          82400013
W1       DS    1F                                                       82500013
W2       DS    1F                                                       82600013
W3       DS    1F                                                       82700013
W4       DS    1F                                                       82800013
W5       DS    1F                                                       82900013
W6       DS    1F                                                       83000013
W7       DS    1F                                                       83100013
W8       DS    1F                                                       83200013
W9       DS    1F                                                       83300013
W10      DS    1F                                                       83400013
         END                                                            83500013
