         TITLE 'IFFAEA02 - SGRAM - SET GRAPHIC MODE'                    01000013
*STATUS: CHANGE LEVEL 000                                               02000013
*                                                                       03000013
*FUNCTION/OPERATION: SETS SWITCHES IN THE GDSCB TO INDICATE MODE        04000013
*        (ABSOLUTE, INCREMENTAL, OR OPTIMIZED) OF GRAPHIC OUTPUT FOR    05000013
*        A GDS.                                                         06000013
*                                                                       07000013
*ENTRY POINTS: IFFAEA02                                                 08000013
*                                                                       09000013
*INPUT:  REGISTER 1 POINTS TO A WORKAREA. THE FIRST WORD CONTAINS THE   10000013
*        ADDRESS OF THE PARAMETER LIST.  THE SECOND CONTAINS THE        11000013
*        ADDRESS OF THE RETURN ARRAY.                                   12000013
*                                                                       13000013
*        THE FIXED-LENGTH PARAMETER LIST IS                             14000013
*     +0 A(POINTER TO THE GDSCB)                                        15000013
*                                                                       16000013
*     +4 A(GRAPHIC MODE CODE)                                           17000013
*                                                                       18000013
*OUTPUT: NONE TO USER. GDSCURMD SET AS APPROPRIATE.                     19000013
*                                                                       20000013
*EXTERNAL ROUTINES: NONE                                                21000013
*                                                                       22000013
*EXITS-NORMAL AND ERROR: VIA RETURN MACRO TO DIRECTOR                   23000013
*                                                                       24000013
*TABLES/WORKAREAS: GSP WORKAREA                                         25000013
*                                                                       26000013
*ATTRIBUTES: PROBLEM STATE, REENTRANT                                   27000013
*                                                                       28000013
IFFAEA02 CSECT                                                          29000013
         SAVE  (14,12)                                                  30000013
         BALR  GRBASE,0                                                 31000013
         USING *,GRBASE           SET CSECT ADDRESSABILITY              32000013
         L     GRWORK,0(1)        GET PARAM LIST ADDR                   33000013
         L     GRSLAVE,0(GRWORK)  GET POINTER TO GDSCB                  34000013
         L     GRGDSCB,0(GRSLAVE) GET GDSCB ADDR                        35000013
         USING GDSCB,GRGDSCB      SET GDSCB DSECT ADDRESSABILITY        36000013
         L     GRGSPCB,4(1)            GET ADDRESS OF GSPARRAY          37000013
         USING GSPARRAY,GRGSPCB        RETURN ARRAY AND NULL VARIABLE   38000013
*                                      ADDRESSABILITY                   39000013
         MVI   GSPARRAY,X'00'     INDICATE SUCCESSFUL COMPLETION        40000013
         C     GRGDSCB,GDSGDSCB        IS DATA SET NAME VALID           41000013
         BNE   GRBADGDS           NO                                    42000013
         L     GRTASK,4(GRWORK)   GET GMODE ADDR                        43000013
         L     GRTASK,0(GRTASK)        GET CODE                         44000013
         CH    GRTASK,GR3         TEST FOR MODE OPTION                  45000013
         BNE   GRTST2                                                   46000013
         MVI   GDSCURMD,X'01'     SET GRAPHIC MODE - INCREMENTAL        47000013
         B     GRRETRN                                                  48000013
GRTST2   CH    GRTASK,GR2         TEST FOR MODE OPTION                  49000013
         BNE   GRTST1                                                   50000013
         MVI   GDSCURMD,X'02'     SET GRAPHIC MODE - ABSOLUTE           51000013
         B     GRRETRN                                                  52000013
GRTST1   CH    GRTASK,GR1         TEST FOR MODE OPTION                  53000013
         BNE   GRPRMERR                                                 54000013
         MVI   GDSCURMD,X'04'     SET GRAPHIC MODE - OPTIMIZED          55000013
         B     GRRETRN                                                  56000013
GRBADGDS MVI   GSPARRAY,X'08'     INDICATE PARAM ERROR                  57000013
         MVC   GSPARRAY+16(4),GR1      GDSCB NOT OPENED                 58000013
         B     GRRETRN                                                  59000013
GRPRMERR MVI   GSPARRAY,X'08'     INDICATE PARAM ERROR                  60000013
         MVC   GSPARRAY+16(4),GR2      INVALID CODE                     61000013
GRRETRN  L     GRWORK,GDSGTMCB         GET ADDRESS OF GTMCB             62000013
         USING GTMCB,GRWORK                                             63000013
         TM    GDSCURMD,GRINCR         IF ONLY ABSOLUTE ORDERS USED,    64000013
         BZ    GRRETRNA                THEN RETURN                      65000013
         TM    GTMFEATS,GRMOD3         IS A MOD 3 AVAILABLE,            66000013
         BO    GRRETRNA                YES, INCREMENTAL ORDERS O.K.     67000013
         TM    GTMFEATS,GRMOD1         IS DEVICE A MOD 1                68000013
         BZ    GRRETRNB                NO, FORCE TO ABSOLUTE ORDERS     69000013
         TM    GTMFEATS+1,GRGDF        DOES IT HAVE GDF                 70000013
         BO    GRRETRNA                YES, INCREMENTAL ORDERS O.K.     71000013
GRRETRNB MVI   GDSCURMD,GRABS          NO, FORCE TO ABSOLUTE            72000013
GRRETRNA RETURN (14,12),T                                               73000013
GR3      DC    H'3'                                                     74000013
GR2      DC    H'2'                                                     75000013
GR1      DC    H'1'                                                     76000013
GRBASE   EQU   9                                                        77000013
GRGSPCB  EQU   6                                                        78000013
GRGDSCB  EQU   8                                                        79000013
GRWORK   EQU   2                                                        80000013
GRTASK   EQU   3                                                        81000013
GRSLAVE  EQU   4                                                        82000013
GRMOD1   EQU   X'01'                                                    83000013
GRMOD3   EQU   X'03'                                                    84000013
GRGDF    EQU   X'04'                                                    85000013
GRABS    EQU   X'02'                                                    86000013
GRINCR   EQU   X'05'                                                    87000013
         COPY  GDSCB                                                    88000013
         COPY  GTMCB                                                    89000013
         COPY  GSPCB                                                    90000013
         END                                                            91000013
