         TITLE 'IFFAEA07 - CHAM - SET CHARACTER MODE'                   00060013
*STATUS:  CHANGE LEVEL 000                                              00120013
*                                                                       00180013
*FUNCTION/OPERATIONS: SETS GDSCHARS IN THE GDSCB TO INCIDATE THE        00240013
*        CHARACTER SIZE (BASIC OR LARGE) AND TYPE (PROTECTED OR         00300013
*        UNPROTECTED) SELECTED BY THE USER.                             00360013
*                                                                       00420013
*ENTRY POINTS: IFFAEA07                                                 00480013
*                                                                       00540013
*INPUT:  REGISTER 1 CONTAINS THE ADDRESS OF A WORKAREA. THE FIRST WORD  00600013
*        CONTAINS THE ADDRESS OF THE PARAMETER LIST, AND THE SECOND,    00660013
*        THAT OF THE RETURN ARRAY.                                      00720013
*                                                                       00780013
*        THE PARAMETER LIST IS                                          00840013
*     +0 A(POINTER TO THE GDSCB)                                        00900013
*                                                                       00960013
*     +4 A(OPTION CODE)                                                 01020013
*                                                                       01080013
*OUTPUT:  NONE TO USER. GDSCHARS IN THE GDSCB IS SET APPROPRIATELY.     01140013
*                                                                       01200013
*EXTERNAL ROUTINES: NONE                                                01260013
*                                                                       01320013
*EXITS-NORMAL AND ERROR: VIA RETURN MACRO TO THE DIRECTOR               01380013
*                                                                       01440013
*TABLES/WORKAREAS: GSP WORKAREA                                         01500013
*                                                                       01560013
*ATTRIBUTES: PROBLEM STATE, REENTRANT.                                  01620013
*                                                                       01680013
IFFAEA07 CSECT                                                          01740013
         SAVE  (14,12)                                                  02000013
         BALR  CHBASE,0                                                 03000013
         USING *,CHBASE           SET CSECT ADDRESSABILITY              04000013
         L     CHWORK,0(1)        GET PARAM LIST ADDR                   05000013
         L     CHSLAVE,0(CHWORK)  GET POINTER TO GDSCB                  06000013
         L     CHGDSCB,0(CHSLAVE) GET GDSCB ADDR                        07000013
         USING GDSCB,CHGDSCB      SET GDSCB DSECT ADDRESSSABILITY       08000013
         L     CHGSPCB,4(1)            GET ADDRESS OF GSPARRAY          09000013
         USING GSPARRAY,CHGSPCB        ADDRESSABILITY FOR RETURN ARRAY  10000013
*                                      AND THE NULL VARIABLE            11000013
         MVI   GSPARRAY,X'00'     INDICATE SUCCESSFUL COMPLETION        12000013
         C     CHGDSCB,GDSGDSCB        IS DATA SET NAME VALID           13000013
         BNE   CHBADGDS           NO                                    14000013
         L     CHTASK,4(CHWORK)   GET CODE ADDR                         15000013
         L     CHTASK,0(CHTASK)        GET CODE                         16000013
         CH    CHTASK,CH4         TEST FOR MODE OPTION                  17000013
         BNE   CHTST3                                                   18000013
         MVI   GDSCHARS,X'01'     SET CHAR MODE - LARGE, UNPROTECTED    19000013
         B     CHRETRN                                                  20000013
CHTST3   CH    CHTASK,CH3         TEST FOR MODE OPTION                  21000013
         BNE   CHTST2                                                   22000013
         MVI   GDSCHARS,X'02'     SET CHAR MODE - BASIC, UNPROTECTED    23000013
         B     CHRETRN                                                  24000013
CHTST2   CH    CHTASK,CH2         TEST FOR MODE OPTION                  25000013
         BNE   CHTST1                                                   26000013
         MVI   GDSCHARS,X'04'     SET CHAR MODE - LARGE, PROTECTED      27000013
         B     CHRETRN                                                  28000013
CHTST1   CH    CHTASK,CH1         TEST FOR MODE OPTION                  29000013
         BNE   CHPRMERR                                                 30000013
         MVI   GDSCHARS,X'08'     SET CHAR MODE - BASIC PROTECTED       31000013
         B     CHRETRN                                                  32000013
CHBADGDS MVI   GSPARRAY,X'08'     INDICATE PARAM ERROR                  33000013
         MVC   GSPARRAY+16(4),CH1      GDSCB NOT OPEN                   34000013
         B     CHRETRN                                                  35000013
CHPRMERR MVI   GSPARRAY,X'08'     INDICATE PARAM ERROR                  36000013
         MVC   GSPARRAY+16(4),CH2      INVALID CODE                     37000013
CHRETRN  RETURN (14,12),T                                               38000013
CH4      DC    H'4'                                                     39000013
CH3      DC    H'3'                                                     40000013
CH2      DC    H'2'                                                     41000013
CH1      DC    H'1'                                                     42000013
CHBASE   EQU   9                                                        43000013
CHGSPCB  EQU   6                                                        44000013
CHWORK   EQU   2                                                        45000013
CHTASK   EQU   3                                                        46000013
CHSLAVE EQU 4                                                           47000013
CHGDSCB  EQU   8                                                        48000013
         COPY  GDSCB                                                    49000013
         COPY  GSPCB                                                    50000013
         END                                                            51000013
